source: branches/generic-class-file/abcl/src/org/armedbear/lisp/jvm-class-file.lisp @ 12863

Last change on this file since 12863 was 12863, checked in by ehuelsmann, 12 years ago

Implement CONSTANT-VALUE-ATTRIBUTE, CHECKED-EXCEPTIONS-ATTRIBUTE,
DEPRECATED-ATTRIBUTE and SYNTHETIC-ATTRIBUTE.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 46.3 KB
Line 
1;;; jvm-class-file.lisp
2;;;
3;;; Copyright (C) 2010 Erik Huelsmann
4;;; $Id: jvm-class-file.lisp 12863 2010-08-05 20:58:38Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package "JVM")
33
34#|
35
36The general design of the class-file writer is to have generic
37- human readable - representations of the class being generated
38during the construction and manipulation phases.
39
40After completing the creation/manipulation of the class, all its
41components will be finalized. This process translates readable
42(e.g. string) representations to indices to be stored on disc.
43
44The only thing to be done after finalization is sending the
45output to a stream ("writing").
46
47
48Finalization happens highest-level first. As an example, take a
49method with exception handlers. The exception handlers are stored
50as attributes in the class file structure. They are children of the
51method's Code attribute. In this example, the body of the Code
52attribute (the higher level) gets finalized before the attributes.
53The reason to do so is that the exceptions need to refer to labels
54(offsets) in the Code segment.
55
56
57|#
58
59
60(defun map-primitive-type (type)
61  "Maps a symbolic primitive type name to its Java string representation."
62  (case type
63    (:int        "I")
64    (:long       "J")
65    (:float      "F")
66    (:double     "D")
67    (:boolean    "Z")
68    (:char       "C")
69    (:byte       "B")
70    (:short      "S")
71    ((nil :void) "V")))
72
73
74#|
75
76The `class-name' facility helps to abstract from "this instruction takes
77a reference" and "this instruction takes a class name". We simply pass
78the class name around and the instructions themselves know which
79representation to use.
80
81|#
82
83(defstruct (class-name (:conc-name class-)
84                       (:constructor %make-class-name))
85  "Used for class identification.
86
87The caller should instantiate only one `class-name' per class, as they are
88used as class identifiers and compared using EQ.
89
90Some instructions need a class argument, others need a reference identifier.
91This class is used to abstract from the difference."
92  name-internal
93  ref
94  array-class ;; cached array class reference
95  ;; keeping a reference to the associated array class allows class
96  ;; name comparisons to be EQ: all classes should exist only once,
97  )
98
99(defun make-class-name (name)
100  "Creates a `class-name' structure for the class or interface `name'.
101
102`name' should be specified using Java representation, which is converted
103to 'internal' (JVM) representation by this function."
104  (setf name (substitute #\/ #\. name))
105  (%make-class-name :name-internal name
106                    :ref (concatenate 'string "L" name ";")))
107
108(defun class-array (class-name)
109  "Returns a class-name representing an array of `class-name'.
110For multi-dimensional arrays, call this function multiple times, using
111its own result.
112
113This function can be called multiple times on the same `class-name' without
114violating the 'only one instance' requirement: the returned value is cached
115and used on successive calls."
116  (unless (class-array-class class-name)
117    ;; Alessio Stalla found by dumping a class file that the JVM uses
118    ;; the same representation (ie '[L<class-name>;') in CHECKCAST as
119    ;; it does in field references, meaning the class name and class ref
120    ;; are identified by the same string
121    (let ((name-and-ref (concatenate 'string "[" (class-ref class-name))))
122      (setf (class-array-class class-name)
123            (%make-class-name :name-internal name-and-ref
124                              :ref name-and-ref))))
125  (class-array-class class-name))
126
127(defmacro define-class-name (symbol java-dotted-name &optional documentation)
128  "Convenience macro to define constants for `class-name' structures,
129initialized from the `java-dotted-name'."
130  `(defconstant ,symbol (make-class-name ,java-dotted-name)
131     ,documentation))
132
133(define-class-name +java-object+ "java.lang.Object")
134(define-class-name +java-string+ "java.lang.String")
135(define-class-name +java-system+ "java.lang.System")
136(define-class-name +lisp-object+ "org.armedbear.lisp.LispObject")
137(defconstant +lisp-object-array+ (class-array +lisp-object+))
138(define-class-name +lisp-simple-string+ "org.armedbear.lisp.SimpleString")
139(define-class-name +lisp+ "org.armedbear.lisp.Lisp")
140(define-class-name +lisp-nil+ "org.armedbear.lisp.Nil")
141(define-class-name +lisp-class+ "org.armedbear.lisp.LispClass")
142(define-class-name +lisp-symbol+ "org.armedbear.lisp.Symbol")
143(define-class-name +lisp-thread+ "org.armedbear.lisp.LispThread")
144(define-class-name +lisp-closure-binding+ "org.armedbear.lisp.ClosureBinding")
145(defconstant +closure-binding-array+ (class-array +lisp-closure-binding+))
146(define-class-name +lisp-integer+ "org.armedbear.lisp.LispInteger")
147(define-class-name +lisp-fixnum+ "org.armedbear.lisp.Fixnum")
148(defconstant +lisp-fixnum-array+ (class-array +lisp-fixnum+))
149(define-class-name +lisp-bignum+ "org.armedbear.lisp.Bignum")
150(define-class-name +lisp-single-float+ "org.armedbear.lisp.SingleFloat")
151(define-class-name +lisp-double-float+ "org.armedbear.lisp.DoubleFloat")
152(define-class-name +lisp-cons+ "org.armedbear.lisp.Cons")
153(define-class-name +lisp-load+ "org.armedbear.lisp.Load")
154(define-class-name +lisp-character+ "org.armedbear.lisp.LispCharacter")
155(defconstant +lisp-character-array+ (class-array +lisp-character+))
156(define-class-name +lisp-structure-object+ "org.armedbear.lisp.StructureObject")
157(define-class-name +lisp-simple-vector+ "org.armedbear.lisp.SimpleVector")
158(define-class-name +lisp-abstract-string+ "org.armedbear.lisp.AbstractString")
159(define-class-name +lisp-abstract-vector+ "org.armedbear.lisp.AbstractVector")
160(define-class-name +lisp-abstract-bit-vector+
161    "org.armedbear.lisp.AbstractBitVector")
162(define-class-name +lisp-environment+ "org.armedbear.lisp.Environment")
163(define-class-name +lisp-special-binding+ "org.armedbear.lisp.SpecialBinding")
164(define-class-name +lisp-special-bindings-mark+
165    "org.armedbear.lisp.SpecialBindingsMark")
166(define-class-name +lisp-throw+ "org.armedbear.lisp.Throw")
167(define-class-name +lisp-return+ "org.armedbear.lisp.Return")
168(define-class-name +lisp-go+ "org.armedbear.lisp.Go")
169(define-class-name +lisp-primitive+ "org.armedbear.lisp.Primitive")
170(define-class-name +lisp-eql-hash-table+ "org.armedbear.lisp.EqlHashTable")
171(define-class-name +lisp-hash-table+ "org.armedbear.lisp.HashTable")
172(define-class-name +lisp-package+ "org.armedbear.lisp.Package")
173(define-class-name +lisp-readtable+ "org.armedbear.lisp.Readtable")
174(define-class-name +lisp-stream+ "org.armedbear.lisp.Stream")
175(define-class-name +lisp-closure+ "org.armedbear.lisp.Closure")
176(define-class-name +lisp-compiled-closure+ "org.armedbear.lisp.CompiledClosure")
177(define-class-name +lisp-closure-parameter+
178    "org.armedbear.lisp.Closure$Parameter")
179(defconstant +lisp-closure-parameter-array+
180  (class-array +lisp-closure-parameter+))
181
182#|
183
184Lisp-side descriptor representation:
185
186 - list: a list starting with a method return value, followed by
187     the argument types
188 - keyword: the primitive type associated with that keyword
189 - class-name structure instance: the class-ref value
190
191The latter two can be converted to a Java representation using
192the `internal-field-ref' function, the former is to be fed to
193`descriptor'.
194
195|#
196
197(defun internal-field-type (field-type)
198  "Returns a string containing the JVM-internal representation
199of `field-type', which should either be a symbol identifying a primitive
200type, or a `class-name' structure identifying a class or interface."
201  (if (symbolp field-type)
202      (map-primitive-type field-type)
203      (class-name-internal field-type)))
204
205(defun internal-field-ref (field-type)
206  "Returns a string containing the JVM-internal representation of a reference
207to `field-type', which should either be a symbol identifying a primitive
208type, or a `class-name' structure identifying a class or interface."
209  (if (symbolp field-type)
210      (map-primitive-type field-type)
211      (class-ref field-type)))
212
213(defun descriptor (return-type &rest argument-types)
214  "Returns a string describing the `return-type' and `argument-types'
215in JVM-internal representation."
216  (let* ((arg-strings (mapcar #'internal-field-ref argument-types))
217         (ret-string (internal-field-ref return-type))
218         (size (+ 2 (reduce #'+ arg-strings
219                            :key #'length
220                            :initial-value (length ret-string))))
221         (str (make-array size :fill-pointer 0 :element-type 'character)))
222    (with-output-to-string (s str)
223      (princ #\( s)
224      (dolist (arg-string arg-strings)
225        (princ arg-string s))
226      (princ #\) s)
227      (princ ret-string s))
228    str)
229;;  (format nil "(~{~A~})~A"
230;;          (internal-field-ref return-type))
231  )
232
233(defun descriptor-stack-effect (return-type &rest argument-types)
234  "Returns the effect on the stack position of the `argument-types' and
235`return-type' of a method call.
236
237If the method consumes an implicit `this' argument, this function does not
238take that effect into account."
239  (flet ((type-stack-effect (arg)
240           (case arg
241             ((:long :double) 2)
242             ((nil :void) 0)
243             (otherwise 1))))
244    (+ (reduce #'- argument-types
245               :key #'type-stack-effect
246               :initial-value 0)
247       (type-stack-effect return-type))))
248
249
250(defstruct pool
251  ;; `index' contains the index of the last allocated slot (0 == empty)
252  ;; "A constant pool entry is considered valid if it has
253  ;; an index greater than 0 (zero) and less than pool-count"
254  (index 0)
255  entries-list
256  ;; the entries hash stores raw values, except in case of string and
257  ;; utf8, because both are string values
258  (entries (make-hash-table :test #'equal :size 2048 :rehash-size 2.0)))
259
260
261(defstruct constant
262  "Structure to be included in all constant sub-types."
263  tag
264  index)
265
266(defparameter +constant-type-map+
267  '((:class          7 1)
268    (:field-ref      9 1)
269    (:method-ref    10 1)
270    ;; (:interface-method-ref 11)
271    (:string         8 1)
272    (:integer        3 1)
273    (:float          4 1)
274    (:long           5 2)
275    (:double         6 2)
276    (:name-and-type 12 1)
277    (:utf8           1 1)))
278
279(defstruct (constant-class (:constructor make-constant-class (index name-index))
280                           (:include constant
281                                     (tag 7)))
282  "Structure holding information on a 'class' type item in the constant pool."
283  name-index)
284
285(defstruct (constant-member-ref (:constructor
286                                 %make-constant-member-ref
287                                     (tag index class-index name/type-index))
288                                (:include constant))
289  "Structure holding information on a member reference type item
290(a field, method or interface method reference) in the constant pool."
291  class-index
292  name/type-index)
293
294(declaim (inline make-constant-field-ref make-constant-method-ref
295                 make-constant-interface-method-ref))
296(defun make-constant-field-ref (index class-index name/type-index)
297  "Creates a `constant-member-ref' instance containing a field reference."
298  (%make-constant-member-ref 9 index class-index name/type-index))
299
300(defun make-constant-method-ref (index class-index name/type-index)
301  "Creates a `constant-member-ref' instance containing a method reference."
302  (%make-constant-member-ref 10 index class-index name/type-index))
303
304(defun make-constant-interface-method-ref (index class-index name/type-index)
305  "Creates a `constant-member-ref' instance containing an
306interface-method reference."
307  (%make-constant-member-ref 11 index class-index name/type-index))
308
309(defstruct (constant-string (:constructor
310                             make-constant-string (index value-index))
311                            (:include constant
312                                      (tag 8)))
313  "Structure holding information on a 'string' type item in the constant pool."
314  value-index)
315
316(defstruct (constant-float/int (:constructor
317                                %make-constant-float/int (tag index value))
318                               (:include constant))
319  "Structure holding information on a 'float' or 'integer' type item
320in the constant pool."
321  value)
322
323(declaim (inline make-constant-float make-constant-int))
324(defun make-constant-float (index value)
325  "Creates a `constant-float/int' structure instance containing a float."
326  (%make-constant-float/int 4 index value))
327
328(defun make-constant-int (index value)
329  "Creates a `constant-float/int' structure instance containing an int."
330  (%make-constant-float/int 3 index value))
331
332(defstruct (constant-double/long (:constructor
333                                  %make-constant-double/long (tag index value))
334                                 (:include constant))
335  "Structure holding information on a 'double' or 'long' type item
336in the constant pool."
337  value)
338
339(declaim (inline make-constant-double make-constant-float))
340(defun make-constant-double (index value)
341  "Creates a `constant-double/long' structure instance containing a double."
342  (%make-constant-double/long 6 index value))
343
344(defun make-constant-long (index value)
345  "Creates a `constant-double/long' structure instance containing a long."
346  (%make-constant-double/long 5 index value))
347
348(defstruct (constant-name/type (:constructor
349                                make-constant-name/type (index
350                                                         name-index
351                                                         descriptor-index))
352                               (:include constant
353                                         (tag 12)))
354  "Structure holding information on a 'name-and-type' type item in the
355constant pool; this type of element is used by 'member-ref' type items."
356  name-index
357  descriptor-index)
358
359(defstruct (constant-utf8 (:constructor make-constant-utf8 (index value))
360                          (:include constant
361                                    (tag 1)))
362  "Structure holding information on a 'utf8' type item in the constant pool;
363
364This type of item is used for text representation of identifiers
365and string contents."
366  value)
367
368
369(defun pool-add-class (pool class)
370  "Returns the index of the constant-pool class item for `class'.
371
372`class' must be an instance of `class-name'."
373  (let ((entry (gethash class (pool-entries pool))))
374    (unless entry
375      (let ((utf8 (pool-add-utf8 pool (class-name-internal class))))
376        (setf entry
377              (make-constant-class (incf (pool-index pool)) utf8)
378              (gethash class (pool-entries pool)) entry))
379      (push entry (pool-entries-list pool)))
380    (constant-index entry)))
381
382(defun pool-add-field-ref (pool class name type)
383  "Returns the index of the constant-pool item which denotes a reference
384to the `name' field of the `class', being of `type'.
385
386`class' should be an instance of `class-name'.
387`name' is a string.
388`type' is a field-type (see `internal-field-type')"
389  (let ((entry (gethash (acons name type class) (pool-entries pool))))
390    (unless entry
391      (let ((c (pool-add-class pool class))
392            (n/t (pool-add-name/type pool name type)))
393        (setf entry (make-constant-field-ref (incf (pool-index pool)) c n/t)
394            (gethash (acons name type class) (pool-entries pool)) entry))
395      (push entry (pool-entries-list pool)))
396    (constant-index entry)))
397
398(defun pool-add-method-ref (pool class name type)
399  "Returns the index of the constant-pool item which denotes a reference
400to the method with `name' in `class', which is of `type'.
401
402Here, `type' is a method descriptor, which defines the argument types
403and return type. `class' is an instance of `class-name'."
404  (let ((entry (gethash (acons name type class) (pool-entries pool))))
405    (unless entry
406      (let ((c (pool-add-class pool class))
407            (n/t (pool-add-name/type pool name type)))
408        (setf entry (make-constant-method-ref (incf (pool-index pool)) c n/t)
409              (gethash (acons name type class) (pool-entries pool)) entry))
410      (push entry (pool-entries-list pool)))
411    (constant-index entry)))
412
413(defun pool-add-interface-method-ref (pool class name type)
414  "Returns the index of the constant-pool item which denotes a reference to
415the method `name' in the interface `class', which is of `type'.
416
417See `pool-add-method-ref' for remarks."
418  (let ((entry (gethash (acons name type class) (pool-entries pool))))
419    (unless entry
420      (let ((c (pool-add-class pool class))
421            (n/t (pool-add-name/type pool name type)))
422        (setf entry
423            (make-constant-interface-method-ref (incf (pool-index pool)) c n/t)
424            (gethash (acons name type class) (pool-entries pool)) entry))
425      (push entry (pool-entries-list pool)))
426    (constant-index entry)))
427
428(defun pool-add-string (pool string)
429  "Returns the index of the constant-pool item denoting the string."
430  (let ((entry (gethash (cons 8 string) ;; 8 == string-tag
431                        (pool-entries pool))))
432    (unless entry
433      (let ((utf8 (pool-add-utf8 pool string)))
434        (setf entry (make-constant-string (incf (pool-index pool)) utf8)
435              (gethash (cons 8 string) (pool-entries pool)) entry))
436      (push entry (pool-entries-list pool)))
437    (constant-index entry)))
438
439(defun pool-add-int (pool int)
440  "Returns the index of the constant-pool item denoting the int."
441  (let ((entry (gethash (cons 3 int) (pool-entries pool))))
442    (unless entry
443      (setf entry (make-constant-int (incf (pool-index pool)) int)
444            (gethash (cons 3 int) (pool-entries pool)) entry)
445      (push entry (pool-entries-list pool)))
446    (constant-index entry)))
447
448(defun pool-add-float (pool float)
449  "Returns the index of the constant-pool item denoting the float."
450  (let ((entry (gethash (cons 4 float) (pool-entries pool))))
451    (unless entry
452      (setf entry (make-constant-float (incf (pool-index pool)) float)
453            (gethash (cons 4 float) (pool-entries pool)) entry)
454      (push entry (pool-entries-list pool)))
455    (constant-index entry)))
456
457(defun pool-add-long (pool long)
458  "Returns the index of the constant-pool item denoting the long."
459  (let ((entry (gethash (cons 5 long) (pool-entries pool))))
460    (unless entry
461      (setf entry (make-constant-long (incf (pool-index pool)) long)
462            (gethash (cons 5 long) (pool-entries pool)) entry)
463      (push entry (pool-entries-list pool))
464      (incf (pool-index pool))) ;; double index increase; long takes 2 slots
465    (constant-index entry)))
466
467(defun pool-add-double (pool double)
468  "Returns the index of the constant-pool item denoting the double."
469  (let ((entry (gethash (cons 6 double) (pool-entries pool))))
470    (unless entry
471      (setf entry (make-constant-double (incf (pool-index pool)) double)
472            (gethash (cons 6 double) (pool-entries pool)) entry)
473      (push entry (pool-entries-list pool))
474      (incf (pool-index pool))) ;; double index increase; 'double' takes 2 slots
475    (constant-index entry)))
476
477(defun pool-add-name/type (pool name type)
478  "Returns the index of the constant-pool item denoting
479the name/type identifier."
480  (let ((entry (gethash (cons name type) (pool-entries pool)))
481        (internal-type (if (listp type)
482                           (apply #'descriptor type)
483                           (internal-field-ref type))))
484    (unless entry
485      (let ((n (pool-add-utf8 pool name))
486            (i-t (pool-add-utf8 pool internal-type)))
487        (setf entry (make-constant-name/type (incf (pool-index pool)) n i-t)
488              (gethash (cons name type) (pool-entries pool)) entry))
489      (push entry (pool-entries-list pool)))
490    (constant-index entry)))
491
492(defun pool-add-utf8 (pool utf8-as-string)
493  "Returns the index of the textual value that will be stored in the
494class file as UTF-8 encoded data."
495  (let ((entry (gethash (cons 11 utf8-as-string) ;; 11 == utf8
496                        (pool-entries pool))))
497    (unless entry
498      (setf entry (make-constant-utf8 (incf (pool-index pool)) utf8-as-string)
499            (gethash (cons 11 utf8-as-string) (pool-entries pool)) entry)
500      (push entry (pool-entries-list pool)))
501    (constant-index entry)))
502
503(defstruct (class-file (:constructor
504                        !make-class-file (class superclass access-flags)))
505  "Holds the components of a class file."
506  (constants (make-pool))
507  access-flags
508  class
509  superclass
510  ;; support for implementing interfaces not yet available
511  ;; interfaces
512  fields
513  methods
514  attributes)
515
516(defun class-add-field (class field)
517  "Adds a `field' created by `make-field'."
518  (push field (class-file-fields class)))
519
520(defun class-field (class name)
521  "Finds a field by name." ;; ### strictly speaking, a field is uniquely
522  ;; identified by its name and type, not by the name alone.
523  (find name (class-file-fields class)
524        :test #'string= :key #'field-name))
525
526(defun class-add-method (class method)
527  "Adds a `method' to `class'; the method must have been created using
528`make-method'."
529  (push method (class-file-methods class)))
530
531(defun class-methods-by-name (class name)
532  "Returns all methods which have `name'."
533  (remove name (class-file-methods class)
534          :test-not #'string= :key #'method-name))
535
536(defun class-method (class name return &rest args)
537  "Return the method which is (uniquely) identified by its name AND descriptor."
538  (let ((return-and-args (cons return args)))
539    (find-if #'(lambda (c)
540                 (and (string= (method-name c) name)
541                      (equal (method-descriptor c) return-and-args)))
542             (class-file-methods class))))
543
544(defun class-add-attribute (class attribute)
545  "Adds `attribute' to the class; attributes must be instances of
546structure classes which include the `attribute' structure class."
547  (push attribute (class-file-attributes class)))
548
549(defun class-attribute (class name)
550  "Returns the attribute which is named `name'."
551  (find name (class-file-attributes class)
552        :test #'string= :key #'attribute-name))
553
554
555(defun finalize-class-file (class)
556  "Transforms the representation of the class-file from one
557which allows easy modification to one which works best for serialization.
558
559The class can't be modified after finalization."
560
561  ;; constant pool contains constants finalized on addition;
562  ;; no need for additional finalization
563
564  (setf (class-file-access-flags class)
565        (map-flags (class-file-access-flags class)))
566  (setf (class-file-superclass class)
567        (pool-add-class (class-file-constants class)
568                        (class-file-superclass class))
569        (class-file-class class)
570        (pool-add-class (class-file-constants class)
571                        (class-file-class class)))
572  ;;  (finalize-interfaces)
573  (dolist (field (class-file-fields class))
574    (finalize-field field class))
575  (dolist (method (class-file-methods class))
576    (finalize-method method class))
577  ;; top-level attributes (no parent attributes to refer to)
578  (finalize-attributes (class-file-attributes class) nil class))
579
580(defun !write-class-file (class stream)
581  "Serializes `class' to `stream', after it has been finalized."
582
583  ;; header
584  (write-u4 #xCAFEBABE stream)
585  (write-u2 3 stream)
586  (write-u2 45 stream)
587
588   ;; constants pool
589  (write-constants (class-file-constants class) stream)
590  ;; flags
591  (write-u2  (class-file-access-flags class) stream)
592  ;; class name
593
594  (write-u2 (class-file-class class) stream)
595  ;; superclass
596  (write-u2 (class-file-superclass class) stream)
597
598  ;; interfaces
599  (write-u2 0 stream)
600
601  ;; fields
602  (write-u2 (length (class-file-fields class)) stream)
603  (dolist (field (class-file-fields class))
604    (!write-field field stream))
605
606  ;; methods
607  (write-u2 (length (class-file-methods class)) stream)
608  (dolist (method (class-file-methods class))
609    (!write-method method stream))
610
611  ;; attributes
612  (write-attributes (class-file-attributes class) stream))
613
614
615(defvar *jvm-class-debug-pool* nil
616  "When bound to a non-NIL value, enables output to *standard-output*
617to allow debugging output of the constant section of the class file.")
618
619(defun write-constants (constants stream)
620  "Writes the constant section given in `constants' to the class file `stream'."
621  (let ((pool-index 0))
622    (write-u2 (1+ (pool-index constants)) stream)
623    (when *jvm-class-debug-pool*
624      (sys::%format t "pool count ~A~%" (pool-index constants)))
625    (dolist (entry (reverse (pool-entries-list constants)))
626      (incf pool-index)
627      (let ((tag (constant-tag entry)))
628        (when *jvm-class-debug-pool*
629          (print-constant entry t))
630        (write-u1 tag stream)
631        (case tag
632          (1                            ; UTF8
633           (write-utf8 (constant-utf8-value entry) stream))
634          ((3 4)                        ; float int
635           (write-u4 (constant-float/int-value entry) stream))
636          ((5 6)                        ; long double
637           (write-u4 (logand (ash (constant-double/long-value entry) -32)
638                             #xFFFFffff) stream)
639           (write-u4 (logand (constant-double/long-value entry) #xFFFFffff)
640                     stream))
641          ((9 10 11)           ; fieldref methodref InterfaceMethodref
642           (write-u2 (constant-member-ref-class-index entry) stream)
643           (write-u2 (constant-member-ref-name/type-index entry) stream))
644          (12                           ; nameAndType
645           (write-u2 (constant-name/type-name-index entry) stream)
646           (write-u2 (constant-name/type-descriptor-index entry) stream))
647          (7                            ; class
648           (write-u2 (constant-class-name-index entry) stream))
649          (8                            ; string
650           (write-u2 (constant-string-value-index entry) stream))
651          (t
652           (error "write-constant-pool-entry unhandled tag ~D~%" tag)))))))
653
654
655(defun print-constant (entry stream)
656  "Debugging helper to print the content of a constant-pool entry."
657  (let ((tag (constant-tag entry))
658        (index (constant-index entry)))
659    (sys::%format stream "pool element ~a, tag ~a, " index tag)
660    (case tag
661      (1     (sys::%format t "utf8: ~a~%" (constant-utf8-value entry)))
662      ((3 4) (sys::%format t "f/i: ~a~%" (constant-float/int-value entry)))
663      ((5 6) (sys::%format t "d/l: ~a~%" (constant-double/long-value entry)))
664      ((9 10 11) (sys::%format t "ref: ~a,~a~%"
665                               (constant-member-ref-class-index entry)
666                               (constant-member-ref-name/type-index entry)))
667      (12 (sys::%format t "n/t: ~a,~a~%"
668                        (constant-name/type-name-index entry)
669                        (constant-name/type-descriptor-index entry)))
670      (7 (sys::%format t "cls: ~a~%" (constant-class-name-index entry)))
671      (8 (sys::%format t "str: ~a~%" (constant-string-value-index entry))))))
672
673
674#|
675
676ABCL doesn't use interfaces, so don't implement it here at this time
677
678(defstruct interface)
679
680|#
681
682
683(defparameter +access-flags-map+
684  '((:public       #x0001)
685    (:private      #x0002)
686    (:protected    #x0004)
687    (:static       #x0008)
688    (:final        #x0010)
689    (:volatile     #x0040)
690    (:synchronized #x0020)
691    (:transient    #x0080)
692    (:native       #x0100)
693    (:abstract     #x0400)
694    (:strict       #x0800))
695  "List of keyword symbols used for human readable representation of (access)
696flags and their binary values.")
697
698(defun map-flags (flags)
699  "Calculates the bitmap of the flags from a list of symbols."
700  (reduce #'(lambda (y x)
701              (logior (or (when (member (car x) flags)
702                            (second x))
703                          0) y))
704          +access-flags-map+
705          :initial-value 0))
706
707(defstruct (field (:constructor %make-field))
708  "Holds information on the properties of fields in the class(-file)."
709  access-flags
710  name
711  descriptor
712  attributes)
713
714(defun !make-field (name type &key (flags '(:public)))
715  "Creates a field for addition to a class file."
716  (%make-field :access-flags flags
717               :name name
718               :descriptor type))
719
720(defun field-add-attribute (field attribute)
721  "Adds an attribute to a field."
722  (push attribute (field-attributes field)))
723
724(defun field-attribute (field name)
725  "Retrieves an attribute named `name' of `field'.
726
727Returns NIL if the attribute isn't found."
728  (find name (field-attributes field)
729        :test #'string= :key #'attribute-name))
730
731(defun finalize-field (field class)
732  "Prepares `field' for serialization."
733  (let ((pool (class-file-constants class)))
734    (setf (field-access-flags field)
735          (map-flags (field-access-flags field))
736          (field-descriptor field)
737          (pool-add-utf8 pool (internal-field-ref (field-descriptor field)))
738          (field-name field)
739          (pool-add-utf8 pool (field-name field))))
740  (finalize-attributes (field-attributes field) nil class))
741
742(defun !write-field (field stream)
743  "Writes classfile representation of `field' to `stream'."
744  (write-u2 (field-access-flags field) stream)
745  (write-u2 (field-name field) stream)
746  (write-u2 (field-descriptor field) stream)
747  (write-attributes (field-attributes field) stream))
748
749
750(defstruct (method (:constructor %!make-method))
751  "Holds information on the properties of methods in the class(-file)."
752  access-flags
753  name
754  descriptor
755  attributes)
756
757
758(defun map-method-name (name)
759  "Methods should be identified by strings containing their names, or,
760be one of two keyword identifiers to identify special methods:
761
762 * :class-constructor
763 * :constructor
764"
765  (cond
766    ((eq name :class-constructor)
767     "<clinit>")
768    ((eq name :constructor)
769     "<init>")
770    (t name)))
771
772(defun !make-method (name return args &key (flags '(:public)))
773  "Creates a method for addition to a class file."
774  (%!make-method :descriptor (cons return args)
775                :access-flags flags
776                :name name))
777
778(defun method-add-attribute (method attribute)
779  "Add `attribute' to the list of attributes of `method',
780returning `attribute'."
781  (push attribute (method-attributes method))
782  attribute)
783
784(defun method-add-code (method)
785  "Creates an (empty) 'Code' attribute for the method,
786returning the created attribute."
787  (method-add-attribute
788   method
789   (make-code-attribute (+ (length (cdr (method-descriptor method)))
790                           (if (member :static (method-access-flags method))
791                               0 1))))) ;; 1 == implicit 'this'
792
793(defun method-ensure-code (method)
794  "Ensures the existence of a 'Code' attribute for the method,
795returning the attribute."
796  (let ((code (method-attribute method "Code")))
797    (if (null code)
798        (method-add-code method)
799        code)))
800
801(defun method-attribute (method name)
802  "Returns the first attribute of `method' with `name'."
803  (find name (method-attributes method)
804        :test #'string= :key #'attribute-name))
805
806
807(defun finalize-method (method class)
808  "Prepares `method' for serialization."
809  (let ((pool (class-file-constants class)))
810    (setf (method-access-flags method)
811          (map-flags (method-access-flags method))
812          (method-descriptor method)
813          (pool-add-utf8 pool (apply #'descriptor (method-descriptor method)))
814          (method-name method)
815          (pool-add-utf8 pool (map-method-name (method-name method)))))
816  (finalize-attributes (method-attributes method) nil class))
817
818
819(defun !write-method (method stream)
820  "Write class file representation of `method' to `stream'."
821  (write-u2 (method-access-flags method) stream)
822  (write-u2 (method-name method) stream)
823  (sys::%format t "method-name: ~a~%" (method-name method))
824  (write-u2 (method-descriptor method) stream)
825  (write-attributes (method-attributes method) stream))
826
827(defstruct attribute
828  "Parent attribute structure to be included into other attributes, mainly
829to define common fields.
830
831Having common fields allows common driver code for
832finalizing and serializing attributes."
833  name
834
835  ;; not in the class file:
836  finalizer  ;; function of 3 arguments: the attribute, parent and class-file
837  writer     ;; function of 2 arguments: the attribute and the output stream
838  )
839
840(defun finalize-attributes (attributes att class)
841  "Prepare `attributes' (a list) of attribute `att' list for serialization."
842  (dolist (attribute attributes)
843    ;; assure header: make sure 'name' is in the pool
844    (setf (attribute-name attribute)
845          (pool-add-utf8 (class-file-constants class)
846                         (attribute-name attribute)))
847    ;; we're saving "root" attributes: attributes which have no parent
848    (funcall (attribute-finalizer attribute) attribute att class)))
849
850(defun write-attributes (attributes stream)
851  "Writes the `attributes' to `stream'."
852  (write-u2 (length attributes) stream)
853  (dolist (attribute attributes)
854    (write-u2 (attribute-name attribute) stream)
855    ;; set up a bulk catcher for (UNSIGNED-BYTE 8)
856    ;; since we need to know the attribute length (excluding the header)
857    (let ((local-stream (sys::%make-byte-array-output-stream)))
858      (funcall (attribute-writer attribute) attribute local-stream)
859      (let ((array (sys::%get-output-stream-array local-stream)))
860        (write-u4 (length array) stream)
861        (write-sequence array stream)))))
862
863
864
865(defstruct (code-attribute (:conc-name code-)
866                           (:include attribute
867                                     (name "Code")
868                                     (finalizer #'!finalize-code)
869                                     (writer #'!write-code))
870                           (:constructor %make-code-attribute))
871  "The attribute containing the actual JVM byte code;
872an attribute of a method."
873  max-stack
874  max-locals
875  code
876  exception-handlers
877  attributes
878
879  ;; fields not in the class file start here
880
881  ;; labels contains offsets into the code array after it's finalized
882  labels ;; an alist
883
884  current-local) ;; used for handling nested WITH-CODE-TO-METHOD blocks
885
886
887
888(defun code-label-offset (code label)
889  "Retrieves the `label' offset within a `code' attribute after the
890attribute has been finalized."
891  (cdr (assoc label (code-labels code))))
892
893(defun (setf code-label-offset) (offset code label)
894  "Sets the `label' offset within a `code' attribute after the attribute
895has been finalized."
896  (setf (code-labels code)
897        (acons label offset (code-labels code))))
898
899(defun !finalize-code (code parent class)
900  "Prepares the `code' attribute for serialization, within method `parent'."
901  (declare (ignore parent))
902  (let ((c (resolve-instructions (coerce (reverse (code-code code)) 'vector))))
903    (setf (code-max-stack code) (analyze-stack c))
904    (multiple-value-bind
905          (c labels)
906        (code-bytes c)
907      (setf (code-code code) c
908            (code-labels code) labels)))
909
910  (dolist (exception (code-exception-handlers code))
911    (setf (exception-start-pc exception)
912          (code-label-offset code (exception-start-pc exception))
913          (exception-end-pc exception)
914          (code-label-offset code (exception-end-pc exception))
915          (exception-handler-pc exception)
916          (code-label-offset code (exception-handler-pc exception))
917          (exception-catch-type exception)
918          (if (null (exception-catch-type exception))
919              0  ;; generic 'catch all' class index number
920              (pool-add-class (class-file-constants class)
921                              (exception-catch-type exception)))))
922
923  (finalize-attributes (code-attributes code) code class))
924
925(defun !write-code (code stream)
926  "Writes the attribute `code' to `stream'."
927  (sys::%format t "max-stack: ~a~%" (code-max-stack code))
928  (write-u2 (code-max-stack code) stream)
929  (sys::%format t "max-locals: ~a~%" (code-max-locals code))
930  (write-u2 (code-max-locals code) stream)
931  (let ((code-array (code-code code)))
932    (sys::%format t "length: ~a~%" (length code-array))
933    (write-u4 (length code-array) stream)
934    (dotimes (i (length code-array))
935      (write-u1 (svref code-array i) stream)))
936
937  (write-u2 (length (code-exception-handlers code)) stream)
938  (dolist (exception (reverse (code-exception-handlers code)))
939    (sys::%format t "start-pc: ~a~%" (exception-start-pc exception))
940    (write-u2 (exception-start-pc exception) stream)
941    (sys::%format t "end-pc: ~a~%" (exception-end-pc exception))
942    (write-u2 (exception-end-pc exception) stream)
943    (sys::%format t "handler-pc: ~a~%" (exception-handler-pc exception))
944    (write-u2 (exception-handler-pc exception) stream)
945    (write-u2 (exception-catch-type exception) stream))
946
947  (write-attributes (code-attributes code) stream))
948
949(defun make-code-attribute (arg-count)
950  "Creates an empty 'Code' attribute for a method which takes
951`arg-count` parameters, including the implicit `this` parameter."
952  (%make-code-attribute :max-locals arg-count))
953
954(defun code-add-attribute (code attribute)
955  "Adds `attribute' to `code', returning `attribute'."
956  (push attribute (code-attributes code))
957  attribute)
958
959(defun code-attribute (code name)
960  "Returns an attribute of `code' identified by `name'."
961  (find name (code-attributes code)
962        :test #'string= :key #'attribute-name))
963
964
965(defun code-add-exception-handler (code start end handler type)
966  "Adds an exception handler to `code' protecting the region from
967labels `start' to `end' (inclusive) from exception `type' - where
968a value of NIL indicates all types. Upon an exception of the given
969type, control is transferred to label `handler'."
970  (push (make-exception :start-pc start
971                        :end-pc end
972                        :handler-pc handler
973                        :catch-type type)
974        (code-exception-handlers code)))
975
976(defstruct exception
977  "Exception handler information.
978
979After finalization, the fields contain offsets instead of labels."
980  start-pc    ;; label target
981  end-pc      ;; label target
982  handler-pc  ;; label target
983  catch-type  ;; a string for a specific type, or NIL for all
984  )
985
986
987(defstruct (constant-value-attribute (:conc-name constant-value-)
988                                     (:include attribute
989                                               (name "ConstantValue")
990                                               ;; finalizer
991                                               ;; writer
992                                               ))
993  "An attribute of a field of primitive type.
994
995"
996 
997  )
998
999
1000(defstruct (checked-exceptions-attribute
1001             (:conc-name checked-)
1002             (:include attribute
1003                       (name "Exceptions")
1004                       (finalizer #'finalize-checked-exceptions)
1005                       (writer #'write-checked-exceptions)))
1006  "An attribute of `code-attribute', "
1007  table ;; a list of checked classes corresponding to Java's 'throws'
1008)
1009
1010(defun finalize-checked-exceptions (checked-exceptions code class)
1011  (declare (ignorable code class))
1012
1013  "Prepare `checked-exceptions' for serialization."
1014  (setf (checked-table checked-exceptions)
1015        (mapcar #'(lambda (exception)
1016                    (pool-add-class (class-file-constants class)
1017                                    exception))
1018                (checked-table checked-exceptions))))
1019
1020(defun write-checked-exceptions (checked-exceptions stream)
1021  "Write `checked-exceptions' to `stream' in class file representation."
1022  (write-u2 (length (checked-table checked-exceptions)) stream)
1023  (dolist (exception (reverse (checked-table checked-exceptions)))
1024    (write-u2 exception stream)))
1025
1026;; Can't be used yet: serialization missing
1027(defstruct (deprecated-attribute (:include attribute
1028                                           (name "Deprecated")
1029                                           (finalizer (constantly nil))
1030                                           (writer (constantly nil))))
1031  ;; finalizer and writer need to do nothing: Deprecated attributes are empty
1032  "An attribute of a class file, field or method, indicating the element
1033to which it has been attached has been superseded.")
1034
1035(defvar *current-code-attribute* nil)
1036
1037(defun save-code-specials (code)
1038  (setf (code-code code) *code*
1039        (code-max-locals code) *registers-allocated*
1040;;        (code-exception-handlers code) *handlers*
1041        (code-current-local code) *register*))
1042
1043(defun restore-code-specials (code)
1044  (setf *code* (code-code code)
1045;;        *handlers* (code-exception-handlers code)
1046        *registers-allocated* (code-max-locals code)
1047        *register* (code-current-local code)))
1048
1049(defmacro with-code-to-method ((class-file method &key safe-nesting) &body body)
1050  (let ((m (gensym))
1051        (c (gensym)))
1052    `(progn
1053       ,@(when safe-nesting
1054           `((when *current-code-attribute*
1055               (save-code-specials *current-code-attribute*))))
1056       (let* ((,m ,method)
1057              (,c (method-ensure-code method))
1058              (*pool* (class-file-constants ,class-file))
1059              (*code* (code-code ,c))
1060              (*registers-allocated* (code-max-locals ,c))
1061              (*register* (code-current-local ,c))
1062              (*current-code-attribute* ,c))
1063         ,@body
1064         (setf (code-code ,c) *code*
1065;;               (code-exception-handlers ,c) *handlers*
1066               (code-max-locals ,c) *registers-allocated*))
1067       ,@(when safe-nesting
1068           `((when *current-code-attribute*
1069               (restore-code-specials *current-code-attribute*)))))))
1070
1071
1072(defstruct (source-file-attribute (:conc-name source-)
1073                                  (:include attribute
1074                                            (name "SourceFile")
1075                                            (finalizer #'finalize-source-file)
1076                                            (writer #'write-source-file)))
1077  "An attribute of the class file indicating which source file
1078it was compiled from."
1079  filename)
1080
1081(defun finalize-source-file (source-file code class)
1082  (declare (ignorable code class))
1083  (setf (source-filename source-file)
1084        (pool-add-utf8 (class-file-constants class)
1085                       (source-filename source-file))))
1086
1087(defun write-source-file (source-file stream)
1088  (write-u2 (source-filename source-file) stream))
1089
1090
1091(defstruct (synthetic-attribute (:include attribute
1092                                          (name "Synthetic")
1093                                          (finalizer (constantly nil))
1094                                          (writer (constantly nil))))
1095  ;; finalizer and writer need to do nothing: Synthetic attributes are empty
1096  "An attribute of a class file, field or method to mark that it wasn't
1097included in the sources - but was generated artificially.")
1098
1099
1100(defstruct (line-numbers-attribute
1101             (:conc-name line-numbers-)
1102             (:include attribute
1103                       (name "LineNumberTable")
1104                       (finalizer #'finalize-line-numbers)
1105                       (writer #'write-line-numbers)))
1106  "An attribute of `code-attribute', containing a mapping of offsets
1107within the code section to the line numbers in the source file."
1108  table ;; a list of line-number structures, in reverse order
1109  )
1110
1111(defstruct line-number
1112  start-pc  ;; a label, before finalization
1113  line)
1114
1115(defun finalize-line-numbers (line-numbers code class)
1116  (declare (ignorable code class))
1117  (dolist (line-number (line-numbers-table line-numbers))
1118    (setf (line-number-start-pc line-number)
1119          (code-label-offset code (line-number-start-pc line-number)))))
1120
1121(defun write-line-numbers (line-numbers stream)
1122  (write-u2 (length (line-numbers-table line-numbers)) stream)
1123  (dolist (line-number (reverse (line-numbers-table line-numbers)))
1124    (write-u2 (line-number-start-pc line-number) stream)
1125    (write-u2 (line-number-line line-number) stream)))
1126
1127
1128
1129(defstruct (local-variables-attribute
1130             (:conc-name local-var-)
1131             (:include attribute
1132                       (name "LocalVariableTable")
1133                       (finalizer #'finalize-local-variables)
1134                       (writer #'write-local-variables)))
1135  "An attribute of the `code-attribute', containing a table of local variable
1136names, their type and their scope of validity."
1137  table ;; a list of local-variable structures, in reverse order
1138  )
1139
1140(defstruct (local-variable (:conc-name local-))
1141  start-pc  ;; a label, before finalization
1142  length    ;; a label (at the ending position) before finalization
1143  name
1144  descriptor
1145  index ;; The index of the variable inside the block of locals
1146  )
1147
1148(defun finalize-local-variables (local-variables code class)
1149  (dolist (local-variable (local-var-table local-variables))
1150    (setf (local-start-pc local-variable)
1151          (code-label-offset code (local-start-pc local-variable))
1152          (local-length local-variable)
1153          ;; calculate 'length' from the distance between 2 labels
1154          (- (code-label-offset code (local-length local-variable))
1155             (local-start-pc local-variable))
1156          (local-name local-variable)
1157          (pool-add-utf8 (class-file-constants class)
1158                         (local-name local-variable))
1159          (local-descriptor local-variable)
1160          (pool-add-utf8 (class-file-constants class)
1161                         (local-descriptor local-variable)))))
1162
1163(defun write-local-variables (local-variables stream)
1164  (write-u2 (length (local-var-table local-variables)) stream)
1165  (dolist (local-variable (reverse (local-var-table local-variables)))
1166    (write-u2 (local-start-pc local-variable) stream)
1167    (write-u2 (local-length local-variable) stream)
1168    (write-u2 (local-name local-variable) stream)
1169    (write-u2 (local-descriptor local-variable) stream)
1170    (write-u2 (local-index local-variable) stream)))
1171
1172#|
1173
1174;; this is the minimal sequence we need to support:
1175
1176;;  create a class file structure
1177;;  add methods
1178;;  add code to the methods, switching from one method to the other
1179;;  finalize the methods, one by one
1180;;  write the class file
1181
1182to support the sequence above, we probably need to
1183be able to
1184
1185- find methods by signature
1186- find the method's code attribute
1187- add code to the code attribute
1188- finalize the code attribute contents (blocking it for further addition)
1189-
1190
1191
1192|#
1193
Note: See TracBrowser for help on using the repository browser.