source: trunk/abcl/src/org/armedbear/lisp/compile-file.lisp @ 13914

Last change on this file since 13914 was 13914, checked in by Mark Evenson, 10 years ago

compiler: don't signal a warning for compiler optimization decision diagnostics.

Set the variable SYSTEM::*DIAGNOSTIC* to nil to muffle the output.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 35.4 KB
Line 
1;;; compile-file.lisp
2;;;
3;;; Copyright (C) 2004-2006 Peter Graves
4;;; $Id: compile-file.lisp 13914 2012-04-16 11:49:48Z mevenson $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package #:system)
33
34(require "JVM")
35;; (require "COMPILER-ERROR") already made accessible through JVM
36
37(defvar *fbound-names*)
38
39(defvar *class-number*)
40
41(defvar *output-file-pathname*)
42
43(defun base-classname (&optional (output-file-pathname *output-file-pathname*))
44  (sanitize-class-name (pathname-name output-file-pathname)))
45
46(defun fasl-loader-classname (&optional (output-file-pathname *output-file-pathname*))
47  (%format nil "~A_0" (base-classname output-file-pathname)))
48
49(declaim (ftype (function (t) t) compute-classfile-name))
50(defun compute-classfile-name (n &optional (output-file-pathname
51                                            *output-file-pathname*))
52  "Computes the name of the class file associated with number `n'."
53  (let ((name
54         (sanitize-class-name
55    (%format nil "~A_~D" (pathname-name output-file-pathname) n))))
56    (namestring (merge-pathnames (make-pathname :name name :type "cls")
57                                 output-file-pathname))))
58
59(defun sanitize-class-name (name)
60  (let ((name (copy-seq name)))
61    (dotimes (i (length name))
62      (declare (type fixnum i))
63      (when (or (char= (char name i) #\-)
64    (char= (char name i) #\.)
65    (char= (char name i) #\Space))
66        (setf (char name i) #\_)))
67    name))
68 
69
70(declaim (ftype (function () t) next-classfile-name))
71(defun next-classfile-name ()
72  (compute-classfile-name (incf *class-number*)))
73
74(defmacro report-error (&rest forms)
75  `(handler-case (progn ,@forms)
76     (compiler-unsupported-feature-error (condition)
77       (fresh-line)
78       (%format t "; UNSUPPORTED-FEATURE: ~A~%" condition)
79       (values nil condition))))
80
81;; Dummy function. Should never be called.
82(defun dummy (&rest ignored)
83  (declare (ignore ignored))
84  (assert nil))
85
86(defparameter *diagnostic* t
87  "The stream to emit compiler diagnostic messages to, or nil to muffle output.")
88
89(declaim (ftype (function (t) t) verify-load))
90(defun verify-load (classfile)
91      (and classfile
92           (unless
93                 (> (file-length (open classfile :direction :input))
94                    0)
95             ;;; TODO hook into a real ABCL compiler condition hierarchy
96             (signal "Internal compiler error detected: Fasl contains ~
97zero-length jvm classfile corresponding to ~A." classfile)))
98           (if (> *safety* *speed*)
99               (progn
100                 (format *diagnostic* 
101                         "~&SYSTEM::*DIAGNOSTIC* Testing compiled bytecode by loading classfile into JVM because (> *safety* *speed*).~%")
102                 (let ((*load-truename* *output-file-pathname*))
103                   (report-error
104                    (load-compiled-function classfile))))
105               t))
106
107(declaim (ftype (function (t) t) note-toplevel-form))
108(defun note-toplevel-form (form)
109  (when *compile-print*
110    (fresh-line)
111    (princ "; ")
112    (let ((*print-length* 2)
113          (*print-level* 2)
114          (*print-pretty* nil))
115      (prin1 form))
116    (terpri)))
117
118(defun output-form (form)
119  (if *binary-fasls*
120      (push form *forms-for-output*)
121      (progn
122        (dump-form form *fasl-stream*)
123        (%stream-terpri *fasl-stream*))))
124
125(defun finalize-fasl-output ()
126  (when *binary-fasls*
127    (let ((*package* (find-package :keyword))
128          (*double-colon-package-separators* T))
129      (dump-form (convert-toplevel-form (list* 'PROGN
130                                               (nreverse *forms-for-output*))
131                                        t)
132                 *fasl-stream*))
133    (%stream-terpri *fasl-stream*)))
134
135
136(declaim (ftype (function (t) t) simple-toplevel-form-p))
137(defun simple-toplevel-form-p (form)
138  "Returns NIL if the form is too complex to become an
139interpreted toplevel form, non-NIL if it is 'simple enough'."
140  (and (consp form)
141       (every #'(lambda (arg)
142                  (or (and (atom arg)
143                           (not (and (symbolp arg)
144                                     (symbol-macro-p arg))))
145                      (and (consp arg)
146                           (eq 'QUOTE (car arg)))))
147              (cdr form))))
148
149(declaim (ftype (function (t t) t) convert-toplevel-form))
150(defun convert-toplevel-form (form declare-inline)
151  (when (or (simple-toplevel-form-p form)
152            (and (eq (car form) 'SETQ)
153                 ;; for SETQ, look at the evaluated part
154                 (simple-toplevel-form-p (third form))))
155    ;; single form with simple or constant arguments
156    ;; Without this exception, toplevel function calls
157    ;; will be compiled into lambdas which get compiled to
158    ;; compiled-functions. Those need to be loaded.
159    ;; Conclusion: Top level interpreting the function call
160    ;;  and its arguments may be (and should be) more efficient.
161    (return-from convert-toplevel-form
162      (precompiler:precompile-form form nil *compile-file-environment*)))
163  (let* ((toplevel-form (third form))
164         (expr `(lambda () ,form))
165         (saved-class-number *class-number*)
166         (classfile (next-classfile-name))
167         (result
168          (with-open-file
169              (f classfile
170                 :direction :output
171                 :element-type '(unsigned-byte 8)
172                 :if-exists :supersede)
173            (report-error (jvm:compile-defun nil
174                                             expr *compile-file-environment*
175                                             classfile f
176                                             declare-inline))))
177         (compiled-function (handler-case (verify-load classfile)
178                              (t (c) 
179                                (error "Compilation failed for JVM class number ~A
180corresponding to form ~A~&with condition ~A" 
181                                       saved-class-number toplevel-form c)))))
182    (declare (ignore result))
183    (progn
184      (when (> *debug* 0)
185        ;;; ??? define an API by perhaps exporting these symbols?
186        (setf (getf form 'form-source) 
187              toplevel-form
188             
189              (getf form 'classfile) 
190              classfile
191                   
192              (getf form 'compiled-function) 
193              compiled-function
194                 
195              (getf form 'class-number) 
196              saved-class-number))
197      (setf form
198            (if compiled-function
199                `(funcall (sys::get-fasl-function *fasl-loader*
200                                                  ,saved-class-number))
201                (precompiler:precompile-form form nil
202                                             *compile-file-environment*))))))
203
204
205(declaim (ftype (function (t stream t) t) process-progn))
206(defun process-progn (forms stream compile-time-too)
207  (dolist (form forms)
208    (process-toplevel-form form stream compile-time-too))
209  nil)
210
211
212(declaim (ftype (function (t t t) t) process-toplevel-form))
213(defun precompile-toplevel-form (form stream compile-time-too)
214  (declare (ignore stream))
215  (let ((form (precompiler:precompile-form form nil
216                                           *compile-file-environment*)))
217    (when compile-time-too
218      (eval form))
219    form))
220
221
222
223(defun process-toplevel-macrolet (form stream compile-time-too)
224  (let ((*compile-file-environment*
225         (make-environment *compile-file-environment*)))
226    (dolist (definition (cadr form))
227      (environment-add-macro-definition *compile-file-environment*
228                                        (car definition)
229                                        (make-macro (car definition)
230                                                    (make-expander-for-macrolet definition))))
231    (dolist (body-form (cddr form))
232      (process-toplevel-form body-form stream compile-time-too)))
233  nil)
234
235(declaim (ftype (function (t t t) t) process-toplevel-defconstant))
236(defun process-toplevel-defconstant (form stream compile-time-too)
237  (declare (ignore stream compile-time-too))
238  ;; "If a DEFCONSTANT form appears as a top level form, the compiler
239  ;; must recognize that [the] name names a constant variable. An
240  ;; implementation may choose to evaluate the value-form at compile
241  ;; time, load time, or both. Therefore, users must ensure that the
242  ;; initial-value can be evaluated at compile time (regardless of
243  ;; whether or not references to name appear in the file) and that
244  ;; it always evaluates to the same value."
245  (note-toplevel-form form)
246  (eval form)
247  form)
248
249(declaim (ftype (function (t t t) t) process-toplevel-quote))
250(defun process-toplevel-quote (form stream compile-time-too)
251  (declare (ignore stream))
252  (when compile-time-too
253    (eval form))
254  nil)
255
256
257(declaim (ftype (function (t t t) t) process-toplevel-import))
258(defun process-toplevel-import (form stream compile-time-too)
259  (declare (ignore stream))
260  (let ((form (precompiler:precompile-form form nil
261                                           *compile-file-environment*)))
262    (let ((*package* +keyword-package+))
263      (output-form form))
264    (when compile-time-too
265      (eval form)))
266  nil)
267
268(declaim (ftype (function (t t t) t) process-toplevel-mop.ensure-method))
269(defun process-toplevel-mop.ensure-method (form stream compile-time-too)
270  (declare (ignore stream))
271  (flet ((convert-ensure-method (form key)
272           (let* ((tail (cddr form))
273                  (function-form (getf tail key)))
274             (when (and function-form (consp function-form)
275               (eq (%car function-form) 'FUNCTION))
276               (let ((lambda-expression (cadr function-form)))
277                 (jvm::with-saved-compiler-policy
278                     (let* ((saved-class-number *class-number*)
279                            (classfile (next-classfile-name))
280                            (result
281                             (with-open-file
282                                 (f classfile
283                                    :direction :output
284                                    :element-type '(unsigned-byte 8)
285                                    :if-exists :supersede)
286                               (report-error
287                                (jvm:compile-defun nil lambda-expression
288                                                   *compile-file-environment*
289                                                   classfile f nil))))
290                            (compiled-function (verify-load classfile)))
291                       (declare (ignore result))
292                       (cond
293                         (compiled-function
294                          (setf (getf tail key)
295                                `(sys::get-fasl-function *fasl-loader*
296                                                         ,saved-class-number)))
297                         (t
298                          ;; FIXME This should be a warning or error of some sort...
299                          (format *error-output* "; Unable to compile method~%"))))))))))
300
301
302    (when compile-time-too
303      (let* ((copy-form (copy-tree form))
304             ;; ### Ideally, the precompiler would leave the forms alone
305             ;;  and copy them where required, instead of forcing us to
306             ;;  do a deep copy in advance
307             (precompiled-form (precompiler:precompile-form copy-form nil
308                                                            *compile-file-environment*)))
309        (eval precompiled-form)))
310    (convert-ensure-method form :function)
311    (convert-ensure-method form :fast-function))
312  (precompiler:precompile-form form nil *compile-file-environment*))
313
314(declaim (ftype (function (t t t) t) process-toplevel-defvar/defparameter))
315(defun process-toplevel-defvar/defparameter (form stream compile-time-too)
316  (declare (ignore stream))
317  (note-toplevel-form form)
318  (if compile-time-too
319      (eval form)
320      ;; "If a DEFVAR or DEFPARAMETER form appears as a top level form,
321      ;; the compiler must recognize that the name has been proclaimed
322      ;; special. However, it must neither evaluate the initial-value
323      ;; form nor assign the dynamic variable named NAME at compile
324      ;; time."
325      (let ((name (second form)))
326        (%defvar name)))
327  form)
328
329(declaim (ftype (function (t t t) t) process-toplevel-defpackage/in-package))
330(defun process-toplevel-defpackage/in-package (form stream compile-time-too)
331  (declare (ignore stream compile-time-too))
332  (note-toplevel-form form)
333  (setf form
334        (precompiler:precompile-form form nil *compile-file-environment*))
335  (eval form)
336  ;; Force package prefix to be used when dumping form.
337  (let ((*package* +keyword-package+))
338    (output-form form))
339  nil)
340
341(declaim (ftype (function (t t t) t) process-toplevel-declare))
342(defun process-toplevel-declare (form stream compile-time-too)
343  (declare (ignore stream compile-time-too))
344  (compiler-style-warn "Misplaced declaration: ~S" form)
345  nil)
346
347(declaim (ftype (function (t t t) t) process-toplevel-progn))
348(defun process-toplevel-progn (form stream compile-time-too)
349  (process-progn (cdr form) stream compile-time-too)
350  nil)
351
352(declaim (ftype (function (t t t) t) process-toplevel-deftype))
353(defun process-toplevel-deftype (form stream compile-time-too)
354  (declare (ignore stream compile-time-too))
355  (note-toplevel-form form)
356  (eval form)
357  form)
358
359(declaim (ftype (function (t t t) t) process-toplevel-eval-when))
360(defun process-toplevel-eval-when (form stream compile-time-too)
361  (flet ((parse-eval-when-situations (situations)
362           "Parse an EVAL-WHEN situations list, returning three flags,
363            (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
364            the types of situations present in the list."
365            ; Adapted from SBCL.
366           (when (or (not (listp situations))
367                     (set-difference situations
368                                     '(:compile-toplevel
369                                       compile
370                                       :load-toplevel
371                                       load
372                                       :execute
373                                       eval)))
374             (error "Bad EVAL-WHEN situation list: ~S." situations))
375           (values (intersection '(:compile-toplevel compile) situations)
376                   (intersection '(:load-toplevel load) situations)
377                   (intersection '(:execute eval) situations))))
378    (multiple-value-bind (ct lt e)
379        (parse-eval-when-situations (cadr form))
380      (let ((new-compile-time-too (or ct (and compile-time-too e)))
381            (body (cddr form)))
382        (if lt
383            (process-progn body stream new-compile-time-too)
384            (when new-compile-time-too
385              (eval `(progn ,@body)))))))
386  nil)
387
388
389(declaim (ftype (function (t t t) t) process-toplevel-defmethod/defgeneric))
390(defun process-toplevel-defmethod/defgeneric (form stream compile-time-too)
391  (note-toplevel-form form)
392  (note-name-defined (second form))
393  (let ((*compile-print* nil))
394    (process-toplevel-form (macroexpand-1 form *compile-file-environment*)
395                           stream compile-time-too))
396  nil)
397
398(declaim (ftype (function (t t t) t) process-toplevel-locally))
399(defun process-toplevel-locally (form stream compile-time-too)
400  (jvm::with-saved-compiler-policy
401      (multiple-value-bind (forms decls)
402          (parse-body (cdr form) nil)
403        (process-optimization-declarations decls)
404        (let* ((jvm::*visible-variables* jvm::*visible-variables*)
405               (specials (jvm::process-declarations-for-vars (cdr form)
406                                                             nil nil)))
407          (dolist (special specials)
408            (push special jvm::*visible-variables*))
409          (process-progn forms stream compile-time-too))))
410  nil)
411
412(declaim (ftype (function (t t t) t) process-toplevel-defmacro))
413(defun process-toplevel-defmacro (form stream compile-time-too)
414  (declare (ignore stream compile-time-too))
415  (note-toplevel-form form)
416  (let ((name (second form)))
417    (eval form)
418    (let* ((expr (function-lambda-expression (macro-function name)))
419           (saved-class-number *class-number*)
420           (classfile (next-classfile-name)))
421      (with-open-file
422          (f classfile
423             :direction :output
424             :element-type '(unsigned-byte 8)
425             :if-exists :supersede)
426        (ignore-errors
427          (jvm:compile-defun nil expr *compile-file-environment*
428                             classfile f nil)))
429      (when (null (verify-load classfile))
430        ;; FIXME error or warning
431        (format *error-output* "; Unable to compile macro ~A~%" name)
432        (return-from process-toplevel-defmacro form))
433
434      (if (special-operator-p name)
435          `(put ',name 'macroexpand-macro
436                (make-macro ',name
437                            (sys::get-fasl-function *fasl-loader*
438                                                    ,saved-class-number)))
439          `(fset ',name
440                 (make-macro ',name
441                             (sys::get-fasl-function *fasl-loader*
442                                                     ,saved-class-number))
443                 ,*source-position*
444                 ',(third form))))))
445
446(declaim (ftype (function (t t t) t) process-toplevel-defun))
447(defun process-toplevel-defun (form stream compile-time-too)
448  (declare (ignore stream))
449  (note-toplevel-form form)
450  (let* ((name (second form))
451         (block-name (fdefinition-block-name name))
452         (lambda-list (third form))
453         (body (nthcdr 3 form)))
454    (jvm::with-saved-compiler-policy
455        (multiple-value-bind (body decls doc)
456            (parse-body body)
457          (let* ((expr `(lambda ,lambda-list
458                          ,@decls (block ,block-name ,@body)))
459                 (saved-class-number *class-number*)
460                 (classfile (next-classfile-name))
461                 (internal-compiler-errors nil)
462                 (result (with-open-file
463                             (f classfile
464                                :direction :output
465                                :element-type '(unsigned-byte 8)
466                                :if-exists :supersede)
467                           (handler-bind
468                               ((internal-compiler-error
469                                 #'(lambda (e)
470                                     (push e internal-compiler-errors)
471                                     (continue))))
472                             (report-error
473                              (jvm:compile-defun name expr *compile-file-environment*
474                                                 classfile f nil)))))
475                 (compiled-function (if (not internal-compiler-errors)
476                                        (verify-load classfile)
477                                        nil)))
478            (declare (ignore result))
479            (cond
480              ((and (not internal-compiler-errors)
481                    compiled-function)
482               (when compile-time-too
483                 (eval form))
484               (setf form
485                     `(fset ',name
486                            (sys::get-fasl-function *fasl-loader*
487                                                    ,saved-class-number)
488                            ,*source-position*
489                            ',lambda-list
490                            ,doc)))
491              (t
492               (compiler-warn "Unable to compile function ~A.  Using interpreted form instead.~%" name)
493               (when internal-compiler-errors
494                 (dolist (e internal-compiler-errors)
495                   (format *error-output*
496                           "; ~A~%" e)))
497               (let ((precompiled-function
498                      (precompiler:precompile-form expr nil
499                                                   *compile-file-environment*)))
500                 (setf form
501                       `(fset ',name
502                              ,precompiled-function
503                              ,*source-position*
504                              ',lambda-list
505                              ,doc)))
506               (when compile-time-too
507                 (eval form)))))
508          (when (and (symbolp name) (eq (get name '%inline) 'INLINE))
509            ;; FIXME Need to support SETF functions too!
510            (setf (inline-expansion name)
511                  (jvm::generate-inline-expansion block-name
512                                                  lambda-list body))
513            (output-form `(setf (inline-expansion ',name)
514                                ',(inline-expansion name))))))
515    (push name jvm::*functions-defined-in-current-file*)
516    (note-name-defined name)
517    ;; If NAME is not fbound, provide a dummy definition so that
518    ;; getSymbolFunctionOrDie() will succeed when we try to verify that
519    ;; functions defined later in the same file can be loaded correctly.
520    (unless (fboundp name)
521      (setf (fdefinition name) #'dummy)
522      (push name *fbound-names*)))
523  form)
524
525
526;; toplevel handlers
527;;   each toplevel handler takes a form and stream as input
528
529(defun install-toplevel-handler (symbol handler)
530  (setf (get symbol 'toplevel-handler) handler))
531
532(dolist (pair '((COMPILER-DEFSTRUCT precompile-toplevel-form)
533                (DECLARE process-toplevel-declare)
534                (DEFCONSTANT process-toplevel-defconstant)
535                (DEFGENERIC process-toplevel-defmethod/defgeneric)
536                (DEFMACRO process-toplevel-defmacro)
537                (DEFMETHOD process-toplevel-defmethod/defgeneric)
538                (DEFPACKAGE process-toplevel-defpackage/in-package)
539                (DEFPARAMETER process-toplevel-defvar/defparameter)
540                (DEFTYPE process-toplevel-deftype)
541                (DEFUN process-toplevel-defun)
542                (DEFVAR process-toplevel-defvar/defparameter)
543                (EVAL-WHEN process-toplevel-eval-when)
544                (EXPORT precompile-toplevel-form)
545                (IMPORT process-toplevel-import)
546                (IN-PACKAGE process-toplevel-defpackage/in-package)
547                (LOCALLY process-toplevel-locally)
548                (MACROLET process-toplevel-macrolet)
549                (PROCLAIM precompile-toplevel-form)
550                (PROGN process-toplevel-progn)
551                (PROVIDE precompile-toplevel-form)
552                (PUT precompile-toplevel-form)
553                (QUOTE process-toplevel-quote)
554                (REQUIRE precompile-toplevel-form)
555                (SHADOW precompile-toplevel-form)
556                (%SET-FDEFINITION precompile-toplevel-form)
557                (MOP::ENSURE-METHOD process-toplevel-mop.ensure-method)))
558  (install-toplevel-handler (car pair) (cadr pair)))
559
560(declaim (ftype (function (t stream t) t) process-toplevel-form))
561(defun process-toplevel-form (form stream compile-time-too)
562  (unless (atom form)
563    (let* ((operator (%car form))
564           (handler (get operator 'toplevel-handler)))
565      (when handler
566        (let ((out-form (funcall handler form stream compile-time-too)))
567          (when out-form
568            (output-form out-form)))
569        (return-from process-toplevel-form))
570      (when (and (symbolp operator)
571                 (macro-function operator *compile-file-environment*))
572        (note-toplevel-form form)
573        ;; Note that we want MACROEXPAND-1 and not MACROEXPAND here, in
574        ;; case the form being expanded expands into something that needs
575        ;; special handling by PROCESS-TOPLEVEL-FORM (e.g. DEFMACRO).
576        (let ((*compile-print* nil))
577          (process-toplevel-form (macroexpand-1 form *compile-file-environment*)
578                                 stream compile-time-too))
579        (return-from process-toplevel-form))
580
581      (cond
582        ((and (symbolp operator)
583              (not (special-operator-p operator))
584              (null (cdr form)))
585         (setf form (precompiler:precompile-form form nil
586                                                 *compile-file-environment*)))
587        (t
588         (note-toplevel-form form)
589         (setf form (convert-toplevel-form form nil)))))
590    (when (consp form)
591      (output-form form)))
592  ;; Make sure the compiled-function loader knows where
593  ;; to load the compiled functions. Note that this trickery
594  ;; was already used in verify-load before I used it,
595  ;; however, binding *load-truename* isn't fully compliant, I think.
596  (when compile-time-too
597    (let ((*load-truename* *output-file-pathname*)
598          (*fasl-loader* (make-fasl-class-loader
599                          (concatenate 'string
600                                       "org.armedbear.lisp." (base-classname)))))
601      (eval form))))
602
603(defun populate-zip-fasl (output-file)
604  (let* ((type ;; Don't use ".zip", it'll result in an extension
605          ;;  with a dot, which is rejected by NAMESTRING
606          (%format nil "~A~A" (pathname-type output-file) "-zip"))
607         (zipfile (namestring
608                   (merge-pathnames (make-pathname :type type)
609                                    output-file)))
610         (pathnames nil)
611         (fasl-loader (namestring (merge-pathnames
612                                   (make-pathname :name (fasl-loader-classname)
613                                                  :type "cls")
614                                   output-file))))
615    (when (probe-file fasl-loader)
616      (push fasl-loader pathnames))
617    (dotimes (i *class-number*)
618      (let ((truename (probe-file (compute-classfile-name (1+ i)))))
619        (when truename
620          (push truename pathnames)
621          ;;; XXX it would be better to just use the recorded number
622          ;;; of class constants, but probing for the first at least
623          ;;; makes this subjectively bearable.
624          (when (probe-file
625                 (make-pathname :name (format nil "~A_0"
626                                              (pathname-name truename))
627                                :type "clc"
628                                :defaults truename))
629            (dolist (resource (directory
630                               (make-pathname :name (format nil "~A_*"
631                                                            (pathname-name truename))
632                                              :type "clc"
633                                              :defaults truename)))
634              (push resource pathnames))))))
635    (setf pathnames (nreverse (remove nil pathnames)))
636    (let ((load-file (merge-pathnames (make-pathname :type "_")
637                                      output-file)))
638      (rename-file output-file load-file)
639      (push load-file pathnames))
640    (zip zipfile pathnames)
641    (dolist (pathname pathnames)
642      (ignore-errors (delete-file pathname)))
643    (rename-file zipfile output-file)))
644
645(defun write-fasl-prologue (stream)
646  (let ((out stream))
647    ;; write header
648    (write "; -*- Mode: Lisp -*-" :escape nil :stream out)
649    (%stream-terpri out)
650    (write (list 'init-fasl :version *fasl-version*) :stream out)
651    (%stream-terpri out)
652    (write (list 'setq '*source* *compile-file-truename*) :stream out)
653    (%stream-terpri out)
654
655    ;; Note: Beyond this point, you can't use DUMP-FORM,
656    ;; because the list of uninterned symbols has been fixed now.
657    (when *fasl-uninterned-symbols*
658      (write (list 'setq '*fasl-uninterned-symbols*
659                   (coerce (mapcar #'car (nreverse *fasl-uninterned-symbols*))
660                           'vector))
661             :stream out :length nil))
662    (%stream-terpri out)
663
664    (when (> *class-number* 0)
665      (write (list 'setq '*fasl-loader*
666                   `(sys::make-fasl-class-loader
667                     ,(concatenate 'string "org.armedbear.lisp."
668                                   (base-classname))))
669             :stream out))
670    (%stream-terpri out)))
671
672
673
674(defvar *binary-fasls* nil)
675(defvar *forms-for-output* nil)
676(defvar *fasl-stream* nil)
677
678(defun compile-file (input-file
679                     &key
680                     output-file
681                     ((:verbose *compile-verbose*) *compile-verbose*)
682                     ((:print *compile-print*) *compile-print*)
683                     external-format)
684  (declare (ignore external-format))    ; FIXME
685  (unless (or (and (probe-file input-file) (not (file-directory-p input-file)))
686              (pathname-type input-file))
687    (let ((pathname (merge-pathnames (make-pathname :type "lisp") input-file)))
688      (when (probe-file pathname)
689        (setf input-file pathname))))
690  (setf output-file (make-pathname 
691         :defaults (if output-file
692           (merge-pathnames output-file 
693                *default-pathname-defaults*)
694           (compile-file-pathname input-file))
695         :version nil))
696  (let* ((*output-file-pathname* output-file)
697         (type (pathname-type output-file))
698         (temp-file (merge-pathnames (make-pathname :type (concatenate 'string type "-tmp"))
699                                     output-file))
700         (temp-file2 (merge-pathnames (make-pathname :type (concatenate 'string type "-tmp2"))
701                                     output-file))
702         (warnings-p nil)
703         (failure-p nil))
704    (with-open-file (in input-file :direction :input)
705      (let* ((*compile-file-pathname* (make-pathname :defaults (pathname in)
706                 :version nil))
707             (*compile-file-truename* (make-pathname :defaults (truename in)
708                                                     :version nil))
709             (*source* *compile-file-truename*)
710             (*class-number* 0)
711             (namestring (namestring *compile-file-truename*))
712             (start (get-internal-real-time))
713             *fasl-uninterned-symbols*)
714        (when *compile-verbose*
715          (format t "; Compiling ~A ...~%" namestring))
716        (with-compilation-unit ()
717          (with-open-file (out temp-file
718                               :direction :output :if-exists :supersede
719                               :external-format *fasl-external-format*)
720            (let ((*readtable* *readtable*)
721                  (*read-default-float-format* *read-default-float-format*)
722                  (*read-base* *read-base*)
723                  (*package* *package*)
724                  (jvm::*functions-defined-in-current-file* '())
725                  (*fbound-names* '())
726                  (*fasl-stream* out)
727                  *forms-for-output*)
728              (jvm::with-saved-compiler-policy
729                (jvm::with-file-compilation
730                    (handler-bind
731                        ((style-warning 
732                          #'(lambda (c)
733                              (setf warnings-p t)
734                              ;; let outer handlers do their thing
735                              (signal c)
736                              ;; prevent the next handler
737                              ;; from running: we're a
738                              ;; WARNING subclass
739                              (continue)))
740                         ((or warning compiler-error)
741                          #'(lambda (c)
742                              (declare (ignore c))
743                              (setf warnings-p t
744                                    failure-p t))))
745                      (loop
746                         (let* ((*source-position* (file-position in))
747                                (jvm::*source-line-number* (stream-line-number in))
748                                (form (read in nil in))
749                                (*compiler-error-context* form))
750                           (when (eq form in)
751                             (return))
752                           (process-toplevel-form form out nil))))
753                    (finalize-fasl-output)
754                    (dolist (name *fbound-names*)
755                      (fmakunbound name)))))))
756        (with-open-file (in temp-file :direction :input)
757          (with-open-file (out temp-file2 :direction :output
758                               :if-does-not-exist :create
759                               :if-exists :supersede)
760            (let ((*package* (find-package '#:cl))
761                  (*print-fasl* t)
762                  (*print-array* t)
763                  (*print-base* 10)
764                  (*print-case* :upcase)
765                  (*print-circle* nil)
766                  (*print-escape* t)
767                  (*print-gensym* t)
768                  (*print-length* nil)
769                  (*print-level* nil)
770                  (*print-lines* nil)
771                  (*print-pretty* nil)
772                  (*print-radix* nil)
773                  (*print-readably* t)
774                  (*print-right-margin* nil)
775                  (*print-structure* t)
776
777                  ;; make sure to write all floats with their exponent marker:
778                  ;; the dump-time default may not be the same at load-time
779
780                  (*read-default-float-format* nil))
781
782              ;; these values are also bound by WITH-STANDARD-IO-SYNTAX,
783              ;; but not used by our reader/printer, so don't bind them,
784              ;; for efficiency reasons.
785              ;;        (*read-eval* t)
786              ;;        (*read-suppress* nil)
787              ;;        (*print-miser-width* nil)
788              ;;        (*print-pprint-dispatch* (copy-pprint-dispatch nil))
789              ;;        (*read-base* 10)
790              ;;        (*read-default-float-format* 'single-float)
791              ;;        (*readtable* (copy-readtable nil))
792
793              (write-fasl-prologue out)
794              ;; copy remaining content
795              (loop for line = (read-line in nil :eof)
796                 while (not (eq line :eof))
797                 do (write-line line out)))))
798        (delete-file temp-file)
799        (remove-zip-cache-entry output-file) ;; Necessary under windows
800        (rename-file temp-file2 output-file)
801
802        (when *compile-file-zip*
803          (populate-zip-fasl output-file))
804
805        (when *compile-verbose*
806          (format t "~&; Wrote ~A (~A seconds)~%"
807                  (namestring output-file)
808                  (/ (- (get-internal-real-time) start) 1000.0)))))
809    (values (truename output-file) warnings-p failure-p)))
810
811(defun compile-file-if-needed (input-file &rest allargs &key force-compile
812                               &allow-other-keys)
813  (setf input-file (truename input-file))
814  (cond (force-compile
815         (remf allargs :force-compile)
816         (apply 'compile-file input-file allargs))
817        (t
818         (let* ((source-write-time (file-write-date input-file))
819                (output-file       (or (getf allargs :output-file)
820                                       (compile-file-pathname input-file)))
821                (target-write-time (and (probe-file output-file)
822                                        (file-write-date output-file))))
823           (if (or (null target-write-time)
824                   (<= target-write-time source-write-time))
825               (apply 'compile-file input-file allargs)
826               output-file)))))
827
828(provide 'compile-file)
Note: See TracBrowser for help on using the repository browser.