source: trunk/abcl/src/org/armedbear/lisp/clos.lisp @ 12391

Last change on this file since 12391 was 12391, checked in by ehuelsmann, 11 years ago

Prevent duplicate subclasses: only push new classes

not already present in the list.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 98.0 KB
Line 
1;;; clos.lisp
2;;;
3;;; Copyright (C) 2003-2007 Peter Graves
4;;; $Id: clos.lisp 12391 2010-01-18 20:12:34Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32;;; Originally based on Closette.
33
34;;; Closette Version 1.0 (February 10, 1991)
35;;;
36;;; Copyright (c) 1990, 1991 Xerox Corporation.
37;;; All rights reserved.
38;;;
39;;; Use and copying of this software and preparation of derivative works
40;;; based upon this software are permitted.  Any distribution of this
41;;; software or derivative works must comply with all applicable United
42;;; States export control laws.
43;;;
44;;; This software is made available AS IS, and Xerox Corporation makes no
45;;; warranty about the software, its performance or its conformity to any
46;;; specification.
47;;;
48;;; Closette is an implementation of a subset of CLOS with a metaobject
49;;; protocol as described in "The Art of The Metaobject Protocol",
50;;; MIT Press, 1991.
51
52(in-package #:mop)
53
54(export '(class-precedence-list class-slots slot-definition-name))
55
56(defun class-slots (class)
57  (%class-slots class))
58
59(defun slot-definition-name (slot-definition)
60  (%slot-definition-name slot-definition))
61
62(defmacro push-on-end (value location)
63  `(setf ,location (nconc ,location (list ,value))))
64
65;;; (SETF GETF*) is like (SETF GETF) except that it always changes the list,
66;;; which must be non-nil.
67
68(defun (setf getf*) (new-value plist key)
69  (block body
70    (do ((x plist (cddr x)))
71        ((null x))
72      (when (eq (car x) key)
73        (setf (car (cdr x)) new-value)
74        (return-from body new-value)))
75    (push-on-end key plist)
76    (push-on-end new-value plist)
77    new-value))
78
79(defun mapappend (fun &rest args)
80  (if (some #'null args)
81      ()
82      (append (apply fun (mapcar #'car args))
83              (apply #'mapappend fun (mapcar #'cdr args)))))
84
85(defun mapplist (fun x)
86  (if (null x)
87      ()
88      (cons (funcall fun (car x) (cadr x))
89            (mapplist fun (cddr x)))))
90
91(defsetf class-layout %set-class-layout)
92(defsetf class-direct-superclasses %set-class-direct-superclasses)
93(defsetf class-direct-subclasses %set-class-direct-subclasses)
94(defsetf class-direct-methods %set-class-direct-methods)
95(defsetf class-direct-slots %set-class-direct-slots)
96;; (defsetf class-slots %set-class-slots)
97(defsetf class-direct-default-initargs %set-class-direct-default-initargs)
98(defsetf class-default-initargs %set-class-default-initargs)
99(defsetf class-finalized-p %set-class-finalized-p)
100(defsetf std-instance-layout %set-std-instance-layout)
101(defsetf standard-instance-access %set-standard-instance-access)
102
103(defun (setf find-class) (new-value symbol &optional errorp environment)
104  (declare (ignore errorp environment))
105  (%set-find-class symbol new-value))
106
107(defun canonicalize-direct-slots (direct-slots)
108  `(list ,@(mapcar #'canonicalize-direct-slot direct-slots)))
109
110(defun canonicalize-direct-slot (spec)
111  (if (symbolp spec)
112      `(list :name ',spec)
113      (let ((name (car spec))
114            (initfunction nil)
115            (initform nil)
116            (initargs ())
117            (type nil)
118            (allocation nil)
119            (documentation nil)
120            (readers ())
121            (writers ())
122            (other-options ()))
123        (do ((olist (cdr spec) (cddr olist)))
124            ((null olist))
125          (case (car olist)
126            (:initform
127             (when initform
128               (error 'program-error
129                      "duplicate slot option :INITFORM for slot named ~S"
130                      name))
131             (setq initfunction
132                   `(function (lambda () ,(cadr olist))))
133             (setq initform `',(cadr olist)))
134            (:initarg
135             (push-on-end (cadr olist) initargs))
136            (:allocation
137             (when allocation
138               (error 'program-error
139                      "duplicate slot option :ALLOCATION for slot named ~S"
140                      name))
141             (setf allocation (cadr olist))
142             (push-on-end (car olist) other-options)
143             (push-on-end (cadr olist) other-options))
144            (:type
145             (when type
146               (error 'program-error
147                      "duplicate slot option :TYPE for slot named ~S"
148                      name))
149             (setf type (cadr olist))) ;; FIXME type is ignored
150            (:documentation
151             (when documentation
152               (error 'program-error
153                      "duplicate slot option :DOCUMENTATION for slot named ~S"
154                      name))
155             (setf documentation (cadr olist))) ;; FIXME documentation is ignored
156            (:reader
157             (maybe-note-name-defined (cadr olist))
158             (push-on-end (cadr olist) readers))
159            (:writer
160             (maybe-note-name-defined (cadr olist))
161             (push-on-end (cadr olist) writers))
162            (:accessor
163             (maybe-note-name-defined (cadr olist))
164             (push-on-end (cadr olist) readers)
165             (push-on-end `(setf ,(cadr olist)) writers))
166            (t
167             (error 'program-error
168                    "invalid initialization argument ~S for slot named ~S"
169                    (car olist) name))))
170        `(list
171          :name ',name
172          ,@(when initfunction
173              `(:initform ,initform
174                          :initfunction ,initfunction))
175          ,@(when initargs `(:initargs ',initargs))
176          ,@(when readers `(:readers ',readers))
177          ,@(when writers `(:writers ',writers))
178          ,@other-options))))
179
180(defun maybe-note-name-defined (name)
181  (when (fboundp 'note-name-defined)
182    (note-name-defined name)))
183
184(defun canonicalize-direct-superclasses (direct-superclasses)
185  (let ((classes '()))
186    (dolist (class-specifier direct-superclasses)
187      (if (classp class-specifier)
188          (push class-specifier classes)
189          (let ((class (find-class class-specifier nil)))
190            (unless class
191              (setf class (make-forward-referenced-class class-specifier)))
192            (push class classes))))
193    (nreverse classes)))
194
195(defun canonicalize-defclass-options (options)
196  (mapappend #'canonicalize-defclass-option options))
197
198(defun canonicalize-defclass-option (option)
199  (case (car option)
200    (:metaclass
201     (list ':metaclass
202           `(find-class ',(cadr option))))
203    (:default-initargs
204     (list
205      ':direct-default-initargs
206      `(list ,@(mapappend
207                #'(lambda (x) x)
208                (mapplist
209                 #'(lambda (key value)
210                    `(',key ,(make-initfunction value)))
211                 (cdr option))))))
212    ((:documentation :report)
213     (list (car option) `',(cadr option)))
214    (t
215     (error 'program-error
216            :format-control "invalid DEFCLASS option ~S"
217            :format-arguments (list (car option))))))
218
219(defun make-initfunction (initform)
220  `(function (lambda () ,initform)))
221
222(defun make-direct-slot-definition (class &key name
223                                          (initargs ())
224                                          (initform nil)
225                                          (initfunction nil)
226                                          (readers ())
227                                          (writers ())
228                                          (allocation :instance)
229                                          &allow-other-keys)
230  (let ((slot (make-slot-definition)))
231    (set-slot-definition-name slot name)
232    (set-slot-definition-initargs slot initargs)
233    (set-slot-definition-initform slot initform)
234    (set-slot-definition-initfunction slot initfunction)
235    (set-slot-definition-readers slot readers)
236    (set-slot-definition-writers slot writers)
237    (set-slot-definition-allocation slot allocation)
238    (set-slot-definition-allocation-class slot class)
239    slot))
240
241(defun make-effective-slot-definition (&key name
242                                            (initargs ())
243                                            (initform nil)
244                                            (initfunction nil)
245                                            (allocation :instance)
246                                            (allocation-class nil)
247                                            &allow-other-keys)
248  (let ((slot (make-slot-definition)))
249    (set-slot-definition-name slot name)
250    (set-slot-definition-initargs slot initargs)
251    (set-slot-definition-initform slot initform)
252    (set-slot-definition-initfunction slot initfunction)
253    (set-slot-definition-allocation slot allocation)
254    (set-slot-definition-allocation-class slot allocation-class)
255    slot))
256
257;;; finalize-inheritance
258
259(defun std-finalize-inheritance (class)
260  (set-class-precedence-list
261   class
262   (funcall (if (eq (class-of class) (find-class 'standard-class))
263                #'std-compute-class-precedence-list
264                #'compute-class-precedence-list)
265            class))
266  (dolist (class (%class-precedence-list class))
267    (when (typep class 'forward-referenced-class)
268      (return-from std-finalize-inheritance)))
269  (set-class-slots class
270                   (funcall (if (eq (class-of class) (find-class 'standard-class))
271                                #'std-compute-slots
272                                #'compute-slots)
273                            class))
274  (let ((old-layout (class-layout class))
275        (length 0)
276        (instance-slots '())
277        (shared-slots '()))
278    (dolist (slot (%class-slots class))
279      (case (%slot-definition-allocation slot)
280        (:instance
281         (set-slot-definition-location slot length)
282         (incf length)
283         (push (%slot-definition-name slot) instance-slots))
284        (:class
285         (unless (%slot-definition-location slot)
286           (let ((allocation-class (%slot-definition-allocation-class slot)))
287             (set-slot-definition-location slot
288                                           (if (eq allocation-class class)
289                                               (cons (%slot-definition-name slot) +slot-unbound+)
290                                               (slot-location allocation-class (%slot-definition-name slot))))))
291         (push (%slot-definition-location slot) shared-slots))))
292    (when old-layout
293      ;; Redefined class: initialize added shared slots.
294      (dolist (location shared-slots)
295        (let* ((slot-name (car location))
296               (old-location (layout-slot-location old-layout slot-name)))
297          (unless old-location
298            (let* ((slot-definition (find slot-name (%class-slots class) :key #'%slot-definition-name))
299                   (initfunction (%slot-definition-initfunction slot-definition)))
300              (when initfunction
301                (setf (cdr location) (funcall initfunction))))))))
302    (setf (class-layout class)
303          (make-layout class (nreverse instance-slots) (nreverse shared-slots))))
304  (setf (class-default-initargs class) (compute-class-default-initargs class))
305  (setf (class-finalized-p class) t))
306
307;;; Class precedence lists
308
309(defun std-compute-class-precedence-list (class)
310  (let ((classes-to-order (collect-superclasses* class)))
311    (topological-sort classes-to-order
312                      (remove-duplicates
313                       (mapappend #'local-precedence-ordering
314                                  classes-to-order))
315                      #'std-tie-breaker-rule)))
316
317;;; topological-sort implements the standard algorithm for topologically
318;;; sorting an arbitrary set of elements while honoring the precedence
319;;; constraints given by a set of (X,Y) pairs that indicate that element
320;;; X must precede element Y.  The tie-breaker procedure is called when it
321;;; is necessary to choose from multiple minimal elements; both a list of
322;;; candidates and the ordering so far are provided as arguments.
323
324(defun topological-sort (elements constraints tie-breaker)
325  (let ((remaining-constraints constraints)
326        (remaining-elements elements)
327        (result ()))
328    (loop
329      (let ((minimal-elements
330             (remove-if
331              #'(lambda (class)
332                 (member class remaining-constraints
333                         :key #'cadr))
334              remaining-elements)))
335        (when (null minimal-elements)
336          (if (null remaining-elements)
337              (return-from topological-sort result)
338              (error "Inconsistent precedence graph.")))
339        (let ((choice (if (null (cdr minimal-elements))
340                          (car minimal-elements)
341                          (funcall tie-breaker
342                                   minimal-elements
343                                   result))))
344          (setq result (append result (list choice)))
345          (setq remaining-elements
346                (remove choice remaining-elements))
347          (setq remaining-constraints
348                (remove choice
349                        remaining-constraints
350                        :test #'member)))))))
351
352;;; In the event of a tie while topologically sorting class precedence lists,
353;;; the CLOS Specification says to "select the one that has a direct subclass
354;;; rightmost in the class precedence list computed so far."  The same result
355;;; is obtained by inspecting the partially constructed class precedence list
356;;; from right to left, looking for the first minimal element to show up among
357;;; the direct superclasses of the class precedence list constituent.
358;;; (There's a lemma that shows that this rule yields a unique result.)
359
360(defun std-tie-breaker-rule (minimal-elements cpl-so-far)
361  (dolist (cpl-constituent (reverse cpl-so-far))
362    (let* ((supers (class-direct-superclasses cpl-constituent))
363           (common (intersection minimal-elements supers)))
364      (when (not (null common))
365        (return-from std-tie-breaker-rule (car common))))))
366
367;;; This version of collect-superclasses* isn't bothered by cycles in the class
368;;; hierarchy, which sometimes happen by accident.
369
370(defun collect-superclasses* (class)
371  (labels ((all-superclasses-loop (seen superclasses)
372                                  (let ((to-be-processed
373                                         (set-difference superclasses seen)))
374                                    (if (null to-be-processed)
375                                        superclasses
376                                        (let ((class-to-process
377                                               (car to-be-processed)))
378                                          (all-superclasses-loop
379                                           (cons class-to-process seen)
380                                           (union (class-direct-superclasses
381                                                   class-to-process)
382                                                  superclasses)))))))
383          (all-superclasses-loop () (list class))))
384
385;;; The local precedence ordering of a class C with direct superclasses C_1,
386;;; C_2, ..., C_n is the set ((C C_1) (C_1 C_2) ...(C_n-1 C_n)).
387
388(defun local-precedence-ordering (class)
389  (mapcar #'list
390          (cons class
391                (butlast (class-direct-superclasses class)))
392          (class-direct-superclasses class)))
393
394;;; Slot inheritance
395
396(defun std-compute-slots (class)
397  (let* ((all-slots (mapappend #'class-direct-slots
398                               (%class-precedence-list class)))
399         (all-names (remove-duplicates
400                     (mapcar #'%slot-definition-name all-slots))))
401    (mapcar #'(lambda (name)
402               (funcall
403                (if (eq (class-of class) (find-class 'standard-class))
404                    #'std-compute-effective-slot-definition
405                    #'compute-effective-slot-definition)
406                class
407                (remove name all-slots
408                        :key #'%slot-definition-name
409                        :test-not #'eq)))
410            all-names)))
411
412(defun std-compute-effective-slot-definition (class direct-slots)
413  (declare (ignore class))
414  (let ((initer (find-if-not #'null direct-slots
415                             :key #'%slot-definition-initfunction)))
416    (make-effective-slot-definition
417     :name (%slot-definition-name (car direct-slots))
418     :initform (if initer
419                   (%slot-definition-initform initer)
420                   nil)
421     :initfunction (if initer
422                       (%slot-definition-initfunction initer)
423                       nil)
424     :initargs (remove-duplicates
425                (mapappend #'%slot-definition-initargs
426                           direct-slots))
427     :allocation (%slot-definition-allocation (car direct-slots))
428     :allocation-class (%slot-definition-allocation-class (car direct-slots)))))
429
430;;; Standard instance slot access
431
432;;; N.B. The location of the effective-slots slots in the class metaobject for
433;;; standard-class must be determined without making any further slot
434;;; references.
435
436(defun find-slot-definition (class slot-name)
437  (dolist (slot (%class-slots class) nil)
438    (when (eq slot-name (%slot-definition-name slot))
439      (return slot))))
440
441(defun slot-location (class slot-name)
442  (let ((slot (find-slot-definition class slot-name)))
443    (if slot
444        (%slot-definition-location slot)
445        nil)))
446
447(defun instance-slot-location (instance slot-name)
448  (let ((layout (std-instance-layout instance)))
449    (and layout (layout-slot-location layout slot-name))))
450
451(defun slot-value (object slot-name)
452  (if (eq (class-of (class-of object)) (find-class 'standard-class))
453      (std-slot-value object slot-name)
454      (slot-value-using-class (class-of object) object slot-name)))
455
456(defsetf std-slot-value set-std-slot-value)
457
458(defun %set-slot-value (object slot-name new-value)
459  (if (eq (class-of (class-of object)) (find-class 'standard-class))
460      (setf (std-slot-value object slot-name) new-value)
461      (set-slot-value-using-class new-value (class-of object)
462                                  object slot-name)))
463
464(defsetf slot-value %set-slot-value)
465
466(defun slot-boundp (object slot-name)
467  (if (eq (class-of (class-of object)) (find-class 'standard-class))
468      (std-slot-boundp object slot-name)
469      (slot-boundp-using-class (class-of object) object slot-name)))
470
471(defun std-slot-makunbound (instance slot-name)
472  (let ((location (instance-slot-location instance slot-name)))
473    (cond ((fixnump location)
474           (setf (standard-instance-access instance location) +slot-unbound+))
475          ((consp location)
476           (setf (cdr location) +slot-unbound+))
477          (t
478           (slot-missing (class-of instance) instance slot-name 'slot-makunbound))))
479  instance)
480
481(defun slot-makunbound (object slot-name)
482  (if (eq (class-of (class-of object)) (find-class 'standard-class))
483      (std-slot-makunbound object slot-name)
484      (slot-makunbound-using-class (class-of object) object slot-name)))
485
486(defun std-slot-exists-p (instance slot-name)
487  (not (null (find slot-name (%class-slots (class-of instance))
488                   :key #'%slot-definition-name))))
489
490(defun slot-exists-p (object slot-name)
491  (if (eq (class-of (class-of object)) (find-class 'standard-class))
492      (std-slot-exists-p object slot-name)
493      (slot-exists-p-using-class (class-of object) object slot-name)))
494
495(defun instance-slot-p (slot)
496  (eq (%slot-definition-allocation slot) :instance))
497
498(defun make-instance-standard-class (metaclass
499                                     &key name direct-superclasses direct-slots
500                                     direct-default-initargs
501                                     documentation
502                                     &allow-other-keys)
503  (declare (ignore metaclass))
504  (let ((class (std-allocate-instance (find-class 'standard-class))))
505    (%set-class-name class name)
506    (setf (class-direct-subclasses class) ())
507    (setf (class-direct-methods class) ())
508    (%set-class-documentation class documentation)
509    (std-after-initialization-for-classes class
510                                          :direct-superclasses direct-superclasses
511                                          :direct-slots direct-slots
512                                          :direct-default-initargs direct-default-initargs)
513    class))
514
515(defun std-after-initialization-for-classes (class
516                                             &key direct-superclasses direct-slots
517                                             direct-default-initargs
518                                             &allow-other-keys)
519  (let ((supers (or direct-superclasses
520                    (list (find-class 'standard-object)))))
521    (setf (class-direct-superclasses class) supers)
522    (dolist (superclass supers)
523      (pushnew class (class-direct-subclasses superclass))))
524  (let ((slots (mapcar #'(lambda (slot-properties)
525                          (apply #'make-direct-slot-definition class slot-properties))
526                       direct-slots)))
527    (setf (class-direct-slots class) slots)
528    (dolist (direct-slot slots)
529      (dolist (reader (%slot-definition-readers direct-slot))
530        (add-reader-method class reader (%slot-definition-name direct-slot)))
531      (dolist (writer (%slot-definition-writers direct-slot))
532        (add-writer-method class writer (%slot-definition-name direct-slot)))))
533  (setf (class-direct-default-initargs class) direct-default-initargs)
534  (funcall (if (eq (class-of class) (find-class 'standard-class))
535               #'std-finalize-inheritance
536               #'finalize-inheritance)
537           class)
538  (values))
539
540(defun canonical-slot-name (canonical-slot)
541  (getf canonical-slot :name))
542
543(defun ensure-class (name &rest all-keys &allow-other-keys)
544  ;; Check for duplicate slots.
545  (let ((slots (getf all-keys :direct-slots)))
546    (dolist (s1 slots)
547      (let ((name1 (canonical-slot-name s1)))
548        (dolist (s2 (cdr (memq s1 slots)))
549          (when (eq name1 (canonical-slot-name s2))
550            (error 'program-error "Duplicate slot ~S" name1))))))
551  ;; Check for duplicate argument names in :DEFAULT-INITARGS.
552  (let ((names ()))
553    (do* ((initargs (getf all-keys :direct-default-initargs) (cddr initargs))
554          (name (car initargs) (car initargs)))
555         ((null initargs))
556      (push name names))
557    (do* ((names names (cdr names))
558          (name (car names) (car names)))
559         ((null names))
560      (when (memq name (cdr names))
561        (error 'program-error
562               :format-control "Duplicate initialization argument name ~S in :DEFAULT-INITARGS."
563               :format-arguments (list name)))))
564  (let ((direct-superclasses (getf all-keys :direct-superclasses)))
565    (dolist (class direct-superclasses)
566      (when (typep class 'built-in-class)
567        (error "Attempt to define a subclass of a built-in-class: ~S" class))))
568  (let ((old-class (find-class name nil)))
569    (cond ((and old-class (eq name (%class-name old-class)))
570           (cond ((typep old-class 'built-in-class)
571                  (error "The symbol ~S names a built-in class." name))
572                 ((typep old-class 'forward-referenced-class)
573                  (let ((new-class (apply #'make-instance-standard-class
574                                          (find-class 'standard-class)
575                                          :name name all-keys)))
576                    (%set-find-class name new-class)
577                    (dolist (subclass (class-direct-subclasses old-class))
578                      (setf (class-direct-superclasses subclass)
579                            (substitute new-class old-class
580                                        (class-direct-superclasses subclass))))
581                    new-class))
582                 (t
583                  ;; We're redefining the class.
584                  (%make-instances-obsolete old-class)
585                  (apply #'std-after-initialization-for-classes old-class all-keys)
586                  old-class)))
587          (t
588           (let ((class (apply #'make-instance-standard-class
589                               (find-class 'standard-class)
590                               :name name all-keys)))
591             (%set-find-class name class)
592             class)))))
593
594(defmacro defclass (&whole form name direct-superclasses direct-slots &rest options)
595  (unless (>= (length form) 3)
596    (error 'program-error "Wrong number of arguments for DEFCLASS."))
597  (check-declaration-type name)
598  `(ensure-class ',name
599                 :direct-superclasses
600                 (canonicalize-direct-superclasses ',direct-superclasses)
601                 :direct-slots
602                 ,(canonicalize-direct-slots direct-slots)
603                 ,@(canonicalize-defclass-options options)))
604
605(eval-when (:compile-toplevel :load-toplevel :execute)
606  (defstruct method-combination
607    name
608    operator
609    identity-with-one-argument
610    documentation)
611
612  (defun expand-short-defcombin (whole)
613    (let* ((name (cadr whole))
614           (documentation
615            (getf (cddr whole) :documentation ""))
616           (identity-with-one-arg
617            (getf (cddr whole) :identity-with-one-argument nil))
618           (operator
619            (getf (cddr whole) :operator name)))
620      `(progn
621         (setf (get ',name 'method-combination-object)
622               (make-method-combination :name ',name
623                                        :operator ',operator
624                                        :identity-with-one-argument ',identity-with-one-arg
625                                        :documentation ',documentation))
626         ',name)))
627
628  (defun expand-long-defcombin (whole)
629    (declare (ignore whole))
630    (error "The long form of DEFINE-METHOD-COMBINATION is not implemented.")))
631
632(defmacro define-method-combination (&whole form &rest args)
633  (declare (ignore args))
634  (if (and (cddr form)
635           (listp (caddr form)))
636      (expand-long-defcombin form)
637      (expand-short-defcombin form)))
638
639(define-method-combination +      :identity-with-one-argument t)
640(define-method-combination and    :identity-with-one-argument t)
641(define-method-combination append :identity-with-one-argument nil)
642(define-method-combination list   :identity-with-one-argument nil)
643(define-method-combination max    :identity-with-one-argument t)
644(define-method-combination min    :identity-with-one-argument t)
645(define-method-combination nconc  :identity-with-one-argument t)
646(define-method-combination or     :identity-with-one-argument t)
647(define-method-combination progn  :identity-with-one-argument t)
648
649(defstruct eql-specializer
650  object)
651
652(defparameter *eql-specializer-table* (make-hash-table :test 'eql))
653
654(defun intern-eql-specializer (object)
655  (or (gethash object *eql-specializer-table*)
656      (setf (gethash object *eql-specializer-table*)
657            (make-eql-specializer :object object))))
658
659;; MOP (p. 216) specifies the following reader generic functions:
660;;   generic-function-argument-precedence-order
661;;   generic-function-declarations
662;;   generic-function-lambda-list
663;;   generic-function-method-class
664;;   generic-function-method-combination
665;;   generic-function-methods
666;;   generic-function-name
667
668(defun generic-function-lambda-list (gf)
669  (%generic-function-lambda-list gf))
670(defsetf generic-function-lambda-list %set-generic-function-lambda-list)
671
672(defun (setf generic-function-documentation) (new-value gf)
673  (set-generic-function-documentation gf new-value))
674
675(defun (setf generic-function-initial-methods) (new-value gf)
676  (set-generic-function-initial-methods gf new-value))
677
678(defun (setf generic-function-methods) (new-value gf)
679  (set-generic-function-methods gf new-value))
680
681(defun (setf generic-function-method-class) (new-value gf)
682  (set-generic-function-method-class gf new-value))
683
684(defun (setf generic-function-method-combination) (new-value gf)
685  (set-generic-function-method-combination gf new-value))
686
687(defun (setf generic-function-argument-precedence-order) (new-value gf)
688  (set-generic-function-argument-precedence-order gf new-value))
689
690(declaim (ftype (function * t) classes-to-emf-table))
691(defun classes-to-emf-table (gf)
692  (generic-function-classes-to-emf-table gf))
693
694(defun (setf classes-to-emf-table) (new-value gf)
695  (set-generic-function-classes-to-emf-table gf new-value))
696
697(defvar the-class-standard-method (find-class 'standard-method))
698
699(defun (setf method-lambda-list) (new-value method)
700  (set-method-lambda-list method new-value))
701
702(defun (setf method-qualifiers) (new-value method)
703  (set-method-qualifiers method new-value))
704
705(defun (setf method-documentation) (new-value method)
706  (set-method-documentation method new-value))
707
708;;; defgeneric
709
710(defmacro defgeneric (function-name lambda-list
711                                    &rest options-and-method-descriptions)
712  (let ((options ())
713        (methods ())
714        (documentation nil))
715    (dolist (item options-and-method-descriptions)
716      (case (car item)
717        (declare) ; FIXME
718        (:documentation
719         (when documentation
720           (error 'program-error
721                  :format-control "Documentation option was specified twice for generic function ~S."
722                  :format-arguments (list function-name)))
723         (setf documentation t)
724         (push item options))
725        (:method
726         (push
727          `(push (defmethod ,function-name ,@(cdr item))
728                 (generic-function-initial-methods (fdefinition ',function-name)))
729          methods))
730        (t
731         (push item options))))
732    (setf options (nreverse options)
733          methods (nreverse methods))
734    `(prog1
735       (%defgeneric
736        ',function-name
737        :lambda-list ',lambda-list
738        ,@(canonicalize-defgeneric-options options))
739       ,@methods)))
740
741(defun canonicalize-defgeneric-options (options)
742  (mapappend #'canonicalize-defgeneric-option options))
743
744(defun canonicalize-defgeneric-option (option)
745  (case (car option)
746    (:generic-function-class
747     (list :generic-function-class `(find-class ',(cadr option))))
748    (:method-class
749     (list :method-class `(find-class ',(cadr option))))
750    (:method-combination
751     (list :method-combination `',(cdr option)))
752    (:argument-precedence-order
753     (list :argument-precedence-order `',(cdr option)))
754    (t
755     (list `',(car option) `',(cadr option)))))
756
757;; From OpenMCL.
758(defun canonicalize-argument-precedence-order (apo req)
759  (cond ((equal apo req) nil)
760        ((not (eql (length apo) (length req)))
761         (error 'program-error
762                :format-control "Specified argument precedence order ~S does not match lambda list."
763                :format-arguments (list apo)))
764        (t (let ((res nil))
765             (dolist (arg apo (nreverse res))
766               (let ((index (position arg req)))
767                 (if (or (null index) (memq index res))
768                     (error 'program-error
769                            :format-control "Specified argument precedence order ~S does not match lambda list."
770                            :format-arguments (list apo)))
771                 (push index res)))))))
772
773(defun find-generic-function (name &optional (errorp t))
774  (let ((function (and (fboundp name) (fdefinition name))))
775    (when function
776      (when (typep function 'generic-function)
777        (return-from find-generic-function function))
778      (when (and *traced-names* (find name *traced-names* :test #'equal))
779        (setf function (untraced-function name))
780        (when (typep function 'generic-function)
781          (return-from find-generic-function function)))))
782  (if errorp
783      (error "There is no generic function named ~S." name)
784      nil))
785
786(defun lambda-lists-congruent-p (lambda-list1 lambda-list2)
787  (let* ((plist1 (analyze-lambda-list lambda-list1))
788         (args1 (getf plist1 :required-args))
789         (plist2 (analyze-lambda-list lambda-list2))
790         (args2 (getf plist2 :required-args)))
791    (= (length args1) (length args2))))
792
793(defun %defgeneric (function-name &rest all-keys)
794  (when (fboundp function-name)
795    (let ((gf (fdefinition function-name)))
796      (when (typep gf 'generic-function)
797        ;; Remove methods defined by previous DEFGENERIC forms.
798        (dolist (method (generic-function-initial-methods gf))
799          (%remove-method gf method))
800        (setf (generic-function-initial-methods gf) '()))))
801  (apply 'ensure-generic-function function-name all-keys))
802
803(defun ensure-generic-function (function-name
804                                &rest all-keys
805                                &key
806                                lambda-list
807                                (generic-function-class (find-class 'standard-generic-function))
808                                (method-class the-class-standard-method)
809                                (method-combination 'standard)
810                                (argument-precedence-order nil apo-p)
811                                documentation
812                                &allow-other-keys)
813  (when (autoloadp function-name)
814    (resolve function-name))
815  (let ((gf (find-generic-function function-name nil)))
816    (if gf
817        (progn
818          (unless (or (null (generic-function-methods gf))
819                      (lambda-lists-congruent-p lambda-list (generic-function-lambda-list gf)))
820            (error 'simple-error
821                   :format-control "The lambda list ~S is incompatible with the existing methods of ~S."
822                   :format-arguments (list lambda-list gf)))
823          (setf (generic-function-lambda-list gf) lambda-list)
824          (setf (generic-function-documentation gf) documentation)
825          (let* ((plist (analyze-lambda-list lambda-list))
826                 (required-args (getf plist ':required-args)))
827            (%set-gf-required-args gf required-args)
828            (when apo-p
829              (setf (generic-function-argument-precedence-order gf)
830                    (if argument-precedence-order
831                        (canonicalize-argument-precedence-order argument-precedence-order
832                                                                required-args)
833                        nil)))
834            (finalize-generic-function gf))
835          gf)
836        (progn
837          (when (fboundp function-name)
838            (error 'program-error
839                   :format-control "~A already names an ordinary function, macro, or special operator."
840                   :format-arguments (list function-name)))
841          (setf gf (apply (if (eq generic-function-class (find-class 'standard-generic-function))
842                              #'make-instance-standard-generic-function
843                              #'make-instance)
844                          generic-function-class
845                          :name function-name
846                          :method-class method-class
847                          :method-combination method-combination
848                          all-keys))
849          gf))))
850
851(defun initial-discriminating-function (gf args)
852  (set-funcallable-instance-function
853   gf
854   (funcall (if (eq (class-of gf) (find-class 'standard-generic-function))
855                #'std-compute-discriminating-function
856                #'compute-discriminating-function)
857            gf))
858  (apply gf args))
859
860(defun collect-eql-specializer-objects (generic-function)
861  (let ((result nil))
862    (dolist (method (generic-function-methods generic-function))
863      (dolist (specializer (%method-specializers method))
864        (when (typep specializer 'eql-specializer)
865          (pushnew (eql-specializer-object specializer)
866                   result
867                   :test 'eql))))
868    result))
869
870(defun finalize-generic-function (gf)
871  (%finalize-generic-function gf)
872  (setf (classes-to-emf-table gf) (make-hash-table :test #'equal))
873  (%init-eql-specializations gf (collect-eql-specializer-objects gf))
874  (set-funcallable-instance-function
875   gf #'(lambda (&rest args)
876          (initial-discriminating-function gf args)))
877  ;; FIXME Do we need to warn on redefinition somewhere else?
878  (let ((*warn-on-redefinition* nil))
879    (setf (fdefinition (%generic-function-name gf)) gf))
880  (values))
881
882(defun make-instance-standard-generic-function (generic-function-class
883                                                &key name lambda-list
884                                                method-class
885                                                method-combination
886                                                argument-precedence-order
887                                                documentation)
888  (declare (ignore generic-function-class))
889  (let ((gf (std-allocate-instance (find-class 'standard-generic-function))))
890    (%set-generic-function-name gf name)
891    (setf (generic-function-lambda-list gf) lambda-list)
892    (setf (generic-function-initial-methods gf) ())
893    (setf (generic-function-methods gf) ())
894    (setf (generic-function-method-class gf) method-class)
895    (setf (generic-function-method-combination gf) method-combination)
896    (setf (generic-function-documentation gf) documentation)
897    (setf (classes-to-emf-table gf) nil)
898    (let* ((plist (analyze-lambda-list (generic-function-lambda-list gf)))
899           (required-args (getf plist ':required-args)))
900      (%set-gf-required-args gf required-args)
901      (setf (generic-function-argument-precedence-order gf)
902            (if argument-precedence-order
903                (canonicalize-argument-precedence-order argument-precedence-order
904                                                        required-args)
905                nil)))
906    (finalize-generic-function gf)
907    gf))
908
909(defun canonicalize-specializers (specializers)
910  (mapcar #'canonicalize-specializer specializers))
911
912(defun canonicalize-specializer (specializer)
913  (cond ((classp specializer)
914         specializer)
915        ((eql-specializer-p specializer)
916         specializer)
917        ((symbolp specializer)
918         (find-class specializer))
919        ((and (consp specializer)
920              (eq (car specializer) 'eql))
921         (let ((object (cadr specializer)))
922           (when (and (consp object)
923                      (eq (car object) 'quote))
924             (setf object (cadr object)))
925           (intern-eql-specializer object)))
926  ((and (consp specializer)
927              (eq (car specializer) 'java:jclass))
928         (let ((class-name (cadr specializer)))
929           (when (and (consp class-name)
930                      (eq (car class-name) 'quote))
931             (setf class-name (cadr class-name)))
932           (java::%find-java-class class-name)))
933        (t
934         (error "Unknown specializer: ~S" specializer))))
935
936(defun parse-defmethod (args)
937  (let ((function-name (car args))
938        (qualifiers ())
939        (specialized-lambda-list ())
940        (body ())
941        (parse-state :qualifiers))
942    (dolist (arg (cdr args))
943      (ecase parse-state
944        (:qualifiers
945         (if (and (atom arg) (not (null arg)))
946             (push arg qualifiers)
947             (progn
948               (setf specialized-lambda-list arg)
949               (setf parse-state :body))))
950        (:body (push arg body))))
951    (setf qualifiers (nreverse qualifiers)
952          body (nreverse body))
953    (multiple-value-bind (real-body declarations documentation)
954        (parse-body body)
955      (values function-name
956              qualifiers
957              (extract-lambda-list specialized-lambda-list)
958              (extract-specializers specialized-lambda-list)
959              documentation
960              declarations
961              (list* 'block
962                     (fdefinition-block-name function-name)
963                     real-body)))))
964
965(defun required-portion (gf args)
966  (let ((number-required (length (gf-required-args gf))))
967    (when (< (length args) number-required)
968      (error 'program-error
969             :format-control "Not enough arguments for generic function ~S."
970             :format-arguments (list (%generic-function-name gf))))
971    (subseq args 0 number-required)))
972
973(defun extract-lambda-list (specialized-lambda-list)
974  (let* ((plist (analyze-lambda-list specialized-lambda-list))
975         (requireds (getf plist :required-names))
976         (rv (getf plist :rest-var))
977         (ks (getf plist :key-args))
978         (keysp (getf plist :keysp))
979         (aok (getf plist :allow-other-keys))
980         (opts (getf plist :optional-args))
981         (auxs (getf plist :auxiliary-args)))
982    `(,@requireds
983      ,@(if rv `(&rest ,rv) ())
984      ,@(if (or ks keysp aok) `(&key ,@ks) ())
985      ,@(if aok '(&allow-other-keys) ())
986      ,@(if opts `(&optional ,@opts) ())
987      ,@(if auxs `(&aux ,@auxs) ()))))
988
989(defun extract-specializers (specialized-lambda-list)
990  (let ((plist (analyze-lambda-list specialized-lambda-list)))
991    (getf plist ':specializers)))
992
993(defun get-keyword-from-arg (arg)
994  (if (listp arg)
995      (if (listp (car arg))
996          (caar arg)
997          (make-keyword (car arg)))
998      (make-keyword arg)))
999
1000(defun analyze-lambda-list (lambda-list)
1001  (let ((keys ())           ; Just the keywords
1002        (key-args ())       ; Keywords argument specs
1003        (keysp nil)         ;
1004        (required-names ()) ; Just the variable names
1005        (required-args ())  ; Variable names & specializers
1006        (specializers ())   ; Just the specializers
1007        (rest-var nil)
1008        (optionals ())
1009        (auxs ())
1010        (allow-other-keys nil)
1011        (state :parsing-required))
1012    (dolist (arg lambda-list)
1013      (if (member arg lambda-list-keywords)
1014          (ecase arg
1015            (&optional
1016             (setq state :parsing-optional))
1017            (&rest
1018             (setq state :parsing-rest))
1019            (&key
1020             (setq keysp t)
1021             (setq state :parsing-key))
1022            (&allow-other-keys
1023             (setq allow-other-keys 't))
1024            (&aux
1025             (setq state :parsing-aux)))
1026          (case state
1027            (:parsing-required
1028             (push-on-end arg required-args)
1029             (if (listp arg)
1030                 (progn (push-on-end (car arg) required-names)
1031                   (push-on-end (cadr arg) specializers))
1032                 (progn (push-on-end arg required-names)
1033                   (push-on-end 't specializers))))
1034            (:parsing-optional (push-on-end arg optionals))
1035            (:parsing-rest (setq rest-var arg))
1036            (:parsing-key
1037             (push-on-end (get-keyword-from-arg arg) keys)
1038             (push-on-end arg key-args))
1039            (:parsing-aux (push-on-end arg auxs)))))
1040    (list  :required-names required-names
1041           :required-args required-args
1042           :specializers specializers
1043           :rest-var rest-var
1044           :keywords keys
1045           :key-args key-args
1046           :keysp keysp
1047           :auxiliary-args auxs
1048           :optional-args optionals
1049           :allow-other-keys allow-other-keys)))
1050
1051#+nil
1052(defun check-method-arg-info (gf arg-info method)
1053  (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1054      (analyze-lambda-list (if (consp method)
1055                               (early-method-lambda-list method)
1056                               (method-lambda-list method)))
1057    (flet ((lose (string &rest args)
1058                 (error 'simple-program-error
1059                        :format-control "~@<attempt to add the method~2I~_~S~I~_~
1060                        to the generic function~2I~_~S;~I~_~
1061                        but ~?~:>"
1062                        :format-arguments (list method gf string args)))
1063           (comparison-description (x y)
1064                                   (if (> x y) "more" "fewer")))
1065      (let ((gf-nreq (arg-info-number-required arg-info))
1066            (gf-nopt (arg-info-number-optional arg-info))
1067            (gf-key/rest-p (arg-info-key/rest-p arg-info))
1068            (gf-keywords (arg-info-keys arg-info)))
1069        (unless (= nreq gf-nreq)
1070          (lose
1071           "the method has ~A required arguments than the generic function."
1072           (comparison-description nreq gf-nreq)))
1073        (unless (= nopt gf-nopt)
1074          (lose
1075           "the method has ~A optional arguments than the generic function."
1076           (comparison-description nopt gf-nopt)))
1077        (unless (eq (or keysp restp) gf-key/rest-p)
1078          (lose
1079           "the method and generic function differ in whether they accept~_~
1080            &REST or &KEY arguments."))
1081        (when (consp gf-keywords)
1082          (unless (or (and restp (not keysp))
1083                      allow-other-keys-p
1084                      (every (lambda (k) (memq k keywords)) gf-keywords))
1085            (lose "the method does not accept each of the &KEY arguments~2I~_~
1086            ~S."
1087                  gf-keywords)))))))
1088
1089(defun check-method-lambda-list (method-lambda-list gf-lambda-list)
1090  (let* ((gf-restp (not (null (memq '&rest gf-lambda-list))))
1091         (gf-plist (analyze-lambda-list gf-lambda-list))
1092         (gf-keysp (getf gf-plist :keysp))
1093         (gf-keywords (getf gf-plist :keywords))
1094         (method-plist (analyze-lambda-list method-lambda-list))
1095         (method-restp (not (null (memq '&rest method-lambda-list))))
1096         (method-keysp (getf method-plist :keysp))
1097         (method-keywords (getf method-plist :keywords))
1098         (method-allow-other-keys-p (getf method-plist :allow-other-keys)))
1099    (unless (= (length (getf gf-plist :required-args))
1100               (length (getf method-plist :required-args)))
1101      (error "The method has the wrong number of required arguments for the generic function."))
1102    (unless (= (length (getf gf-plist :optional-args))
1103               (length (getf method-plist :optional-args)))
1104      (error "The method has the wrong number of optional arguments for the generic function."))
1105    (unless (eq (or gf-restp gf-keysp) (or method-restp method-keysp))
1106      (error "The method and the generic function differ in whether they accept &REST or &KEY arguments."))
1107    (when (consp gf-keywords)
1108      (unless (or (and method-restp (not method-keysp))
1109                  method-allow-other-keys-p
1110                  (every (lambda (k) (memq k method-keywords)) gf-keywords))
1111        (error "The method does not accept all of the keyword arguments defined for the generic function.")))))
1112
1113(declaim (ftype (function * method) ensure-method))
1114(defun ensure-method (name &rest all-keys)
1115  (let ((method-lambda-list (getf all-keys :lambda-list))
1116        (gf (find-generic-function name nil)))
1117    (if gf
1118        (check-method-lambda-list method-lambda-list (generic-function-lambda-list gf))
1119        (setf gf (ensure-generic-function name :lambda-list method-lambda-list)))
1120    (let ((method
1121           (if (eq (generic-function-method-class gf) the-class-standard-method)
1122               (apply #'make-instance-standard-method gf all-keys)
1123               (apply #'make-instance (generic-function-method-class gf) all-keys))))
1124      (%add-method gf method)
1125      method)))
1126
1127(defun make-instance-standard-method (gf
1128                                      &key
1129                                      lambda-list
1130                                      qualifiers
1131                                      specializers
1132                                      documentation
1133                                      function
1134                                      fast-function)
1135  (declare (ignore gf))
1136  (let ((method (std-allocate-instance the-class-standard-method)))
1137    (setf (method-lambda-list method) lambda-list)
1138    (setf (method-qualifiers method) qualifiers)
1139    (%set-method-specializers method (canonicalize-specializers specializers))
1140    (setf (method-documentation method) documentation)
1141    (%set-method-generic-function method nil)
1142    (%set-method-function method function)
1143    (%set-method-fast-function method fast-function)
1144    method))
1145
1146(defun %add-method (gf method)
1147  (when (%method-generic-function method)
1148    (error 'simple-error
1149           :format-control "ADD-METHOD: ~S is a method of ~S."
1150           :format-arguments (list method (%method-generic-function method))))
1151  ;; Remove existing method with same qualifiers and specializers (if any).
1152  (let ((old-method (%find-method gf (method-qualifiers method)
1153                                 (%method-specializers method) nil)))
1154    (when old-method
1155      (%remove-method gf old-method)))
1156  (%set-method-generic-function method gf)
1157  (push method (generic-function-methods gf))
1158  (dolist (specializer (%method-specializers method))
1159    (when (typep specializer 'class) ;; FIXME What about EQL specializer objects?
1160      (pushnew method (class-direct-methods specializer))))
1161  (finalize-generic-function gf)
1162  gf)
1163
1164(defun %remove-method (gf method)
1165  (setf (generic-function-methods gf)
1166        (remove method (generic-function-methods gf)))
1167  (%set-method-generic-function method nil)
1168  (dolist (specializer (%method-specializers method))
1169    (when (typep specializer 'class) ;; FIXME What about EQL specializer objects?
1170      (setf (class-direct-methods specializer)
1171            (remove method (class-direct-methods specializer)))))
1172  (finalize-generic-function gf)
1173  gf)
1174
1175(defun %find-method (gf qualifiers specializers &optional (errorp t))
1176  ;; "If the specializers argument does not correspond in length to the number
1177  ;; of required arguments of the generic-function, an an error of type ERROR
1178  ;; is signaled."
1179  (unless (= (length specializers) (length (gf-required-args gf)))
1180    (error "The specializers argument has length ~S, but ~S has ~S required parameters."
1181           (length specializers)
1182           gf
1183           (length (gf-required-args gf))))
1184  (let* ((canonical-specializers (canonicalize-specializers specializers))
1185         (method
1186          (find-if #'(lambda (method)
1187                      (and (equal qualifiers
1188                                  (method-qualifiers method))
1189                           (equal canonical-specializers
1190                                  (%method-specializers method))))
1191                   (generic-function-methods gf))))
1192    (if (and (null method) errorp)
1193        (error "No such method for ~S." (%generic-function-name gf))
1194        method)))
1195
1196(defun fast-callable-p (gf)
1197  (and (eq (generic-function-method-combination gf) 'standard)
1198       (null (intersection (%generic-function-lambda-list gf)
1199                           '(&rest &optional &key &allow-other-keys &aux)))))
1200
1201(declaim (ftype (function * t) slow-method-lookup-1))
1202
1203(declaim (ftype (function (t t t) t) slow-reader-lookup))
1204(defun slow-reader-lookup (gf layout slot-name)
1205  (let ((location (layout-slot-location layout slot-name)))
1206    (cache-slot-location gf layout location)
1207    location))
1208
1209(defun std-compute-discriminating-function (gf)
1210  (let ((code
1211         (cond
1212           ((and (= (length (generic-function-methods gf)) 1)
1213                 (typep (car (generic-function-methods gf)) 'standard-reader-method))
1214            ;;                 (sys::%format t "standard reader function ~S~%" (generic-function-name gf))
1215
1216            (let* ((method (%car (generic-function-methods gf)))
1217                   (class (car (%method-specializers method)))
1218                   (slot-name (reader-method-slot-name method)))
1219              #'(lambda (arg)
1220                  (declare (optimize speed))
1221                  (let* ((layout (std-instance-layout arg))
1222                         (location (get-cached-slot-location gf layout)))
1223                    (unless location
1224                      (unless (simple-typep arg class)
1225                        ;; FIXME no applicable method
1226                        (error 'simple-type-error
1227                               :datum arg
1228                               :expected-type class))
1229                      (setf location (slow-reader-lookup gf layout slot-name)))
1230                    (if (consp location)
1231                        ;; Shared slot.
1232                        (cdr location)
1233                        (standard-instance-access arg location))))))
1234
1235           (t
1236            (let* ((emf-table (classes-to-emf-table gf))
1237                   (number-required (length (gf-required-args gf)))
1238                   (lambda-list (%generic-function-lambda-list gf))
1239                   (exact (null (intersection lambda-list
1240                                              '(&rest &optional &key
1241                                                &allow-other-keys &aux)))))
1242              (if exact
1243                  (cond
1244                    ((= number-required 1)
1245                     (cond
1246                       ((and (eq (generic-function-method-combination gf) 'standard)
1247                             (= (length (generic-function-methods gf)) 1))
1248                        (let* ((method (%car (generic-function-methods gf)))
1249                               (specializer (car (%method-specializers method)))
1250                               (function (or (%method-fast-function method)
1251                                             (%method-function method))))
1252                          (if (eql-specializer-p specializer)
1253                              (let ((specializer-object (eql-specializer-object specializer)))
1254                                #'(lambda (arg)
1255                                    (declare (optimize speed))
1256                                    (if (eql arg specializer-object)
1257                                        (funcall function arg)
1258                                        (no-applicable-method gf (list arg)))))
1259                              #'(lambda (arg)
1260                                  (declare (optimize speed))
1261                                  (unless (simple-typep arg specializer)
1262                                    ;; FIXME no applicable method
1263                                    (error 'simple-type-error
1264                                           :datum arg
1265                                           :expected-type specializer))
1266                                  (funcall function arg)))))
1267                       (t
1268                        #'(lambda (arg)
1269                            (declare (optimize speed))
1270                            (let* ((specialization
1271                                    (%get-arg-specialization gf arg))
1272                                   (emfun (or (gethash1 specialization
1273                                                        emf-table)
1274                                              (slow-method-lookup-1
1275                                               gf arg specialization))))
1276                              (if emfun
1277                                  (funcall emfun (list arg))
1278                                  (apply #'no-applicable-method gf (list arg))))))))
1279                    ((= number-required 2)
1280                     #'(lambda (arg1 arg2)
1281                         (declare (optimize speed))
1282                         (let* ((args (list arg1 arg2))
1283                                (emfun (get-cached-emf gf args)))
1284                           (if emfun
1285                               (funcall emfun args)
1286                               (slow-method-lookup gf args)))))
1287                    ((= number-required 3)
1288                     #'(lambda (arg1 arg2 arg3)
1289                         (declare (optimize speed))
1290                         (let* ((args (list arg1 arg2 arg3))
1291                                (emfun (get-cached-emf gf args)))
1292                           (if emfun
1293                               (funcall emfun args)
1294                               (slow-method-lookup gf args)))))
1295                    (t
1296                     #'(lambda (&rest args)
1297                         (declare (optimize speed))
1298                         (let ((len (length args)))
1299                           (unless (= len number-required)
1300                             (error 'program-error
1301                                    :format-control "Not enough arguments for generic function ~S."
1302                                    :format-arguments (list (%generic-function-name gf)))))
1303                         (let ((emfun (get-cached-emf gf args)))
1304                           (if emfun
1305                               (funcall emfun args)
1306                               (slow-method-lookup gf args))))))
1307                  #'(lambda (&rest args)
1308                      (declare (optimize speed))
1309                      (let ((len (length args)))
1310                        (unless (>= len number-required)
1311                          (error 'program-error
1312                                 :format-control "Not enough arguments for generic function ~S."
1313                                 :format-arguments (list (%generic-function-name gf)))))
1314                      (let ((emfun (get-cached-emf gf args)))
1315                        (if emfun
1316                            (funcall emfun args)
1317                            (slow-method-lookup gf args))))))))))
1318
1319    code))
1320
1321(defun method-applicable-p (method args)
1322  (do* ((specializers (%method-specializers method) (cdr specializers))
1323        (args args (cdr args)))
1324       ((null specializers) t)
1325    (let ((specializer (car specializers)))
1326      (if (typep specializer 'eql-specializer)
1327          (unless (eql (car args) (eql-specializer-object specializer))
1328            (return nil))
1329          (unless (subclassp (class-of (car args)) specializer)
1330            (return nil))))))
1331
1332(defun %compute-applicable-methods (gf args)
1333  (let ((required-classes (mapcar #'class-of (required-portion gf args)))
1334        (methods '()))
1335    (dolist (method (generic-function-methods gf))
1336      (when (method-applicable-p method args)
1337        (push method methods)))
1338    (if (or (null methods) (null (%cdr methods)))
1339        methods
1340        (sort methods
1341              (if (eq (class-of gf) (find-class 'standard-generic-function))
1342                  #'(lambda (m1 m2)
1343                     (std-method-more-specific-p m1 m2 required-classes
1344                                                 (generic-function-argument-precedence-order gf)))
1345                  #'(lambda (m1 m2)
1346                     (method-more-specific-p gf m1 m2 required-classes)))))))
1347
1348(defun method-applicable-p-using-classes (method classes)
1349  (do* ((specializers (%method-specializers method) (cdr specializers))
1350        (classes classes (cdr classes)))
1351       ((null specializers) t)
1352    (let ((specializer (car specializers)))
1353      (unless (subclassp (car classes) specializer)
1354        (return nil)))))
1355
1356(defun slow-method-lookup (gf args)
1357  (let ((applicable-methods (%compute-applicable-methods gf args)))
1358    (if applicable-methods
1359        (let ((emfun (funcall (if (eq (class-of gf) (find-class 'standard-generic-function))
1360                                  #'std-compute-effective-method-function
1361                                  #'compute-effective-method-function)
1362                              gf applicable-methods)))
1363          (cache-emf gf args emfun)
1364          (funcall emfun args))
1365        (apply #'no-applicable-method gf args))))
1366
1367(defun slow-method-lookup-1 (gf arg arg-specialization)
1368  (let ((applicable-methods (%compute-applicable-methods gf (list arg))))
1369    (if applicable-methods
1370        (let ((emfun (funcall (if (eq (class-of gf) (find-class 'standard-generic-function))
1371                                  #'std-compute-effective-method-function
1372                                  #'compute-effective-method-function)
1373                              gf applicable-methods)))
1374          (when emfun
1375            (setf (gethash arg-specialization (classes-to-emf-table gf)) emfun))
1376          emfun))))
1377
1378(defun sub-specializer-p (c1 c2 c-arg)
1379  (find c2 (cdr (memq c1 (%class-precedence-list c-arg)))))
1380
1381(defun std-method-more-specific-p (method1 method2 required-classes argument-precedence-order)
1382  (if argument-precedence-order
1383      (let ((specializers-1 (%method-specializers method1))
1384            (specializers-2 (%method-specializers method2)))
1385        (dolist (index argument-precedence-order)
1386          (let ((spec1 (nth index specializers-1))
1387                (spec2 (nth index specializers-2)))
1388            (unless (eq spec1 spec2)
1389              (cond ((eql-specializer-p spec1)
1390                     (return t))
1391                    ((eql-specializer-p spec2)
1392                     (return nil))
1393                    (t
1394                     (return (sub-specializer-p spec1 spec2
1395                                                (nth index required-classes)))))))))
1396      (do ((specializers-1 (%method-specializers method1) (cdr specializers-1))
1397           (specializers-2 (%method-specializers method2) (cdr specializers-2))
1398           (classes required-classes (cdr classes)))
1399          ((null specializers-1) nil)
1400        (let ((spec1 (car specializers-1))
1401              (spec2 (car specializers-2)))
1402          (unless (eq spec1 spec2)
1403            (cond ((eql-specializer-p spec1)
1404                   (return t))
1405                  ((eql-specializer-p spec2)
1406                   (return nil))
1407                  (t
1408                   (return (sub-specializer-p spec1 spec2 (car classes))))))))))
1409
1410(defun primary-method-p (method)
1411  (null (intersection '(:before :after :around) (method-qualifiers method))))
1412
1413(defun before-method-p (method)
1414  (equal '(:before) (method-qualifiers method)))
1415
1416(defun after-method-p (method)
1417  (equal '(:after) (method-qualifiers method)))
1418
1419(defun around-method-p (method)
1420  (equal '(:around) (method-qualifiers method)))
1421
1422(defun std-compute-effective-method-function (gf methods)
1423  (let* ((mc (generic-function-method-combination gf))
1424         (mc-name (if (atom mc) mc (%car mc)))
1425         (options (if (atom mc) '() (%cdr mc)))
1426         (order (car options))
1427         (primaries '())
1428         (arounds '())
1429         around
1430         emf-form)
1431    (dolist (m methods)
1432      (let ((qualifiers (method-qualifiers m)))
1433        (cond ((null qualifiers)
1434               (if (eq mc-name 'standard)
1435                   (push m primaries)
1436                   (error "Method combination type mismatch.")))
1437              ((cdr qualifiers)
1438               (error "Invalid method qualifiers."))
1439              ((eq (car qualifiers) :around)
1440               (push m arounds))
1441              ((eq (car qualifiers) mc-name)
1442               (push m primaries))
1443              ((memq (car qualifiers) '(:before :after)))
1444              (t
1445               (error "Invalid method qualifiers.")))))
1446    (unless (eq order :most-specific-last)
1447      (setf primaries (nreverse primaries)))
1448    (setf arounds (nreverse arounds))
1449    (setf around (car arounds))
1450    (when (null primaries)
1451      (error "No primary methods for the generic function ~S." gf))
1452    (cond
1453      (around
1454       (let ((next-emfun
1455              (funcall
1456               (if (eq (class-of gf) (find-class 'standard-generic-function))
1457                   #'std-compute-effective-method-function
1458                   #'compute-effective-method-function)
1459               gf (remove around methods))))
1460         (setf emf-form
1461;;;           `(lambda (args)
1462;;;          (funcall ,(%method-function around) args ,next-emfun))
1463               (generate-emf-lambda (%method-function around) next-emfun)
1464               )))
1465      ((eq mc-name 'standard)
1466       (let* ((next-emfun (compute-primary-emfun (cdr primaries)))
1467              (befores (remove-if-not #'before-method-p methods))
1468              (reverse-afters
1469               (reverse (remove-if-not #'after-method-p methods))))
1470         (setf emf-form
1471               (cond
1472                 ((and (null befores) (null reverse-afters))
1473                  (let ((fast-function (%method-fast-function (car primaries))))
1474
1475                    (if fast-function
1476                        (ecase (length (gf-required-args gf))
1477                          (1
1478                           #'(lambda (args)
1479                               (declare (optimize speed))
1480                               (funcall fast-function (car args))))
1481                          (2
1482                           #'(lambda (args)
1483                               (declare (optimize speed))
1484                               (funcall fast-function (car args) (cadr args)))))
1485                        ;;                               `(lambda (args)
1486                        ;;                                  (declare (optimize speed))
1487                        ;;                                  (funcall ,(%method-function (car primaries)) args ,next-emfun))
1488                        (generate-emf-lambda (%method-function (car primaries))
1489                                             next-emfun))))
1490                 (t
1491                  (let ((method-function (%method-function (car primaries))))
1492
1493                    #'(lambda (args)
1494                        (declare (optimize speed))
1495                        (dolist (before befores)
1496                          (funcall (%method-function before) args nil))
1497                        (multiple-value-prog1
1498                            (funcall method-function args next-emfun)
1499                          (dolist (after reverse-afters)
1500                            (funcall (%method-function after) args nil))))))))))
1501          (t
1502           (let ((mc-obj (get mc-name 'method-combination-object)))
1503             (unless mc-obj
1504               (error "Unsupported method combination type ~A." mc-name))
1505             (let* ((operator (method-combination-operator mc-obj))
1506                    (ioa (method-combination-identity-with-one-argument mc-obj)))
1507               (setf emf-form
1508                     (if (and (null (cdr primaries))
1509                              (not (null ioa)))
1510;;                          `(lambda (args)
1511;;                             (funcall ,(%method-function (car primaries)) args nil))
1512                         (generate-emf-lambda (%method-function (car primaries)) nil)
1513                         `(lambda (args)
1514                            (,operator ,@(mapcar
1515                                          (lambda (primary)
1516                                            `(funcall ,(%method-function primary) args nil))
1517                                          primaries)))))))))
1518    (or (ignore-errors (autocompile emf-form))
1519        (coerce-to-function emf-form))))
1520
1521(defun generate-emf-lambda (method-function next-emfun)
1522  #'(lambda (args)
1523      (declare (optimize speed))
1524      (funcall method-function args next-emfun)))
1525
1526;;; compute an effective method function from a list of primary methods:
1527
1528(defun compute-primary-emfun (methods)
1529  (if (null methods)
1530      nil
1531      (let ((next-emfun (compute-primary-emfun (cdr methods))))
1532        #'(lambda (args)
1533           (funcall (%method-function (car methods)) args next-emfun)))))
1534
1535(defvar *call-next-method-p*)
1536(defvar *next-method-p-p*)
1537
1538(defun walk-form (form)
1539  (cond ((atom form)
1540         (cond ((eq form 'call-next-method)
1541                (setf *call-next-method-p* t))
1542               ((eq form 'next-method-p)
1543                (setf *next-method-p-p* t))))
1544        (t
1545         (walk-form (%car form))
1546         (walk-form (%cdr form)))))
1547
1548(defun compute-method-function (lambda-expression)
1549  (let ((lambda-list (allow-other-keys (cadr lambda-expression)))
1550        (body (cddr lambda-expression))
1551        (*call-next-method-p* nil)
1552        (*next-method-p-p* nil))
1553    (multiple-value-bind (body declarations) (parse-body body)
1554      (let ((ignorable-vars '()))
1555        (dolist (var lambda-list)
1556          (if (memq var lambda-list-keywords)
1557              (return)
1558              (push var ignorable-vars)))
1559        (push `(declare (ignorable ,@ignorable-vars)) declarations))
1560      (walk-form body)
1561      (cond ((or *call-next-method-p* *next-method-p-p*)
1562             `(lambda (args next-emfun)
1563                (flet ((call-next-method (&rest cnm-args)
1564                         (if (null next-emfun)
1565                             (error "No next method for generic function.")
1566                             (funcall next-emfun (or cnm-args args))))
1567                       (next-method-p ()
1568                         (not (null next-emfun))))
1569                  (declare (ignorable (function call-next-method)
1570                                      (function next-method-p)))
1571                  (apply #'(lambda ,lambda-list ,@declarations ,@body) args))))
1572            ((null (intersection lambda-list '(&rest &optional &key &allow-other-keys &aux)))
1573             ;; Required parameters only.
1574             (case (length lambda-list)
1575               (1
1576                `(lambda (args next-emfun)
1577                   (declare (ignore next-emfun))
1578                   (let ((,(%car lambda-list) (%car args)))
1579                     (declare (ignorable ,(%car lambda-list)))
1580                     ,@declarations ,@body)))
1581               (2
1582                `(lambda (args next-emfun)
1583                   (declare (ignore next-emfun))
1584                   (let ((,(%car lambda-list) (%car args))
1585                         (,(%cadr lambda-list) (%cadr args)))
1586                     (declare (ignorable ,(%car lambda-list)
1587                                         ,(%cadr lambda-list)))
1588                     ,@declarations ,@body)))
1589               (3
1590                `(lambda (args next-emfun)
1591                   (declare (ignore next-emfun))
1592                   (let ((,(%car lambda-list) (%car args))
1593                         (,(%cadr lambda-list) (%cadr args))
1594                         (,(%caddr lambda-list) (%caddr args)))
1595                     (declare (ignorable ,(%car lambda-list)
1596                                         ,(%cadr lambda-list)
1597                                         ,(%caddr lambda-list)))
1598                     ,@declarations ,@body)))
1599               (t
1600                `(lambda (args next-emfun)
1601                   (declare (ignore next-emfun))
1602                   (apply #'(lambda ,lambda-list ,@declarations ,@body) args)))))
1603            (t
1604             `(lambda (args next-emfun)
1605                (declare (ignore next-emfun))
1606                (apply #'(lambda ,lambda-list ,@declarations ,@body) args)))))))
1607
1608(defun compute-method-fast-function (lambda-expression)
1609  (let ((lambda-list (allow-other-keys (cadr lambda-expression))))
1610    (when (intersection lambda-list '(&rest &optional &key &allow-other-keys &aux))
1611      (return-from compute-method-fast-function nil))
1612    ;; Only required args.
1613    (let ((body (cddr lambda-expression))
1614          (*call-next-method-p* nil)
1615          (*next-method-p-p* nil))
1616      (multiple-value-bind (body declarations) (parse-body body)
1617        (walk-form body)
1618        (when (or *call-next-method-p* *next-method-p-p*)
1619          (return-from compute-method-fast-function nil))
1620        (let ((decls `(declare (ignorable ,@lambda-list))))
1621          (setf lambda-expression
1622                (list* (car lambda-expression)
1623                       (cadr lambda-expression)
1624                       decls
1625                       (cddr lambda-expression))))
1626        (case (length lambda-list)
1627          (1
1628;;            `(lambda (args next-emfun)
1629;;               (let ((,(%car lambda-list) (%car args)))
1630;;                 (declare (ignorable ,(%car lambda-list)))
1631;;                 ,@declarations ,@body)))
1632           lambda-expression)
1633          (2
1634;;            `(lambda (args next-emfun)
1635;;               (let ((,(%car lambda-list) (%car args))
1636;;                     (,(%cadr lambda-list) (%cadr args)))
1637;;                 (declare (ignorable ,(%car lambda-list)
1638;;                                     ,(%cadr lambda-list)))
1639;;                 ,@declarations ,@body)))
1640           lambda-expression)
1641;;           (3
1642;;            `(lambda (args next-emfun)
1643;;               (let ((,(%car lambda-list) (%car args))
1644;;                     (,(%cadr lambda-list) (%cadr args))
1645;;                     (,(%caddr lambda-list) (%caddr args)))
1646;;                 (declare (ignorable ,(%car lambda-list)
1647;;                                     ,(%cadr lambda-list)
1648;;                                     ,(%caddr lambda-list)))
1649;;                 ,@declarations ,@body)))
1650          (t
1651           nil))))))
1652
1653;; From CLHS section 7.6.5:
1654;; "When a generic function or any of its methods mentions &key in a lambda
1655;; list, the specific set of keyword arguments accepted by the generic function
1656;; varies according to the applicable methods. The set of keyword arguments
1657;; accepted by the generic function for a particular call is the union of the
1658;; keyword arguments accepted by all applicable methods and the keyword
1659;; arguments mentioned after &key in the generic function definition, if any."
1660;; Adapted from Sacla.
1661(defun allow-other-keys (lambda-list)
1662  (if (and (member '&key lambda-list)
1663           (not (member '&allow-other-keys lambda-list)))
1664      (let* ((key-end (or (position '&aux lambda-list) (length lambda-list)))
1665             (aux-part (subseq lambda-list key-end)))
1666        `(,@(subseq lambda-list 0 key-end) &allow-other-keys ,@aux-part))
1667      lambda-list))
1668
1669(defmacro defmethod (&rest args)
1670  (multiple-value-bind
1671      (function-name qualifiers lambda-list specializers documentation declarations body)
1672      (parse-defmethod args)
1673    (let* ((specializers-form '())
1674           (lambda-expression `(lambda ,lambda-list ,@declarations ,body))
1675           (method-function (compute-method-function lambda-expression))
1676           (fast-function (compute-method-fast-function lambda-expression))
1677           )
1678      (dolist (specializer specializers)
1679        (cond ((and (consp specializer) (eq (car specializer) 'eql))
1680               (push `(list 'eql ,(cadr specializer)) specializers-form))
1681              (t
1682               (push `',specializer specializers-form))))
1683      (setf specializers-form `(list ,@(nreverse specializers-form)))
1684      `(progn
1685         (ensure-method ',function-name
1686                        :lambda-list ',lambda-list
1687                        :qualifiers ',qualifiers
1688                        :specializers ,specializers-form
1689                        ,@(if documentation `(:documentation ,documentation))
1690                        :function (function ,method-function)
1691                        ,@(if fast-function `(:fast-function (function ,fast-function)))
1692                        )))))
1693
1694;;; Reader and writer methods
1695
1696(defun make-instance-standard-reader-method (gf
1697                                             &key
1698                                             lambda-list
1699                                             qualifiers
1700                                             specializers
1701                                             documentation
1702                                             function
1703                                             fast-function
1704                                             slot-name)
1705  (declare (ignore gf))
1706  (let ((method (std-allocate-instance (find-class 'standard-reader-method))))
1707    (setf (method-lambda-list method) lambda-list)
1708    (setf (method-qualifiers method) qualifiers)
1709    (%set-method-specializers method (canonicalize-specializers specializers))
1710    (setf (method-documentation method) documentation)
1711    (%set-method-generic-function method nil)
1712    (%set-method-function method function)
1713    (%set-method-fast-function method fast-function)
1714    (set-reader-method-slot-name method slot-name)
1715    method))
1716
1717(defun add-reader-method (class function-name slot-name)
1718  (let* ((lambda-expression
1719          (if (eq (class-of class) (find-class 'standard-class))
1720              `(lambda (object) (std-slot-value object ',slot-name))
1721              `(lambda (object) (slot-value object ',slot-name))))
1722         (method-function (compute-method-function lambda-expression))
1723         (fast-function (compute-method-fast-function lambda-expression)))
1724    (let ((method-lambda-list '(object))
1725          (gf (find-generic-function function-name nil)))
1726      (if gf
1727          (check-method-lambda-list method-lambda-list (generic-function-lambda-list gf))
1728          (setf gf (ensure-generic-function function-name :lambda-list method-lambda-list)))
1729      (let ((method
1730             (make-instance-standard-reader-method gf
1731                                                   :lambda-list '(object)
1732                                                   :qualifiers ()
1733                                                   :specializers (list class)
1734                                                   :function (if (autoloadp 'compile)
1735                                                                 method-function
1736                                                                 (autocompile method-function))
1737                                                   :fast-function (if (autoloadp 'compile)
1738                                                                      fast-function
1739                                                                      (autocompile fast-function))
1740                                                   :slot-name slot-name)))
1741        (%add-method gf method)
1742        method))))
1743
1744(defun add-writer-method (class function-name slot-name)
1745  (let* ((lambda-expression
1746          (if (eq (class-of class) (find-class 'standard-class))
1747              `(lambda (new-value object)
1748                 (setf (std-slot-value object ',slot-name) new-value))
1749              `(lambda (new-value object)
1750                 (setf (slot-value object ',slot-name) new-value))))
1751         (method-function (compute-method-function lambda-expression))
1752         (fast-function (compute-method-fast-function lambda-expression))
1753         )
1754    (ensure-method function-name
1755                   :lambda-list '(new-value object)
1756                   :qualifiers ()
1757                   :specializers (list (find-class 't) class)
1758;;                    :function `(function ,method-function)
1759                   :function (if (autoloadp 'compile)
1760                                 method-function
1761                                 (autocompile method-function))
1762                   :fast-function (if (autoloadp 'compile)
1763                                      fast-function
1764                                      (autocompile fast-function))
1765                   )))
1766
1767(fmakunbound 'class-name)
1768
1769(defgeneric class-name (class))
1770
1771(defmethod class-name ((class class))
1772  (%class-name class))
1773
1774(defgeneric (setf class-name) (new-value class))
1775
1776(defmethod (setf class-name) (new-value (class class))
1777  (%set-class-name class new-value))
1778
1779(when (autoloadp 'class-precedence-list)
1780  (fmakunbound 'class-precedence-list))
1781
1782(defgeneric class-precedence-list (class))
1783
1784(defmethod class-precedence-list ((class class))
1785  (%class-precedence-list class))
1786
1787(defgeneric documentation (x doc-type))
1788
1789(defgeneric (setf documentation) (new-value x doc-type))
1790
1791(defmethod documentation ((x symbol) doc-type)
1792  (%documentation x doc-type))
1793
1794(defmethod (setf documentation) (new-value (x symbol) doc-type)
1795  (%set-documentation x doc-type new-value))
1796
1797(defmethod documentation ((x function) doc-type)
1798  (%documentation x doc-type))
1799
1800(defmethod (setf documentation) (new-value (x function) doc-type)
1801  (%set-documentation x doc-type new-value))
1802
1803;; FIXME This should be a weak hashtable!
1804(defvar *list-documentation-hashtable* (make-hash-table :test #'equal))
1805
1806(defmethod documentation ((x list) (doc-type (eql 'function)))
1807  (let ((alist (gethash x *list-documentation-hashtable*)))
1808    (and alist (cdr (assoc doc-type alist)))))
1809
1810(defmethod documentation ((x list) (doc-type (eql 'compiler-macro)))
1811  (let ((alist (gethash x *list-documentation-hashtable*)))
1812    (and alist (cdr (assoc doc-type alist)))))
1813
1814(defmethod (setf documentation) (new-value (x list) (doc-type (eql 'function)))
1815  (let* ((alist (gethash x *list-documentation-hashtable*))
1816         (entry (and alist (assoc doc-type alist))))
1817    (cond (entry
1818           (setf (cdr entry) new-value))
1819          (t
1820           (setf (gethash x *list-documentation-hashtable*)
1821                 (push (cons doc-type new-value) alist)))))
1822  new-value)
1823
1824(defmethod (setf documentation) (new-value (x list) (doc-type (eql 'compiler-macro)))
1825  (let* ((alist (gethash x *list-documentation-hashtable*))
1826         (entry (and alist (assoc doc-type alist))))
1827    (cond (entry
1828           (setf (cdr entry) new-value))
1829          (t
1830           (setf (gethash x *list-documentation-hashtable*)
1831                 (push (cons doc-type new-value) alist)))))
1832  new-value)
1833
1834(defmethod documentation ((x standard-class) (doc-type (eql 't)))
1835  (class-documentation x))
1836
1837(defmethod documentation ((x standard-class) (doc-type (eql 'type)))
1838  (class-documentation x))
1839
1840(defmethod (setf documentation) (new-value (x standard-class) (doc-type (eql 't)))
1841  (%set-class-documentation x new-value))
1842
1843(defmethod (setf documentation) (new-value (x standard-class) (doc-type (eql 'type)))
1844  (%set-class-documentation x new-value))
1845
1846(defmethod documentation ((x structure-class) (doc-type (eql 't)))
1847  (%documentation x doc-type))
1848
1849(defmethod documentation ((x structure-class) (doc-type (eql 'type)))
1850  (%documentation x doc-type))
1851
1852(defmethod (setf documentation) (new-value (x structure-class) (doc-type (eql 't)))
1853  (%set-documentation x doc-type new-value))
1854
1855(defmethod (setf documentation) (new-value (x structure-class) (doc-type (eql 'type)))
1856  (%set-documentation x doc-type new-value))
1857
1858(defmethod documentation ((x standard-generic-function) (doc-type (eql 't)))
1859  (generic-function-documentation x))
1860
1861(defmethod (setf documentation) (new-value (x standard-generic-function) (doc-type (eql 't)))
1862  (setf (generic-function-documentation x) new-value))
1863
1864(defmethod documentation ((x standard-generic-function) (doc-type (eql 'function)))
1865  (generic-function-documentation x))
1866
1867(defmethod (setf documentation) (new-value (x standard-generic-function) (doc-type (eql 'function)))
1868  (setf (generic-function-documentation x) new-value))
1869
1870(defmethod documentation ((x standard-method) (doc-type (eql 't)))
1871  (method-documentation x))
1872
1873(defmethod (setf documentation) (new-value (x standard-method) (doc-type (eql 't)))
1874  (setf (method-documentation x) new-value))
1875
1876(defmethod documentation ((x package) (doc-type (eql 't)))
1877  (%documentation x doc-type))
1878
1879(defmethod (setf documentation) (new-value (x package) (doc-type (eql 't)))
1880  (%set-documentation x doc-type new-value))
1881
1882;;; Slot access
1883
1884(defun set-slot-value-using-class (new-value class instance slot-name)
1885  (declare (ignore class)) ; FIXME
1886  (setf (std-slot-value instance slot-name) new-value))
1887
1888(defgeneric slot-value-using-class (class instance slot-name))
1889
1890(defmethod slot-value-using-class ((class standard-class) instance slot-name)
1891  (std-slot-value instance slot-name))
1892
1893(defgeneric (setf slot-value-using-class) (new-value class instance slot-name))
1894(defmethod (setf slot-value-using-class) (new-value
1895                                          (class standard-class)
1896                                          instance
1897                                          slot-name)
1898  (setf (std-slot-value instance slot-name) new-value))
1899
1900(defgeneric slot-exists-p-using-class (class instance slot-name))
1901
1902(defmethod slot-exists-p-using-class (class instance slot-name)
1903  nil)
1904
1905(defmethod slot-exists-p-using-class ((class standard-class) instance slot-name)
1906  (std-slot-exists-p instance slot-name))
1907
1908(defmethod slot-exists-p-using-class ((class structure-class) instance slot-name)
1909  (dolist (dsd (%class-slots class))
1910    (when (eq (sys::dsd-name dsd) slot-name)
1911      (return-from slot-exists-p-using-class t)))
1912  nil)
1913
1914(defgeneric slot-boundp-using-class (class instance slot-name))
1915(defmethod slot-boundp-using-class ((class standard-class) instance slot-name)
1916  (std-slot-boundp instance slot-name))
1917
1918(defgeneric slot-makunbound-using-class (class instance slot-name))
1919(defmethod slot-makunbound-using-class ((class standard-class)
1920                                        instance
1921                                        slot-name)
1922  (std-slot-makunbound instance slot-name))
1923
1924(defgeneric slot-missing (class instance slot-name operation &optional new-value))
1925
1926(defmethod slot-missing ((class t) instance slot-name operation &optional new-value)
1927  (declare (ignore new-value))
1928  (error "The slot ~S is missing from the class ~S." slot-name class))
1929
1930(defgeneric slot-unbound (class instance slot-name))
1931
1932(defmethod slot-unbound ((class t) instance slot-name)
1933  (error 'unbound-slot :instance instance :name slot-name))
1934
1935;;; Instance creation and initialization
1936
1937(defgeneric allocate-instance (class &rest initargs &key &allow-other-keys))
1938
1939(defmethod allocate-instance ((class standard-class) &rest initargs)
1940  (declare (ignore initargs))
1941  (std-allocate-instance class))
1942
1943(defmethod allocate-instance ((class structure-class) &rest initargs)
1944  (declare (ignore initargs))
1945  (%make-structure (%class-name class)
1946                   (make-list (length (%class-slots class))
1947                              :initial-element +slot-unbound+)))
1948
1949;; "The set of valid initialization arguments for a class is the set of valid
1950;; initialization arguments that either fill slots or supply arguments to
1951;; methods, along with the predefined initialization argument :ALLOW-OTHER-KEYS."
1952;; 7.1.2
1953
1954(defun check-initargs (instance shared-initialize-param initargs)
1955  (when (oddp (length initargs))
1956    (error 'program-error
1957           :format-control "Odd number of keyword arguments."))
1958  (unless (getf initargs :allow-other-keys)
1959    (let ((methods 
1960     (nconc 
1961      (compute-applicable-methods 
1962       #'shared-initialize
1963       (if initargs
1964     `(,instance ,shared-initialize-param ,@initargs)
1965         (list instance shared-initialize-param)))
1966      (compute-applicable-methods 
1967       #'initialize-instance
1968       (if initargs
1969     `(,instance ,@initargs)
1970         (list instance)))))
1971    (slots (%class-slots (class-of instance))))
1972      (do* ((tail initargs (cddr tail))
1973            (initarg (car tail) (car tail)))
1974           ((null tail))
1975        (unless (or (valid-initarg-p initarg slots)
1976        (valid-methodarg-p initarg methods)
1977                    (eq initarg :allow-other-keys))
1978          (error 'program-error
1979                 :format-control "Invalid initarg ~S."
1980                 :format-arguments (list initarg)))))))
1981
1982(defun valid-methodarg-p (initarg methods)
1983  (when (symbolp initarg)
1984    (dolist (method methods nil)
1985      (let ((valid-initargs (method-lambda-list method)))
1986  (when (find (symbol-value initarg) valid-initargs 
1987         :test #'(lambda (a b)
1988             (if (listp b)
1989           (string= a (car b))
1990         (or
1991          (string= a b)
1992          (string= b "&ALLOW-OTHER-KEYS")))))
1993
1994    (return t))))))
1995
1996(defun valid-initarg-p (initarg slots)
1997  (dolist (slot slots nil)
1998    (let ((valid-initargs (%slot-definition-initargs slot)))
1999      (when (memq initarg valid-initargs)
2000        (return t)))))
2001
2002(defgeneric make-instance (class &rest initargs &key &allow-other-keys))
2003
2004(defmethod make-instance ((class standard-class) &rest initargs)
2005  (when (oddp (length initargs))
2006    (error 'program-error :format-control "Odd number of keyword arguments."))
2007  (unless (class-finalized-p class)
2008    (std-finalize-inheritance class))
2009  (let ((class-default-initargs (class-default-initargs class)))
2010    (when class-default-initargs
2011      (let ((default-initargs '()))
2012        (do* ((list class-default-initargs (cddr list))
2013              (key (car list) (car list))
2014              (fn (cadr list) (cadr list)))
2015             ((null list))
2016          (when (eq (getf initargs key 'not-found) 'not-found)
2017            (setf default-initargs (append default-initargs (list key (funcall fn))))))
2018        (setf initargs (append initargs default-initargs)))))
2019
2020  (let ((instance (std-allocate-instance class)))
2021    (check-initargs instance t initargs)
2022    (apply #'initialize-instance instance initargs)
2023    instance))
2024
2025(defmethod make-instance ((class symbol) &rest initargs)
2026  (apply #'make-instance (find-class class) initargs))
2027
2028(defgeneric initialize-instance (instance &key))
2029
2030(defmethod initialize-instance ((instance standard-object) &rest initargs)
2031  (apply #'shared-initialize instance t initargs))
2032
2033(defgeneric reinitialize-instance (instance &key))
2034
2035;; "The system-supplied primary method for REINITIALIZE-INSTANCE checks the
2036;; validity of initargs and signals an error if an initarg is supplied that is
2037;; not declared as valid. The method then calls the generic function SHARED-
2038;; INITIALIZE with the following arguments: the instance, nil (which means no
2039;; slots should be initialized according to their initforms), and the initargs
2040;; it received."
2041(defmethod reinitialize-instance ((instance standard-object) &rest initargs)
2042  (apply #'shared-initialize instance () initargs))
2043
2044(defun std-shared-initialize (instance slot-names all-keys)
2045  (when (oddp (length all-keys))
2046    (error 'program-error :format-control "Odd number of keyword arguments."))
2047  (do* ((tail all-keys (cddr tail))
2048  (initarg (car tail) (car tail)))
2049      ((null tail))
2050    (when (and initarg (not (symbolp initarg)))
2051      (error 'program-error
2052       :format-control "Invalid initarg ~S."
2053       :format-arguments (list initarg))))
2054  (dolist (slot (%class-slots (class-of instance)))
2055    (let ((slot-name (%slot-definition-name slot)))
2056      (multiple-value-bind (init-key init-value foundp)
2057          (get-properties all-keys (%slot-definition-initargs slot))
2058        (if foundp
2059            (setf (std-slot-value instance slot-name) init-value)
2060            (unless (std-slot-boundp instance slot-name)
2061              (let ((initfunction (%slot-definition-initfunction slot)))
2062                (when (and initfunction (or (eq slot-names t)
2063                                            (memq slot-name slot-names)))
2064                  (setf (std-slot-value instance slot-name)
2065                        (funcall initfunction)))))))))
2066  instance)
2067
2068(defgeneric shared-initialize (instance slot-names &key))
2069
2070(defmethod shared-initialize ((instance standard-object) slot-names &rest initargs)
2071  (std-shared-initialize instance slot-names initargs))
2072
2073;;; change-class
2074
2075(defgeneric change-class (instance new-class &key))
2076
2077(defmethod change-class ((old-instance standard-object) (new-class standard-class)
2078                         &rest initargs)
2079  (let ((old-slots (%class-slots (class-of old-instance)))
2080        (new-slots (%class-slots new-class))
2081        (new-instance (allocate-instance new-class)))
2082    ;; "The values of local slots specified by both the class CTO and the class
2083    ;; CFROM are retained. If such a local slot was unbound, it remains
2084    ;; unbound."
2085    (dolist (new-slot new-slots)
2086      (when (instance-slot-p new-slot)
2087        (let* ((slot-name (%slot-definition-name new-slot))
2088               (old-slot (find slot-name old-slots :key #'%slot-definition-name)))
2089          ;; "The values of slots specified as shared in the class CFROM and as
2090          ;; local in the class CTO are retained."
2091          (when (and old-slot (slot-boundp old-instance slot-name))
2092            (setf (slot-value new-instance slot-name)
2093                  (slot-value old-instance slot-name))))))
2094    (swap-slots old-instance new-instance)
2095    (rotatef (std-instance-layout new-instance)
2096             (std-instance-layout old-instance))
2097    (apply #'update-instance-for-different-class
2098           new-instance old-instance initargs)
2099    old-instance))
2100
2101(defmethod change-class ((instance standard-object) (new-class symbol) &rest initargs)
2102  (apply #'change-class instance (find-class new-class) initargs))
2103
2104(defgeneric update-instance-for-different-class (old new &key))
2105
2106(defmethod update-instance-for-different-class
2107  ((old standard-object) (new standard-object) &rest initargs)
2108  (let ((added-slots
2109         (remove-if #'(lambda (slot-name)
2110                       (slot-exists-p old slot-name))
2111                    (mapcar #'%slot-definition-name
2112                            (%class-slots (class-of new))))))
2113    (check-initargs new added-slots initargs)
2114    (apply #'shared-initialize new added-slots initargs)))
2115
2116;;; make-instances-obsolete
2117
2118(defgeneric make-instances-obsolete (class))
2119
2120(defmethod make-instances-obsolete ((class standard-class))
2121  (%make-instances-obsolete class))
2122
2123(defmethod make-instances-obsolete ((class symbol))
2124  (make-instances-obsolete (find-class class))
2125  class)
2126
2127;;; update-instance-for-redefined-class
2128
2129(defgeneric update-instance-for-redefined-class (instance
2130                                                 added-slots
2131                                                 discarded-slots
2132                                                 property-list
2133                                                 &rest initargs
2134                                                 &key
2135                                                 &allow-other-keys))
2136
2137(defmethod update-instance-for-redefined-class ((instance standard-object)
2138            added-slots
2139            discarded-slots
2140            property-list
2141            &rest initargs)
2142  (check-initargs instance added-slots initargs)
2143  (apply #'shared-initialize instance added-slots initargs))
2144
2145;;;  Methods having to do with class metaobjects.
2146
2147(defmethod initialize-instance :after ((class standard-class) &rest args)
2148  (apply #'std-after-initialization-for-classes class args))
2149
2150;;; Finalize inheritance
2151
2152(defgeneric finalize-inheritance (class))
2153
2154(defmethod finalize-inheritance ((class standard-class))
2155  (std-finalize-inheritance class))
2156
2157;;; Class precedence lists
2158
2159(defgeneric compute-class-precedence-list (class))
2160(defmethod compute-class-precedence-list ((class standard-class))
2161  (std-compute-class-precedence-list class))
2162
2163;;; Slot inheritance
2164
2165(defgeneric compute-slots (class))
2166(defmethod compute-slots ((class standard-class))
2167  (std-compute-slots class))
2168
2169(defgeneric compute-effective-slot-definition (class direct-slots))
2170(defmethod compute-effective-slot-definition
2171  ((class standard-class) direct-slots)
2172  (std-compute-effective-slot-definition class direct-slots))
2173
2174;;; Methods having to do with generic function metaobjects.
2175
2176(defmethod initialize-instance :after ((gf standard-generic-function) &key)
2177  (finalize-generic-function gf))
2178
2179;;; Methods having to do with generic function invocation.
2180
2181(defgeneric compute-discriminating-function (gf))
2182(defmethod compute-discriminating-function ((gf standard-generic-function))
2183  (std-compute-discriminating-function gf))
2184
2185(defgeneric method-more-specific-p (gf method1 method2 required-classes))
2186
2187(defmethod method-more-specific-p ((gf standard-generic-function)
2188                                   method1 method2 required-classes)
2189  (std-method-more-specific-p method1 method2 required-classes
2190                              (generic-function-argument-precedence-order gf)))
2191
2192(defgeneric compute-effective-method-function (gf methods))
2193(defmethod compute-effective-method-function ((gf standard-generic-function) methods)
2194  (std-compute-effective-method-function gf methods))
2195
2196(defgeneric compute-applicable-methods (gf args))
2197(defmethod compute-applicable-methods ((gf standard-generic-function) args)
2198  (%compute-applicable-methods gf args))
2199
2200;;; Conditions.
2201
2202(defmacro define-condition (name (&rest parent-types) (&rest slot-specs) &body options)
2203  (let ((parent-types (or parent-types '(condition)))
2204        (report nil))
2205    (dolist (option options)
2206      (when (eq (car option) :report)
2207        (setf report (cadr option))
2208        (return)))
2209    (typecase report
2210      (null
2211       `(progn
2212          (defclass ,name ,parent-types ,slot-specs ,@options)
2213          ',name))
2214      (string
2215       `(progn
2216          (defclass ,name ,parent-types ,slot-specs ,@options)
2217          (defmethod print-object ((condition ,name) stream)
2218            (if *print-escape*
2219                (call-next-method)
2220                (progn (write-string ,report stream) condition)))
2221          ',name))
2222      (t
2223       `(progn
2224          (defclass ,name ,parent-types ,slot-specs ,@options)
2225          (defmethod print-object ((condition ,name) stream)
2226            (if *print-escape*
2227                (call-next-method)
2228                (funcall #',report condition stream)))
2229          ',name)))))
2230
2231(defun make-condition (type &rest initargs)
2232  (or (%make-condition type initargs)
2233      (let ((class (if (symbolp type) (find-class type) type)))
2234        (apply #'make-instance class initargs))))
2235
2236;; Adapted from SBCL.
2237;; Originally defined in signal.lisp. Redefined here now that we have MAKE-CONDITION.
2238(defun coerce-to-condition (datum arguments default-type fun-name)
2239  (cond ((typep datum 'condition)
2240         (when arguments
2241           (error 'simple-type-error
2242                  :datum arguments
2243                  :expected-type 'null
2244                  :format-control "You may not supply additional arguments when giving ~S to ~S."
2245                  :format-arguments (list datum fun-name)))
2246         datum)
2247        ((symbolp datum)
2248         (apply #'make-condition datum arguments))
2249        ((or (stringp datum) (functionp datum))
2250         (make-condition default-type
2251                         :format-control datum
2252                         :format-arguments arguments))
2253        (t
2254         (error 'simple-type-error
2255                :datum datum
2256                :expected-type '(or symbol string)
2257                :format-control "Bad argument to ~S: ~S."
2258                :format-arguments (list fun-name datum)))))
2259
2260(defgeneric make-load-form (object &optional environment))
2261
2262(defmethod make-load-form ((object t) &optional environment)
2263  (declare (ignore environment))
2264  (apply #'no-applicable-method #'make-load-form (list object)))
2265
2266(defmethod make-load-form ((class class) &optional environment)
2267  (declare (ignore environment))
2268  (let ((name (%class-name class)))
2269    (unless (and name (eq (find-class name nil) class))
2270      (error 'simple-type-error
2271             :format-control "Can't use anonymous or undefined class as a constant: ~S."
2272             :format-arguments (list class)))
2273    `(find-class ',name)))
2274
2275(defun invalid-method-error (method format-control &rest args)
2276  (let ((message (apply #'format nil format-control args)))
2277    (error "Invalid method error for ~S:~%    ~A" method message)))
2278
2279(defun method-combination-error (format-control &rest args)
2280  (let ((message (apply #'format nil format-control args)))
2281    (error "Method combination error in CLOS dispatch:~%    ~A" message)))
2282
2283(defgeneric no-applicable-method (generic-function &rest args))
2284
2285(defmethod no-applicable-method (generic-function &rest args)
2286  (error "There is no applicable method for the generic function ~S when called with arguments ~S."
2287         generic-function
2288         args))
2289
2290(defgeneric find-method (generic-function
2291                         qualifiers
2292                         specializers
2293                         &optional errorp))
2294
2295(defmethod find-method ((generic-function standard-generic-function)
2296      qualifiers specializers &optional (errorp t))
2297  (%find-method generic-function qualifiers specializers errorp))
2298
2299(defgeneric add-method (generic-function method))
2300
2301(defmethod add-method ((generic-function standard-generic-function) (method method))
2302  (let ((method-lambda-list (method-lambda-list method))
2303        (gf-lambda-list (generic-function-lambda-list generic-function)))
2304    (check-method-lambda-list method-lambda-list gf-lambda-list))
2305  (%add-method generic-function method))
2306
2307(defgeneric remove-method (generic-function method))
2308
2309(defmethod remove-method ((generic-function standard-generic-function) method)
2310  (%remove-method generic-function method))
2311
2312;; See describe.lisp.
2313(defgeneric describe-object (object stream))
2314
2315;; FIXME
2316(defgeneric no-next-method (generic-function method &rest args))
2317
2318;; FIXME
2319(defgeneric function-keywords (method))
2320
2321(provide 'clos)
Note: See TracBrowser for help on using the repository browser.