source: trunk/abcl/src/org/armedbear/lisp/compile-file.lisp @ 13497

Last change on this file since 13497 was 13497, checked in by ehuelsmann, 10 years ago

More code shuffling.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 33.4 KB
Line 
1;;; compile-file.lisp
2;;;
3;;; Copyright (C) 2004-2006 Peter Graves
4;;; $Id: compile-file.lisp 13497 2011-08-14 19:55:17Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package #:system)
33
34(require "JVM")
35;; (require "COMPILER-ERROR") already made accessible through JVM
36
37(defvar *fbound-names*)
38
39(defvar *class-number*)
40
41(defvar *output-file-pathname*)
42
43(defun base-classname (&optional (output-file-pathname *output-file-pathname*))
44  (sanitize-class-name (pathname-name output-file-pathname)))
45
46(defun fasl-loader-classname (&optional (output-file-pathname *output-file-pathname*))
47  (%format nil "~A_0" (base-classname output-file-pathname)))
48
49(declaim (ftype (function (t) t) compute-classfile-name))
50(defun compute-classfile-name (n &optional (output-file-pathname
51                                            *output-file-pathname*))
52  "Computes the name of the class file associated with number `n'."
53  (let ((name
54         (sanitize-class-name
55    (%format nil "~A_~D" (pathname-name output-file-pathname) n))))
56    (namestring (merge-pathnames (make-pathname :name name :type "cls")
57                                 output-file-pathname))))
58
59(defun sanitize-class-name (name)
60  (let ((name (copy-seq name)))
61    (dotimes (i (length name))
62      (declare (type fixnum i))
63      (when (or (char= (char name i) #\-)
64    (char= (char name i) #\.)
65    (char= (char name i) #\Space))
66        (setf (char name i) #\_)))
67    name))
68 
69
70(declaim (ftype (function () t) next-classfile-name))
71(defun next-classfile-name ()
72  (compute-classfile-name (incf *class-number*)))
73
74(defmacro report-error (&rest forms)
75  `(handler-case (progn ,@forms)
76     (compiler-unsupported-feature-error (condition)
77       (fresh-line)
78       (%format t "; UNSUPPORTED-FEATURE: ~A~%" condition)
79       (values nil condition))))
80
81;; Dummy function. Should never be called.
82(defun dummy (&rest ignored)
83  (declare (ignore ignored))
84  (assert nil))
85
86(declaim (ftype (function (t) t) verify-load))
87(defun verify-load (classfile)
88  #|(if (> *safety* 0)
89      (and classfile
90         (let ((*load-truename* *output-file-pathname*))
91           (report-error
92            (load-compiled-function classfile))))
93    t)|#
94  (declare (ignore classfile))
95  t)
96
97(declaim (ftype (function (t) t) note-toplevel-form))
98(defun note-toplevel-form (form)
99  (when *compile-print*
100    (fresh-line)
101    (princ "; ")
102    (let ((*print-length* 2)
103          (*print-level* 2)
104          (*print-pretty* nil))
105      (prin1 form))
106    (terpri)))
107
108(defun output-form (form)
109  (if *binary-fasls*
110      (push form *forms-for-output*)
111      (progn
112        (dump-form form *fasl-stream*)
113        (%stream-terpri *fasl-stream*))))
114
115(defun finalize-fasl-output ()
116  (when *binary-fasls*
117    (let ((*package* (find-package :keyword))
118          (*double-colon-package-separators* T))
119      (dump-form (convert-toplevel-form (list* 'PROGN
120                                               (nreverse *forms-for-output*))
121                                        t)
122                 *fasl-stream*))
123    (%stream-terpri *fasl-stream*)))
124
125
126(declaim (ftype (function (t) t) simple-toplevel-form-p))
127(defun simple-toplevel-form-p (form)
128  "Returns NIL if the form is too complex to become an
129interpreted toplevel form, non-NIL if it is 'simple enough'."
130  (and (consp form)
131       (every #'(lambda (arg)
132                  (or (and (atom arg)
133                           (not (and (symbolp arg)
134                                     (symbol-macro-p arg))))
135                      (and (consp arg)
136                           (eq 'QUOTE (car arg)))))
137              (cdr form))))
138
139(declaim (ftype (function (t t) t) convert-toplevel-form))
140(defun convert-toplevel-form (form declare-inline)
141  (when (or (simple-toplevel-form-p form)
142            (and (eq (car form) 'SETQ)
143                 ;; for SETQ, look at the evaluated part
144                 (simple-toplevel-form-p (third form))))
145    ;; single form with simple or constant arguments
146    ;; Without this exception, toplevel function calls
147    ;; will be compiled into lambdas which get compiled to
148    ;; compiled-functions. Those need to be loaded.
149    ;; Conclusion: Top level interpreting the function call
150    ;;  and its arguments may be (and should be) more efficient.
151    (return-from convert-toplevel-form
152      (precompiler:precompile-form form nil *compile-file-environment*)))
153  (let* ((expr `(lambda () ,form))
154         (saved-class-number *class-number*)
155         (classfile (next-classfile-name))
156         (result
157          (with-open-file
158              (f classfile
159                 :direction :output
160                 :element-type '(unsigned-byte 8)
161                 :if-exists :supersede)
162            (report-error (jvm:compile-defun nil
163                                             expr *compile-file-environment*
164                                             classfile f declare-inline))))
165         (compiled-function (verify-load classfile)))
166    (declare (ignore result))
167    (setf form
168          (if compiled-function
169              `(funcall (sys::get-fasl-function *fasl-loader*
170                                                ,saved-class-number))
171              (precompiler:precompile-form form nil
172                                           *compile-file-environment*)))))
173
174
175
176
177(declaim (ftype (function (t stream t) t) process-progn))
178(defun process-progn (forms stream compile-time-too)
179  (dolist (form forms)
180    (process-toplevel-form form stream compile-time-too))
181  nil)
182
183
184(declaim (ftype (function (t t t) t) process-toplevel-form))
185(defun precompile-toplevel-form (form stream compile-time-too)
186  (declare (ignore stream))
187  (let ((form (precompiler:precompile-form form nil
188                                           *compile-file-environment*)))
189    (when compile-time-too
190      (eval form))
191    form))
192
193
194
195(defun process-toplevel-macrolet (form stream compile-time-too)
196  (let ((*compile-file-environment*
197         (make-environment *compile-file-environment*)))
198    (dolist (definition (cadr form))
199      (environment-add-macro-definition *compile-file-environment*
200                                        (car definition)
201                                        (make-macro (car definition)
202                                                    (make-expander-for-macrolet definition))))
203    (dolist (body-form (cddr form))
204      (process-toplevel-form body-form stream compile-time-too)))
205  nil)
206
207(declaim (ftype (function (t t t) t) process-toplevel-defconstant))
208(defun process-toplevel-defconstant (form stream compile-time-too)
209  (declare (ignore stream compile-time-too))
210  ;; "If a DEFCONSTANT form appears as a top level form, the compiler
211  ;; must recognize that [the] name names a constant variable. An
212  ;; implementation may choose to evaluate the value-form at compile
213  ;; time, load time, or both. Therefore, users must ensure that the
214  ;; initial-value can be evaluated at compile time (regardless of
215  ;; whether or not references to name appear in the file) and that
216  ;; it always evaluates to the same value."
217  (note-toplevel-form form)
218  (eval form)
219  form)
220
221(declaim (ftype (function (t t t) t) process-toplevel-quote))
222(defun process-toplevel-quote (form stream compile-time-too)
223  (declare (ignore stream))
224  (when compile-time-too
225    (eval form))
226  nil)
227
228
229(declaim (ftype (function (t t t) t) process-toplevel-import))
230(defun process-toplevel-import (form stream compile-time-too)
231  (declare (ignore stream))
232  (let ((form (precompiler:precompile-form form nil
233                                           *compile-file-environment*)))
234    (let ((*package* +keyword-package+))
235      (output-form form))
236    (when compile-time-too
237      (eval form)))
238  nil)
239
240(declaim (ftype (function (t t t) t) process-toplevel-mop.ensure-method))
241(defun process-toplevel-mop.ensure-method (form stream compile-time-too)
242  (declare (ignore stream))
243  (flet ((convert-ensure-method (form key)
244           (let* ((tail (cddr form))
245                  (function-form (getf tail key)))
246             (when (and function-form (consp function-form)
247               (eq (%car function-form) 'FUNCTION))
248               (let ((lambda-expression (cadr function-form)))
249                 (jvm::with-saved-compiler-policy
250                     (let* ((saved-class-number *class-number*)
251                            (classfile (next-classfile-name))
252                            (result
253                             (with-open-file
254                                 (f classfile
255                                    :direction :output
256                                    :element-type '(unsigned-byte 8)
257                                    :if-exists :supersede)
258                               (report-error
259                                (jvm:compile-defun nil lambda-expression
260                                                   *compile-file-environment*
261                                                   classfile f nil))))
262                            (compiled-function (verify-load classfile)))
263                       (declare (ignore result))
264                       (cond
265                         (compiled-function
266                          (setf (getf tail key)
267                                `(sys::get-fasl-function *fasl-loader*
268                                                         ,saved-class-number)))
269                         (t
270                          ;; FIXME This should be a warning or error of some sort...
271                          (format *error-output* "; Unable to compile method~%"))))))))))
272
273
274    (convert-ensure-method form :function)
275    (convert-ensure-method form :fast-function))
276  (let ((form (precompiler:precompile-form form nil
277                                           *compile-file-environment*)))
278    (when compile-time-too
279      (eval form))
280    form))
281
282(declaim (ftype (function (t t t) t) process-toplevel-defvar/defparameter))
283(defun process-toplevel-defvar/defparameter (form stream compile-time-too)
284  (declare (ignore stream))
285  (note-toplevel-form form)
286  (if compile-time-too
287      (eval form)
288      ;; "If a DEFVAR or DEFPARAMETER form appears as a top level form,
289      ;; the compiler must recognize that the name has been proclaimed
290      ;; special. However, it must neither evaluate the initial-value
291      ;; form nor assign the dynamic variable named NAME at compile
292      ;; time."
293      (let ((name (second form)))
294        (%defvar name)))
295  form)
296
297(declaim (ftype (function (t t t) t) process-toplevel-defpackage/in-package))
298(defun process-toplevel-defpackage/in-package (form stream compile-time-too)
299  (declare (ignore stream compile-time-too))
300  (note-toplevel-form form)
301  (setf form
302        (precompiler:precompile-form form nil *compile-file-environment*))
303  (eval form)
304  ;; Force package prefix to be used when dumping form.
305  (let ((*package* +keyword-package+))
306    (output-form form))
307  nil)
308
309(declaim (ftype (function (t t t) t) process-toplevel-declare))
310(defun process-toplevel-declare (form stream compile-time-too)
311  (declare (ignore stream compile-time-too))
312  (compiler-style-warn "Misplaced declaration: ~S" form)
313  nil)
314
315(declaim (ftype (function (t t t) t) process-toplevel-progn))
316(defun process-toplevel-progn (form stream compile-time-too)
317  (process-progn (cdr form) stream compile-time-too)
318  nil)
319
320(declaim (ftype (function (t t t) t) process-toplevel-deftype))
321(defun process-toplevel-deftype (form stream compile-time-too)
322  (declare (ignore stream compile-time-too))
323  (note-toplevel-form form)
324  (eval form)
325  form)
326
327(declaim (ftype (function (t t t) t) process-toplevel-eval-when))
328(defun process-toplevel-eval-when (form stream compile-time-too)
329  (flet ((parse-eval-when-situations (situations)
330           "Parse an EVAL-WHEN situations list, returning three flags,
331            (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
332            the types of situations present in the list."
333            ; Adapted from SBCL.
334           (when (or (not (listp situations))
335                     (set-difference situations
336                                     '(:compile-toplevel
337                                       compile
338                                       :load-toplevel
339                                       load
340                                       :execute
341                                       eval)))
342             (error "Bad EVAL-WHEN situation list: ~S." situations))
343           (values (intersection '(:compile-toplevel compile) situations)
344                   (intersection '(:load-toplevel load) situations)
345                   (intersection '(:execute eval) situations))))
346    (multiple-value-bind (ct lt e)
347        (parse-eval-when-situations (cadr form))
348      (let ((new-compile-time-too (or ct (and compile-time-too e)))
349            (body (cddr form)))
350        (if lt
351            (process-progn body stream new-compile-time-too)
352            (when new-compile-time-too
353              (eval `(progn ,@body)))))))
354  nil)
355
356
357(declaim (ftype (function (t t t) t) process-toplevel-defmethod/defgeneric))
358(defun process-toplevel-defmethod/defgeneric (form stream compile-time-too)
359  (note-toplevel-form form)
360  (note-name-defined (second form))
361  (let ((*compile-print* nil))
362    (process-toplevel-form (macroexpand-1 form *compile-file-environment*)
363                           stream compile-time-too))
364  nil)
365
366(declaim (ftype (function (t t t) t) process-toplevel-locally))
367(defun process-toplevel-locally (form stream compile-time-too)
368  (jvm::with-saved-compiler-policy
369      (multiple-value-bind (forms decls)
370          (parse-body (cdr form) nil)
371        (process-optimization-declarations decls)
372        (let* ((jvm::*visible-variables* jvm::*visible-variables*)
373               (specials (jvm::process-declarations-for-vars (cdr form)
374                                                             nil nil)))
375          (dolist (special specials)
376            (push special jvm::*visible-variables*))
377          (process-progn forms stream compile-time-too))))
378  nil)
379
380(declaim (ftype (function (t t t) t) process-toplevel-defmacro))
381(defun process-toplevel-defmacro (form stream compile-time-too)
382  (declare (ignore stream compile-time-too))
383  (note-toplevel-form form)
384  (let ((name (second form)))
385    (eval form)
386    (let* ((expr (function-lambda-expression (macro-function name)))
387           (saved-class-number *class-number*)
388           (classfile (next-classfile-name)))
389      (with-open-file
390          (f classfile
391             :direction :output
392             :element-type '(unsigned-byte 8)
393             :if-exists :supersede)
394        (ignore-errors
395          (jvm:compile-defun nil expr *compile-file-environment*
396                             classfile f nil)))
397      (when (null (verify-load classfile))
398        ;; FIXME error or warning
399        (format *error-output* "; Unable to compile macro ~A~%" name)
400        (return-from process-toplevel-defmacro form))
401
402      (if (special-operator-p name)
403          `(put ',name 'macroexpand-macro
404                (make-macro ',name
405                            (sys::get-fasl-function *fasl-loader*
406                                                    ,saved-class-number)))
407          `(fset ',name
408                 (make-macro ',name
409                             (sys::get-fasl-function *fasl-loader*
410                                                     ,saved-class-number))
411                 ,*source-position*
412                 ',(third form))))))
413
414(declaim (ftype (function (t t t) t) process-toplevel-defun))
415(defun process-toplevel-defun (form stream compile-time-too)
416  (declare (ignore stream))
417  (note-toplevel-form form)
418  (let* ((name (second form))
419         (block-name (fdefinition-block-name name))
420         (lambda-list (third form))
421         (body (nthcdr 3 form)))
422    (jvm::with-saved-compiler-policy
423        (multiple-value-bind (body decls doc)
424            (parse-body body)
425          (let* ((expr `(lambda ,lambda-list
426                          ,@decls (block ,block-name ,@body)))
427                 (saved-class-number *class-number*)
428                 (classfile (next-classfile-name))
429                 (internal-compiler-errors nil)
430                 (result (with-open-file
431                             (f classfile
432                                :direction :output
433                                :element-type '(unsigned-byte 8)
434                                :if-exists :supersede)
435                           (handler-bind
436                               ((internal-compiler-error
437                                 #'(lambda (e)
438                                     (push e internal-compiler-errors)
439                                     (continue))))
440                             (report-error
441                              (jvm:compile-defun name expr *compile-file-environment*
442                                                 classfile f nil)))))
443                 (compiled-function (if (not internal-compiler-errors)
444                                        (verify-load classfile)
445                                        nil)))
446            (declare (ignore result))
447            (cond
448              ((and (not internal-compiler-errors)
449                    compiled-function)
450               (when compile-time-too
451                 (eval form))
452               (setf form
453                     `(fset ',name
454                            (sys::get-fasl-function *fasl-loader*
455                                                    ,saved-class-number)
456                            ,*source-position*
457                            ',lambda-list
458                            ,doc)))
459              (t
460               (compiler-warn "Unable to compile function ~A.  Using interpreted form instead.~%" name)
461               (when internal-compiler-errors
462                 (dolist (e internal-compiler-errors)
463                   (format *error-output*
464                           "; ~A~%" e)))
465               (let ((precompiled-function
466                      (precompiler:precompile-form expr nil
467                                                   *compile-file-environment*)))
468                 (setf form
469                       `(fset ',name
470                              ,precompiled-function
471                              ,*source-position*
472                              ',lambda-list
473                              ,doc)))
474               (when compile-time-too
475                 (eval form)))))
476          (when (and (symbolp name) (eq (get name '%inline) 'INLINE))
477            ;; FIXME Need to support SETF functions too!
478            (setf (inline-expansion name)
479                  (jvm::generate-inline-expansion block-name
480                                                  lambda-list body))
481            (output-form `(setf (inline-expansion ',name)
482                                ',(inline-expansion name))))))
483    (push name jvm::*functions-defined-in-current-file*)
484    (note-name-defined name)
485    ;; If NAME is not fbound, provide a dummy definition so that
486    ;; getSymbolFunctionOrDie() will succeed when we try to verify that
487    ;; functions defined later in the same file can be loaded correctly.
488    (unless (fboundp name)
489      (setf (fdefinition name) #'dummy)
490      (push name *fbound-names*)))
491  form)
492
493
494;; toplevel handlers
495;;   each toplevel handler takes a form and stream as input
496
497(defun install-toplevel-handler (symbol handler)
498  (setf (get symbol 'toplevel-handler) handler))
499
500(dolist (pair '((COMPILER-DEFSTRUCT precompile-toplevel-form)
501                (DECLARE process-toplevel-declare)
502                (DEFCONSTANT process-toplevel-defconstant)
503                (DEFGENERIC process-toplevel-defmethod/defgeneric)
504                (DEFMACRO process-toplevel-defmacro)
505                (DEFMETHOD process-toplevel-defmethod/defgeneric)
506                (DEFPACKAGE process-toplevel-defpackage/in-package)
507                (DEFPARAMETER process-toplevel-defvar/defparameter)
508                (DEFTYPE process-toplevel-deftype)
509                (DEFUN process-toplevel-defun)
510                (DEFVAR process-toplevel-defvar/defparameter)
511                (EVAL-WHEN process-toplevel-eval-when)
512                (EXPORT precompile-toplevel-form)
513                (IMPORT process-toplevel-import)
514                (IN-PACKAGE process-toplevel-defpackage/in-package)
515                (LOCALLY process-toplevel-locally)
516                (MACROLET process-toplevel-macrolet)
517                (PROCLAIM precompile-toplevel-form)
518                (PROGN process-toplevel-progn)
519                (PROVIDE precompile-toplevel-form)
520                (PUT precompile-toplevel-form)
521                (QUOTE process-toplevel-quote)
522                (REQUIRE precompile-toplevel-form)
523                (SHADOW precompile-toplevel-form)
524                (%SET-FDEFINITION precompile-toplevel-form)
525                (MOP::ENSURE-METHOD process-toplevel-mop.ensure-method)))
526  (install-toplevel-handler (car pair) (cadr pair)))
527
528(declaim (ftype (function (t stream t) t) process-toplevel-form))
529(defun process-toplevel-form (form stream compile-time-too)
530  (unless (atom form)
531    (let* ((operator (%car form))
532           (handler (get operator 'toplevel-handler)))
533      (when handler
534        (let ((out-form (funcall handler form stream compile-time-too)))
535          (when out-form
536            (output-form out-form)))
537        (return-from process-toplevel-form))
538      (when (and (symbolp operator)
539                 (macro-function operator *compile-file-environment*))
540        (note-toplevel-form form)
541        ;; Note that we want MACROEXPAND-1 and not MACROEXPAND here, in
542        ;; case the form being expanded expands into something that needs
543        ;; special handling by PROCESS-TOPLEVEL-FORM (e.g. DEFMACRO).
544        (let ((*compile-print* nil))
545          (process-toplevel-form (macroexpand-1 form *compile-file-environment*)
546                                 stream compile-time-too))
547        (return-from process-toplevel-form))
548
549      (cond
550        ((and (symbolp operator)
551              (not (special-operator-p operator))
552              (null (cdr form)))
553         (setf form (precompiler:precompile-form form nil
554                                                 *compile-file-environment*)))
555        (t
556         (note-toplevel-form form)
557         (setf form (convert-toplevel-form form nil)))))
558    (when (consp form)
559      (output-form form)))
560  ;; Make sure the compiled-function loader knows where
561  ;; to load the compiled functions. Note that this trickery
562  ;; was already used in verify-load before I used it,
563  ;; however, binding *load-truename* isn't fully compliant, I think.
564  (when compile-time-too
565    (let ((*load-truename* *output-file-pathname*)
566          (*fasl-loader* (make-fasl-class-loader
567                          nil
568                          (concatenate 'string
569                                       "org.armedbear.lisp." (base-classname))
570                          nil)))
571      (eval form))))
572
573
574
575(defvar *binary-fasls* nil)
576(defvar *forms-for-output* nil)
577(defvar *fasl-stream* nil)
578
579(defun compile-file (input-file
580                     &key
581                     output-file
582                     ((:verbose *compile-verbose*) *compile-verbose*)
583                     ((:print *compile-print*) *compile-print*)
584                     external-format)
585  (declare (ignore external-format))    ; FIXME
586  (unless (or (and (probe-file input-file) (not (file-directory-p input-file)))
587              (pathname-type input-file))
588    (let ((pathname (merge-pathnames (make-pathname :type "lisp") input-file)))
589      (when (probe-file pathname)
590        (setf input-file pathname))))
591  (setf output-file (make-pathname 
592         :defaults (if output-file
593           (merge-pathnames output-file 
594                *default-pathname-defaults*)
595           (compile-file-pathname input-file))
596         :version nil))
597  (let* ((*output-file-pathname* output-file)
598         (type (pathname-type output-file))
599         (temp-file (merge-pathnames (make-pathname :type (concatenate 'string type "-tmp"))
600                                     output-file))
601         (temp-file2 (merge-pathnames (make-pathname :type (concatenate 'string type "-tmp2"))
602                                     output-file))
603         (warnings-p nil)
604         (failure-p nil))
605    (with-open-file (in input-file :direction :input)
606      (let* ((*compile-file-pathname* (make-pathname :defaults (pathname in)
607                 :version nil))
608             (*compile-file-truename* (make-pathname :defaults (truename in)
609                                                     :version nil))
610             (*source* *compile-file-truename*)
611             (*class-number* 0)
612             (namestring (namestring *compile-file-truename*))
613             (start (get-internal-real-time))
614             elapsed
615             *fasl-uninterned-symbols*)
616        (when *compile-verbose*
617          (format t "; Compiling ~A ...~%" namestring))
618        (with-compilation-unit ()
619          (with-open-file (out temp-file
620                               :direction :output :if-exists :supersede
621                               :external-format *fasl-external-format*)
622            (let ((*readtable* *readtable*)
623                  (*read-default-float-format* *read-default-float-format*)
624                  (*read-base* *read-base*)
625                  (*package* *package*)
626                  (jvm::*functions-defined-in-current-file* '())
627                  (*fbound-names* '())
628                  (*fasl-stream* out)
629                  *forms-for-output*)
630              (jvm::with-saved-compiler-policy
631                (jvm::with-file-compilation
632                    (handler-bind ((style-warning 
633                                    #'(lambda (c)
634                                        (setf warnings-p t)
635                                        ;; let outer handlers do their thing
636                                        (signal c)
637                                        ;; prevent the next handler
638                                        ;; from running: we're a
639                                        ;; WARNING subclass
640                                        (continue)))
641                                   ((or warning 
642                                        compiler-error)
643                                    #'(lambda (c)
644                                        (declare (ignore c))
645                                        (setf warnings-p t
646                                              failure-p t))))
647                      (loop
648                         (let* ((*source-position* (file-position in))
649                                (jvm::*source-line-number* (stream-line-number in))
650                                (form (read in nil in))
651                                (*compiler-error-context* form))
652                           (when (eq form in)
653                             (return))
654                           (process-toplevel-form form out nil))))
655                    (finalize-fasl-output)
656                    (dolist (name *fbound-names*)
657                      (fmakunbound name)))))))
658        (with-open-file (in temp-file :direction :input)
659          (with-open-file (out temp-file2 :direction :output
660                               :if-does-not-exist :create
661                               :if-exists :supersede)
662            ;; write header
663            (write "; -*- Mode: Lisp -*-" :escape nil :stream out)
664            (%stream-terpri out)
665            (let ((*package* (find-package '#:cl))
666                  (*print-fasl* t)
667                  (*print-array* t)
668                  (*print-base* 10)
669                  (*print-case* :upcase)
670                  (*print-circle* nil)
671                  (*print-escape* t)
672                  (*print-gensym* t)
673                  (*print-length* nil)
674                  (*print-level* nil)
675                  (*print-lines* nil)
676                  (*print-pretty* nil)
677                  (*print-radix* nil)
678                  (*print-readably* t)
679                  (*print-right-margin* nil)
680                  (*print-structure* t)
681
682                  ;; make sure to write all floats with their exponent marker:
683                  ;; the dump-time default may not be the same at load-time
684
685                  (*read-default-float-format* nil))
686
687              ;; these values are also bound by WITH-STANDARD-IO-SYNTAX,
688              ;; but not used by our reader/printer, so don't bind them,
689              ;; for efficiency reasons.
690              ;;        (*read-eval* t)
691              ;;        (*read-suppress* nil)
692              ;;        (*print-miser-width* nil)
693              ;;        (*print-pprint-dispatch* (copy-pprint-dispatch nil))
694              ;;        (*read-base* 10)
695              ;;        (*read-default-float-format* 'single-float)
696              ;;        (*readtable* (copy-readtable nil))
697
698              (write (list 'init-fasl :version *fasl-version*)
699                     :stream out)
700              (%stream-terpri out)
701              (write (list 'setq '*source* *compile-file-truename*)
702                     :stream out)
703              (%stream-terpri out)
704              ;; Note: Beyond this point, you can't use DUMP-FORM,
705              ;; because the list of uninterned symbols has been fixed now.
706              (when *fasl-uninterned-symbols*
707                (write (list 'setq '*fasl-uninterned-symbols*
708                             (coerce (mapcar #'car
709                                             (nreverse *fasl-uninterned-symbols*))
710                                     'vector))
711                       :stream out
712                       :length nil))
713              (%stream-terpri out)
714
715              (when (> *class-number* 0)
716                (write (list 'setq '*fasl-loader*
717                             `(sys::make-fasl-class-loader
718                               nil
719                               ,(concatenate 'string "org.armedbear.lisp." (base-classname))
720                               nil)) :stream out))
721              (%stream-terpri out))
722
723
724            ;; copy remaining content
725            (loop for line = (read-line in nil :eof)
726               while (not (eq line :eof))
727               do (write-line line out))))
728        (delete-file temp-file)
729        (remove-zip-cache-entry output-file) ;; Necessary under windows
730        (rename-file temp-file2 output-file)
731
732        (when *compile-file-zip*
733          (let* ((type ;; Don't use ".zip", it'll result in an extension
734                  ;;  with a dot, which is rejected by NAMESTRING
735                  (%format nil "~A~A" (pathname-type output-file) "-zip"))
736                 (zipfile (namestring
737                           (merge-pathnames (make-pathname :type type)
738                                            output-file)))
739                 (pathnames nil)
740     (fasl-loader (namestring (merge-pathnames (make-pathname :name (fasl-loader-classname) :type "cls")
741                 output-file))))
742      (when (probe-file fasl-loader)
743        (push fasl-loader pathnames))
744            (dotimes (i *class-number*)
745              (let* ((pathname (compute-classfile-name (1+ i))))
746                (when (probe-file pathname)
747                  (push pathname pathnames))))
748            (setf pathnames (nreverse pathnames))
749            (let ((load-file (merge-pathnames (make-pathname :type "_")
750                                              output-file)))
751              (rename-file output-file load-file)
752              (push load-file pathnames))
753            (zip zipfile pathnames)
754            (dolist (pathname pathnames)
755              (let ((truename (probe-file pathname)))
756                (when truename
757                  (delete-file truename))))
758            (rename-file zipfile output-file)))
759
760        (setf elapsed (/ (- (get-internal-real-time) start) 1000.0))
761        (when *compile-verbose*
762          (format t "~&; Wrote ~A (~A seconds)~%"
763                  (namestring output-file) elapsed))))
764    (values (truename output-file) warnings-p failure-p)))
765
766(defun compile-file-if-needed (input-file &rest allargs &key force-compile
767                               &allow-other-keys)
768  (setf input-file (truename input-file))
769  (cond (force-compile
770         (remf allargs :force-compile)
771         (apply 'compile-file input-file allargs))
772        (t
773         (let* ((source-write-time (file-write-date input-file))
774                (output-file       (or (getf allargs :output-file)
775                                       (compile-file-pathname input-file)))
776                (target-write-time (and (probe-file output-file)
777                                        (file-write-date output-file))))
778           (if (or (null target-write-time)
779                   (<= target-write-time source-write-time))
780               (apply 'compile-file input-file allargs)
781               output-file)))))
782
783(provide 'compile-file)
Note: See TracBrowser for help on using the repository browser.