source: trunk/abcl/src/org/armedbear/lisp/compile-file.lisp @ 13916

Last change on this file since 13916 was 13916, checked in by Mark Evenson, 10 years ago

ansi-interpreted: restore execution.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 35.6 KB
Line 
1;;; compile-file.lisp
2;;;
3;;; Copyright (C) 2004-2006 Peter Graves
4;;; $Id: compile-file.lisp 13916 2012-04-16 21:24:36Z mevenson $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package #:system)
33
34(require "JVM")
35;; (require "COMPILER-ERROR") already made accessible through JVM
36
37(defvar *fbound-names*)
38
39(defvar *class-number*)
40
41(defvar *output-file-pathname*)
42
43(defun base-classname (&optional (output-file-pathname *output-file-pathname*))
44  (sanitize-class-name (pathname-name output-file-pathname)))
45
46(defun fasl-loader-classname (&optional (output-file-pathname *output-file-pathname*))
47  (%format nil "~A_0" (base-classname output-file-pathname)))
48
49(declaim (ftype (function (t) t) compute-classfile-name))
50(defun compute-classfile-name (n &optional (output-file-pathname
51                                            *output-file-pathname*))
52  "Computes the name of the class file associated with number `n'."
53  (let ((name
54         (sanitize-class-name
55    (%format nil "~A_~D" (pathname-name output-file-pathname) n))))
56    (namestring (merge-pathnames (make-pathname :name name :type "cls")
57                                 output-file-pathname))))
58
59(defun sanitize-class-name (name)
60  (let ((name (copy-seq name)))
61    (dotimes (i (length name))
62      (declare (type fixnum i))
63      (when (or (char= (char name i) #\-)
64    (char= (char name i) #\.)
65    (char= (char name i) #\Space))
66        (setf (char name i) #\_)))
67    name))
68 
69
70(declaim (ftype (function () t) next-classfile-name))
71(defun next-classfile-name ()
72  (compute-classfile-name (incf *class-number*)))
73
74(defmacro report-error (&rest forms)
75  `(handler-case (progn ,@forms)
76     (compiler-unsupported-feature-error (condition)
77       (fresh-line)
78       (%format t "; UNSUPPORTED-FEATURE: ~A~%" condition)
79       (values nil condition))))
80
81;; Dummy function. Should never be called.
82(defun dummy (&rest ignored)
83  (declare (ignore ignored))
84  (assert nil))
85
86;;; ??? rename to something shorter?
87(defparameter *compiler-diagnostic* nil
88  "The stream to emit compiler diagnostic messages to, or nil to muffle output.")
89(export '*compiler-diagnostic*)
90(defmacro diag (fmt &rest args)
91  `(format *compiler-diagnostic* "~&SYSTEM::*COMPILER-DIAGNOSTIC* ~A~&" (format nil ,fmt ,@args)))
92
93(declaim (ftype (function (t) t) verify-load))
94(defun verify-load (classfile &key (force nil))
95  "Return whether the file at the path denoted by CLASSFILE is a loadable JVM artifact."
96  (declare (ignore force))
97  (unless classfile
98    (diag "Nil classfile argument passed to verify-load.")
99    (return-from verify-load nil))
100  (when 
101      (= 0 (file-length (open classfile :direction :input)))
102             ;;; TODO hook into a real ABCL compiler condition hierarchy
103    (diag "Internal compiler error detected: Fasl contains ~
104zero-length jvm classfile corresponding to ~A." classfile)
105    (return-from verify-load nil))
106  #+nil
107  (when (or force (> *safety* *speed*))
108    (diag "Testing compiled bytecode by loading classfile into JVM.")
109    (let ((*load-truename* *output-file-pathname*))
110      ;; load-compiled-function used to be wrapped via report-error
111      (return-from verify-load (load-compiled-function classfile))))
112  t)
113
114(declaim (ftype (function (t) t) note-toplevel-form))
115(defun note-toplevel-form (form)
116  (when *compile-print*
117    (fresh-line)
118    (princ "; ")
119    (let ((*print-length* 2)
120          (*print-level* 2)
121          (*print-pretty* nil))
122      (prin1 form))
123    (terpri)))
124
125(defun output-form (form)
126  (if *binary-fasls*
127      (push form *forms-for-output*)
128      (progn
129        (dump-form form *fasl-stream*)
130        (%stream-terpri *fasl-stream*))))
131
132(defun finalize-fasl-output ()
133  (when *binary-fasls*
134    (let ((*package* (find-package :keyword))
135          (*double-colon-package-separators* T))
136      (dump-form (convert-toplevel-form (list* 'PROGN
137                                               (nreverse *forms-for-output*))
138                                        t)
139                 *fasl-stream*))
140    (%stream-terpri *fasl-stream*)))
141
142
143(declaim (ftype (function (t) t) simple-toplevel-form-p))
144(defun simple-toplevel-form-p (form)
145  "Returns NIL if the form is too complex to become an
146interpreted toplevel form, non-NIL if it is 'simple enough'."
147  (and (consp form)
148       (every #'(lambda (arg)
149                  (or (and (atom arg)
150                           (not (and (symbolp arg)
151                                     (symbol-macro-p arg))))
152                      (and (consp arg)
153                           (eq 'QUOTE (car arg)))))
154              (cdr form))))
155
156(declaim (ftype (function (t t) t) convert-toplevel-form))
157(defun convert-toplevel-form (form declare-inline)
158  (when (or (simple-toplevel-form-p form)
159            (and (eq (car form) 'SETQ)
160                 ;; for SETQ, look at the evaluated part
161                 (simple-toplevel-form-p (third form))))
162    ;; single form with simple or constant arguments
163    ;; Without this exception, toplevel function calls
164    ;; will be compiled into lambdas which get compiled to
165    ;; compiled-functions. Those need to be loaded.
166    ;; Conclusion: Top level interpreting the function call
167    ;;  and its arguments may be (and should be) more efficient.
168    (return-from convert-toplevel-form
169      (precompiler:precompile-form form nil *compile-file-environment*)))
170  (let* ((toplevel-form (third form))
171         (expr `(lambda () ,form))
172         (saved-class-number *class-number*)
173         (classfile (next-classfile-name))
174         (result
175          (with-open-file
176              (f classfile
177                 :direction :output
178                 :element-type '(unsigned-byte 8)
179                 :if-exists :supersede)
180            (report-error (jvm:compile-defun nil
181                                             expr *compile-file-environment*
182                                             classfile f
183                                             declare-inline))))
184         (compiled-function (verify-load classfile)))
185    (declare (ignore toplevel-form result))
186    (progn
187      #+nil
188      (when (> *debug* 0)
189;; TODO        (annotate form toplevel-form classfile compiled-function fasl-class-number)
190        ;;; ??? define an API by perhaps exporting these symbols?
191        (setf (getf form 'form-source) 
192              toplevel-form
193             
194              (getf form 'classfile) 
195              classfile
196                   
197              (getf form 'compiled-function) 
198              compiled-function
199                 
200              (getf form 'class-number) 
201              saved-class-number))
202      (setf form
203            (if compiled-function
204                `(funcall (sys::get-fasl-function *fasl-loader*
205                                                  ,saved-class-number))
206                (precompiler:precompile-form form nil
207                                             *compile-file-environment*))))))
208
209
210(declaim (ftype (function (t stream t) t) process-progn))
211(defun process-progn (forms stream compile-time-too)
212  (dolist (form forms)
213    (process-toplevel-form form stream compile-time-too))
214  nil)
215
216
217(declaim (ftype (function (t t t) t) process-toplevel-form))
218(defun precompile-toplevel-form (form stream compile-time-too)
219  (declare (ignore stream))
220  (let ((form (precompiler:precompile-form form nil
221                                           *compile-file-environment*)))
222    (when compile-time-too
223      (eval form))
224    form))
225
226
227
228(defun process-toplevel-macrolet (form stream compile-time-too)
229  (let ((*compile-file-environment*
230         (make-environment *compile-file-environment*)))
231    (dolist (definition (cadr form))
232      (environment-add-macro-definition *compile-file-environment*
233                                        (car definition)
234                                        (make-macro (car definition)
235                                                    (make-expander-for-macrolet definition))))
236    (dolist (body-form (cddr form))
237      (process-toplevel-form body-form stream compile-time-too)))
238  nil)
239
240(declaim (ftype (function (t t t) t) process-toplevel-defconstant))
241(defun process-toplevel-defconstant (form stream compile-time-too)
242  (declare (ignore stream compile-time-too))
243  ;; "If a DEFCONSTANT form appears as a top level form, the compiler
244  ;; must recognize that [the] name names a constant variable. An
245  ;; implementation may choose to evaluate the value-form at compile
246  ;; time, load time, or both. Therefore, users must ensure that the
247  ;; initial-value can be evaluated at compile time (regardless of
248  ;; whether or not references to name appear in the file) and that
249  ;; it always evaluates to the same value."
250  (note-toplevel-form form)
251  (eval form)
252  form)
253
254(declaim (ftype (function (t t t) t) process-toplevel-quote))
255(defun process-toplevel-quote (form stream compile-time-too)
256  (declare (ignore stream))
257  (when compile-time-too
258    (eval form))
259  nil)
260
261
262(declaim (ftype (function (t t t) t) process-toplevel-import))
263(defun process-toplevel-import (form stream compile-time-too)
264  (declare (ignore stream))
265  (let ((form (precompiler:precompile-form form nil
266                                           *compile-file-environment*)))
267    (let ((*package* +keyword-package+))
268      (output-form form))
269    (when compile-time-too
270      (eval form)))
271  nil)
272
273(declaim (ftype (function (t t t) t) process-toplevel-mop.ensure-method))
274(defun process-toplevel-mop.ensure-method (form stream compile-time-too)
275  (declare (ignore stream))
276  (flet ((convert-ensure-method (form key)
277           (let* ((tail (cddr form))
278                  (function-form (getf tail key)))
279             (when (and function-form (consp function-form)
280               (eq (%car function-form) 'FUNCTION))
281               (let ((lambda-expression (cadr function-form)))
282                 (jvm::with-saved-compiler-policy
283                     (let* ((saved-class-number *class-number*)
284                            (classfile (next-classfile-name))
285                            (result
286                             (with-open-file
287                                 (f classfile
288                                    :direction :output
289                                    :element-type '(unsigned-byte 8)
290                                    :if-exists :supersede)
291                               (report-error
292                                (jvm:compile-defun nil lambda-expression
293                                                   *compile-file-environment*
294                                                   classfile f nil))))
295                            (compiled-function (verify-load classfile)))
296                       (declare (ignore result))
297                       (cond
298                         (compiled-function
299                          (setf (getf tail key)
300                                `(sys::get-fasl-function *fasl-loader*
301                                                         ,saved-class-number)))
302                         (t
303                          ;; FIXME This should be a warning or error of some sort...
304                          (format *error-output* "; Unable to compile method~%"))))))))))
305
306
307    (when compile-time-too
308      (let* ((copy-form (copy-tree form))
309             ;; ### Ideally, the precompiler would leave the forms alone
310             ;;  and copy them where required, instead of forcing us to
311             ;;  do a deep copy in advance
312             (precompiled-form (precompiler:precompile-form copy-form nil
313                                                            *compile-file-environment*)))
314        (eval precompiled-form)))
315    (convert-ensure-method form :function)
316    (convert-ensure-method form :fast-function))
317  (precompiler:precompile-form form nil *compile-file-environment*))
318
319(declaim (ftype (function (t t t) t) process-toplevel-defvar/defparameter))
320(defun process-toplevel-defvar/defparameter (form stream compile-time-too)
321  (declare (ignore stream))
322  (note-toplevel-form form)
323  (if compile-time-too
324      (eval form)
325      ;; "If a DEFVAR or DEFPARAMETER form appears as a top level form,
326      ;; the compiler must recognize that the name has been proclaimed
327      ;; special. However, it must neither evaluate the initial-value
328      ;; form nor assign the dynamic variable named NAME at compile
329      ;; time."
330      (let ((name (second form)))
331        (%defvar name)))
332  form)
333
334(declaim (ftype (function (t t t) t) process-toplevel-defpackage/in-package))
335(defun process-toplevel-defpackage/in-package (form stream compile-time-too)
336  (declare (ignore stream compile-time-too))
337  (note-toplevel-form form)
338  (setf form
339        (precompiler:precompile-form form nil *compile-file-environment*))
340  (eval form)
341  ;; Force package prefix to be used when dumping form.
342  (let ((*package* +keyword-package+))
343    (output-form form))
344  nil)
345
346(declaim (ftype (function (t t t) t) process-toplevel-declare))
347(defun process-toplevel-declare (form stream compile-time-too)
348  (declare (ignore stream compile-time-too))
349  (compiler-style-warn "Misplaced declaration: ~S" form)
350  nil)
351
352(declaim (ftype (function (t t t) t) process-toplevel-progn))
353(defun process-toplevel-progn (form stream compile-time-too)
354  (process-progn (cdr form) stream compile-time-too)
355  nil)
356
357(declaim (ftype (function (t t t) t) process-toplevel-deftype))
358(defun process-toplevel-deftype (form stream compile-time-too)
359  (declare (ignore stream compile-time-too))
360  (note-toplevel-form form)
361  (eval form)
362  form)
363
364(declaim (ftype (function (t t t) t) process-toplevel-eval-when))
365(defun process-toplevel-eval-when (form stream compile-time-too)
366  (flet ((parse-eval-when-situations (situations)
367           "Parse an EVAL-WHEN situations list, returning three flags,
368            (VALUES COMPILE-TOPLEVEL LOAD-TOPLEVEL EXECUTE), indicating
369            the types of situations present in the list."
370            ; Adapted from SBCL.
371           (when (or (not (listp situations))
372                     (set-difference situations
373                                     '(:compile-toplevel
374                                       compile
375                                       :load-toplevel
376                                       load
377                                       :execute
378                                       eval)))
379             (error "Bad EVAL-WHEN situation list: ~S." situations))
380           (values (intersection '(:compile-toplevel compile) situations)
381                   (intersection '(:load-toplevel load) situations)
382                   (intersection '(:execute eval) situations))))
383    (multiple-value-bind (ct lt e)
384        (parse-eval-when-situations (cadr form))
385      (let ((new-compile-time-too (or ct (and compile-time-too e)))
386            (body (cddr form)))
387        (if lt
388            (process-progn body stream new-compile-time-too)
389            (when new-compile-time-too
390              (eval `(progn ,@body)))))))
391  nil)
392
393
394(declaim (ftype (function (t t t) t) process-toplevel-defmethod/defgeneric))
395(defun process-toplevel-defmethod/defgeneric (form stream compile-time-too)
396  (note-toplevel-form form)
397  (note-name-defined (second form))
398  (let ((*compile-print* nil))
399    (process-toplevel-form (macroexpand-1 form *compile-file-environment*)
400                           stream compile-time-too))
401  nil)
402
403(declaim (ftype (function (t t t) t) process-toplevel-locally))
404(defun process-toplevel-locally (form stream compile-time-too)
405  (jvm::with-saved-compiler-policy
406      (multiple-value-bind (forms decls)
407          (parse-body (cdr form) nil)
408        (process-optimization-declarations decls)
409        (let* ((jvm::*visible-variables* jvm::*visible-variables*)
410               (specials (jvm::process-declarations-for-vars (cdr form)
411                                                             nil nil)))
412          (dolist (special specials)
413            (push special jvm::*visible-variables*))
414          (process-progn forms stream compile-time-too))))
415  nil)
416
417(declaim (ftype (function (t t t) t) process-toplevel-defmacro))
418(defun process-toplevel-defmacro (form stream compile-time-too)
419  (declare (ignore stream compile-time-too))
420  (note-toplevel-form form)
421  (let ((name (second form)))
422    (eval form)
423    (let* ((expr (function-lambda-expression (macro-function name)))
424           (saved-class-number *class-number*)
425           (classfile (next-classfile-name)))
426      (with-open-file
427          (f classfile
428             :direction :output
429             :element-type '(unsigned-byte 8)
430             :if-exists :supersede)
431        (ignore-errors
432          (jvm:compile-defun nil expr *compile-file-environment*
433                             classfile f nil)))
434      (when (null (verify-load classfile))
435        ;; FIXME error or warning
436        (format *error-output* "; Unable to compile macro ~A~%" name)
437        (return-from process-toplevel-defmacro form))
438
439      (if (special-operator-p name)
440          `(put ',name 'macroexpand-macro
441                (make-macro ',name
442                            (sys::get-fasl-function *fasl-loader*
443                                                    ,saved-class-number)))
444          `(fset ',name
445                 (make-macro ',name
446                             (sys::get-fasl-function *fasl-loader*
447                                                     ,saved-class-number))
448                 ,*source-position*
449                 ',(third form))))))
450
451(declaim (ftype (function (t t t) t) process-toplevel-defun))
452(defun process-toplevel-defun (form stream compile-time-too)
453  (declare (ignore stream))
454  (note-toplevel-form form)
455  (let* ((name (second form))
456         (block-name (fdefinition-block-name name))
457         (lambda-list (third form))
458         (body (nthcdr 3 form)))
459    (jvm::with-saved-compiler-policy
460        (multiple-value-bind (body decls doc)
461            (parse-body body)
462          (let* ((expr `(lambda ,lambda-list
463                          ,@decls (block ,block-name ,@body)))
464                 (saved-class-number *class-number*)
465                 (classfile (next-classfile-name))
466                 (internal-compiler-errors nil)
467                 (result (with-open-file
468                             (f classfile
469                                :direction :output
470                                :element-type '(unsigned-byte 8)
471                                :if-exists :supersede)
472                           (handler-bind
473                               ((internal-compiler-error
474                                 #'(lambda (e)
475                                     (push e internal-compiler-errors)
476                                     (continue))))
477                             (report-error
478                              (jvm:compile-defun name expr *compile-file-environment*
479                                                 classfile f nil)))))
480                 (compiled-function (if (not internal-compiler-errors)
481                                        (verify-load classfile)
482                                        nil)))
483            (declare (ignore result))
484            (cond
485              ((and (not internal-compiler-errors)
486                    compiled-function)
487               (when compile-time-too
488                 (eval form))
489               (setf form
490                     `(fset ',name
491                            (sys::get-fasl-function *fasl-loader*
492                                                    ,saved-class-number)
493                            ,*source-position*
494                            ',lambda-list
495                            ,doc)))
496              (t
497               (compiler-warn "Unable to compile function ~A.  Using interpreted form instead.~%" name)
498               (when internal-compiler-errors
499                 (dolist (e internal-compiler-errors)
500                   (format *error-output*
501                           "; ~A~%" e)))
502               (let ((precompiled-function
503                      (precompiler:precompile-form expr nil
504                                                   *compile-file-environment*)))
505                 (setf form
506                       `(fset ',name
507                              ,precompiled-function
508                              ,*source-position*
509                              ',lambda-list
510                              ,doc)))
511               (when compile-time-too
512                 (eval form)))))
513          (when (and (symbolp name) (eq (get name '%inline) 'INLINE))
514            ;; FIXME Need to support SETF functions too!
515            (setf (inline-expansion name)
516                  (jvm::generate-inline-expansion block-name
517                                                  lambda-list body))
518            (output-form `(setf (inline-expansion ',name)
519                                ',(inline-expansion name))))))
520    (push name jvm::*functions-defined-in-current-file*)
521    (note-name-defined name)
522    ;; If NAME is not fbound, provide a dummy definition so that
523    ;; getSymbolFunctionOrDie() will succeed when we try to verify that
524    ;; functions defined later in the same file can be loaded correctly.
525    (unless (fboundp name)
526      (setf (fdefinition name) #'dummy)
527      (push name *fbound-names*)))
528  form)
529
530
531;; toplevel handlers
532;;   each toplevel handler takes a form and stream as input
533
534(defun install-toplevel-handler (symbol handler)
535  (setf (get symbol 'toplevel-handler) handler))
536
537(dolist (pair '((COMPILER-DEFSTRUCT precompile-toplevel-form)
538                (DECLARE process-toplevel-declare)
539                (DEFCONSTANT process-toplevel-defconstant)
540                (DEFGENERIC process-toplevel-defmethod/defgeneric)
541                (DEFMACRO process-toplevel-defmacro)
542                (DEFMETHOD process-toplevel-defmethod/defgeneric)
543                (DEFPACKAGE process-toplevel-defpackage/in-package)
544                (DEFPARAMETER process-toplevel-defvar/defparameter)
545                (DEFTYPE process-toplevel-deftype)
546                (DEFUN process-toplevel-defun)
547                (DEFVAR process-toplevel-defvar/defparameter)
548                (EVAL-WHEN process-toplevel-eval-when)
549                (EXPORT precompile-toplevel-form)
550                (IMPORT process-toplevel-import)
551                (IN-PACKAGE process-toplevel-defpackage/in-package)
552                (LOCALLY process-toplevel-locally)
553                (MACROLET process-toplevel-macrolet)
554                (PROCLAIM precompile-toplevel-form)
555                (PROGN process-toplevel-progn)
556                (PROVIDE precompile-toplevel-form)
557                (PUT precompile-toplevel-form)
558                (QUOTE process-toplevel-quote)
559                (REQUIRE precompile-toplevel-form)
560                (SHADOW precompile-toplevel-form)
561                (%SET-FDEFINITION precompile-toplevel-form)
562                (MOP::ENSURE-METHOD process-toplevel-mop.ensure-method)))
563  (install-toplevel-handler (car pair) (cadr pair)))
564
565(declaim (ftype (function (t stream t) t) process-toplevel-form))
566(defun process-toplevel-form (form stream compile-time-too)
567  (unless (atom form)
568    (let* ((operator (%car form))
569           (handler (get operator 'toplevel-handler)))
570      (when handler
571        (let ((out-form (funcall handler form stream compile-time-too)))
572          (when out-form
573            (output-form out-form)))
574        (return-from process-toplevel-form))
575      (when (and (symbolp operator)
576                 (macro-function operator *compile-file-environment*))
577        (note-toplevel-form form)
578        ;; Note that we want MACROEXPAND-1 and not MACROEXPAND here, in
579        ;; case the form being expanded expands into something that needs
580        ;; special handling by PROCESS-TOPLEVEL-FORM (e.g. DEFMACRO).
581        (let ((*compile-print* nil))
582          (process-toplevel-form (macroexpand-1 form *compile-file-environment*)
583                                 stream compile-time-too))
584        (return-from process-toplevel-form))
585
586      (cond
587        ((and (symbolp operator)
588              (not (special-operator-p operator))
589              (null (cdr form)))
590         (setf form (precompiler:precompile-form form nil
591                                                 *compile-file-environment*)))
592        (t
593         (note-toplevel-form form)
594         (setf form (convert-toplevel-form form nil)))))
595    (when (consp form)
596      (output-form form)))
597  ;; Make sure the compiled-function loader knows where
598  ;; to load the compiled functions. Note that this trickery
599  ;; was already used in verify-load before I used it,
600  ;; however, binding *load-truename* isn't fully compliant, I think.
601  (when compile-time-too
602    (let ((*load-truename* *output-file-pathname*)
603          (*fasl-loader* (make-fasl-class-loader
604                          (concatenate 'string
605                                       "org.armedbear.lisp." (base-classname)))))
606      (eval form))))
607
608(defun populate-zip-fasl (output-file)
609  (let* ((type ;; Don't use ".zip", it'll result in an extension
610          ;;  with a dot, which is rejected by NAMESTRING
611          (%format nil "~A~A" (pathname-type output-file) "-zip"))
612         (zipfile (namestring
613                   (merge-pathnames (make-pathname :type type)
614                                    output-file)))
615         (pathnames nil)
616         (fasl-loader (namestring (merge-pathnames
617                                   (make-pathname :name (fasl-loader-classname)
618                                                  :type "cls")
619                                   output-file))))
620    (when (probe-file fasl-loader)
621      (push fasl-loader pathnames))
622    (dotimes (i *class-number*)
623      (let ((truename (probe-file (compute-classfile-name (1+ i)))))
624        (when truename
625          (push truename pathnames)
626          ;;; XXX it would be better to just use the recorded number
627          ;;; of class constants, but probing for the first at least
628          ;;; makes this subjectively bearable.
629          (when (probe-file
630                 (make-pathname :name (format nil "~A_0"
631                                              (pathname-name truename))
632                                :type "clc"
633                                :defaults truename))
634            (dolist (resource (directory
635                               (make-pathname :name (format nil "~A_*"
636                                                            (pathname-name truename))
637                                              :type "clc"
638                                              :defaults truename)))
639              (push resource pathnames))))))
640    (setf pathnames (nreverse (remove nil pathnames)))
641    (let ((load-file (merge-pathnames (make-pathname :type "_")
642                                      output-file)))
643      (rename-file output-file load-file)
644      (push load-file pathnames))
645    (zip zipfile pathnames)
646    (dolist (pathname pathnames)
647      (ignore-errors (delete-file pathname)))
648    (rename-file zipfile output-file)))
649
650(defun write-fasl-prologue (stream)
651  (let ((out stream))
652    ;; write header
653    (write "; -*- Mode: Lisp -*-" :escape nil :stream out)
654    (%stream-terpri out)
655    (write (list 'init-fasl :version *fasl-version*) :stream out)
656    (%stream-terpri out)
657    (write (list 'setq '*source* *compile-file-truename*) :stream out)
658    (%stream-terpri out)
659
660    ;; Note: Beyond this point, you can't use DUMP-FORM,
661    ;; because the list of uninterned symbols has been fixed now.
662    (when *fasl-uninterned-symbols*
663      (write (list 'setq '*fasl-uninterned-symbols*
664                   (coerce (mapcar #'car (nreverse *fasl-uninterned-symbols*))
665                           'vector))
666             :stream out :length nil))
667    (%stream-terpri out)
668
669    (when (> *class-number* 0)
670      (write (list 'setq '*fasl-loader*
671                   `(sys::make-fasl-class-loader
672                     ,(concatenate 'string "org.armedbear.lisp."
673                                   (base-classname))))
674             :stream out))
675    (%stream-terpri out)))
676
677
678
679(defvar *binary-fasls* nil)
680(defvar *forms-for-output* nil)
681(defvar *fasl-stream* nil)
682
683(defun compile-file (input-file
684                     &key
685                     output-file
686                     ((:verbose *compile-verbose*) *compile-verbose*)
687                     ((:print *compile-print*) *compile-print*)
688                     external-format)
689  (declare (ignore external-format))    ; FIXME
690  (unless (or (and (probe-file input-file) (not (file-directory-p input-file)))
691              (pathname-type input-file))
692    (let ((pathname (merge-pathnames (make-pathname :type "lisp") input-file)))
693      (when (probe-file pathname)
694        (setf input-file pathname))))
695  (setf output-file (make-pathname 
696         :defaults (if output-file
697           (merge-pathnames output-file 
698                *default-pathname-defaults*)
699           (compile-file-pathname input-file))
700         :version nil))
701  (let* ((*output-file-pathname* output-file)
702         (type (pathname-type output-file))
703         (temp-file (merge-pathnames (make-pathname :type (concatenate 'string type "-tmp"))
704                                     output-file))
705         (temp-file2 (merge-pathnames (make-pathname :type (concatenate 'string type "-tmp2"))
706                                     output-file))
707         (warnings-p nil)
708         (failure-p nil))
709    (with-open-file (in input-file :direction :input)
710      (let* ((*compile-file-pathname* (make-pathname :defaults (pathname in)
711                 :version nil))
712             (*compile-file-truename* (make-pathname :defaults (truename in)
713                                                     :version nil))
714             (*source* *compile-file-truename*)
715             (*class-number* 0)
716             (namestring (namestring *compile-file-truename*))
717             (start (get-internal-real-time))
718             *fasl-uninterned-symbols*)
719        (when *compile-verbose*
720          (format t "; Compiling ~A ...~%" namestring))
721        (with-compilation-unit ()
722          (with-open-file (out temp-file
723                               :direction :output :if-exists :supersede
724                               :external-format *fasl-external-format*)
725            (let ((*readtable* *readtable*)
726                  (*read-default-float-format* *read-default-float-format*)
727                  (*read-base* *read-base*)
728                  (*package* *package*)
729                  (jvm::*functions-defined-in-current-file* '())
730                  (*fbound-names* '())
731                  (*fasl-stream* out)
732                  *forms-for-output*)
733              (jvm::with-saved-compiler-policy
734                (jvm::with-file-compilation
735                    (handler-bind
736                        ((style-warning 
737                          #'(lambda (c)
738                              (setf warnings-p t)
739                              ;; let outer handlers do their thing
740                              (signal c)
741                              ;; prevent the next handler
742                              ;; from running: we're a
743                              ;; WARNING subclass
744                              (continue)))
745                         ((or warning compiler-error)
746                          #'(lambda (c)
747                              (declare (ignore c))
748                              (setf warnings-p t
749                                    failure-p t))))
750                      (loop
751                         (let* ((*source-position* (file-position in))
752                                (jvm::*source-line-number* (stream-line-number in))
753                                (form (read in nil in))
754                                (*compiler-error-context* form))
755                           (when (eq form in)
756                             (return))
757                           (process-toplevel-form form out nil))))
758                    (finalize-fasl-output)
759                    (dolist (name *fbound-names*)
760                      (fmakunbound name)))))))
761        (with-open-file (in temp-file :direction :input)
762          (with-open-file (out temp-file2 :direction :output
763                               :if-does-not-exist :create
764                               :if-exists :supersede)
765            (let ((*package* (find-package '#:cl))
766                  (*print-fasl* t)
767                  (*print-array* t)
768                  (*print-base* 10)
769                  (*print-case* :upcase)
770                  (*print-circle* nil)
771                  (*print-escape* t)
772                  (*print-gensym* t)
773                  (*print-length* nil)
774                  (*print-level* nil)
775                  (*print-lines* nil)
776                  (*print-pretty* nil)
777                  (*print-radix* nil)
778                  (*print-readably* t)
779                  (*print-right-margin* nil)
780                  (*print-structure* t)
781
782                  ;; make sure to write all floats with their exponent marker:
783                  ;; the dump-time default may not be the same at load-time
784
785                  (*read-default-float-format* nil))
786
787              ;; these values are also bound by WITH-STANDARD-IO-SYNTAX,
788              ;; but not used by our reader/printer, so don't bind them,
789              ;; for efficiency reasons.
790              ;;        (*read-eval* t)
791              ;;        (*read-suppress* nil)
792              ;;        (*print-miser-width* nil)
793              ;;        (*print-pprint-dispatch* (copy-pprint-dispatch nil))
794              ;;        (*read-base* 10)
795              ;;        (*read-default-float-format* 'single-float)
796              ;;        (*readtable* (copy-readtable nil))
797
798              (write-fasl-prologue out)
799              ;; copy remaining content
800              (loop for line = (read-line in nil :eof)
801                 while (not (eq line :eof))
802                 do (write-line line out)))))
803        (delete-file temp-file)
804        (remove-zip-cache-entry output-file) ;; Necessary under windows
805        (rename-file temp-file2 output-file)
806
807        (when *compile-file-zip*
808          (populate-zip-fasl output-file))
809
810        (when *compile-verbose*
811          (format t "~&; Wrote ~A (~A seconds)~%"
812                  (namestring output-file)
813                  (/ (- (get-internal-real-time) start) 1000.0)))))
814    (values (truename output-file) warnings-p failure-p)))
815
816(defun compile-file-if-needed (input-file &rest allargs &key force-compile
817                               &allow-other-keys)
818  (setf input-file (truename input-file))
819  (cond (force-compile
820         (remf allargs :force-compile)
821         (apply 'compile-file input-file allargs))
822        (t
823         (let* ((source-write-time (file-write-date input-file))
824                (output-file       (or (getf allargs :output-file)
825                                       (compile-file-pathname input-file)))
826                (target-write-time (and (probe-file output-file)
827                                        (file-write-date output-file))))
828           (if (or (null target-write-time)
829                   (<= target-write-time source-write-time))
830               (apply 'compile-file input-file allargs)
831               output-file)))))
832
833(provide 'compile-file)
Note: See TracBrowser for help on using the repository browser.