source: trunk/abcl/src/org/armedbear/lisp/clos.lisp @ 13830

Last change on this file since 13830 was 13830, checked in by rschlatte, 10 years ago

Clear generic-function slot of method object in remove-method.

... Fixes ansi tests ADD-METHOD.1, ADD-METHOD.2.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 160.1 KB
Line 
1;;; clos.lisp
2;;;
3;;; Copyright (C) 2003-2007 Peter Graves
4;;; Copyright (C) 2010 Mark Evenson
5;;; $Id: clos.lisp 13830 2012-01-29 23:40:50Z rschlatte $
6;;;
7;;; This program is free software; you can redistribute it and/or
8;;; modify it under the terms of the GNU General Public License
9;;; as published by the Free Software Foundation; either version 2
10;;; of the License, or (at your option) any later version.
11;;;
12;;; This program is distributed in the hope that it will be useful,
13;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
14;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15;;; GNU General Public License for more details.
16;;;
17;;; You should have received a copy of the GNU General Public License
18;;; along with this program; if not, write to the Free Software
19;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
20;;;
21;;; As a special exception, the copyright holders of this library give you
22;;; permission to link this library with independent modules to produce an
23;;; executable, regardless of the license terms of these independent
24;;; modules, and to copy and distribute the resulting executable under
25;;; terms of your choice, provided that you also meet, for each linked
26;;; independent module, the terms and conditions of the license of that
27;;; module.  An independent module is a module which is not derived from
28;;; or based on this library.  If you modify this library, you may extend
29;;; this exception to your version of the library, but you are not
30;;; obligated to do so.  If you do not wish to do so, delete this
31;;; exception statement from your version.
32
33;;; Originally based on Closette.
34
35;;; Closette Version 1.0 (February 10, 1991)
36;;;
37;;; Copyright (c) 1990, 1991 Xerox Corporation.
38;;; All rights reserved.
39;;;
40;;; Use and copying of this software and preparation of derivative works
41;;; based upon this software are permitted.  Any distribution of this
42;;; software or derivative works must comply with all applicable United
43;;; States export control laws.
44;;;
45;;; This software is made available AS IS, and Xerox Corporation makes no
46;;; warranty about the software, its performance or its conformity to any
47;;; specification.
48;;;
49;;; Closette is an implementation of a subset of CLOS with a metaobject
50;;; protocol as described in "The Art of The Metaobject Protocol",
51;;; MIT Press, 1991.
52
53(in-package #:mop)
54
55;;
56;;
57;;
58;; In order to bootstrap CLOS, first implement the required API as
59;; normal functions which only apply to the "root" metaclass
60;; STANDARD-CLASS.
61;;
62;; After putting the normal functions in place, the building blocks
63;; are in place to gradually swap the normal functions with
64;; generic functions and methods.
65;;
66;; Some functionality implemented in the temporary regular functions
67;; needs to be available later as a method definition to be dispatched
68;; to for the standard case, e.g. with arguments of type STANDARD-CLASS
69;; or STANDARD-GENERIC-FUNCTION.  To prevent repeated code, the
70;; functions are implemented in functions by the same name as the API
71;; functions, but with the STD- prefix.  These functions are sometimes
72;; used in regular code as well, either in a "fast path" or to break a
73;; circularity (e.g., within compute-discriminating-function when the
74;; user adds a method to compute-discriminating-function).
75;;
76;; When hacking this file, note that some important parts are implemented
77;; in the Java world. These Java bits can be found in the files
78;;
79;; * LispClass.java
80;; * SlotClass.java
81;; * StandardClass.java
82;; * BuiltInClass.java
83;; * StandardObject.java
84;; * StandardObjectFunctions.java
85;; * FuncallableStandardObject.java
86;; * Layout.java
87;;
88;; In case of function names, those defined on the Java side can be
89;; recognized by their prefixed percent (%) sign.
90;;
91;; The API functions need to be declaimed NOTINLINE explicitly, because
92;; that prevents inlining in the current FASL (which is allowed by the
93;; CLHS without the declaration); this is a hard requirement to in order
94;; to be able to swap the symbol's function slot with a generic function
95;; later on - with it actually being used.
96;;
97;;
98;;
99;; ### Note that the "declares all API functions as regular functions"
100;; isn't true when I write the above, but it's definitely the target.
101;;
102;;
103
104(export '(class-precedence-list class-slots
105          slot-definition-name))
106(defconstant +the-standard-class+ (find-class 'standard-class))
107(defconstant +the-structure-class+ (find-class 'structure-class))
108(defconstant +the-standard-object-class+ (find-class 'standard-object))
109(defconstant +the-standard-method-class+ (find-class 'standard-method))
110(defconstant +the-forward-referenced-class+
111  (find-class 'forward-referenced-class))
112(defconstant +the-standard-reader-method-class+
113  (find-class 'standard-reader-method))
114(defconstant +the-standard-writer-method-class+
115  (find-class 'standard-writer-method))
116(defconstant +the-standard-generic-function-class+
117  (find-class 'standard-generic-function))
118(defconstant +the-T-class+ (find-class 'T))
119(defconstant +the-standard-slot-definition-class+ (find-class 'standard-slot-definition))
120(defconstant +the-standard-direct-slot-definition-class+ (find-class 'standard-direct-slot-definition))
121(defconstant +the-standard-effective-slot-definition-class+ (find-class 'standard-effective-slot-definition))
122
123;; Don't use DEFVAR, because that disallows loading clos.lisp
124;; after compiling it: the binding won't get assigned to T anymore
125(defparameter *clos-booting* t)
126
127(defmacro define-class->%class-forwarder (name)
128  (let* (($name (if (consp name) (cadr name) name))
129         (%name (intern (concatenate 'string
130                                     "%"
131                                     (if (consp name)
132                                         (symbol-name 'set-) "")
133                                     (symbol-name $name))
134                        (symbol-package $name))))
135    `(progn
136       (declaim (notinline ,name))
137       (defun ,name (&rest args)
138         (apply #',%name args)))))
139
140;;
141;;  DEFINE PLACE HOLDER FUNCTIONS
142;;
143
144(define-class->%class-forwarder class-name)
145(define-class->%class-forwarder (setf class-name))
146(define-class->%class-forwarder class-slots)
147(define-class->%class-forwarder (setf class-slots))
148(define-class->%class-forwarder class-direct-slots)
149(define-class->%class-forwarder (setf class-direct-slots))
150(define-class->%class-forwarder class-layout)
151(define-class->%class-forwarder (setf class-layout))
152(define-class->%class-forwarder class-direct-superclasses)
153(define-class->%class-forwarder (setf class-direct-superclasses))
154(define-class->%class-forwarder class-direct-subclasses)
155(define-class->%class-forwarder (setf class-direct-subclasses))
156(define-class->%class-forwarder class-direct-methods)
157(define-class->%class-forwarder (setf class-direct-methods))
158(define-class->%class-forwarder class-precedence-list)
159(define-class->%class-forwarder (setf class-precedence-list))
160(define-class->%class-forwarder class-finalized-p)
161(define-class->%class-forwarder (setf class-finalized-p))
162(define-class->%class-forwarder class-default-initargs)
163(define-class->%class-forwarder (setf class-default-initargs))
164(define-class->%class-forwarder class-direct-default-initargs)
165(define-class->%class-forwarder (setf class-direct-default-initargs))
166
167(defun no-applicable-method (generic-function &rest args)
168  (error "There is no applicable method for the generic function ~S when called with arguments ~S."
169         generic-function
170         args))
171
172(defun function-keywords (method)
173  (std-function-keywords method))
174
175
176
177(defmacro push-on-end (value location)
178  `(setf ,location (nconc ,location (list ,value))))
179
180;;; (SETF GETF*) is like (SETF GETF) except that it always changes the list,
181;;; which must be non-nil.
182
183(defun (setf getf*) (new-value plist key)
184  (block body
185    (do ((x plist (cddr x)))
186        ((null x))
187      (when (eq (car x) key)
188        (setf (car (cdr x)) new-value)
189        (return-from body new-value)))
190    (push-on-end key plist)
191    (push-on-end new-value plist)
192    new-value))
193
194(defun mapappend (fun &rest args)
195  (if (some #'null args)
196      ()
197      (append (apply fun (mapcar #'car args))
198              (apply #'mapappend fun (mapcar #'cdr args)))))
199
200(defun mapplist (fun x)
201  (if (null x)
202      ()
203      (cons (funcall fun (car x) (cadr x))
204            (mapplist fun (cddr x)))))
205
206(defsetf std-instance-layout %set-std-instance-layout)
207(defsetf standard-instance-access %set-standard-instance-access)
208
209(defun (setf find-class) (new-value symbol &optional errorp environment)
210  (declare (ignore errorp environment))
211  (%set-find-class symbol new-value))
212
213(defun canonicalize-direct-slots (direct-slots)
214  `(list ,@(mapcar #'canonicalize-direct-slot direct-slots)))
215
216(defun canonicalize-direct-slot (spec)
217  (if (symbolp spec)
218      `(list :name ',spec)
219      (let ((name (car spec))
220            (initfunction nil)
221            (initform nil)
222            (initargs ())
223            (type nil)
224            (allocation nil)
225            (documentation nil)
226            (readers ())
227            (writers ())
228            (other-options ())
229            (non-std-options ()))
230        (do ((olist (cdr spec) (cddr olist)))
231            ((null olist))
232          (case (car olist)
233            (:initform
234             (when initform
235               (error 'program-error
236                      "duplicate slot option :INITFORM for slot named ~S"
237                      name))
238             (setq initfunction t)
239             (setq initform (cadr olist)))
240            (:initarg
241             (push-on-end (cadr olist) initargs))
242            (:allocation
243             (when allocation
244               (error 'program-error
245                      "duplicate slot option :ALLOCATION for slot named ~S"
246                      name))
247             (setf allocation (cadr olist))
248             (push-on-end (car olist) other-options)
249             (push-on-end (cadr olist) other-options))
250            (:type
251             (when type
252               (error 'program-error
253                      "duplicate slot option :TYPE for slot named ~S"
254                      name))
255             (setf type (cadr olist))) ;; FIXME type is ignored
256            (:documentation
257             (when documentation
258               (error 'program-error
259                      "duplicate slot option :DOCUMENTATION for slot named ~S"
260                      name))
261             (setf documentation (cadr olist))) ;; FIXME documentation is ignored
262            (:reader
263             (maybe-note-name-defined (cadr olist))
264             (push-on-end (cadr olist) readers))
265            (:writer
266             (maybe-note-name-defined (cadr olist))
267             (push-on-end (cadr olist) writers))
268            (:accessor
269             (maybe-note-name-defined (cadr olist))
270             (push-on-end (cadr olist) readers)
271             (push-on-end `(setf ,(cadr olist)) writers))
272            (t
273             (push-on-end `(quote ,(car olist)) non-std-options)
274             (push-on-end `(quote ,(cadr olist)) non-std-options))))
275        `(list
276          :name ',name
277          ,@(when initfunction
278              `(:initform ',initform
279                :initfunction ,(if (eq allocation :class)
280                                   ;; CLHS specifies the initform for a
281                                   ;; class allocation level slot needs
282                                   ;; to be evaluated in the dynamic
283                                   ;; extent of the DEFCLASS form
284                                   (let ((var (gensym)))
285                                     `(let ((,var ,initform))
286                                        (lambda () ,var)))
287                                 `(lambda () ,initform))))
288          ,@(when initargs `(:initargs ',initargs))
289          ,@(when readers `(:readers ',readers))
290          ,@(when writers `(:writers ',writers))
291          ,@other-options
292    ,@non-std-options))))
293
294(defun maybe-note-name-defined (name)
295  (when (fboundp 'note-name-defined)
296    (note-name-defined name)))
297
298(defun canonicalize-defclass-options (options)
299  (mapappend #'canonicalize-defclass-option options))
300
301(defun canonicalize-defclass-option (option)
302  (case (car option)
303    (:metaclass
304     (list ':metaclass
305           `(find-class ',(cadr option))))
306    (:default-initargs
307     (list
308      ':direct-default-initargs
309      `(list ,@(mapappend
310                #'(lambda (x) x)
311                (mapplist
312                 #'(lambda (key value)
313                    `(',key ,(make-initfunction value)))
314                 (cdr option))))))
315    ((:documentation :report)
316     (list (car option) `',(cadr option)))
317    (t (list `(quote ,(car option)) `(quote ,(cdr option))))))
318
319(defun make-initfunction (initform)
320  `(function (lambda () ,initform)))
321
322(defun slot-definition-allocation (slot-definition)
323  (%slot-definition-allocation slot-definition))
324
325(declaim (notinline (setf slot-definition-allocation)))
326(defun (setf slot-definition-allocation) (value slot-definition)
327  (set-slot-definition-allocation slot-definition value))
328
329(defun slot-definition-initargs (slot-definition)
330  (%slot-definition-initargs slot-definition))
331
332(declaim (notinline (setf slot-definition-initargs)))
333(defun (setf slot-definition-initargs) (value slot-definition)
334  (set-slot-definition-initargs slot-definition value))
335
336(defun slot-definition-initform (slot-definition)
337  (%slot-definition-initform slot-definition))
338
339(declaim (notinline (setf slot-definition-initform)))
340(defun (setf slot-definition-initform) (value slot-definition)
341  (set-slot-definition-initform slot-definition value))
342
343(defun slot-definition-initfunction (slot-definition)
344  (%slot-definition-initfunction slot-definition))
345
346(declaim (notinline (setf slot-definition-initfunction)))
347(defun (setf slot-definition-initfunction) (value slot-definition)
348  (set-slot-definition-initfunction slot-definition value))
349
350(defun slot-definition-name (slot-definition)
351  (%slot-definition-name slot-definition))
352
353(declaim (notinline (setf slot-definition-name)))
354(defun (setf slot-definition-name) (value slot-definition)
355  (set-slot-definition-name slot-definition value))
356
357(defun slot-definition-readers (slot-definition)
358  (%slot-definition-readers slot-definition))
359
360(declaim (notinline (setf slot-definition-readers)))
361(defun (setf slot-definition-readers) (value slot-definition)
362  (set-slot-definition-readers slot-definition value))
363
364(defun slot-definition-writers (slot-definition)
365  (%slot-definition-writers slot-definition))
366
367(declaim (notinline (setf slot-definition-writers)))
368(defun (setf slot-definition-writers) (value slot-definition)
369  (set-slot-definition-writers slot-definition value))
370
371(defun slot-definition-allocation-class (slot-definition)
372  (%slot-definition-allocation-class slot-definition))
373
374(declaim (notinline (setf slot-definition-allocation-class)))
375(defun (setf slot-definition-allocation-class) (value slot-definition)
376  (set-slot-definition-allocation-class slot-definition value))
377
378(defun slot-definition-location (slot-definition)
379  (%slot-definition-location slot-definition))
380
381(declaim (notinline (setf slot-definition-location-class)))
382(defun (setf slot-definition-location) (value slot-definition)
383  (set-slot-definition-location slot-definition value))
384
385(defun init-slot-definition (slot &key name
386                             (initargs ())
387                             (initform nil)
388                             (initfunction nil)
389                             (readers ())
390                             (writers ())
391                             (allocation :instance)
392                             (allocation-class nil))
393  (setf (slot-definition-name slot) name)
394  (setf (slot-definition-initargs slot) initargs)
395  (setf (slot-definition-initform slot) initform)
396  (setf (slot-definition-initfunction slot) initfunction)
397  (setf (slot-definition-readers slot) readers)
398  (setf (slot-definition-writers slot) writers)
399  (setf (slot-definition-allocation slot) allocation)
400  (setf (slot-definition-allocation-class slot) allocation-class)
401  slot)
402
403(defun make-direct-slot-definition (class &rest args)
404  (let ((slot-class (direct-slot-definition-class class)))
405    (if (eq slot-class +the-standard-direct-slot-definition-class+)
406  (let ((slot (make-slot-definition +the-standard-direct-slot-definition-class+)))
407    (apply #'init-slot-definition slot :allocation-class class args)
408    slot)
409  (progn
410    (let ((slot (apply #'make-instance slot-class :allocation-class class
411           args)))
412      slot)))))
413
414(defun make-effective-slot-definition (class &rest args)
415  (let ((slot-class (effective-slot-definition-class class)))
416    (if (eq slot-class +the-standard-effective-slot-definition-class+)
417  (let ((slot (make-slot-definition +the-standard-effective-slot-definition-class+)))
418    (apply #'init-slot-definition slot args)
419    slot)
420  (progn
421    (let ((slot (apply #'make-instance slot-class args)))
422      slot)))))
423
424;;; finalize-inheritance
425
426(defun std-compute-class-default-initargs (class)
427  (mapcan #'(lambda (c)
428              (copy-list
429               (class-direct-default-initargs c)))
430          (class-precedence-list class)))
431
432(defun std-finalize-inheritance (class)
433  ;; In case the class is already finalized, return
434  ;; immediately, as per AMOP.
435  (when (class-finalized-p class)
436    (return-from std-finalize-inheritance))
437  (setf (class-precedence-list class)
438   (funcall (if (eq (class-of class) +the-standard-class+)
439                #'std-compute-class-precedence-list
440                #'compute-class-precedence-list)
441            class))
442  (setf (class-slots class)
443                   (funcall (if (eq (class-of class) +the-standard-class+)
444                                #'std-compute-slots
445                     #'compute-slots) class))
446  (let ((old-layout (class-layout class))
447        (length 0)
448        (instance-slots '())
449        (shared-slots '()))
450    (dolist (slot (class-slots class))
451      (case (slot-definition-allocation slot)
452        (:instance
453         (setf (slot-definition-location slot) length)
454         (incf length)
455         (push (slot-definition-name slot) instance-slots))
456        (:class
457         (unless (slot-definition-location slot)
458           (let ((allocation-class (slot-definition-allocation-class slot)))
459             (setf (slot-definition-location slot)
460       (if (eq allocation-class class)
461           (cons (slot-definition-name slot) +slot-unbound+)
462           (slot-location allocation-class (slot-definition-name slot))))))
463         (push (slot-definition-location slot) shared-slots))))
464    (when old-layout
465      ;; Redefined class: initialize added shared slots.
466      (dolist (location shared-slots)
467        (let* ((slot-name (car location))
468               (old-location (layout-slot-location old-layout slot-name)))
469          (unless old-location
470            (let* ((slot-definition (find slot-name (class-slots class) :key 'slot-definition-name))
471                   (initfunction (slot-definition-initfunction slot-definition)))
472              (when initfunction
473                (setf (cdr location) (funcall initfunction))))))))
474    (setf (class-layout class)
475          (make-layout class (nreverse instance-slots) (nreverse shared-slots))))
476  (setf (class-default-initargs class)
477        (std-compute-class-default-initargs class))
478  (setf (class-finalized-p class) t))
479
480(declaim (notinline finalize-inheritance))
481(defun finalize-inheritance (class)
482  (std-finalize-inheritance class))
483
484
485;;; Class precedence lists
486
487(defun std-compute-class-precedence-list (class)
488  (let ((classes-to-order (collect-superclasses* class)))
489    (dolist (super classes-to-order)
490      (when (typep super 'forward-referenced-class)
491        (error "Can't compute class precedence list for class ~A ~
492                which depends on forward referenced class ~A." class super)))
493    (topological-sort classes-to-order
494                      (remove-duplicates
495                       (mapappend #'local-precedence-ordering
496                                  classes-to-order))
497                      #'std-tie-breaker-rule)))
498
499;;; topological-sort implements the standard algorithm for topologically
500;;; sorting an arbitrary set of elements while honoring the precedence
501;;; constraints given by a set of (X,Y) pairs that indicate that element
502;;; X must precede element Y.  The tie-breaker procedure is called when it
503;;; is necessary to choose from multiple minimal elements; both a list of
504;;; candidates and the ordering so far are provided as arguments.
505
506(defun topological-sort (elements constraints tie-breaker)
507  (let ((remaining-constraints constraints)
508        (remaining-elements elements)
509        (result ()))
510    (loop
511      (let ((minimal-elements
512             (remove-if
513              #'(lambda (class)
514                 (member class remaining-constraints
515                         :key #'cadr))
516              remaining-elements)))
517        (when (null minimal-elements)
518          (if (null remaining-elements)
519              (return-from topological-sort result)
520              (error "Inconsistent precedence graph.")))
521        (let ((choice (if (null (cdr minimal-elements))
522                          (car minimal-elements)
523                          (funcall tie-breaker
524                                   minimal-elements
525                                   result))))
526          (setq result (append result (list choice)))
527          (setq remaining-elements
528                (remove choice remaining-elements))
529          (setq remaining-constraints
530                (remove choice
531                        remaining-constraints
532                        :test #'member)))))))
533
534;;; In the event of a tie while topologically sorting class precedence lists,
535;;; the CLOS Specification says to "select the one that has a direct subclass
536;;; rightmost in the class precedence list computed so far."  The same result
537;;; is obtained by inspecting the partially constructed class precedence list
538;;; from right to left, looking for the first minimal element to show up among
539;;; the direct superclasses of the class precedence list constituent.
540;;; (There's a lemma that shows that this rule yields a unique result.)
541
542(defun std-tie-breaker-rule (minimal-elements cpl-so-far)
543  (dolist (cpl-constituent (reverse cpl-so-far))
544    (let* ((supers (class-direct-superclasses cpl-constituent))
545           (common (intersection minimal-elements supers)))
546      (when (not (null common))
547        (return-from std-tie-breaker-rule (car common))))))
548
549;;; This version of collect-superclasses* isn't bothered by cycles in the class
550;;; hierarchy, which sometimes happen by accident.
551
552(defun collect-superclasses* (class)
553  (labels ((all-superclasses-loop (seen superclasses)
554                                  (let ((to-be-processed
555                                         (set-difference superclasses seen)))
556                                    (if (null to-be-processed)
557                                        superclasses
558                                        (let ((class-to-process
559                                               (car to-be-processed)))
560                                          (all-superclasses-loop
561                                           (cons class-to-process seen)
562                                           (union (class-direct-superclasses
563                                                   class-to-process)
564                                                  superclasses)))))))
565          (all-superclasses-loop () (list class))))
566
567;;; The local precedence ordering of a class C with direct superclasses C_1,
568;;; C_2, ..., C_n is the set ((C C_1) (C_1 C_2) ...(C_n-1 C_n)).
569
570(defun local-precedence-ordering (class)
571  (mapcar #'list
572          (cons class
573                (butlast (class-direct-superclasses class)))
574          (class-direct-superclasses class)))
575
576;;; Slot inheritance
577
578(defun std-compute-slots (class)
579  (let* ((all-slots (mapappend #'class-direct-slots
580                               (class-precedence-list class)))
581         (all-names (remove-duplicates
582                     (mapcar 'slot-definition-name all-slots))))
583    (mapcar #'(lambda (name)
584               (funcall
585                (if (eq (class-of class) +the-standard-class+)
586                    #'std-compute-effective-slot-definition
587                    #'compute-effective-slot-definition)
588                class
589                name
590                (remove name all-slots
591                        :key 'slot-definition-name
592                        :test-not #'eq)))
593            all-names)))
594
595(defun std-compute-effective-slot-definition (class name direct-slots)
596  (let ((initer (find-if-not #'null direct-slots
597                             :key 'slot-definition-initfunction)))
598    (make-effective-slot-definition
599     class
600     :name name
601     :initform (if initer
602                   (slot-definition-initform initer)
603                   nil)
604     :initfunction (if initer
605                       (slot-definition-initfunction initer)
606                       nil)
607     :initargs (remove-duplicates
608                (mapappend 'slot-definition-initargs
609                           direct-slots))
610     :allocation (slot-definition-allocation (car direct-slots))
611     :allocation-class (when (slot-boundp (car direct-slots)
612            'sys::allocation-class)
613       ;;for some classes created in Java
614       ;;(e.g. SimpleCondition) this slot is unbound
615       (slot-definition-allocation-class (car direct-slots))))))
616
617;;; Standard instance slot access
618
619;;; N.B. The location of the effective-slots slots in the class metaobject for
620;;; standard-class must be determined without making any further slot
621;;; references.
622
623(defun find-slot-definition (class slot-name)
624  (dolist (slot (class-slots class) nil)
625    (when (eq slot-name (slot-definition-name slot))
626      (return slot))))
627
628(defun slot-location (class slot-name)
629  (let ((slot (find-slot-definition class slot-name)))
630    (if slot
631        (slot-definition-location slot)
632        nil)))
633
634(defun instance-slot-location (instance slot-name)
635  (let ((layout (std-instance-layout instance)))
636    (and layout (layout-slot-location layout slot-name))))
637
638(defun slot-value (object slot-name)
639  (if (or (eq (class-of (class-of object)) +the-standard-class+)
640    (eq (class-of (class-of object)) +the-structure-class+))
641      (std-slot-value object slot-name)
642      (slot-value-using-class (class-of object) object slot-name)))
643
644(defsetf std-slot-value set-std-slot-value)
645
646(defun %set-slot-value (object slot-name new-value)
647  (if (or (eq (class-of (class-of object)) +the-standard-class+)
648    (eq (class-of (class-of object)) +the-structure-class+))
649      (setf (std-slot-value object slot-name) new-value)
650      (set-slot-value-using-class new-value (class-of object)
651                                  object slot-name)))
652
653(defsetf slot-value %set-slot-value)
654
655(defun slot-boundp (object slot-name)
656  (if (eq (class-of (class-of object)) +the-standard-class+)
657      (std-slot-boundp object slot-name)
658      (slot-boundp-using-class (class-of object) object slot-name)))
659
660(defun std-slot-makunbound (instance slot-name)
661  (let ((location (instance-slot-location instance slot-name)))
662    (cond ((fixnump location)
663           (setf (standard-instance-access instance location) +slot-unbound+))
664          ((consp location)
665           (setf (cdr location) +slot-unbound+))
666          (t
667           (slot-missing (class-of instance) instance slot-name 'slot-makunbound))))
668  instance)
669
670(defun slot-makunbound (object slot-name)
671  (if (eq (class-of (class-of object)) +the-standard-class+)
672      (std-slot-makunbound object slot-name)
673      (slot-makunbound-using-class (class-of object) object slot-name)))
674
675(defun std-slot-exists-p (instance slot-name)
676  (not (null (find slot-name (class-slots (class-of instance))
677                   :key 'slot-definition-name))))
678
679(defun slot-exists-p (object slot-name)
680  (if (eq (class-of (class-of object)) +the-standard-class+)
681      (std-slot-exists-p object slot-name)
682      (slot-exists-p-using-class (class-of object) object slot-name)))
683
684(defun instance-slot-p (slot)
685  (eq (slot-definition-allocation slot) :instance))
686
687(defun std-allocate-instance (class)
688  ;; AMOP says ALLOCATE-INSTANCE checks if the class is finalized
689  ;; and if not, tries to finalize it.
690  (unless (class-finalized-p class)
691    (std-finalize-inheritance class))
692  (sys::%std-allocate-instance class))
693
694(defun allocate-funcallable-instance (class)
695  (unless (class-finalized-p class)
696    (std-finalize-inheritance class))
697  (let ((instance (sys::%allocate-funcallable-instance class)))
698    (set-funcallable-instance-function
699     instance
700     #'(lambda (&rest args)
701         (declare (ignore args))
702         (error 'program-error "Called a funcallable-instance with unset function.")))
703    instance))
704
705(defun make-instance-standard-class (metaclass
706             &rest initargs
707                                     &key name direct-superclasses direct-slots
708                                     direct-default-initargs
709                                     documentation)
710  (declare (ignore metaclass))
711  (let ((class (std-allocate-instance +the-standard-class+)))
712    (check-initargs (list #'allocate-instance #'initialize-instance)
713                    (list* class initargs)
714                    class t initargs
715                    *make-instance-initargs-cache* 'make-instance)
716    (%set-class-name name class)
717    (%set-class-layout nil class)
718    (%set-class-direct-subclasses ()  class)
719    (%set-class-direct-methods ()  class)
720    (%set-class-documentation class documentation)
721    (std-after-initialization-for-classes class
722                                          :direct-superclasses direct-superclasses
723                                          :direct-slots direct-slots
724                                          :direct-default-initargs direct-default-initargs)
725    class))
726
727;(defun convert-to-direct-slot-definition (class canonicalized-slot)
728;  (apply #'make-instance
729;         (apply #'direct-slot-definition-class
730;                class canonicalized-slot)
731;         canonicalized-slot))
732
733(defun std-after-initialization-for-classes (class
734                                             &key direct-superclasses direct-slots
735                                             direct-default-initargs
736                                             &allow-other-keys)
737  (let ((supers (or direct-superclasses
738                    (list +the-standard-object-class+))))
739    (setf (class-direct-superclasses class) supers)
740    (dolist (superclass supers)
741      (pushnew class (class-direct-subclasses superclass))))
742  (let ((slots (mapcar #'(lambda (slot-properties)
743                          (apply #'make-direct-slot-definition class slot-properties))
744                       direct-slots)))
745    (setf (class-direct-slots class) slots)
746    (dolist (direct-slot slots)
747      (dolist (reader (slot-definition-readers direct-slot))
748        (add-reader-method class reader direct-slot))
749      (dolist (writer (slot-definition-writers direct-slot))
750        (add-writer-method class writer direct-slot))))
751  (setf (class-direct-default-initargs class) direct-default-initargs)
752  (maybe-finalize-class-subtree class)
753  (values))
754
755(defun canonical-slot-name (canonical-slot)
756  (getf canonical-slot :name))
757
758(defvar *extensible-built-in-classes*
759  (list (find-class 'sequence)
760        (find-class 'java:java-object)))
761
762(defvar *make-instance-initargs-cache*
763  (make-hash-table :test #'eq)
764  "Cached sets of allowable initargs, keyed on the class they belong to.")
765(defvar *reinitialize-instance-initargs-cache*
766  (make-hash-table :test #'eq)
767  "Cached sets of allowable initargs, keyed on the class they belong to.")
768
769(defun expand-long-defcombin (name args)
770  (destructuring-bind (lambda-list method-groups &rest body) args
771    `(apply #'define-long-form-method-combination
772            ',name
773            ',lambda-list
774            (list ,@(mapcar #'canonicalize-method-group-spec method-groups))
775            ',body)))
776
777;;; The class method-combination and its subclasses are defined in
778;;; StandardClass.java, but we cannot use make-instance and slot-value
779;;; yet.
780
781(defun %make-long-method-combination (&key name documentation lambda-list
782                                       method-group-specs args-lambda-list
783                                       generic-function-symbol function
784                                       arguments declarations forms)
785  (let ((instance (std-allocate-instance (find-class 'long-method-combination))))
786    (setf (std-slot-value instance 'sys::name) name)
787    (setf (std-slot-value instance 'documentation) documentation)
788    (setf (std-slot-value instance 'sys::lambda-list) lambda-list)
789    (setf (std-slot-value instance 'method-group-specs) method-group-specs)
790    (setf (std-slot-value instance 'args-lambda-list) args-lambda-list)
791    (setf (std-slot-value instance 'generic-function-symbol)
792          generic-function-symbol)
793    (setf (std-slot-value instance 'function) function)
794    (setf (std-slot-value instance 'arguments) arguments)
795    (setf (std-slot-value instance 'declarations) declarations)
796    (setf (std-slot-value instance 'forms) forms)
797    instance))
798
799(defun method-combination-name (method-combination)
800  (check-type method-combination method-combination)
801  (std-slot-value method-combination 'sys::name))
802
803(defun method-combination-documentation (method-combination)
804  (check-type method-combination method-combination)
805  (std-slot-value method-combination 'documentation))
806
807(defun short-method-combination-operator (method-combination)
808  (check-type method-combination short-method-combination)
809  (std-slot-value method-combination 'operator))
810
811(defun short-method-combination-identity-with-one-argument (method-combination)
812  (check-type method-combination short-method-combination)
813  (std-slot-value method-combination 'identity-with-one-argument))
814
815(defun long-method-combination-lambda-list (method-combination)
816  (check-type method-combination long-method-combination)
817  (std-slot-value method-combination 'sys::lambda-list))
818
819(defun long-method-combination-method-group-specs (method-combination)
820  (check-type method-combination long-method-combination)
821  (std-slot-value method-combination 'method-group-specs))
822
823(defun long-method-combination-args-lambda-list (method-combination)
824  (check-type method-combination long-method-combination)
825  (std-slot-value method-combination 'args-lambda-list))
826
827(defun long-method-combination-generic-function-symbol (method-combination)
828  (check-type method-combination long-method-combination)
829  (std-slot-value method-combination 'generic-function-symbol))
830
831(defun long-method-combination-function (method-combination)
832  (check-type method-combination long-method-combination)
833  (std-slot-value method-combination 'function))
834
835(defun long-method-combination-arguments (method-combination)
836  (check-type method-combination long-method-combination)
837  (std-slot-value method-combination 'arguments))
838
839(defun long-method-combination-declarations (method-combination)
840  (check-type method-combination long-method-combination)
841  (std-slot-value method-combination 'declarations))
842
843(defun long-method-combination-forms (method-combination)
844  (check-type method-combination long-method-combination)
845  (std-slot-value method-combination 'forms))
846
847
848(defun expand-short-defcombin (whole)
849  (let* ((name (cadr whole))
850         (documentation
851          (getf (cddr whole) :documentation ""))
852         (identity-with-one-arg
853          (getf (cddr whole) :identity-with-one-argument nil))
854         (operator
855          (getf (cddr whole) :operator name)))
856    `(progn
857       ;; Class short-method-combination is defined in StandardClass.java.
858       (let ((instance (std-allocate-instance
859                        (find-class 'short-method-combination))))
860         (setf (std-slot-value instance 'sys::name) ',name)
861         (setf (std-slot-value instance 'documentation) ',documentation)
862         (setf (std-slot-value instance 'operator) ',operator)
863         (setf (std-slot-value instance 'identity-with-one-argument)
864               ',identity-with-one-arg)
865         (setf (get ',name 'method-combination-object) instance)
866         ',name))))
867
868(defmacro define-method-combination (&whole form name &rest args)
869  (if (and (cddr form)
870           (listp (caddr form)))
871      (expand-long-defcombin name args)
872      (expand-short-defcombin form)))
873
874(define-method-combination +      :identity-with-one-argument t)
875(define-method-combination and    :identity-with-one-argument t)
876(define-method-combination append :identity-with-one-argument nil)
877(define-method-combination list   :identity-with-one-argument nil)
878(define-method-combination max    :identity-with-one-argument t)
879(define-method-combination min    :identity-with-one-argument t)
880(define-method-combination nconc  :identity-with-one-argument t)
881(define-method-combination or     :identity-with-one-argument t)
882(define-method-combination progn  :identity-with-one-argument t)
883
884;;;
885;;; long form of define-method-combination (from Sacla and XCL)
886;;;
887(defun define-method-combination-type (name &rest initargs)
888    (setf (get name 'method-combination-object)
889          (apply '%make-long-method-combination initargs)))
890
891(defun method-group-p (selecter qualifiers)
892  ;; selecter::= qualifier-pattern | predicate
893  (etypecase selecter
894    (list (or (equal selecter qualifiers)
895              (let ((last (last selecter)))
896                (when (eq '* (cdr last))
897                  (let* ((prefix `(,@(butlast selecter) ,(car last)))
898                         (pos (mismatch prefix qualifiers)))
899                    (or (null pos) (= pos (length prefix))))))))
900    ((eql *) t)
901    (symbol (funcall (symbol-function selecter) qualifiers))))
902
903(defun check-variable-name (name)
904  (flet ((valid-variable-name-p (name)
905                                (and (symbolp name) (not (constantp name)))))
906    (assert (valid-variable-name-p name))))
907
908(defun canonicalize-method-group-spec (spec)
909  ;; spec ::= (name {qualifier-pattern+ | predicate} [[long-form-option]])
910  ;; long-form-option::= :description description | :order order |
911  ;;                     :required required-p
912  ;; a canonicalized-spec is a simple plist.
913  (let* ((rest spec)
914         (name (prog2 (check-variable-name (car rest))
915                 (car rest)
916                 (setq rest (cdr rest))))
917         (option-names '(:description :order :required))
918         (selecters (let ((end (or (position-if #'(lambda (it)
919                                                   (member it option-names))
920                                                rest)
921                                   (length rest))))
922                      (prog1 (subseq rest 0 end)
923                        (setq rest (subseq rest end)))))
924         (description (getf rest :description ""))
925         (order (getf rest :order :most-specific-first))
926         (required-p (getf rest :required)))
927    `(list :name ',name
928           :predicate (lambda (qualifiers)
929                        (loop for item in ',selecters
930                          thereis (method-group-p item qualifiers)))
931           :description ',description
932           :order ',order
933           :required ',required-p
934           :*-selecter ,(equal selecters '(*)))))
935
936(defun extract-required-part (lambda-list)
937  (flet ((skip (key lambda-list)
938               (if (eq (first lambda-list) key)
939                   (cddr lambda-list)
940                   lambda-list)))
941    (ldiff (skip '&environment (skip '&whole lambda-list))
942           (member-if #'(lambda (it) (member it lambda-list-keywords))
943                      lambda-list))))
944
945(defun extract-specified-part (key lambda-list)
946  (case key
947    ((&eval &whole)
948     (list (second (member key lambda-list))))
949    (t
950     (let ((here (cdr (member key lambda-list))))
951       (ldiff here
952              (member-if #'(lambda (it) (member it lambda-list-keywords))
953                         here))))))
954
955(defun extract-optional-part (lambda-list)
956  (extract-specified-part '&optional lambda-list))
957
958(defun parse-define-method-combination-arguments-lambda-list (lambda-list)
959  ;; Define-method-combination Arguments Lambda Lists
960  ;; http://www.lispworks.com/reference/HyperSpec/Body/03_dj.htm
961  (let ((required (extract-required-part lambda-list))
962        (whole    (extract-specified-part '&whole    lambda-list))
963        (optional (extract-specified-part '&optional lambda-list))
964        (rest     (extract-specified-part '&rest     lambda-list))
965        (keys     (extract-specified-part '&key      lambda-list))
966        (aux      (extract-specified-part '&aux      lambda-list)))
967    (values (first whole)
968            required
969            (mapcar #'(lambda (spec)
970                       (if (consp spec)
971                           `(,(first spec) ,(second spec) ,@(cddr spec))
972                           `(,spec nil)))
973                    optional)
974            (first rest)
975            (mapcar #'(lambda (spec)
976                       (let ((key (if (consp spec) (car spec) spec))
977                             (rest (when (consp spec) (rest spec))))
978                         `(,(if (consp key) key `(,(make-keyword key) ,key))
979                           ,(car rest)
980                           ,@(cdr rest))))
981                    keys)
982            (mapcar #'(lambda (spec)
983                       (if (consp spec)
984                           `(,(first spec) ,(second spec))
985                           `(,spec nil)))
986                    aux))))
987
988(defmacro getk (plist key init-form)
989  "Similar to getf except eval and return INIT-FORM if KEY has no value in PLIST."
990  (let ((not-exist (gensym))
991        (value (gensym)))
992    `(let ((,value (getf ,plist ,key ,not-exist)))
993       (if (eq ,not-exist ,value) ,init-form ,value))))
994
995(defun wrap-with-call-method-macro (gf args-var forms)
996  `(macrolet
997       ((call-method (method &optional next-method-list)
998          `(funcall
999            ,(cond
1000              ((listp method)
1001               (assert (eq (first method) 'make-method))
1002               ;; by generating an inline expansion we prevent allocation
1003               ;; of a method instance which will be discarded immediately
1004               ;; after reading the METHOD-FUNCTION slot
1005               (compute-method-function
1006                    `(lambda (&rest ,(gensym))
1007                       ;; the MAKE-METHOD body form gets evaluated in
1008                       ;; the null lexical environment augmented
1009                       ;; with a binding for CALL-METHOD
1010                       ,(wrap-with-call-method-macro ,gf
1011                                                     ',args-var
1012                                                     (second method)))))
1013              (t (method-function method)))
1014            ,',args-var
1015            ,(unless (null next-method-list)
1016                     ;; by not generating an emf when there are no next methods,
1017                     ;; we ensure next-method-p returns NIL
1018                     (compute-effective-method-function
1019                        ,gf (process-next-method-list next-method-list))))))
1020     ,@forms))
1021
1022(defmacro with-args-lambda-list (args-lambda-list
1023                                 generic-function-symbol
1024                                 gf-args-symbol
1025                                 &body forms)
1026  (let ((gf-lambda-list (gensym))
1027        (nrequired (gensym))
1028        (noptional (gensym))
1029        (rest-args (gensym)))
1030    (multiple-value-bind (whole required optional rest keys aux)
1031        (parse-define-method-combination-arguments-lambda-list args-lambda-list)
1032      `(let* ((,gf-lambda-list (slot-value ,generic-function-symbol 'sys::lambda-list))
1033              (,nrequired (length (extract-required-part ,gf-lambda-list)))
1034              (,noptional (length (extract-optional-part ,gf-lambda-list)))
1035              (,rest-args (subseq ,gf-args-symbol (+ ,nrequired ,noptional)))
1036              ,@(when whole `((,whole ,gf-args-symbol)))
1037              ,@(loop for var in required and i upfrom 0
1038                  collect `(,var (when (< ,i ,nrequired)
1039                                   (nth ,i ,gf-args-symbol))))
1040              ,@(loop for (var init-form) in optional and i upfrom 0
1041                  collect
1042                  `(,var (if (< ,i ,noptional)
1043                             (nth (+ ,nrequired ,i) ,gf-args-symbol)
1044                             ,init-form)))
1045              ,@(when rest `((,rest ,rest-args)))
1046              ,@(loop for ((key var) init-form) in keys and i upfrom 0
1047                  collect `(,var (getk ,rest-args ',key ,init-form)))
1048              ,@(loop for (var init-form) in aux and i upfrom 0
1049                  collect `(,var ,init-form)))
1050         ,@forms))))
1051
1052(defun assert-unambiguous-method-sorting (group-name methods)
1053  (let ((specializers (make-hash-table :test 'equal)))
1054    (dolist (method methods)
1055      (push method (gethash (method-specializers method) specializers)))
1056    (loop for specializer-methods being each hash-value of specializers
1057       using (hash-key method-specializers)
1058       unless (= 1 (length specializer-methods))
1059       do (error "Ambiguous method sorting in method group ~A due to multiple ~
1060                  methods with specializers ~S: ~S"
1061                 group-name method-specializers specializer-methods))))
1062
1063(defmacro with-method-groups (method-group-specs methods-form &body forms)
1064  (flet ((grouping-form (spec methods-var)
1065           (let ((predicate (coerce-to-function (getf spec :predicate)))
1066                 (group (gensym))
1067                 (leftovers (gensym))
1068                 (method (gensym)))
1069             `(let ((,group '())
1070                    (,leftovers '()))
1071                (dolist (,method ,methods-var)
1072                  (if (funcall ,predicate (method-qualifiers ,method))
1073                      (push ,method ,group)
1074                      (push ,method ,leftovers)))
1075                (ecase ,(getf spec :order)
1076                  (:most-specific-last )
1077                  (:most-specific-first (setq ,group (nreverse ,group))))
1078                ,@(when (getf spec :required)
1079                        `((when (null ,group)
1080                            (error "Method group ~S must not be empty."
1081                                   ',(getf spec :name)))))
1082                (setq ,methods-var (nreverse ,leftovers))
1083                ,group))))
1084    (let ((rest (gensym))
1085          (method (gensym)))
1086      `(let* ((,rest ,methods-form)
1087              ,@(mapcar #'(lambda (spec)
1088                           `(,(getf spec :name) ,(grouping-form spec rest)))
1089                        method-group-specs))
1090         (dolist (,method ,rest)
1091           (invalid-method-error ,method
1092                                 "Method ~S with qualifiers ~S does not belong to any method group."
1093                                 ,method (method-qualifiers ,method)))
1094         ,@(unless (and (= 1 (length method-group-specs))
1095                        (getf (car method-group-specs) :*-selecter))
1096             (mapcar #'(lambda (spec)
1097                         `(assert-unambiguous-method-sorting ',(getf spec :name) ,(getf spec :name)))
1098                     method-group-specs))
1099         ,@forms))))
1100
1101(defun method-combination-type-lambda
1102  (&key name lambda-list args-lambda-list generic-function-symbol
1103        method-group-specs declarations forms &allow-other-keys)
1104  (declare (ignore name))
1105  (let ((methods (gensym))
1106        (args-var (gensym)))
1107    `(lambda (,generic-function-symbol ,methods ,@lambda-list)
1108       ,@declarations
1109       (with-method-groups ,method-group-specs
1110           ,methods
1111         ,(if (null args-lambda-list)
1112              `(let ((result (progn ,@forms)))
1113                 `(lambda (,',args-var)
1114                    ,(wrap-with-call-method-macro ,generic-function-symbol
1115                                                  ',args-var (list result))))
1116              `(lambda (,args-var)
1117                 (let* ((result
1118                         (with-args-lambda-list ,args-lambda-list
1119                             ,generic-function-symbol ,args-var
1120                           ,@forms))
1121                        (function
1122                         `(lambda (,',args-var) ;; ugly: we're reusing it
1123                          ;; to prevent calling gensym on every EMF invocation
1124                          ,(wrap-with-call-method-macro ,generic-function-symbol
1125                                                        ',args-var
1126                                                        (list result)))))
1127                   (funcall function ,args-var))))))))
1128
1129(defun declarationp (expr)
1130  (and (consp expr) (eq (car expr) 'DECLARE)))
1131
1132(defun long-form-method-combination-args (args)
1133  ;; define-method-combination name lambda-list (method-group-specifier*) args
1134  ;; args ::= [(:arguments . args-lambda-list)]
1135  ;;          [(:generic-function generic-function-symbol)]
1136  ;;          [[declaration* | documentation]] form*
1137  (let ((rest args))
1138    (labels ((nextp (key) (and (consp (car rest)) (eq key (caar rest))))
1139             (args-lambda-list ()
1140               (when (nextp :arguments)
1141                 (prog1 (cdr (car rest)) (setq rest (cdr rest)))))
1142             (generic-function-symbol ()
1143                (if (nextp :generic-function)
1144                    (prog1 (second (car rest)) (setq rest (cdr rest)))
1145                    (gensym)))
1146             (declaration* ()
1147               (let ((end (position-if-not #'declarationp rest)))
1148                 (when end
1149                   (prog1 (subseq rest 0 end) (setq rest (nthcdr end rest))))))
1150             (documentation? ()
1151               (when (stringp (car rest))
1152                 (prog1 (car rest) (setq rest (cdr rest)))))
1153             (form* () rest))
1154      (let ((declarations '()))
1155        `(:args-lambda-list ,(args-lambda-list)
1156                            :generic-function-symbol ,(generic-function-symbol)
1157                            :documentation ,(prog2 (setq declarations (declaration*))
1158                                              (documentation?))
1159                            :declarations (,@declarations ,@(declaration*))
1160                            :forms ,(form*))))))
1161
1162(defun define-long-form-method-combination (name lambda-list method-group-specs
1163                                                 &rest args)
1164  (let* ((initargs `(:name ,name
1165                     :lambda-list ,lambda-list
1166                     :method-group-specs ,method-group-specs
1167                     ,@(long-form-method-combination-args args)))
1168         (lambda-expression (apply #'method-combination-type-lambda initargs)))
1169    (apply #'define-method-combination-type name
1170           `(,@initargs
1171;;              :function ,(compile nil lambda-expression)
1172             :function ,(coerce-to-function lambda-expression)))
1173    name))
1174
1175(defparameter *eql-specializer-table* (make-hash-table :test 'eql))
1176
1177(defun intern-eql-specializer (object)
1178  (or (gethash object *eql-specializer-table*)
1179      (setf (gethash object *eql-specializer-table*)
1180            ;; we will be called during generic function invocation
1181            ;; setup, so have to rely on plain functions here.
1182            (let ((instance (std-allocate-instance (find-class 'eql-specializer))))
1183              (setf (std-slot-value instance 'sys::object) object)
1184              instance))))
1185
1186(defun eql-specializer-object (eql-specializer)
1187  (check-type eql-specializer eql-specializer)
1188  (std-slot-value eql-specializer 'sys::object))
1189
1190;;; Initial versions of some method metaobject readers.  Defined on
1191;;; AMOP pg. 218ff, will be redefined when generic functions are set up.
1192
1193(defun std-method-function (method)
1194  (std-slot-value method 'cl:function))
1195
1196(defun std-method-generic-function (method)
1197  (std-slot-value method 'cl:generic-function))
1198
1199(defun std-method-specializers (method)
1200  (std-slot-value method 'sys::specializers))
1201
1202(defun std-method-qualifiers (method)
1203  (std-slot-value method 'sys::qualifiers))
1204
1205(defun std-accessor-method-slot-definition (accessor-method)
1206  (std-slot-value accessor-method 'sys:slot-definition))
1207
1208;;; Additional method readers
1209(defun std-method-fast-function (method)
1210  (std-slot-value method 'sys::fast-function))
1211
1212(defun std-function-keywords (method)
1213  (values (std-slot-value method 'sys::keywords)
1214          (std-slot-value method 'sys::other-keywords-p)))
1215
1216;;; Preliminary accessor definitions, will be redefined as generic
1217;;; functions later in this file
1218
1219(declaim (notinline method-generic-function))
1220(defun method-generic-function (method)
1221  (std-method-generic-function method))
1222
1223(declaim (notinline method-specializers))
1224(defun method-specializers (method)
1225  (std-method-specializers method))
1226
1227(declaim (notinline method-qualifiers))
1228(defun method-qualifiers (method)
1229  (std-method-qualifiers method))
1230
1231
1232
1233;; MOP (p. 216) specifies the following reader generic functions:
1234;;   generic-function-argument-precedence-order
1235;;   generic-function-declarations
1236;;   generic-function-lambda-list
1237;;   generic-function-method-class
1238;;   generic-function-method-combination
1239;;   generic-function-methods
1240;;   generic-function-name
1241
1242;;; These are defined with % in package SYS, defined as functions here
1243;;; and redefined as generic functions once we're all set up.
1244
1245(defun generic-function-lambda-list (gf)
1246  (%generic-function-lambda-list gf))
1247(defsetf generic-function-lambda-list %set-generic-function-lambda-list)
1248
1249(defun (setf generic-function-documentation) (new-value gf)
1250  (set-generic-function-documentation gf new-value))
1251
1252(defun (setf generic-function-initial-methods) (new-value gf)
1253  (set-generic-function-initial-methods gf new-value))
1254
1255(defun generic-function-methods (gf)
1256  (sys:%generic-function-methods gf))
1257(defun (setf generic-function-methods) (new-value gf)
1258  (set-generic-function-methods gf new-value))
1259
1260(defun generic-function-method-class (gf)
1261  (sys:%generic-function-method-class gf))
1262(defun (setf generic-function-method-class) (new-value gf)
1263  (set-generic-function-method-class gf new-value))
1264
1265(defun generic-function-method-combination (gf)
1266  (sys:%generic-function-method-combination gf))
1267(defun (setf generic-function-method-combination) (new-value gf)
1268  (set-generic-function-method-combination gf new-value))
1269
1270(defun generic-function-argument-precedence-order (gf)
1271  (sys:%generic-function-argument-precedence-order gf))
1272(defun (setf generic-function-argument-precedence-order) (new-value gf)
1273  (set-generic-function-argument-precedence-order gf new-value))
1274
1275(declaim (ftype (function * t) classes-to-emf-table))
1276(defun classes-to-emf-table (gf)
1277  (generic-function-classes-to-emf-table gf))
1278
1279(defun (setf classes-to-emf-table) (new-value gf)
1280  (set-generic-function-classes-to-emf-table gf new-value))
1281
1282(defun (setf method-lambda-list) (new-value method)
1283  (setf (std-slot-value method 'sys::lambda-list) new-value))
1284
1285(defun (setf method-qualifiers) (new-value method)
1286  (setf (std-slot-value method 'sys::qualifiers) new-value))
1287
1288(defun method-documentation (method)
1289  (std-slot-value method 'documentation))
1290
1291(defun (setf method-documentation) (new-value method)
1292  (setf (std-slot-value method 'documentation) new-value))
1293
1294;;; defgeneric
1295
1296(defmacro defgeneric (function-name lambda-list
1297                                    &rest options-and-method-descriptions)
1298  (let ((options ())
1299        (methods ())
1300        (documentation nil))
1301    (dolist (item options-and-method-descriptions)
1302      (case (car item)
1303        (declare) ; FIXME
1304        (:documentation
1305         (when documentation
1306           (error 'program-error
1307                  :format-control "Documentation option was specified twice for generic function ~S."
1308                  :format-arguments (list function-name)))
1309         (setf documentation t)
1310         (push item options))
1311        (:method
1312         (push
1313          `(push (defmethod ,function-name ,@(cdr item))
1314                 (generic-function-initial-methods (fdefinition ',function-name)))
1315          methods))
1316        (t
1317         (push item options))))
1318    (setf options (nreverse options)
1319          methods (nreverse methods))
1320    `(prog1
1321       (%defgeneric
1322        ',function-name
1323        :lambda-list ',lambda-list
1324        ,@(canonicalize-defgeneric-options options))
1325       ,@methods)))
1326
1327(defun canonicalize-defgeneric-options (options)
1328  (mapappend #'canonicalize-defgeneric-option options))
1329
1330(defun canonicalize-defgeneric-option (option)
1331  (case (car option)
1332    (:generic-function-class
1333     (list :generic-function-class `(find-class ',(cadr option))))
1334    (:method-class
1335     (list :method-class `(find-class ',(cadr option))))
1336    (:method-combination
1337     (list :method-combination `',(cdr option)))
1338    (:argument-precedence-order
1339     (list :argument-precedence-order `',(cdr option)))
1340    (t
1341     (list `',(car option) `',(cadr option)))))
1342
1343;; From OpenMCL.
1344(defun canonicalize-argument-precedence-order (apo req)
1345  (cond ((equal apo req) nil)
1346        ((not (eql (length apo) (length req)))
1347         (error 'program-error
1348                :format-control "Specified argument precedence order ~S does not match lambda list."
1349                :format-arguments (list apo)))
1350        (t (let ((res nil))
1351             (dolist (arg apo (nreverse res))
1352               (let ((index (position arg req)))
1353                 (if (or (null index) (memq index res))
1354                     (error 'program-error
1355                            :format-control "Specified argument precedence order ~S does not match lambda list."
1356                            :format-arguments (list apo)))
1357                 (push index res)))))))
1358
1359(defun find-generic-function (name &optional (errorp t))
1360  (let ((function (and (fboundp name) (fdefinition name))))
1361    (when function
1362      (when (typep function 'generic-function)
1363        (return-from find-generic-function function))
1364      (when (and *traced-names* (find name *traced-names* :test #'equal))
1365        (setf function (untraced-function name))
1366        (when (typep function 'generic-function)
1367          (return-from find-generic-function function)))))
1368  (if errorp
1369      (error "There is no generic function named ~S." name)
1370      nil))
1371
1372(defun lambda-lists-congruent-p (lambda-list1 lambda-list2)
1373  (let* ((plist1 (analyze-lambda-list lambda-list1))
1374         (args1 (getf plist1 :required-args))
1375         (plist2 (analyze-lambda-list lambda-list2))
1376         (args2 (getf plist2 :required-args)))
1377    (= (length args1) (length args2))))
1378
1379(defun %defgeneric (function-name &rest all-keys)
1380  (when (fboundp function-name)
1381    (let ((gf (fdefinition function-name)))
1382      (when (typep gf 'generic-function)
1383        ;; Remove methods defined by previous DEFGENERIC forms, as
1384        ;; specified by CLHS, 7.7 (Macro DEFGENERIC).
1385        (dolist (method (generic-function-initial-methods gf))
1386          (if (typep gf 'standard-generic-function)
1387              (std-remove-method gf method)
1388              (remove-method gf method)))
1389        (setf (generic-function-initial-methods gf) '()))))
1390  (apply 'ensure-generic-function function-name all-keys))
1391
1392;;; Bootstrap version of ensure-generic-function, handling only
1393;;; standard-generic-function.  This function will be replaced in
1394;;; mop.lisp.
1395(declaim (notinline ensure-generic-function))
1396(defun ensure-generic-function (function-name
1397                                &rest all-keys
1398                                &key
1399                                lambda-list
1400                                (generic-function-class +the-standard-generic-function-class+)
1401                                (method-class +the-standard-method-class+)
1402                                (method-combination 'standard)
1403                                (argument-precedence-order nil apo-p)
1404                                documentation
1405                                &allow-other-keys)
1406  (when (autoloadp function-name)
1407    (resolve function-name))
1408  (let ((gf (find-generic-function function-name nil)))
1409    (if gf
1410        (progn
1411          (unless (or (null (generic-function-methods gf))
1412                      (lambda-lists-congruent-p lambda-list (generic-function-lambda-list gf)))
1413            (error 'simple-error
1414                   :format-control "The lambda list ~S is incompatible with the existing methods of ~S."
1415                   :format-arguments (list lambda-list gf)))
1416          (setf (generic-function-lambda-list gf) lambda-list)
1417          (setf (generic-function-documentation gf) documentation)
1418          (let* ((plist (analyze-lambda-list lambda-list))
1419                 (required-args (getf plist ':required-args)))
1420            (%set-gf-required-args gf required-args)
1421            (%set-gf-optional-args gf (getf plist :optional-args))
1422            (when apo-p
1423              (setf (generic-function-argument-precedence-order gf)
1424                    (if argument-precedence-order
1425                        (canonicalize-argument-precedence-order argument-precedence-order
1426                                                                required-args)
1427                        nil)))
1428            (finalize-standard-generic-function gf))
1429          gf)
1430        (progn
1431          (when (and (null *clos-booting*)
1432                     (fboundp function-name))
1433            (error 'program-error
1434                   :format-control "~A already names an ordinary function, macro, or special operator."
1435                   :format-arguments (list function-name)))
1436          (setf gf (apply (if (eq generic-function-class +the-standard-generic-function-class+)
1437                              #'make-instance-standard-generic-function
1438                              #'make-instance)
1439                          generic-function-class
1440                          :name function-name
1441                          :method-class method-class
1442                          :method-combination method-combination
1443                          all-keys))
1444          gf))))
1445
1446(defun initial-discriminating-function (gf args)
1447  (set-funcallable-instance-function
1448   gf
1449   (funcall (if (eq (class-of gf) +the-standard-generic-function-class+)
1450                #'std-compute-discriminating-function
1451                #'compute-discriminating-function)
1452            gf))
1453  (apply gf args))
1454
1455(defun collect-eql-specializer-objects (generic-function)
1456  (let ((result nil))
1457    (dolist (method (generic-function-methods generic-function))
1458      (dolist (specializer (method-specializers method))
1459        (when (typep specializer 'eql-specializer)
1460          (pushnew (eql-specializer-object specializer)
1461                   result
1462                   :test 'eql))))
1463    result))
1464
1465(defun finalize-standard-generic-function (gf)
1466  (%finalize-generic-function gf)
1467  (unless (generic-function-classes-to-emf-table gf)
1468    (set-generic-function-classes-to-emf-table gf (make-hash-table :test #'equal)))
1469  (clrhash (generic-function-classes-to-emf-table gf))
1470  (%init-eql-specializations gf (collect-eql-specializer-objects gf))
1471  (set-funcallable-instance-function
1472   gf #'(lambda (&rest args)
1473          (initial-discriminating-function gf args)))
1474  ;; FIXME Do we need to warn on redefinition somewhere else?
1475  (let ((*warn-on-redefinition* nil))
1476    (setf (fdefinition (%generic-function-name gf)) gf))
1477  (values))
1478
1479(defun make-instance-standard-generic-function (generic-function-class
1480                                                &key name lambda-list
1481                                                method-class
1482                                                method-combination
1483                                                argument-precedence-order
1484                                                documentation)
1485  ;; to avoid circularities, we do not call generic functions in here.
1486  (declare (ignore generic-function-class))
1487  (let ((gf (std-allocate-instance +the-standard-generic-function-class+)))
1488    (%set-generic-function-name gf name)
1489    (%set-generic-function-lambda-list gf lambda-list)
1490    (set-generic-function-initial-methods gf ())
1491    (set-generic-function-methods gf ())
1492    (set-generic-function-method-class gf method-class)
1493    (set-generic-function-method-combination gf method-combination)
1494    (set-generic-function-documentation gf documentation)
1495    (set-generic-function-classes-to-emf-table gf nil)
1496    (let* ((plist (analyze-lambda-list (generic-function-lambda-list gf)))
1497           (required-args (getf plist ':required-args)))
1498      (%set-gf-required-args gf required-args)
1499      (%set-gf-optional-args gf (getf plist :optional-args))
1500      (set-generic-function-argument-precedence-order gf
1501            (if argument-precedence-order
1502                (canonicalize-argument-precedence-order argument-precedence-order
1503                                                        required-args)
1504                nil)))
1505    (finalize-standard-generic-function gf)
1506    gf))
1507
1508(defun canonicalize-specializers (specializers)
1509  (mapcar #'canonicalize-specializer specializers))
1510
1511(defun canonicalize-specializer (specializer)
1512  (cond ((classp specializer)
1513         specializer)
1514        ((typep specializer 'eql-specializer)
1515         specializer)
1516        ((symbolp specializer)
1517         (find-class specializer))
1518        ((and (consp specializer)
1519              (eq (car specializer) 'eql))
1520         (let ((object (cadr specializer)))
1521           (when (and (consp object)
1522                      (eq (car object) 'quote))
1523             (setf object (cadr object)))
1524           (intern-eql-specializer object)))
1525        ((and (consp specializer)
1526              (eq (car specializer) 'java:jclass))
1527         (let ((jclass (eval specializer)))
1528           (java::ensure-java-class jclass)))
1529        (t
1530         (error "Unknown specializer: ~S" specializer))))
1531
1532(defun parse-defmethod (args)
1533  (let ((function-name (car args))
1534        (qualifiers ())
1535        (specialized-lambda-list ())
1536        (body ())
1537        (parse-state :qualifiers))
1538    (dolist (arg (cdr args))
1539      (ecase parse-state
1540        (:qualifiers
1541         (if (and (atom arg) (not (null arg)))
1542             (push arg qualifiers)
1543             (progn
1544               (setf specialized-lambda-list arg)
1545               (setf parse-state :body))))
1546        (:body (push arg body))))
1547    (setf qualifiers (nreverse qualifiers)
1548          body (nreverse body))
1549    (multiple-value-bind (real-body declarations documentation)
1550        (parse-body body)
1551      (values function-name
1552              qualifiers
1553              (extract-lambda-list specialized-lambda-list)
1554              (extract-specializer-names specialized-lambda-list)
1555              documentation
1556              declarations
1557              (list* 'block
1558                     (fdefinition-block-name function-name)
1559                     real-body)))))
1560
1561(defun required-portion (gf args)
1562  (let ((number-required (length (gf-required-args gf))))
1563    (when (< (length args) number-required)
1564      (error 'program-error
1565             :format-control "Not enough arguments for generic function ~S."
1566             :format-arguments (list (%generic-function-name gf))))
1567    (subseq args 0 number-required)))
1568
1569(defun extract-lambda-list (specialized-lambda-list)
1570  (let* ((plist (analyze-lambda-list specialized-lambda-list))
1571         (requireds (getf plist :required-names))
1572         (rv (getf plist :rest-var))
1573         (ks (getf plist :key-args))
1574         (keysp (getf plist :keysp))
1575         (aok (getf plist :allow-other-keys))
1576         (opts (getf plist :optional-args))
1577         (auxs (getf plist :auxiliary-args)))
1578    `(,@requireds
1579      ,@(if rv `(&rest ,rv) ())
1580      ,@(if (or ks keysp aok) `(&key ,@ks) ())
1581      ,@(if aok '(&allow-other-keys) ())
1582      ,@(if opts `(&optional ,@opts) ())
1583      ,@(if auxs `(&aux ,@auxs) ()))))
1584
1585(defun extract-specializer-names (specialized-lambda-list)
1586  (let ((plist (analyze-lambda-list specialized-lambda-list)))
1587    (getf plist ':specializers)))
1588
1589(defun get-keyword-from-arg (arg)
1590  (if (listp arg)
1591      (if (listp (car arg))
1592          (caar arg)
1593          (make-keyword (car arg)))
1594      (make-keyword arg)))
1595
1596(defun analyze-lambda-list (lambda-list)
1597  (let ((keys ())           ; Just the keywords
1598        (key-args ())       ; Keywords argument specs
1599        (keysp nil)         ;
1600        (required-names ()) ; Just the variable names
1601        (required-args ())  ; Variable names & specializers
1602        (specializers ())   ; Just the specializers
1603        (rest-var nil)
1604        (optionals ())
1605        (auxs ())
1606        (allow-other-keys nil)
1607        (state :parsing-required))
1608    (dolist (arg lambda-list)
1609      (if (member arg lambda-list-keywords)
1610          (ecase arg
1611            (&optional
1612             (setq state :parsing-optional))
1613            (&rest
1614             (setq state :parsing-rest))
1615            (&key
1616             (setq keysp t)
1617             (setq state :parsing-key))
1618            (&allow-other-keys
1619             (setq allow-other-keys 't))
1620            (&aux
1621             (setq state :parsing-aux)))
1622          (case state
1623            (:parsing-required
1624             (push-on-end arg required-args)
1625             (if (listp arg)
1626                 (progn (push-on-end (car arg) required-names)
1627                   (push-on-end (cadr arg) specializers))
1628                 (progn (push-on-end arg required-names)
1629                   (push-on-end 't specializers))))
1630            (:parsing-optional (push-on-end arg optionals))
1631            (:parsing-rest (setq rest-var arg))
1632            (:parsing-key
1633             (push-on-end (get-keyword-from-arg arg) keys)
1634             (push-on-end arg key-args))
1635            (:parsing-aux (push-on-end arg auxs)))))
1636    (list  :required-names required-names
1637           :required-args required-args
1638           :specializers specializers
1639           :rest-var rest-var
1640           :keywords keys
1641           :key-args key-args
1642           :keysp keysp
1643           :auxiliary-args auxs
1644           :optional-args optionals
1645           :allow-other-keys allow-other-keys)))
1646
1647#+nil
1648(defun check-method-arg-info (gf arg-info method)
1649  (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
1650      (analyze-lambda-list (if (consp method)
1651                               (early-method-lambda-list method)
1652                               (method-lambda-list method)))
1653    (flet ((lose (string &rest args)
1654                 (error 'simple-program-error
1655                        :format-control "~@<attempt to add the method~2I~_~S~I~_~
1656                        to the generic function~2I~_~S;~I~_~
1657                        but ~?~:>"
1658                        :format-arguments (list method gf string args)))
1659           (comparison-description (x y)
1660                                   (if (> x y) "more" "fewer")))
1661      (let ((gf-nreq (arg-info-number-required arg-info))
1662            (gf-nopt (arg-info-number-optional arg-info))
1663            (gf-key/rest-p (arg-info-key/rest-p arg-info))
1664            (gf-keywords (arg-info-keys arg-info)))
1665        (unless (= nreq gf-nreq)
1666          (lose
1667           "the method has ~A required arguments than the generic function."
1668           (comparison-description nreq gf-nreq)))
1669        (unless (= nopt gf-nopt)
1670          (lose
1671           "the method has ~A optional arguments than the generic function."
1672           (comparison-description nopt gf-nopt)))
1673        (unless (eq (or keysp restp) gf-key/rest-p)
1674          (lose
1675           "the method and generic function differ in whether they accept~_~
1676            &REST or &KEY arguments."))
1677        (when (consp gf-keywords)
1678          (unless (or (and restp (not keysp))
1679                      allow-other-keys-p
1680                      (every (lambda (k) (memq k keywords)) gf-keywords))
1681            (lose "the method does not accept each of the &KEY arguments~2I~_~
1682            ~S."
1683                  gf-keywords)))))))
1684
1685(defun check-method-lambda-list (name method-lambda-list gf-lambda-list)
1686  (let* ((gf-restp (not (null (memq '&rest gf-lambda-list))))
1687         (gf-plist (analyze-lambda-list gf-lambda-list))
1688         (gf-keysp (getf gf-plist :keysp))
1689         (gf-keywords (getf gf-plist :keywords))
1690         (method-plist (analyze-lambda-list method-lambda-list))
1691         (method-restp (not (null (memq '&rest method-lambda-list))))
1692         (method-keysp (getf method-plist :keysp))
1693         (method-keywords (getf method-plist :keywords))
1694         (method-allow-other-keys-p (getf method-plist :allow-other-keys)))
1695    (unless (= (length (getf gf-plist :required-args))
1696               (length (getf method-plist :required-args)))
1697      (error "The method-lambda-list ~S ~
1698              has the wrong number of required arguments ~
1699              for the generic function ~S." method-lambda-list name))
1700    (unless (= (length (getf gf-plist :optional-args))
1701               (length (getf method-plist :optional-args)))
1702      (error "The method-lambda-list ~S ~
1703              has the wrong number of optional arguments ~
1704              for the generic function ~S." method-lambda-list name))
1705    (unless (eq (or gf-restp gf-keysp) (or method-restp method-keysp))
1706      (error "The method-lambda-list ~S ~
1707              and the generic function ~S ~
1708              differ in whether they accept &REST or &KEY arguments."
1709             method-lambda-list name))
1710    (when (consp gf-keywords)
1711      (unless (or (and method-restp (not method-keysp))
1712                  method-allow-other-keys-p
1713                  (every (lambda (k) (memq k method-keywords)) gf-keywords))
1714        (error "The method-lambda-list ~S does not accept ~
1715                all of the keyword arguments defined for the ~
1716                generic function." method-lambda-list name)))))
1717
1718(defvar *gf-initialize-instance* nil
1719  "Cached value of the INITIALIZE-INSTANCE generic function.
1720Initialized with the true value near the end of the file.")
1721(defvar *gf-allocate-instance* nil
1722  "Cached value of the ALLOCATE-INSTANCE generic function.
1723Initialized with the true value near the end of the file.")
1724(defvar *gf-shared-initialize* nil
1725  "Cached value of the SHARED-INITIALIZE generic function.
1726Initialized with the true value near the end of the file.")
1727(defvar *gf-reinitialize-instance* nil
1728  "Cached value of the REINITIALIZE-INSTANCE generic function.
1729Initialized with the true value near the end of the file.")
1730
1731(declaim (ftype (function * method) ensure-method))
1732(defun ensure-method (name &rest all-keys)
1733  (let ((method-lambda-list (getf all-keys :lambda-list))
1734        (gf (find-generic-function name nil)))
1735    (when (or (eq gf *gf-initialize-instance*)
1736              (eq gf *gf-allocate-instance*)
1737              (eq gf *gf-shared-initialize*)
1738              (eq gf *gf-reinitialize-instance*))
1739      ;; ### Clearly, this can be targeted much more exact
1740      ;; as we only need to remove the specializing class and all
1741      ;; its subclasses from the hash.
1742      (clrhash *make-instance-initargs-cache*)
1743      (clrhash *reinitialize-instance-initargs-cache*))
1744    (if gf
1745        (check-method-lambda-list name method-lambda-list
1746                                  (generic-function-lambda-list gf))
1747        (setf gf (ensure-generic-function name :lambda-list method-lambda-list)))
1748    (let ((method
1749           (if (eq (generic-function-method-class gf) +the-standard-method-class+)
1750               (apply #'make-instance-standard-method gf all-keys)
1751               (apply #'make-instance (generic-function-method-class gf) all-keys))))
1752      (std-add-method gf method)
1753      method)))
1754
1755(defun make-instance-standard-method (gf
1756                                      &key
1757                                      lambda-list
1758                                      qualifiers
1759                                      specializers
1760                                      documentation
1761                                      function
1762                                      fast-function)
1763  (declare (ignore gf))
1764  (let ((method (std-allocate-instance +the-standard-method-class+))
1765        (analyzed-args (analyze-lambda-list lambda-list)))
1766    (setf (method-lambda-list method) lambda-list)
1767    (setf (method-qualifiers method) qualifiers)
1768    (setf (std-slot-value method 'sys::specializers)
1769          (canonicalize-specializers specializers))
1770    (setf (method-documentation method) documentation)
1771    (setf (std-slot-value method 'generic-function) nil) ; set by add-method
1772    (setf (std-slot-value method 'function) function)
1773    (setf (std-slot-value method 'sys::fast-function) fast-function)
1774    (setf (std-slot-value method 'sys::keywords) (getf analyzed-args :keywords))
1775    (setf (std-slot-value method 'sys::other-keywords-p)
1776          (getf analyzed-args :allow-other-keys))
1777    method))
1778
1779(defun std-add-method (gf method)
1780  (when (and (method-generic-function method)
1781             (not (eql gf (method-generic-function method))))
1782    (error 'simple-error
1783           :format-control "~S is already a method of ~S, cannot add to ~S."
1784           :format-arguments (list method (method-generic-function method) gf)))
1785  ;; Remove existing method with same qualifiers and specializers (if any).
1786  (let ((old-method (%find-method gf (std-method-qualifiers method)
1787                                 (method-specializers method) nil)))
1788    (when old-method
1789      (std-remove-method gf old-method)))
1790  (setf (std-slot-value method 'generic-function) gf)
1791  (push method (generic-function-methods gf))
1792  (dolist (specializer (method-specializers method))
1793    ;; FIXME use add-direct-method here (AMOP pg. 165))
1794    (when (typep specializer 'class)
1795      (pushnew method (class-direct-methods specializer))))
1796  (finalize-standard-generic-function gf)
1797  gf)
1798
1799(defun std-remove-method (gf method)
1800  (setf (generic-function-methods gf)
1801        (remove method (generic-function-methods gf)))
1802  (setf (std-slot-value method 'generic-function) nil)
1803  (dolist (specializer (method-specializers method))
1804    ;; FIXME use remove-direct-method here (AMOP pg. 227)
1805    (when (typep specializer 'class)
1806      (setf (class-direct-methods specializer)
1807            (remove method (class-direct-methods specializer)))))
1808  (finalize-standard-generic-function gf)
1809  gf)
1810
1811(defun %find-method (gf qualifiers specializers &optional (errorp t))
1812  ;; "If the specializers argument does not correspond in length to the number
1813  ;; of required arguments of the generic-function, an an error of type ERROR
1814  ;; is signaled."
1815  (unless (= (length specializers) (length (gf-required-args gf)))
1816    (error "The specializers argument has length ~S, but ~S has ~S required parameters."
1817           (length specializers)
1818           gf
1819           (length (gf-required-args gf))))
1820  (let* ((canonical-specializers (canonicalize-specializers specializers))
1821         (method
1822          (find-if #'(lambda (method)
1823                      (and (equal qualifiers
1824                                  (method-qualifiers method))
1825                           (equal canonical-specializers
1826                                  (method-specializers method))))
1827                   (generic-function-methods gf))))
1828    (if (and (null method) errorp)
1829        (error "No such method for ~S." (%generic-function-name gf))
1830        method)))
1831
1832(defun fast-callable-p (gf)
1833  (and (eq (generic-function-method-combination gf) 'standard)
1834       (null (intersection (%generic-function-lambda-list gf)
1835                           '(&rest &optional &key &allow-other-keys &aux)))))
1836
1837(declaim (ftype (function * t) slow-method-lookup-1))
1838
1839(declaim (ftype (function (t t t) t) slow-reader-lookup))
1840(defun slow-reader-lookup (gf layout slot-name)
1841  (let ((location (layout-slot-location layout slot-name)))
1842    (cache-slot-location gf layout location)
1843    location))
1844
1845(defun std-compute-discriminating-function (gf)
1846  ;; In this function, we know that gf is of class
1847  ;; standard-generic-function, so we call various
1848  ;; sys:%generic-function-foo readers to break circularities.
1849  ;; (rudi 2012-01-27): maybe we need to discriminate between
1850  ;; standard-methods and methods as well.
1851  (cond
1852    ((and (= (length (sys:%generic-function-methods gf)) 1)
1853          (typep (car (sys:%generic-function-methods gf)) 'standard-reader-method))
1854     (let* ((method (%car (sys:%generic-function-methods gf)))
1855            (class (car (std-method-specializers method)))
1856            (slot-name (slot-definition-name (accessor-method-slot-definition method))))
1857       #'(lambda (arg)
1858           (declare (optimize speed))
1859           (let* ((layout (std-instance-layout arg))
1860                  (location (get-cached-slot-location gf layout)))
1861             (unless location
1862               (unless (simple-typep arg class)
1863                 ;; FIXME no applicable method
1864                 (error 'simple-type-error
1865                        :datum arg
1866                        :expected-type class))
1867               (setf location (slow-reader-lookup gf layout slot-name)))
1868             (if (consp location)
1869                 ;; Shared slot.
1870                 (cdr location)
1871                 (standard-instance-access arg location))))))
1872
1873    (t
1874     (let* ((emf-table (classes-to-emf-table gf))
1875            (number-required (length (gf-required-args gf)))
1876            (lambda-list (%generic-function-lambda-list gf))
1877            (exact (null (intersection lambda-list
1878                                       '(&rest &optional &key
1879                                         &allow-other-keys &aux)))))
1880       (if exact
1881           (cond
1882             ((= number-required 1)
1883              (cond
1884                ((and (eq (sys:%generic-function-method-combination gf) 'standard)
1885                      (= (length (sys:%generic-function-methods gf)) 1))
1886                 (let* ((method (%car (sys:%generic-function-methods gf)))
1887                        (specializer (car (std-method-specializers method)))
1888                        (function (or (std-method-fast-function method)
1889                                      (std-method-function method))))
1890                   (if (typep specializer 'eql-specializer)
1891                       (let ((specializer-object (eql-specializer-object specializer)))
1892                         #'(lambda (arg)
1893                             (declare (optimize speed))
1894                             (if (eql arg specializer-object)
1895                                 (funcall function arg)
1896                                 (no-applicable-method gf (list arg)))))
1897                       #'(lambda (arg)
1898                           (declare (optimize speed))
1899                           (unless (simple-typep arg specializer)
1900                             ;; FIXME no applicable method
1901                             (error 'simple-type-error
1902                                    :datum arg
1903                                    :expected-type specializer))
1904                           (funcall function arg)))))
1905                (t
1906                 #'(lambda (arg)
1907                     (declare (optimize speed))
1908                     (let* ((specialization
1909                             (%get-arg-specialization gf arg))
1910                            (emfun (or (gethash1 specialization
1911                                                 emf-table)
1912                                       (slow-method-lookup-1
1913                                        gf arg specialization))))
1914                       (if emfun
1915                           (funcall emfun (list arg))
1916                           (apply #'no-applicable-method gf (list arg))))))))
1917             ((= number-required 2)
1918              #'(lambda (arg1 arg2)
1919                  (declare (optimize speed))
1920                  (let* ((args (list arg1 arg2))
1921                         (emfun (get-cached-emf gf args)))
1922                    (if emfun
1923                        (funcall emfun args)
1924                        (slow-method-lookup gf args)))))
1925             ((= number-required 3)
1926              #'(lambda (arg1 arg2 arg3)
1927                  (declare (optimize speed))
1928                  (let* ((args (list arg1 arg2 arg3))
1929                         (emfun (get-cached-emf gf args)))
1930                    (if emfun
1931                        (funcall emfun args)
1932                        (slow-method-lookup gf args)))))
1933             (t
1934              #'(lambda (&rest args)
1935                  (declare (optimize speed))
1936                  (let ((len (length args)))
1937                    (unless (= len number-required)
1938                      (error 'program-error
1939                             :format-control "Not enough arguments for generic function ~S."
1940                             :format-arguments (list (%generic-function-name gf)))))
1941                  (let ((emfun (get-cached-emf gf args)))
1942                    (if emfun
1943                        (funcall emfun args)
1944                        (slow-method-lookup gf args))))))
1945           ;;           (let ((non-key-args (+ number-required
1946           ;;                                  (length (gf-optional-args gf))))))
1947           #'(lambda (&rest args)
1948               (declare (optimize speed))
1949               (let ((len (length args)))
1950                 (unless (>= len number-required)
1951                   (error 'program-error
1952                          :format-control "Not enough arguments for generic function ~S."
1953                          :format-arguments (list (%generic-function-name gf)))))
1954               (let ((emfun (get-cached-emf gf args)))
1955                 (if emfun
1956                     (funcall emfun args)
1957                     (slow-method-lookup gf args)))))))))
1958
1959(defun sort-methods (methods gf required-classes)
1960  (if (or (null methods) (null (%cdr methods)))
1961      methods
1962      (sort methods
1963      (if (eq (class-of gf) +the-standard-generic-function-class+)
1964    #'(lambda (m1 m2)
1965        (std-method-more-specific-p m1 m2 required-classes
1966            (generic-function-argument-precedence-order gf)))
1967    #'(lambda (m1 m2)
1968        (method-more-specific-p gf m1 m2 required-classes))))))
1969
1970(defun method-applicable-p (method args)
1971  (do* ((specializers (method-specializers method) (cdr specializers))
1972        (args args (cdr args)))
1973       ((null specializers) t)
1974    (let ((specializer (car specializers)))
1975      (if (typep specializer 'eql-specializer)
1976          (unless (eql (car args) (eql-specializer-object specializer))
1977            (return nil))
1978          (unless (subclassp (class-of (car args)) specializer)
1979            (return nil))))))
1980
1981(defun %compute-applicable-methods (gf args)
1982  (let ((required-classes (mapcar #'class-of (required-portion gf args)))
1983        (methods '()))
1984    (dolist (method (generic-function-methods gf))
1985      (when (method-applicable-p method args)
1986        (push method methods)))
1987    (sort-methods methods gf required-classes)))
1988
1989;;; METHOD-APPLICABLE-USING-CLASSES-P
1990;;;
1991;;; If the first return value is T, METHOD is definitely applicable to
1992;;; arguments that are instances of CLASSES.  If the first value is
1993;;; NIL and the second value is T, METHOD is definitely not applicable
1994;;; to arguments that are instances of CLASSES; if the second value is
1995;;; NIL the applicability of METHOD cannot be determined by inspecting
1996;;; the classes of its arguments only.
1997;;;
1998(defun method-applicable-using-classes-p (method classes)
1999  (do* ((specializers (method-specializers method) (cdr specializers))
2000  (classes classes (cdr classes))
2001  (knownp t))
2002       ((null specializers)
2003  (if knownp (values t t) (values nil nil)))
2004    (let ((specializer (car specializers)))
2005      (if (typep specializer 'eql-specializer)
2006    (if (eql (class-of (eql-specializer-object specializer)) 
2007       (car classes))
2008        (setf knownp nil)
2009        (return (values nil t)))
2010    (unless (subclassp (car classes) specializer)
2011      (return (values nil t)))))))
2012
2013(defun check-applicable-method-keyword-args (gf args
2014                                             keyword-args
2015                                             applicable-keywords)
2016  (when (oddp (length keyword-args))
2017    (error 'program-error
2018           :format-control "Odd number of keyword arguments in call to ~S ~
2019with arguments list ~S"
2020           :format-arguments (list gf args)))
2021  (unless (getf keyword-args :allow-other-keys)
2022    (loop for key in keyword-args by #'cddr
2023       unless (or (member key applicable-keywords)
2024                  (eq key :allow-other-keys))
2025       do (error 'program-error
2026                 :format-control "Invalid keyword argument ~S in call ~
2027to ~S with argument list ~S."
2028                 :format-arguments (list key gf args)))))
2029
2030(defun compute-applicable-keywords (gf applicable-methods)
2031  (let ((applicable-keywords
2032         (getf (analyze-lambda-list (generic-function-lambda-list gf))
2033               :keywords)))
2034    (loop for method in applicable-methods
2035       do (multiple-value-bind
2036                (keywords allow-other-keys)
2037              (function-keywords method)
2038            (when allow-other-keys
2039              (setf applicable-keywords :any)
2040              (return))
2041            (setf applicable-keywords
2042                  (union applicable-keywords keywords))))
2043    applicable-keywords))
2044
2045(defun wrap-emfun-for-keyword-args-check (gf emfun non-keyword-args
2046                                          applicable-keywords)
2047  #'(lambda (args)
2048      (check-applicable-method-keyword-args
2049         gf args
2050         (nthcdr non-keyword-args args) applicable-keywords)
2051      (funcall emfun args)))
2052
2053(defun slow-method-lookup (gf args)
2054  (let ((applicable-methods (%compute-applicable-methods gf args)))
2055    (if applicable-methods
2056        (let* ((emfun (funcall (if (eq (class-of gf) +the-standard-generic-function-class+)
2057                                   #'std-compute-effective-method-function
2058                                   #'compute-effective-method-function)
2059                               gf applicable-methods))
2060               (non-keyword-args
2061                (+ (length (gf-required-args gf))
2062                   (length (gf-optional-args gf))))
2063               (gf-lambda-list (generic-function-lambda-list gf))
2064               (checks-required (and (member '&key gf-lambda-list)
2065                                     (not (member '&allow-other-keys
2066                                                  gf-lambda-list)))
2067                 )
2068              (applicable-keywords
2069               (when checks-required
2070                 ;; Don't do applicable keyword checks when this is
2071                 ;; one of the 'exceptional four' or when the gf allows
2072                 ;; other keywords.
2073                 (compute-applicable-keywords gf applicable-methods))))
2074          (when (and checks-required
2075                     (not (eq applicable-keywords :any)))
2076            (setf emfun
2077                  (wrap-emfun-for-keyword-args-check gf emfun non-keyword-args
2078                                                     applicable-keywords)))
2079          (cache-emf gf args emfun)
2080          (funcall emfun args))
2081        (apply #'no-applicable-method gf args))))
2082
2083(defun slow-method-lookup-1 (gf arg arg-specialization)
2084  (let ((applicable-methods (%compute-applicable-methods gf (list arg))))
2085    (if applicable-methods
2086        (let ((emfun (funcall (if (eq (class-of gf) +the-standard-generic-function-class+)
2087                                  #'std-compute-effective-method-function
2088                                  #'compute-effective-method-function)
2089                              gf applicable-methods)))
2090          (when emfun
2091            (setf (gethash arg-specialization (classes-to-emf-table gf)) emfun))
2092          emfun))))
2093
2094(defun sub-specializer-p (c1 c2 c-arg)
2095  (find c2 (cdr (memq c1 (%class-precedence-list c-arg)))))
2096
2097(defun std-method-more-specific-p (method1 method2 required-classes argument-precedence-order)
2098  (if argument-precedence-order
2099      (let ((specializers-1 (std-method-specializers method1))
2100            (specializers-2 (std-method-specializers method2)))
2101        (dolist (index argument-precedence-order)
2102          (let ((spec1 (nth index specializers-1))
2103                (spec2 (nth index specializers-2)))
2104            (unless (eq spec1 spec2)
2105              (cond ((typep spec1 'eql-specializer)
2106                     (return t))
2107                    ((typep spec2 'eql-specializer)
2108                     (return nil))
2109                    (t
2110                     (return (sub-specializer-p spec1 spec2
2111                                                (nth index required-classes)))))))))
2112      (do ((specializers-1 (std-method-specializers method1) (cdr specializers-1))
2113           (specializers-2 (std-method-specializers method2) (cdr specializers-2))
2114           (classes required-classes (cdr classes)))
2115          ((null specializers-1) nil)
2116        (let ((spec1 (car specializers-1))
2117              (spec2 (car specializers-2)))
2118          (unless (eq spec1 spec2)
2119            (cond ((typep spec1 'eql-specializer)
2120                   (return t))
2121                  ((typep spec2 'eql-specializer)
2122                   (return nil))
2123                  (t
2124                   (return (sub-specializer-p spec1 spec2 (car classes))))))))))
2125
2126(defun primary-method-p (method)
2127  (null (intersection '(:before :after :around) (method-qualifiers method))))
2128
2129(defun before-method-p (method)
2130  (equal '(:before) (method-qualifiers method)))
2131
2132(defun after-method-p (method)
2133  (equal '(:after) (method-qualifiers method)))
2134
2135(defun around-method-p (method)
2136  (equal '(:around) (method-qualifiers method)))
2137
2138(defun process-next-method-list (next-method-list)
2139  (mapcar #'(lambda (next-method-form)
2140              (cond
2141                ((listp next-method-form)
2142                 (assert (eq (first next-method-form) 'make-method))
2143                 (let* ((rest-sym (gensym)))
2144                   (make-instance-standard-method
2145                    nil ;; ignored
2146                    :lambda-list (list '&rest rest-sym)
2147                    :function (compute-method-function `(lambda (&rest ,rest-sym)
2148                                                          ,(second next-method-form))))))
2149                (t
2150                 (assert (typep next-method-form 'method))
2151                 next-method-form)))
2152          next-method-list))
2153
2154(defun std-compute-effective-method-function (gf methods)
2155  (let* ((mc (generic-function-method-combination gf))
2156         (mc-name (if (atom mc) mc (%car mc)))
2157         (options (if (atom mc) '() (%cdr mc)))
2158         (order (car options))
2159         (primaries '())
2160         (arounds '())
2161         around
2162         emf-form
2163         (long-method-combination-p
2164          (typep (get mc-name 'method-combination-object) 'long-method-combination)))
2165    (unless long-method-combination-p
2166      (dolist (m methods)
2167        (let ((qualifiers (method-qualifiers m)))
2168          (cond ((null qualifiers)
2169                 (if (eq mc-name 'standard)
2170                     (push m primaries)
2171                     (error "Method combination type mismatch.")))
2172                ((cdr qualifiers)
2173                 (error "Invalid method qualifiers."))
2174                ((eq (car qualifiers) :around)
2175                 (push m arounds))
2176                ((eq (car qualifiers) mc-name)
2177                 (push m primaries))
2178                ((memq (car qualifiers) '(:before :after)))
2179                (t
2180                 (error "Invalid method qualifiers."))))))
2181    (unless (eq order :most-specific-last)
2182      (setf primaries (nreverse primaries)))
2183    (setf arounds (nreverse arounds))
2184    (setf around (car arounds))
2185    (when (and (null primaries) (not long-method-combination-p))
2186      (error "No primary methods for the generic function ~S." gf))
2187    (cond
2188      (around
2189       (let ((next-emfun
2190              (funcall
2191               (if (eq (class-of gf) +the-standard-generic-function-class+)
2192                   #'std-compute-effective-method-function
2193                   #'compute-effective-method-function)
2194               gf (remove around methods))))
2195         (setf emf-form
2196               (generate-emf-lambda (std-method-function around) next-emfun))))
2197      ((eq mc-name 'standard)
2198       (let* ((next-emfun (compute-primary-emfun (cdr primaries)))
2199              (befores (remove-if-not #'before-method-p methods))
2200              (reverse-afters
2201               (reverse (remove-if-not #'after-method-p methods))))
2202         (setf emf-form
2203               (cond
2204                 ((and (null befores) (null reverse-afters))
2205                  (let ((fast-function (std-method-fast-function (car primaries))))
2206                    (if fast-function
2207                        (ecase (length (gf-required-args gf))
2208                          (1
2209                           #'(lambda (args)
2210                               (declare (optimize speed))
2211                               (funcall fast-function (car args))))
2212                          (2
2213                           #'(lambda (args)
2214                               (declare (optimize speed))
2215                               (funcall fast-function (car args) (cadr args)))))
2216                        (generate-emf-lambda (std-method-function (car primaries))
2217                                             next-emfun))))
2218                 (t
2219                  (let ((method-function (std-method-function (car primaries))))
2220                    #'(lambda (args)
2221                        (declare (optimize speed))
2222                        (dolist (before befores)
2223                          (funcall (std-method-function before) args nil))
2224                        (multiple-value-prog1
2225                            (funcall method-function args next-emfun)
2226                          (dolist (after reverse-afters)
2227                            (funcall (std-method-function after) args nil))))))))))
2228      (long-method-combination-p
2229       (let* ((mc-obj (get mc-name 'method-combination-object))
2230              (function (long-method-combination-function mc-obj))
2231              (arguments (rest (slot-value gf 'method-combination))))
2232         (assert (typep mc-obj 'long-method-combination))
2233         (assert function)
2234         (setf emf-form
2235               (if arguments
2236                   (apply function gf methods arguments)
2237                   (funcall function gf methods)))))
2238      (t
2239       (let ((mc-obj (get mc-name 'method-combination-object)))
2240         (unless (typep mc-obj 'short-method-combination)
2241           (error "Unsupported method combination type ~A."
2242                  mc-name))
2243         (let* ((operator (short-method-combination-operator mc-obj))
2244                (ioa (short-method-combination-identity-with-one-argument mc-obj)))
2245           (setf emf-form
2246                 (if (and (null (cdr primaries))
2247                          (not (null ioa)))
2248                     (generate-emf-lambda (std-method-function (car primaries)) nil)
2249                     `(lambda (args)
2250                        (,operator ,@(mapcar
2251                                      (lambda (primary)
2252                                        `(funcall ,(std-method-function primary) args nil))
2253                                      primaries)))))))))
2254    (assert (not (null emf-form)))
2255    (or #+nil (ignore-errors (autocompile emf-form))
2256        (coerce-to-function emf-form))))
2257
2258(defun generate-emf-lambda (method-function next-emfun)
2259  #'(lambda (args)
2260      (declare (optimize speed))
2261      (funcall method-function args next-emfun)))
2262
2263;;; compute an effective method function from a list of primary methods:
2264
2265(defun compute-primary-emfun (methods)
2266  (if (null methods)
2267      nil
2268      (let ((next-emfun (compute-primary-emfun (cdr methods))))
2269        #'(lambda (args)
2270           (funcall (std-method-function (car methods)) args next-emfun)))))
2271
2272(defvar *call-next-method-p*)
2273(defvar *next-method-p-p*)
2274
2275(defun walk-form (form)
2276  (cond ((atom form)
2277         (cond ((eq form 'call-next-method)
2278                (setf *call-next-method-p* t))
2279               ((eq form 'next-method-p)
2280                (setf *next-method-p-p* t))))
2281        (t
2282         (walk-form (%car form))
2283         (walk-form (%cdr form)))))
2284
2285(defun compute-method-function (lambda-expression)
2286  (let ((lambda-list (allow-other-keys (cadr lambda-expression)))
2287        (body (cddr lambda-expression))
2288        (*call-next-method-p* nil)
2289        (*next-method-p-p* nil))
2290    (multiple-value-bind (body declarations) (parse-body body)
2291      (let ((ignorable-vars '()))
2292        (dolist (var lambda-list)
2293          (if (memq var lambda-list-keywords)
2294              (return)
2295              (push var ignorable-vars)))
2296        (push `(declare (ignorable ,@ignorable-vars)) declarations))
2297      (walk-form body)
2298      (cond ((or *call-next-method-p* *next-method-p-p*)
2299             `(lambda (args next-emfun)
2300                (flet ((call-next-method (&rest cnm-args)
2301                         (if (null next-emfun)
2302                             (error "No next method for generic function.")
2303                             (funcall next-emfun (or cnm-args args))))
2304                       (next-method-p ()
2305                         (not (null next-emfun))))
2306                  (declare (ignorable (function call-next-method)
2307                                      (function next-method-p)))
2308                  (apply #'(lambda ,lambda-list ,@declarations ,@body) args))))
2309            ((null (intersection lambda-list '(&rest &optional &key &allow-other-keys &aux)))
2310             ;; Required parameters only.
2311             (case (length lambda-list)
2312               (1
2313                `(lambda (args next-emfun)
2314                   (declare (ignore next-emfun))
2315                   (let ((,(%car lambda-list) (%car args)))
2316                     (declare (ignorable ,(%car lambda-list)))
2317                     ,@declarations ,@body)))
2318               (2
2319                `(lambda (args next-emfun)
2320                   (declare (ignore next-emfun))
2321                   (let ((,(%car lambda-list) (%car args))
2322                         (,(%cadr lambda-list) (%cadr args)))
2323                     (declare (ignorable ,(%car lambda-list)
2324                                         ,(%cadr lambda-list)))
2325                     ,@declarations ,@body)))
2326               (3
2327                `(lambda (args next-emfun)
2328                   (declare (ignore next-emfun))
2329                   (let ((,(%car lambda-list) (%car args))
2330                         (,(%cadr lambda-list) (%cadr args))
2331                         (,(%caddr lambda-list) (%caddr args)))
2332                     (declare (ignorable ,(%car lambda-list)
2333                                         ,(%cadr lambda-list)
2334                                         ,(%caddr lambda-list)))
2335                     ,@declarations ,@body)))
2336               (t
2337                `(lambda (args next-emfun)
2338                   (declare (ignore next-emfun))
2339                   (apply #'(lambda ,lambda-list ,@declarations ,@body) args)))))
2340            (t
2341             `(lambda (args next-emfun)
2342                (declare (ignore next-emfun))
2343                (apply #'(lambda ,lambda-list ,@declarations ,@body) args)))))))
2344
2345(defun compute-method-fast-function (lambda-expression)
2346  (let ((lambda-list (allow-other-keys (cadr lambda-expression))))
2347    (when (intersection lambda-list '(&rest &optional &key &allow-other-keys &aux))
2348      (return-from compute-method-fast-function nil))
2349    ;; Only required args.
2350    (let ((body (cddr lambda-expression))
2351          (*call-next-method-p* nil)
2352          (*next-method-p-p* nil))
2353      (multiple-value-bind (body declarations) (parse-body body)
2354        (walk-form body)
2355        (when (or *call-next-method-p* *next-method-p-p*)
2356          (return-from compute-method-fast-function nil))
2357        (let ((decls `(declare (ignorable ,@lambda-list))))
2358          (setf lambda-expression
2359                (list* (car lambda-expression)
2360                       (cadr lambda-expression)
2361                       decls
2362                       (cddr lambda-expression))))
2363        (case (length lambda-list)
2364          (1
2365;;            `(lambda (args next-emfun)
2366;;               (let ((,(%car lambda-list) (%car args)))
2367;;                 (declare (ignorable ,(%car lambda-list)))
2368;;                 ,@declarations ,@body)))
2369           lambda-expression)
2370          (2
2371;;            `(lambda (args next-emfun)
2372;;               (let ((,(%car lambda-list) (%car args))
2373;;                     (,(%cadr lambda-list) (%cadr args)))
2374;;                 (declare (ignorable ,(%car lambda-list)
2375;;                                     ,(%cadr lambda-list)))
2376;;                 ,@declarations ,@body)))
2377           lambda-expression)
2378;;           (3
2379;;            `(lambda (args next-emfun)
2380;;               (let ((,(%car lambda-list) (%car args))
2381;;                     (,(%cadr lambda-list) (%cadr args))
2382;;                     (,(%caddr lambda-list) (%caddr args)))
2383;;                 (declare (ignorable ,(%car lambda-list)
2384;;                                     ,(%cadr lambda-list)
2385;;                                     ,(%caddr lambda-list)))
2386;;                 ,@declarations ,@body)))
2387          (t
2388           nil))))))
2389
2390;; From CLHS section 7.6.5:
2391;; "When a generic function or any of its methods mentions &key in a lambda
2392;; list, the specific set of keyword arguments accepted by the generic function
2393;; varies according to the applicable methods. The set of keyword arguments
2394;; accepted by the generic function for a particular call is the union of the
2395;; keyword arguments accepted by all applicable methods and the keyword
2396;; arguments mentioned after &key in the generic function definition, if any."
2397;; Adapted from Sacla.
2398(defun allow-other-keys (lambda-list)
2399  (if (and (member '&key lambda-list)
2400           (not (member '&allow-other-keys lambda-list)))
2401      (let* ((key-end (or (position '&aux lambda-list) (length lambda-list)))
2402             (aux-part (subseq lambda-list key-end)))
2403        `(,@(subseq lambda-list 0 key-end) &allow-other-keys ,@aux-part))
2404      lambda-list))
2405
2406(defmacro defmethod (&rest args)
2407  (multiple-value-bind
2408      (function-name qualifiers lambda-list specializers documentation declarations body)
2409      (parse-defmethod args)
2410    (let* ((specializers-form '())
2411           (lambda-expression `(lambda ,lambda-list ,@declarations ,body))
2412           (method-function (compute-method-function lambda-expression))
2413           (fast-function (compute-method-fast-function lambda-expression))
2414           )
2415      (dolist (specializer specializers)
2416        (cond ((and (consp specializer) (eq (car specializer) 'eql))
2417               (push `(list 'eql ,(cadr specializer)) specializers-form))
2418              (t
2419               (push `',specializer specializers-form))))
2420      (setf specializers-form `(list ,@(nreverse specializers-form)))
2421      `(progn
2422         (ensure-method ',function-name
2423                        :lambda-list ',lambda-list
2424                        :qualifiers ',qualifiers
2425                        :specializers ,specializers-form
2426                        ,@(if documentation `(:documentation ,documentation))
2427                        :function (function ,method-function)
2428                        ,@(if fast-function `(:fast-function (function ,fast-function)))
2429                        )))))
2430
2431;;; Reader and writer methods
2432
2433(defun make-instance-standard-accessor-method (method-class
2434                                               &key
2435                                               lambda-list
2436                                               qualifiers
2437                                               specializers
2438                                               documentation
2439                                               function
2440                                               fast-function
2441                                               slot-definition)
2442  (let ((method (std-allocate-instance method-class)))
2443    (setf (method-lambda-list method) lambda-list)
2444    (setf (method-qualifiers method) qualifiers)
2445    (setf (std-slot-value method 'sys::specializers)
2446          (canonicalize-specializers specializers))
2447    (setf (method-documentation method) documentation)
2448    (setf (std-slot-value method 'generic-function) nil)
2449    (setf (std-slot-value method 'function) function)
2450    (setf (std-slot-value method 'sys::fast-function) fast-function)
2451    (setf (std-slot-value method 'sys:slot-definition) slot-definition)
2452    (setf (std-slot-value method 'sys::keywords) nil)
2453    (setf (std-slot-value method 'sys::other-keywords-p) nil)
2454    method))
2455
2456(defun add-reader-method (class function-name slot-definition)
2457  (let* ((slot-name (slot-definition-name slot-definition))
2458         (lambda-expression
2459          (if (eq (class-of class) +the-standard-class+)
2460              `(lambda (object) (std-slot-value object ',slot-name))
2461              `(lambda (object) (slot-value object ',slot-name))))
2462         (method-function (compute-method-function lambda-expression))
2463         (fast-function (compute-method-fast-function lambda-expression))
2464         (method-lambda-list '(object))
2465         (gf (find-generic-function function-name nil))
2466         (initargs `(:lambda-list ,method-lambda-list
2467                     :qualifiers ()
2468                     :specializers (,class)
2469                     :function ,(if (autoloadp 'compile)
2470                                    method-function
2471                                    (autocompile method-function))
2472                     :fast-function ,(if (autoloadp 'compile)
2473                                         fast-function
2474                                         (autocompile fast-function))
2475                     :slot-definition ,slot-definition))
2476         (method-class (if (eq class +the-standard-class+)
2477                           +the-standard-reader-method-class+
2478                           (apply #'reader-method-class class slot-definition
2479                                  initargs))))
2480    ;; required by AMOP pg. 225
2481    (assert (subtypep method-class +the-standard-reader-method-class+))
2482    (if gf
2483        (check-method-lambda-list function-name
2484                                  method-lambda-list
2485                                  (generic-function-lambda-list gf))
2486        (setf gf (ensure-generic-function function-name
2487                                          :lambda-list method-lambda-list)))
2488    (let ((method
2489           (if (eq method-class +the-standard-reader-method-class+)
2490               (apply #'make-instance-standard-accessor-method method-class
2491                      initargs)
2492               (apply #'make-instance method-class
2493                      :generic-function nil ; handled by add-method
2494                      initargs))))
2495      (if (eq (class-of gf) +the-standard-generic-function-class+)
2496          (std-add-method gf method)
2497          (add-method gf method))
2498      method)))
2499
2500(defun add-writer-method (class function-name slot-definition)
2501  (let* ((slot-name (slot-definition-name slot-definition))
2502         (lambda-expression
2503          (if (eq (class-of class) +the-standard-class+)
2504              `(lambda (new-value object)
2505                 (setf (std-slot-value object ',slot-name) new-value))
2506              `(lambda (new-value object)
2507                 (setf (slot-value object ',slot-name) new-value))))
2508         (method-function (compute-method-function lambda-expression))
2509         (fast-function (compute-method-fast-function lambda-expression))
2510         (method-lambda-list '(new-value object))
2511         (gf (find-generic-function function-name nil))
2512         (initargs `(:lambda-list ,method-lambda-list
2513                     :qualifiers ()
2514                     :specializers (,+the-T-class+ ,class)
2515                     :function ,(if (autoloadp 'compile)
2516                                    method-function
2517                                    (autocompile method-function))
2518                     :fast-function ,(if (autoloadp 'compile)
2519                                         fast-function
2520                                         (autocompile fast-function))))
2521         (method-class (if (eq class +the-standard-class+)
2522                           +the-standard-writer-method-class+
2523                           (apply #'writer-method-class class slot-definition
2524                                  initargs))))
2525    ;; required by AMOP pg. 242
2526    (assert (subtypep method-class +the-standard-writer-method-class+))
2527    (if gf
2528        (check-method-lambda-list function-name
2529                                  method-lambda-list
2530                                  (generic-function-lambda-list gf))
2531        (setf gf (ensure-generic-function function-name
2532                                          :lambda-list method-lambda-list)))
2533    (let ((method
2534           (if (eq method-class +the-standard-writer-method-class+)
2535               (apply #'make-instance-standard-accessor-method method-class
2536                      initargs)
2537               (apply #'make-instance method-class
2538                      :generic-function nil ; handled by add-method
2539                      initargs))))
2540      (if (eq (class-of gf) +the-standard-generic-function-class+)
2541          (std-add-method gf method)
2542          (add-method gf method))
2543      method)))
2544
2545(defmacro atomic-defgeneric (function-name &rest rest)
2546  "Macro to define a generic function and 'swap it into place' after
2547it's been fully defined with all its methods.
2548
2549Note: the user should really use the (:method ..) method description
2550way of defining methods; there's not much use in atomically defining
2551generic functions without providing sensible behaviour..."
2552  (let ((temp-sym (gensym)))
2553    `(progn
2554       (defgeneric ,temp-sym ,@rest)
2555       (let ((gf (symbol-function ',temp-sym)))
2556         (setf ,(if (and (consp function-name)
2557                         (eq (car function-name) 'setf))
2558                    `(get ',(second function-name) 'setf-function)
2559                  `(symbol-function ',function-name)) gf)
2560         (%set-generic-function-name gf ',function-name)
2561         gf))))
2562
2563(defmacro redefine-class-forwarder (name slot)
2564  "Define a generic function on a temporary symbol as an accessor
2565for the slot `slot'. Then, when definition is complete (including
2566allocation of methods), swap the definition in place.
2567
2568Without this approach, we can't depend the old forwarders to be
2569in place, while we still need them to "
2570  (let* (($name (if (consp name) (cadr name) name))
2571         (%name (intern (concatenate 'string
2572                                     "%"
2573                                     (if (consp name)
2574                                         (symbol-name 'set-) "")
2575                                     (symbol-name $name))
2576                        (find-package "SYS"))))
2577    `(atomic-defgeneric ,name (;; splice a new-value parameter for setters
2578                               ,@(when (consp name) (list 'new-value))
2579                               class)
2580         ,@(mapcar (if (consp name)
2581                       #'(lambda (class-name)
2582                           `(:method (new-value (class ,class-name))
2583                              (,%name new-value class)))
2584                       #'(lambda (class-name)
2585                           `(:method ((class ,class-name))
2586                              (,%name class))))
2587                   '(built-in-class forward-referenced-class structure-class))
2588         ,@(mapcar #'(lambda (class-name)
2589                       `(:method (,@(when (consp name) (list 'new-value))
2590                                  (class ,class-name))
2591                          ,(if (consp name)
2592                               `(setf (slot-value class ',slot) new-value)
2593                               `(slot-value class ',slot))))
2594                   '(standard-class funcallable-standard-class)))))
2595
2596
2597(redefine-class-forwarder class-name name)
2598(redefine-class-forwarder (setf class-name) name)
2599(redefine-class-forwarder class-slots slots)
2600(redefine-class-forwarder (setf class-slots) slots)
2601(redefine-class-forwarder class-direct-slots direct-slots)
2602(redefine-class-forwarder (setf class-direct-slots) direct-slots)
2603(redefine-class-forwarder class-layout layout)
2604(redefine-class-forwarder (setf class-layout) layout)
2605(redefine-class-forwarder class-direct-superclasses direct-superclasses)
2606(redefine-class-forwarder (setf class-direct-superclasses) direct-superclasses)
2607(redefine-class-forwarder class-direct-subclasses direct-subclasses)
2608(redefine-class-forwarder (setf class-direct-subclasses) direct-subclasses)
2609(redefine-class-forwarder class-direct-methods direct-methods)
2610(redefine-class-forwarder (setf class-direct-methods) direct-methods)
2611(redefine-class-forwarder class-precedence-list precedence-list)
2612(redefine-class-forwarder (setf class-precedence-list) precedence-list)
2613(redefine-class-forwarder class-finalized-p finalized-p)
2614(redefine-class-forwarder (setf class-finalized-p) finalized-p)
2615(redefine-class-forwarder class-default-initargs default-initargs)
2616(redefine-class-forwarder (setf class-default-initargs) default-initargs)
2617(redefine-class-forwarder class-direct-default-initargs direct-default-initargs)
2618(redefine-class-forwarder (setf class-direct-default-initargs) direct-default-initargs)
2619
2620;;; Class definition
2621
2622(defun check-duplicate-slots (slots)
2623  (dolist (s1 slots)
2624    (let ((name1 (canonical-slot-name s1)))
2625      (dolist (s2 (cdr (memq s1 slots)))
2626        (when (eq name1 (canonical-slot-name s2))
2627          (error 'program-error "Duplicate slot ~S" name1))))))
2628
2629(defun check-duplicate-default-initargs (initargs)
2630  (let ((names ()))
2631    (do* ((initargs initargs (cddr initargs))
2632          (name (car initargs) (car initargs)))
2633         ((null initargs))
2634      (push name names))
2635    (do* ((names names (cdr names))
2636          (name (car names) (car names)))
2637         ((null names))
2638      (when (memq name (cdr names))
2639        (error 'program-error
2640               :format-control "Duplicate initialization argument name ~S in :DEFAULT-INITARGS."
2641               :format-arguments (list name))))))
2642
2643(defun canonicalize-direct-superclasses (direct-superclasses)
2644  (let ((classes '()))
2645    (dolist (class-specifier direct-superclasses)
2646      (let ((class (if (classp class-specifier)
2647                       class-specifier
2648                       (find-class class-specifier nil))))
2649        (unless class
2650          (setf class (make-instance +the-forward-referenced-class+
2651                                     :name class-specifier))
2652          (setf (find-class class-specifier) class))
2653        (when (and (typep class 'built-in-class)
2654                   (not (member class *extensible-built-in-classes*)))
2655          (error "Attempt to define a subclass of built-in-class ~S."
2656                 class-specifier))
2657        (push class classes)))
2658    (nreverse classes)))
2659
2660 ;;; AMOP pg. 182
2661(defun ensure-class (name &rest all-keys &key &allow-other-keys)
2662  (let ((class (find-class name nil)))
2663    ;; CLHS DEFCLASS: "If a class with the same proper name already
2664    ;; exists [...] the existing class is redefined."  Ansi-tests
2665    ;; CLASS-0309 and CLASS-0310.1 demand this behavior.
2666    (if (and class (eql (class-name class) name))
2667        (apply #'ensure-class-using-class class name all-keys)
2668        (apply #'ensure-class-using-class nil name all-keys))))
2669
2670;;; AMOP pg. 183ff.
2671(defgeneric ensure-class-using-class (class name &key direct-default-initargs
2672                                      direct-slots direct-superclasses
2673                                      metaclass &allow-other-keys))
2674
2675(defmethod ensure-class-using-class :before (class name  &key direct-slots
2676                                             direct-default-initargs 
2677                                             &allow-other-keys)
2678  (check-duplicate-slots direct-slots)
2679  (check-duplicate-default-initargs direct-default-initargs))
2680
2681(defmethod ensure-class-using-class ((class null) name &rest all-keys
2682                                     &key (metaclass +the-standard-class+)
2683                                     direct-superclasses
2684                                     &allow-other-keys)
2685  (setf all-keys (copy-list all-keys))  ; since we modify it
2686  (remf all-keys :metaclass)
2687  (unless (classp metaclass) (setf metaclass (find-class metaclass)))
2688  (let ((class (apply (if (eq metaclass +the-standard-class+)
2689                          #'make-instance-standard-class
2690                          #'make-instance)
2691                      metaclass :name name
2692                      :direct-superclasses (canonicalize-direct-superclasses
2693                                            direct-superclasses)
2694                      all-keys)))
2695    (%set-find-class name class)
2696    class))
2697
2698(defmethod ensure-class-using-class ((class built-in-class) name &rest all-keys
2699                                     &key &allow-other-keys)
2700  (declare (ignore all-keys))
2701  (error "The symbol ~S names a built-in class." name))
2702
2703(defmethod ensure-class-using-class ((class forward-referenced-class) name
2704                                     &rest all-keys
2705                                     &key (metaclass +the-standard-class+)
2706                                     direct-superclasses &allow-other-keys)
2707  (setf all-keys (copy-list all-keys))  ; since we modify it
2708  (remf all-keys :metaclass)
2709  (unless (classp metaclass) (setf metaclass (find-class metaclass)))
2710  (change-class class metaclass)
2711  (apply #'reinitialize-instance class
2712         :name name
2713         :direct-superclasses (canonicalize-direct-superclasses
2714                               direct-superclasses)
2715         all-keys)
2716  class)
2717
2718(defmethod ensure-class-using-class ((class class) name
2719                                     &key (metaclass +the-standard-class+ metaclassp)
2720                                     direct-superclasses &rest all-keys
2721                                     &allow-other-keys)
2722  (declare (ignore name))
2723  (setf all-keys (copy-list all-keys))  ; since we modify it
2724  (remf all-keys :metaclass)
2725  (unless (classp metaclass) (setf metaclass (find-class metaclass)))
2726  (when (and metaclassp (not (eq (class-of class) metaclass)))
2727    (error 'program-error
2728           "Trying to redefine class ~S with different metaclass."
2729           (class-name class)))
2730  (apply #'reinitialize-instance class
2731         :direct-superclasses (canonicalize-direct-superclasses direct-superclasses)
2732         all-keys)
2733  class)
2734
2735(defun maybe-finalize-class-subtree (class)
2736  (when (every #'class-finalized-p (class-direct-superclasses class))
2737    (finalize-inheritance class)
2738    (dolist (subclass (class-direct-subclasses class))
2739      (maybe-finalize-class-subtree subclass))))
2740
2741(defmacro defclass (&whole form name direct-superclasses direct-slots &rest options)
2742  (unless (>= (length form) 3)
2743    (error 'program-error "Wrong number of arguments for DEFCLASS."))
2744  (check-declaration-type name)
2745  `(ensure-class ',name
2746                 :direct-superclasses
2747                 (canonicalize-direct-superclasses ',direct-superclasses)
2748                 :direct-slots
2749                 ,(canonicalize-direct-slots direct-slots)
2750                 ,@(canonicalize-defclass-options options)))
2751
2752
2753;;; AMOP pg. 180
2754(defgeneric direct-slot-definition-class (class &rest initargs))
2755
2756(defmethod direct-slot-definition-class ((class class) &rest initargs)
2757  (declare (ignore initargs))
2758  +the-standard-direct-slot-definition-class+)
2759
2760;;; AMOP pg. 181
2761(defgeneric effective-slot-definition-class (class &rest initargs))
2762
2763(defmethod effective-slot-definition-class ((class class) &rest initargs)
2764  (declare (ignore initargs))
2765  +the-standard-effective-slot-definition-class+)
2766
2767;;; AMOP pg. 224
2768(defgeneric reader-method-class (class direct-slot &rest initargs))
2769
2770(defmethod reader-method-class ((class standard-class)
2771                                (direct-slot standard-direct-slot-definition)
2772                                &rest initargs)
2773  (declare (ignore initargs))
2774  +the-standard-reader-method-class+)
2775
2776(defmethod reader-method-class ((class funcallable-standard-class)
2777                                (direct-slot standard-direct-slot-definition)
2778                                &rest initargs)
2779  (declare (ignore initargs))
2780  +the-standard-reader-method-class+)
2781
2782;;; AMOP pg. 242
2783(defgeneric writer-method-class (class direct-slot &rest initargs))
2784
2785(defmethod writer-method-class ((class standard-class)
2786                                (direct-slot standard-direct-slot-definition)
2787                                &rest initargs)
2788  (declare (ignore initargs))
2789  +the-standard-writer-method-class+)
2790
2791(defmethod writer-method-class ((class funcallable-standard-class)
2792                                (direct-slot standard-direct-slot-definition)
2793                                &rest initargs)
2794  (declare (ignore initargs))
2795  +the-standard-writer-method-class+)
2796
2797(atomic-defgeneric documentation (x doc-type)
2798    (:method ((x symbol) doc-type)
2799        (%documentation x doc-type))
2800    (:method ((x function) doc-type)
2801        (%documentation x doc-type)))
2802
2803(atomic-defgeneric (setf documentation) (new-value x doc-type)
2804    (:method (new-value (x symbol) doc-type)
2805        (%set-documentation x doc-type new-value))
2806    (:method (new-value (x function) doc-type)
2807        (%set-documentation x doc-type new-value)))
2808
2809
2810;; FIXME This should be a weak hashtable!
2811(defvar *list-documentation-hashtable* (make-hash-table :test #'equal))
2812
2813(defmethod documentation ((x list) (doc-type (eql 'function)))
2814  (let ((alist (gethash x *list-documentation-hashtable*)))
2815    (and alist (cdr (assoc doc-type alist)))))
2816
2817(defmethod documentation ((x list) (doc-type (eql 'compiler-macro)))
2818  (let ((alist (gethash x *list-documentation-hashtable*)))
2819    (and alist (cdr (assoc doc-type alist)))))
2820
2821(defmethod (setf documentation) (new-value (x list) (doc-type (eql 'function)))
2822  (let* ((alist (gethash x *list-documentation-hashtable*))
2823         (entry (and alist (assoc doc-type alist))))
2824    (cond (entry
2825           (setf (cdr entry) new-value))
2826          (t
2827           (setf (gethash x *list-documentation-hashtable*)
2828                 (push (cons doc-type new-value) alist)))))
2829  new-value)
2830
2831(defmethod (setf documentation) (new-value (x list) (doc-type (eql 'compiler-macro)))
2832  (let* ((alist (gethash x *list-documentation-hashtable*))
2833         (entry (and alist (assoc doc-type alist))))
2834    (cond (entry
2835           (setf (cdr entry) new-value))
2836          (t
2837           (setf (gethash x *list-documentation-hashtable*)
2838                 (push (cons doc-type new-value) alist)))))
2839  new-value)
2840
2841(defmethod documentation ((x class) (doc-type (eql 't)))
2842  (class-documentation x))
2843
2844(defmethod documentation ((x class) (doc-type (eql 'type)))
2845  (class-documentation x))
2846
2847(defmethod (setf documentation) (new-value (x class) (doc-type (eql 't)))
2848  (%set-class-documentation x new-value))
2849
2850(defmethod (setf documentation) (new-value (x class) (doc-type (eql 'type)))
2851  (%set-class-documentation x new-value))
2852
2853(defmethod documentation ((x structure-class) (doc-type (eql 't)))
2854  (%documentation x doc-type))
2855
2856(defmethod documentation ((x structure-class) (doc-type (eql 'type)))
2857  (%documentation x doc-type))
2858
2859(defmethod (setf documentation) (new-value (x structure-class) (doc-type (eql 't)))
2860  (%set-documentation x doc-type new-value))
2861
2862(defmethod (setf documentation) (new-value (x structure-class) (doc-type (eql 'type)))
2863  (%set-documentation x doc-type new-value))
2864
2865(defmethod documentation ((x standard-generic-function) (doc-type (eql 't)))
2866  (generic-function-documentation x))
2867
2868(defmethod (setf documentation) (new-value (x standard-generic-function) (doc-type (eql 't)))
2869  (setf (generic-function-documentation x) new-value))
2870
2871(defmethod documentation ((x standard-generic-function) (doc-type (eql 'function)))
2872  (generic-function-documentation x))
2873
2874(defmethod (setf documentation) (new-value (x standard-generic-function) (doc-type (eql 'function)))
2875  (setf (generic-function-documentation x) new-value))
2876
2877(defmethod documentation ((x standard-method) (doc-type (eql 't)))
2878  (method-documentation x))
2879
2880(defmethod (setf documentation) (new-value (x standard-method) (doc-type (eql 't)))
2881  (setf (method-documentation x) new-value))
2882
2883(defmethod documentation ((x package) (doc-type (eql 't)))
2884  (%documentation x doc-type))
2885
2886(defmethod (setf documentation) (new-value (x package) (doc-type (eql 't)))
2887  (%set-documentation x doc-type new-value))
2888
2889(defmethod documentation ((x symbol) (doc-type (eql 'function)))
2890  (%documentation x doc-type))
2891
2892;;; Applicable methods
2893
2894(defgeneric compute-applicable-methods (gf args)
2895  (:method ((gf standard-generic-function) args)
2896    (%compute-applicable-methods gf args)))
2897
2898(defgeneric compute-applicable-methods-using-classes (gf classes)
2899  (:method ((gf standard-generic-function) classes)
2900    (let ((methods '()))
2901      (dolist (method (generic-function-methods gf))
2902  (multiple-value-bind (applicable knownp)
2903      (method-applicable-using-classes-p method classes)
2904    (cond (applicable
2905     (push method methods))
2906    ((not knownp)
2907     (return-from compute-applicable-methods-using-classes
2908       (values nil nil))))))
2909      (values (sort-methods methods gf classes)
2910        t))))
2911
2912(export '(compute-applicable-methods
2913    compute-applicable-methods-using-classes))
2914
2915
2916;;; Slot access
2917
2918(defun set-slot-value-using-class (new-value class instance slot-name)
2919  (declare (ignore class)) ; FIXME
2920  (setf (std-slot-value instance slot-name) new-value))
2921
2922(defgeneric slot-value-using-class (class instance slot-name))
2923
2924(defmethod slot-value-using-class ((class standard-class) instance slot-name)
2925  (std-slot-value instance slot-name))
2926(defmethod slot-value-using-class ((class funcallable-standard-class)
2927                                   instance slot-name)
2928  (std-slot-value instance slot-name))
2929(defmethod slot-value-using-class ((class structure-class) instance slot-name)
2930  (std-slot-value instance slot-name))
2931
2932(defgeneric (setf slot-value-using-class) (new-value class instance slot-name))
2933
2934(defmethod (setf slot-value-using-class) (new-value
2935                                          (class standard-class)
2936                                          instance
2937                                          slot-name)
2938  (setf (std-slot-value instance slot-name) new-value))
2939
2940(defmethod (setf slot-value-using-class) (new-value
2941                                          (class funcallable-standard-class)
2942                                          instance
2943                                          slot-name)
2944  (setf (std-slot-value instance slot-name) new-value))
2945
2946(defmethod (setf slot-value-using-class) (new-value
2947                                          (class structure-class)
2948                                          instance
2949                                          slot-name)
2950  (setf (std-slot-value instance slot-name) new-value))
2951
2952(defgeneric slot-exists-p-using-class (class instance slot-name))
2953
2954(defmethod slot-exists-p-using-class (class instance slot-name)
2955  nil)
2956
2957(defmethod slot-exists-p-using-class ((class standard-class) instance slot-name)
2958  (std-slot-exists-p instance slot-name))
2959(defmethod slot-exists-p-using-class ((class funcallable-standard-class) instance slot-name)
2960  (std-slot-exists-p instance slot-name))
2961
2962(defmethod slot-exists-p-using-class ((class structure-class) instance slot-name)
2963  (dolist (dsd (class-slots class))
2964    (when (eq (sys::dsd-name dsd) slot-name)
2965      (return-from slot-exists-p-using-class t)))
2966  nil)
2967
2968(defgeneric slot-boundp-using-class (class instance slot-name))
2969(defmethod slot-boundp-using-class ((class standard-class) instance slot-name)
2970  (std-slot-boundp instance slot-name))
2971(defmethod slot-boundp-using-class ((class funcallable-standard-class) instance slot-name)
2972  (std-slot-boundp instance slot-name))
2973(defmethod slot-boundp-using-class ((class structure-class) instance slot-name)
2974  "Structure slots can't be unbound, so this method always returns T."
2975  (declare (ignore class instance slot-name))
2976  t)
2977
2978(defgeneric slot-makunbound-using-class (class instance slot-name))
2979(defmethod slot-makunbound-using-class ((class standard-class)
2980                                        instance
2981                                        slot-name)
2982  (std-slot-makunbound instance slot-name))
2983(defmethod slot-makunbound-using-class ((class funcallable-standard-class)
2984                                        instance
2985                                        slot-name)
2986  (std-slot-makunbound instance slot-name))
2987(defmethod slot-makunbound-using-class ((class structure-class)
2988                                        instance
2989                                        slot-name)
2990  (declare (ignore class instance slot-name))
2991  (error "Structure slots can't be unbound"))
2992
2993(defgeneric slot-missing (class instance slot-name operation &optional new-value))
2994
2995(defmethod slot-missing ((class t) instance slot-name operation &optional new-value)
2996  (declare (ignore new-value))
2997  (error "The slot ~S is missing from the class ~S." slot-name class))
2998
2999(defgeneric slot-unbound (class instance slot-name))
3000
3001(defmethod slot-unbound ((class t) instance slot-name)
3002  (error 'unbound-slot :instance instance :name slot-name))
3003
3004;;; Instance creation and initialization
3005
3006;;; AMOP pg. 168ff.  Checking whether the class is finalized is done
3007;;; inside std-allocate-instance and allocate-funcallable-instance.
3008(defgeneric allocate-instance (class &rest initargs &key &allow-other-keys))
3009
3010(defmethod allocate-instance ((class standard-class) &rest initargs)
3011  (declare (ignore initargs))
3012  (std-allocate-instance class))
3013
3014(defmethod allocate-instance ((class funcallable-standard-class) &rest initargs)
3015  (declare (ignore initargs))
3016  (allocate-funcallable-instance class))
3017
3018(defmethod allocate-instance ((class structure-class) &rest initargs)
3019  (declare (ignore initargs))
3020  (%make-structure (class-name class)
3021                   (make-list (length (class-slots class))
3022                              :initial-element +slot-unbound+)))
3023
3024(defmethod allocate-instance ((class built-in-class) &rest initargs)
3025  (declare (ignore initargs))
3026  (error "Cannot allocate instances of a built-in class: ~S" class))
3027
3028;; "The set of valid initialization arguments for a class is the set of valid
3029;; initialization arguments that either fill slots or supply arguments to
3030;; methods, along with the predefined initialization argument :ALLOW-OTHER-KEYS."
3031;; 7.1.2
3032
3033(defun calculate-allowable-initargs (gf-list args instance
3034                                             shared-initialize-param
3035                                             initargs)
3036  (let* ((methods
3037          (nconc
3038             (compute-applicable-methods #'shared-initialize
3039                                         (list* instance
3040                                                shared-initialize-param
3041                                                initargs))
3042             (mapcan #'(lambda (gf)
3043                         (compute-applicable-methods gf args))
3044                     gf-list)))
3045         (method-keyword-args
3046          (reduce #'merge-initargs-sets
3047                  (mapcar #'method-lambda-list methods)
3048                  :key #'extract-lambda-list-keywords
3049                  :initial-value nil))
3050         (slots-initargs
3051          (mapappend #'slot-definition-initargs
3052                     (class-slots (class-of instance)))))
3053    (merge-initargs-sets
3054     (merge-initargs-sets slots-initargs method-keyword-args)
3055     '(:allow-other-keys))))  ;; allow-other-keys is always allowed
3056
3057(defun check-initargs (gf-list args instance
3058                       shared-initialize-param initargs
3059                       cache call-site)
3060  "Checks the validity of `initargs' for the generic functions in `gf-list'
3061when called with `args' by calculating the applicable methods for each gf.
3062The applicable methods for SHARED-INITIALIZE based on `instance',
3063`shared-initialize-param' and `initargs' are added to the list of
3064applicable methods."
3065  (when (oddp (length initargs))
3066    (error 'program-error
3067           :format-control "Odd number of keyword arguments."))
3068  (unless (getf initargs :allow-other-keys)
3069    (multiple-value-bind (allowable-initargs present-p)
3070                         (when cache
3071                           (gethash (class-of instance) cache))
3072       (unless present-p
3073         (setf allowable-initargs
3074               (calculate-allowable-initargs gf-list args instance
3075                                             shared-initialize-param initargs))
3076         (when cache
3077           (setf (gethash (class-of instance) cache)
3078                 allowable-initargs)))
3079       (unless (eq t allowable-initargs)
3080         (do* ((tail initargs (cddr tail))
3081               (initarg (car tail) (car tail)))
3082              ((null tail))
3083              (unless (memq initarg allowable-initargs)
3084                (error 'program-error
3085                       :format-control "Invalid initarg ~S in call to ~S with arglist ~S."
3086                       :format-arguments (list initarg call-site args))))))))
3087
3088(defun merge-initargs-sets (list1 list2)
3089  (cond
3090   ((eq list1 t)  t)
3091   ((eq list2 t)  t)
3092   (t             (union list1 list2))))
3093
3094(defun extract-lambda-list-keywords (lambda-list)
3095  "Returns a list of keywords acceptable as keyword arguments,
3096or T when any keyword is acceptable due to presence of
3097&allow-other-keys."
3098  (when (member '&allow-other-keys lambda-list)
3099    (return-from extract-lambda-list-keywords t))
3100  (loop with keyword-args = (cdr (memq '&key lambda-list))
3101        for key in keyword-args
3102        when (eq key '&aux) do (loop-finish)
3103        when (eq key '&allow-other-keys) do (return t)
3104        when (listp key) do (setq key (car key))
3105        collect (if (symbolp key)
3106                    (make-keyword key)
3107                  (car key))))
3108
3109
3110(defgeneric make-instance (class &rest initargs &key &allow-other-keys))
3111
3112(defmethod make-instance :before ((class class) &rest initargs)
3113  (when (oddp (length initargs))
3114    (error 'program-error :format-control "Odd number of keyword arguments."))
3115  (unless (class-finalized-p class)
3116    (finalize-inheritance class)))
3117
3118(defun augment-initargs-with-defaults (class initargs)
3119  (let ((default-initargs '()))
3120    (do* ((list (class-default-initargs class) (cddr list))
3121          (key (car list) (car list))
3122          (fn (cadr list) (cadr list)))
3123         ((null list))
3124      (when (eq (getf initargs key 'not-found) 'not-found)
3125        (setf default-initargs (append default-initargs (list key (funcall fn))))))
3126    (append initargs default-initargs)))
3127
3128(defmethod make-instance ((class standard-class) &rest initargs)
3129  (setf initargs (augment-initargs-with-defaults class initargs))
3130  (let ((instance (std-allocate-instance class)))
3131    (check-initargs (list #'allocate-instance #'initialize-instance)
3132                    (list* instance initargs)
3133                    instance t initargs
3134                    *make-instance-initargs-cache* 'make-instance)
3135    (apply #'initialize-instance instance initargs)
3136    instance))
3137
3138(defmethod make-instance ((class funcallable-standard-class) &rest initargs)
3139  (setf initargs (augment-initargs-with-defaults class initargs))
3140  (let ((instance (allocate-funcallable-instance class)))
3141    (check-initargs (list #'allocate-instance #'initialize-instance)
3142                    (list* instance initargs)
3143                    instance t initargs
3144                    *make-instance-initargs-cache* 'make-instance)
3145    (apply #'initialize-instance instance initargs)
3146    instance))
3147
3148(defmethod make-instance ((class symbol) &rest initargs)
3149  (apply #'make-instance (find-class class) initargs))
3150
3151(defgeneric initialize-instance (instance &rest initargs
3152                                          &key &allow-other-keys))
3153
3154(defmethod initialize-instance ((instance standard-object) &rest initargs)
3155  (apply #'shared-initialize instance t initargs))
3156
3157(defgeneric reinitialize-instance (instance &rest initargs
3158                                            &key &allow-other-keys))
3159
3160;; "The system-supplied primary method for REINITIALIZE-INSTANCE checks the
3161;; validity of initargs and signals an error if an initarg is supplied that is
3162;; not declared as valid. The method then calls the generic function SHARED-
3163;; INITIALIZE with the following arguments: the instance, nil (which means no
3164;; slots should be initialized according to their initforms), and the initargs
3165;; it received."
3166(defmethod reinitialize-instance ((instance standard-object) &rest initargs)
3167  (check-initargs (list #'reinitialize-instance) (list* instance initargs)
3168                  instance () initargs
3169                  *reinitialize-instance-initargs-cache* 'reinitialize-instance)
3170  (apply #'shared-initialize instance () initargs))
3171
3172(defun std-shared-initialize (instance slot-names all-keys)
3173  (when (oddp (length all-keys))
3174    (error 'program-error :format-control "Odd number of keyword arguments."))
3175  ;; do a quick scan of the arguments list to see if it's a real
3176  ;; 'initialization argument list' (which is not the same as
3177  ;; checking initarg validity
3178  (do* ((tail all-keys (cddr tail))
3179        (initarg (car tail) (car tail)))
3180      ((null tail))
3181    (unless (symbolp initarg)
3182      (error 'program-error
3183             :format-control "Initarg ~S not a symbol."
3184             :format-arguments (list initarg))))
3185  (dolist (slot (class-slots (class-of instance)))
3186    (let ((slot-name (slot-definition-name slot)))
3187      (multiple-value-bind (init-key init-value foundp)
3188          (get-properties all-keys (slot-definition-initargs slot))
3189        (if foundp
3190            (setf (std-slot-value instance slot-name) init-value)
3191            (unless (std-slot-boundp instance slot-name)
3192              (let ((initfunction (slot-definition-initfunction slot)))
3193                (when (and initfunction (or (eq slot-names t)
3194                                            (memq slot-name slot-names)))
3195                  (setf (std-slot-value instance slot-name)
3196                        (funcall initfunction)))))))))
3197  instance)
3198
3199(defgeneric shared-initialize (instance slot-names
3200                                        &rest initargs
3201                                        &key &allow-other-keys))
3202
3203(defmethod shared-initialize ((instance standard-object) slot-names
3204                              &rest initargs)
3205  (std-shared-initialize instance slot-names initargs))
3206
3207(defmethod shared-initialize :after ((instance standard-class) slot-names
3208                                     &key direct-superclasses
3209                                     direct-slots direct-default-initargs
3210                                     &allow-other-keys)
3211  (std-after-initialization-for-classes
3212   instance :direct-superclasses direct-superclasses
3213   :direct-slots direct-slots
3214   :direct-default-initargs direct-default-initargs))
3215
3216(defmethod shared-initialize :after ((instance funcallable-standard-class)
3217                                     slot-names &key direct-superclasses
3218                                     direct-slots direct-default-initargs
3219                                     &allow-other-keys)
3220  (std-after-initialization-for-classes
3221   instance :direct-superclasses direct-superclasses
3222   :direct-slots direct-slots
3223   :direct-default-initargs direct-default-initargs))
3224
3225(defmethod shared-initialize ((slot slot-definition) slot-names
3226                              &rest args
3227                              &key name initargs initform initfunction
3228                              readers writers allocation
3229                              &allow-other-keys)
3230  ;;Keyword args are duplicated from init-slot-definition only to have
3231  ;;them checked.
3232  (declare (ignore slot-names)) ;;TODO?
3233  (declare (ignore name initargs initform initfunction readers writers allocation))
3234  ;;For built-in slots
3235  (apply #'init-slot-definition slot :allow-other-keys t args)
3236  ;;For user-defined slots
3237  (call-next-method))
3238
3239;;; change-class
3240
3241(defgeneric change-class (instance new-class &key &allow-other-keys))
3242
3243(defmethod change-class ((old-instance standard-object) (new-class standard-class)
3244                         &rest initargs)
3245  (let ((old-slots (class-slots (class-of old-instance)))
3246        (new-slots (class-slots new-class))
3247        (new-instance (allocate-instance new-class)))
3248    ;; "The values of local slots specified by both the class CTO and the class
3249    ;; CFROM are retained. If such a local slot was unbound, it remains
3250    ;; unbound."
3251    (dolist (new-slot new-slots)
3252      (when (instance-slot-p new-slot)
3253        (let* ((slot-name (slot-definition-name new-slot))
3254               (old-slot (find slot-name old-slots :key 'slot-definition-name)))
3255          ;; "The values of slots specified as shared in the class CFROM and as
3256          ;; local in the class CTO are retained."
3257          (when (and old-slot (slot-boundp old-instance slot-name))
3258            (setf (slot-value new-instance slot-name)
3259                  (slot-value old-instance slot-name))))))
3260    (swap-slots old-instance new-instance)
3261    (rotatef (std-instance-layout new-instance)
3262             (std-instance-layout old-instance))
3263    (apply #'update-instance-for-different-class
3264           new-instance old-instance initargs)
3265    old-instance))
3266
3267(defmethod change-class ((instance standard-object) (new-class symbol) &rest initargs)
3268  (apply #'change-class instance (find-class new-class) initargs))
3269
3270(defgeneric update-instance-for-different-class (old new
3271                                                     &rest initargs
3272                                                     &key &allow-other-keys))
3273
3274(defmethod update-instance-for-different-class
3275  ((old standard-object) (new standard-object) &rest initargs)
3276  (let ((added-slots
3277         (remove-if #'(lambda (slot-name)
3278                       (slot-exists-p old slot-name))
3279                    (mapcar 'slot-definition-name
3280                            (class-slots (class-of new))))))
3281    (check-initargs (list #'update-instance-for-different-class)
3282                    (list old new initargs)
3283                    new added-slots initargs
3284                    nil 'update-instance-for-different-class)
3285    (apply #'shared-initialize new added-slots initargs)))
3286
3287;;; make-instances-obsolete
3288
3289(defgeneric make-instances-obsolete (class))
3290
3291(defmethod make-instances-obsolete ((class standard-class))
3292  (%make-instances-obsolete class))
3293(defmethod make-instances-obsolete ((class funcallable-standard-class))
3294  (%make-instances-obsolete class))
3295(defmethod make-instances-obsolete ((class symbol))
3296  (make-instances-obsolete (find-class class))
3297  class)
3298
3299;;; update-instance-for-redefined-class
3300
3301(defgeneric update-instance-for-redefined-class (instance
3302                                                 added-slots
3303                                                 discarded-slots
3304                                                 property-list
3305                                                 &rest initargs
3306                                                 &key
3307                                                 &allow-other-keys))
3308
3309(defmethod update-instance-for-redefined-class ((instance standard-object)
3310            added-slots
3311            discarded-slots
3312            property-list
3313            &rest initargs)
3314  (check-initargs (list #'update-instance-for-redefined-class)
3315                  (list* instance added-slots discarded-slots
3316                         property-list initargs)
3317                  instance added-slots initargs
3318                  nil 'update-instance-for-redefined-class)
3319  (apply #'shared-initialize instance added-slots initargs))
3320
3321;;;  Methods having to do with class metaobjects.
3322
3323(defmethod initialize-instance :after ((class standard-class) &rest args)
3324  (apply #'std-after-initialization-for-classes class args))
3325
3326(defmethod initialize-instance :after ((class funcallable-standard-class)
3327                                       &rest args)
3328  (apply #'std-after-initialization-for-classes class args))
3329
3330(defmethod reinitialize-instance :after ((class standard-class) &rest all-keys)
3331  (remhash class *make-instance-initargs-cache*)
3332  (remhash class *reinitialize-instance-initargs-cache*)
3333  (%make-instances-obsolete class)
3334  (setf (class-finalized-p class) nil)
3335  (check-initargs (list #'allocate-instance
3336                        #'initialize-instance)
3337                  (list* class all-keys)
3338                  class t all-keys
3339                  nil 'reinitialize-instance)
3340  (apply #'std-after-initialization-for-classes class all-keys))
3341
3342;;; Finalize inheritance
3343
3344(atomic-defgeneric finalize-inheritance (class)
3345    (:method ((class standard-class))
3346       (std-finalize-inheritance class))
3347    (:method ((class funcallable-standard-class))
3348       (std-finalize-inheritance class)))
3349
3350;;; Class precedence lists
3351
3352(defgeneric compute-class-precedence-list (class))
3353(defmethod compute-class-precedence-list ((class standard-class))
3354  (std-compute-class-precedence-list class))
3355(defmethod compute-class-precedence-list ((class funcallable-standard-class))
3356  (std-compute-class-precedence-list class))
3357
3358;;; Slot inheritance
3359
3360(defgeneric compute-slots (class))
3361(defmethod compute-slots ((class standard-class))
3362  (std-compute-slots class))
3363(defmethod compute-slots ((class funcallable-standard-class))
3364  (std-compute-slots class))
3365
3366(defgeneric compute-effective-slot-definition (class name direct-slots))
3367(defmethod compute-effective-slot-definition
3368  ((class standard-class) name direct-slots)
3369  (std-compute-effective-slot-definition class name direct-slots))
3370(defmethod compute-effective-slot-definition
3371  ((class funcallable-standard-class) name direct-slots)
3372  (std-compute-effective-slot-definition class name direct-slots))
3373;;; Methods having to do with generic function metaobjects.
3374
3375(defmethod initialize-instance :after ((gf standard-generic-function) &key)
3376  (finalize-standard-generic-function gf))
3377
3378;;; Methods having to do with generic function invocation.
3379
3380(defgeneric compute-discriminating-function (gf))
3381(defmethod compute-discriminating-function ((gf standard-generic-function))
3382  (std-compute-discriminating-function gf))
3383
3384(defgeneric method-more-specific-p (gf method1 method2 required-classes))
3385
3386(defmethod method-more-specific-p ((gf standard-generic-function)
3387                                   method1 method2 required-classes)
3388  (std-method-more-specific-p method1 method2 required-classes
3389                              (generic-function-argument-precedence-order gf)))
3390
3391;;; XXX AMOP has COMPUTE-EFFECTIVE-METHOD
3392(defgeneric compute-effective-method-function (gf methods))
3393(defmethod compute-effective-method-function ((gf standard-generic-function) methods)
3394  (std-compute-effective-method-function gf methods))
3395
3396(defgeneric compute-applicable-methods (gf args))
3397(defmethod compute-applicable-methods ((gf standard-generic-function) args)
3398  (%compute-applicable-methods gf args))
3399
3400;;; Slot definition accessors
3401
3402(defmacro slot-definition-dispatch (slot-definition std-form generic-form)
3403  `(let (($cl (class-of ,slot-definition)))
3404     (case $cl
3405       ((+the-standard-slot-definition-class+
3406         +the-standard-direct-slot-definition-class+
3407         +the-standard-effective-slot-definition-class+)
3408        ,std-form)
3409       (t ,generic-form))))
3410
3411(atomic-defgeneric slot-definition-allocation (slot-definition)
3412  (:method ((slot-definition slot-definition))
3413    (slot-definition-dispatch slot-definition
3414      (%slot-definition-allocation slot-definition)
3415      (slot-value slot-definition 'sys::allocation))))
3416
3417(atomic-defgeneric (setf slot-definition-allocation) (value slot-definition)
3418  (:method (value (slot-definition slot-definition))
3419    (slot-definition-dispatch slot-definition
3420      (set-slot-definition-allocation slot-definition value)
3421      (setf (slot-value slot-definition 'sys::allocation) value))))
3422
3423(atomic-defgeneric slot-definition-initargs (slot-definition)
3424  (:method ((slot-definition slot-definition))
3425    (slot-definition-dispatch slot-definition
3426      (%slot-definition-initargs slot-definition)
3427      (slot-value slot-definition 'sys::initargs))))
3428
3429(atomic-defgeneric slot-definition-initform (slot-definition)
3430  (:method ((slot-definition slot-definition))
3431    (slot-definition-dispatch slot-definition
3432      (%slot-definition-initform slot-definition)
3433      (slot-value slot-definition 'sys::initform))))
3434
3435(atomic-defgeneric (setf slot-definition-initform) (value slot-definition)
3436  (:method (value (slot-definition slot-definition))
3437    (slot-definition-dispatch slot-definition
3438      (set-slot-definition-initform slot-definition value)
3439      (setf (slot-value slot-definition 'sys::initform) value))))
3440
3441(atomic-defgeneric slot-definition-initfunction (slot-definition)
3442  (:method ((slot-definition slot-definition))
3443    (slot-definition-dispatch slot-definition
3444      (%slot-definition-initfunction slot-definition)
3445      (slot-value slot-definition 'sys::initfunction))))
3446
3447(atomic-defgeneric (setf slot-definition-initfunction) (value slot-definition)
3448  (:method (value (slot-definition slot-definition))
3449    (slot-definition-dispatch slot-definition
3450      (set-slot-definition-initfunction slot-definition value)
3451      (setf (slot-value slot-definition 'sys::initfunction) value))))
3452
3453(atomic-defgeneric slot-definition-name (slot-definition)
3454  (:method ((slot-definition slot-definition))
3455    (slot-definition-dispatch slot-definition
3456      (%slot-definition-name slot-definition)
3457      (slot-value slot-definition 'sys::name))))
3458
3459(atomic-defgeneric (setf slot-definition-name) (value slot-definition)
3460  (:method (value (slot-definition slot-definition))
3461    (slot-definition-dispatch slot-definition
3462      (set-slot-definition-name slot-definition value)
3463      (setf (slot-value slot-definition 'sys::name) value))))
3464
3465(atomic-defgeneric slot-definition-readers (slot-definition)
3466  (:method ((slot-definition slot-definition))
3467    (slot-definition-dispatch slot-definition
3468      (%slot-definition-readers slot-definition)
3469      (slot-value slot-definition 'sys::readers))))
3470
3471(atomic-defgeneric (setf slot-definition-readers) (value slot-definition)
3472  (:method (value (slot-definition slot-definition))
3473    (slot-definition-dispatch slot-definition
3474      (set-slot-definition-readers slot-definition value)
3475      (setf (slot-value slot-definition 'sys::readers) value))))
3476
3477(atomic-defgeneric slot-definition-writers (slot-definition)
3478  (:method ((slot-definition slot-definition))
3479    (slot-definition-dispatch slot-definition
3480      (%slot-definition-writers slot-definition)
3481      (slot-value slot-definition 'sys::writers))))
3482
3483(atomic-defgeneric (setf slot-definition-writers) (value slot-definition)
3484  (:method (value (slot-definition slot-definition))
3485    (slot-definition-dispatch slot-definition
3486      (set-slot-definition-writers slot-definition value)
3487      (setf (slot-value slot-definition 'sys::writers) value))))
3488
3489(atomic-defgeneric slot-definition-allocation-class (slot-definition)
3490  (:method ((slot-definition slot-definition))
3491    (slot-definition-dispatch slot-definition
3492      (%slot-definition-allocation-class slot-definition)
3493      (slot-value slot-definition 'sys::allocation-class))))
3494
3495(atomic-defgeneric (setf slot-definition-allocation-class)
3496                       (value slot-definition)
3497  (:method (value (slot-definition slot-definition))
3498    (slot-definition-dispatch slot-definition
3499      (set-slot-definition-allocation-class slot-definition value)
3500      (setf (slot-value slot-definition 'sys::allocation-class) value))))
3501
3502(atomic-defgeneric slot-definition-location (slot-definition)
3503  (:method ((slot-definition slot-definition))
3504    (slot-definition-dispatch slot-definition
3505      (%slot-definition-location slot-definition)
3506      (slot-value slot-definition 'sys::location))))
3507
3508(atomic-defgeneric (setf slot-definition-location) (value slot-definition)
3509  (:method (value (slot-definition slot-definition))
3510    (slot-definition-dispatch slot-definition
3511      (set-slot-definition-location slot-definition value)
3512      (setf (slot-value slot-definition 'sys::location) value))))
3513
3514;;; No %slot-definition-type.
3515
3516
3517;;; Conditions.
3518
3519(defmacro define-condition (name (&rest parent-types) (&rest slot-specs) &body options)
3520  (let ((parent-types (or parent-types '(condition)))
3521        (report nil))
3522    (dolist (option options)
3523      (when (eq (car option) :report)
3524        (setf report (cadr option))
3525  (setf options (delete option options :test #'equal))
3526        (return)))
3527    (typecase report
3528      (null
3529       `(progn
3530          (defclass ,name ,parent-types ,slot-specs ,@options)
3531          ',name))
3532      (string
3533       `(progn
3534          (defclass ,name ,parent-types ,slot-specs ,@options)
3535          (defmethod print-object ((condition ,name) stream)
3536            (if *print-escape*
3537                (call-next-method)
3538                (progn (write-string ,report stream) condition)))
3539          ',name))
3540      (t
3541       `(progn
3542          (defclass ,name ,parent-types ,slot-specs ,@options)
3543          (defmethod print-object ((condition ,name) stream)
3544            (if *print-escape*
3545                (call-next-method)
3546                (funcall #',report condition stream)))
3547          ',name)))))
3548
3549(defun make-condition (type &rest initargs)
3550  (or (%make-condition type initargs)
3551      (let ((class (if (symbolp type) (find-class type) type)))
3552        (apply #'make-instance class initargs))))
3553
3554;; Adapted from SBCL.
3555;; Originally defined in signal.lisp. Redefined here now that we have MAKE-CONDITION.
3556(defun coerce-to-condition (datum arguments default-type fun-name)
3557  (cond ((typep datum 'condition)
3558         (when arguments
3559           (error 'simple-type-error
3560                  :datum arguments
3561                  :expected-type 'null
3562                  :format-control "You may not supply additional arguments when giving ~S to ~S."
3563                  :format-arguments (list datum fun-name)))
3564         datum)
3565        ((symbolp datum)
3566         (apply #'make-condition datum arguments))
3567        ((or (stringp datum) (functionp datum))
3568         (make-condition default-type
3569                         :format-control datum
3570                         :format-arguments arguments))
3571        (t
3572         (error 'simple-type-error
3573                :datum datum
3574                :expected-type '(or symbol string)
3575                :format-control "Bad argument to ~S: ~S."
3576                :format-arguments (list fun-name datum)))))
3577
3578(defgeneric make-load-form (object &optional environment))
3579
3580(defmethod make-load-form ((object t) &optional environment)
3581  (declare (ignore environment))
3582  (apply #'no-applicable-method #'make-load-form (list object)))
3583
3584(defmethod make-load-form ((class class) &optional environment)
3585  (declare (ignore environment))
3586  (let ((name (class-name class)))
3587    (unless (and name (eq (find-class name nil) class))
3588      (error 'simple-type-error
3589             :format-control "Can't use anonymous or undefined class as a constant: ~S."
3590             :format-arguments (list class)))
3591    `(find-class ',name)))
3592
3593(defun invalid-method-error (method format-control &rest args)
3594  (let ((message (apply #'format nil format-control args)))
3595    (error "Invalid method error for ~S:~%    ~A" method message)))
3596
3597(defun method-combination-error (format-control &rest args)
3598  (let ((message (apply #'format nil format-control args)))
3599    (error "Method combination error in CLOS dispatch:~%    ~A" message)))
3600
3601
3602(atomic-defgeneric no-applicable-method (generic-function &rest args)
3603  (:method (generic-function &rest args)
3604      (error "There is no applicable method for the generic function ~S ~
3605              when called with arguments ~S."
3606             generic-function
3607             args)))
3608
3609
3610;;; FIXME (rudi 2012-01-28): this can be a function, it only needs to
3611;;; use standard accessor functions
3612(defgeneric find-method (generic-function
3613                         qualifiers
3614                         specializers
3615                         &optional errorp))
3616
3617(defmethod find-method ((generic-function standard-generic-function)
3618                        qualifiers specializers &optional (errorp t))
3619  (%find-method generic-function qualifiers specializers errorp))
3620
3621(defgeneric find-method ((generic-function symbol)
3622                         qualifiers specializers &optional (errorp t))
3623  (find-method (find-generic-function generic-function errorp)
3624               qualifiers specializers errorp))
3625
3626(defgeneric add-method (generic-function method))
3627
3628(defmethod add-method ((generic-function standard-generic-function)
3629                       (method method))
3630  (let ((method-lambda-list (method-lambda-list method))
3631        (gf-lambda-list (generic-function-lambda-list generic-function)))
3632    (check-method-lambda-list (%generic-function-name generic-function)
3633                              method-lambda-list gf-lambda-list))
3634  (std-add-method generic-function method))
3635
3636(defgeneric remove-method (generic-function method))
3637
3638(defmethod remove-method ((generic-function standard-generic-function) method)
3639  (std-remove-method generic-function method))
3640
3641;; See describe.lisp.
3642(defgeneric describe-object (object stream))
3643
3644;; FIXME
3645(defgeneric no-next-method (generic-function method &rest args))
3646
3647(atomic-defgeneric function-keywords (method)
3648  (:method ((method standard-method))
3649    (std-function-keywords method)))
3650
3651(setf *gf-initialize-instance* (symbol-function 'initialize-instance))
3652(setf *gf-allocate-instance* (symbol-function 'allocate-instance))
3653(setf *gf-shared-initialize* (symbol-function 'shared-initialize))
3654(setf *gf-reinitialize-instance* (symbol-function 'reinitialize-instance))
3655(setf *clos-booting* nil)
3656
3657(defgeneric class-prototype (class))
3658
3659(defmethod class-prototype :before (class)
3660  (unless (class-finalized-p class)
3661    (error "~@<~S is not finalized.~:@>" class)))
3662
3663(defmethod class-prototype ((class standard-class))
3664  (allocate-instance class))
3665
3666(defmethod class-prototype ((class funcallable-standard-class))
3667  (allocate-instance class))
3668
3669(defmethod class-prototype ((class structure-class))
3670  (allocate-instance class))
3671
3672;;; Readers for generic function metaobjects
3673;;; See AMOP pg. 216ff.
3674(atomic-defgeneric generic-function-argument-precedence-order (generic-function)
3675  (:method ((generic-function standard-generic-function))
3676    (sys:%generic-function-argument-precedence-order generic-function)))
3677
3678(atomic-defgeneric generic-function-declarations (generic-function)
3679  (:method ((generic-function standard-generic-function))
3680    ;; TODO: add slot to StandardGenericFunctionClass.java, use it
3681    nil))
3682
3683(atomic-defgeneric generic-function-lambda-list (generic-function)
3684  (:method ((generic-function standard-generic-function))
3685    (sys:%generic-function-lambda-list generic-function)))
3686
3687(atomic-defgeneric generic-function-method-class (generic-function)
3688  (:method ((generic-function standard-generic-function))
3689    (sys:%generic-function-method-class generic-function)))
3690
3691(atomic-defgeneric generic-function-method-combination (generic-function)
3692  (:method ((generic-function standard-generic-function))
3693    (sys:%generic-function-method-combination generic-function)))
3694
3695(atomic-defgeneric generic-function-methods (generic-function)
3696  (:method ((generic-function standard-generic-function))
3697    (sys:%generic-function-methods generic-function)))
3698
3699(atomic-defgeneric generic-function-name (generic-function)
3700  (:method ((generic-function standard-generic-function))
3701    (sys:%generic-function-name generic-function)))
3702
3703;;; Readers for Method Metaobjects
3704;;; AMOP pg. 218ff.
3705
3706(atomic-defgeneric method-function (method)
3707  (:method ((method standard-method))
3708    (std-method-function method)))
3709
3710(atomic-defgeneric method-generic-function (method)
3711  (:method ((method standard-method))
3712    (std-method-generic-function method)))
3713
3714(atomic-defgeneric method-lambda-list (method)
3715  (:method ((method standard-method))
3716    (std-slot-value method 'sys::lambda-list)))
3717
3718(atomic-defgeneric method-specializers (method)
3719  (:method ((method standard-method))
3720    (std-method-specializers method)))
3721
3722(atomic-defgeneric method-qualifiers (method)
3723  (:method ((method standard-method))
3724    (std-method-qualifiers method)))
3725
3726(atomic-defgeneric accessor-method-slot-definition (method)
3727  (:method ((method standard-accessor-method))
3728    (std-accessor-method-slot-definition method)))
3729
3730;;; SLIME compatibility functions.
3731
3732(defun %method-generic-function (method)
3733  (method-generic-function method))
3734
3735(defun %method-function (method)
3736  (method-function method))
3737
3738(eval-when (:compile-toplevel :load-toplevel :execute)
3739  (require "MOP"))
3740
3741(provide 'clos)
3742
Note: See TracBrowser for help on using the repository browser.