source: trunk/abcl/src/org/armedbear/lisp/compiler-pass1.lisp @ 13228

Last change on this file since 13228 was 13228, checked in by astalla, 11 years ago

Fix incorrect elimination of named local functions declared inline when they're actually reified in the flet/labels body.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 55.1 KB
Line 
1;;; compiler-pass1.lisp
2;;;
3;;; Copyright (C) 2003-2008 Peter Graves
4;;; $Id: compiler-pass1.lisp 13228 2011-02-25 22:43:08Z astalla $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package "JVM")
33
34(eval-when (:compile-toplevel :load-toplevel :execute)
35  (require "LOOP")
36  (require "FORMAT")
37  (require "CLOS")
38  (require "PRINT-OBJECT")
39  (require "COMPILER-TYPES")
40  (require "KNOWN-FUNCTIONS")
41  (require "KNOWN-SYMBOLS")
42  (require "DUMP-FORM")
43  (require "OPCODES")
44  (require "JAVA"))
45
46
47(eval-when (:compile-toplevel :load-toplevel :execute)
48  (defun generate-inline-expansion (name lambda-list body
49            &optional (args nil args-p))
50    "Generates code that can be used to expand a named local function inline. It can work either per-function (no args provided) or per-call."
51    (if args-p
52  (expand-function-call-inline
53   nil lambda-list
54   (copy-tree `((block ,name ,@body)))
55   args)
56  (cond ((intersection lambda-list
57           '(&optional &rest &key &allow-other-keys &aux)
58           :test #'eq)
59         nil)
60        (t
61         (setf body (copy-tree body))
62         (list 'LAMBDA lambda-list
63         (list* 'BLOCK name body))))))
64    ) ; EVAL-WHEN
65
66;;; Pass 1.
67
68(defun parse-lambda-list (lambda-list)
69  "Breaks the lambda list into the different elements, returning the values
70
71 required-vars
72 optional-vars
73 key-vars
74 key-p
75 rest-var
76 allow-other-keys-p
77 aux-vars
78 whole-var
79 env-var
80
81where each of the vars returned is a list with these elements:
82
83 var      - the actual variable name
84 initform - the init form if applicable; optional, keyword and aux vars
85 p-var    - variable indicating presence
86 keyword  - the keyword argument to match against
87
88"
89  (let ((state :req)
90        req opt key rest whole env aux key-p allow-others-p)
91    (dolist (arg lambda-list)
92      (case arg
93        (&optional (setf state :opt))
94        (&key (setf state :key
95                    key-p t))
96        (&rest (setf state :rest))
97        (&aux (setf state :aux))
98        (&allow-other-keys (setf state :none
99                                 allow-others-p t))
100        (&whole (setf state :whole))
101        (&environment (setf state :env))
102        (t
103         (case state
104           (:req (push arg req))
105           (:rest (setf rest (list arg)
106                        state :none))
107           (:env (setf env (list arg)
108                       state :req))
109           (:whole (setf whole (list arg)
110                         state :req))
111           (:none
112            (error "Invalid lambda list: argument found in :none state."))
113           (:opt
114            (cond
115              ((symbolp arg)
116               (push (list arg nil nil nil) opt))
117              ((consp arg)
118               (push (list (car arg) (cadr arg) (caddr arg)) opt))
119              (t
120               (error "Invalid state."))))
121           (:aux
122            (cond
123              ((symbolp arg)
124               (push (list arg nil nil nil) aux))
125              ((consp arg)
126               (push (list (car arg) (cadr arg) nil nil) aux))
127              (t
128               (error "Invalid :aux state."))))
129           (:key
130            (cond
131              ((symbolp arg)
132               (push (list arg nil nil (sys::keywordify arg)) key))
133              ((and (consp arg)
134                    (consp (car arg)))
135               (push (list (cadar arg) (cadr arg) (caddr arg) (caar arg)) key))
136              ((consp arg)
137               (push (list (car arg) (cadr arg) (caddr arg)
138                           (sys::keywordify (car arg))) key))
139              (t
140               (error "Invalid :key state."))))
141           (t (error "Invalid state found."))))))
142    (values
143     (nreverse req)
144     (nreverse opt)
145     (nreverse key)
146     key-p
147     rest allow-others-p
148     (nreverse aux) whole env)))
149
150(define-condition lambda-list-mismatch (error)
151  ((mismatch-type :reader lambda-list-mismatch-type :initarg :mismatch-type)))
152
153(defmacro push-argument-binding (var form temp-bindings bindings)
154  (let ((g (gensym)))
155    `(let ((,g (gensym (symbol-name '#:temp))))
156       (push (list ,g ,form) ,temp-bindings)
157       (push (list ,var ,g) ,bindings))))
158
159(defun match-lambda-list (parsed-lambda-list arguments)
160  (flet ((pop-required-argument ()
161     (if (null arguments)
162         (error 'lambda-list-mismatch :mismatch-type :too-few-arguments)
163         (pop arguments)))
164   (var (var-info) (car var-info))
165   (initform (var-info) (cadr var-info))
166   (p-var (var-info) (caddr var-info)))
167    (destructuring-bind (req opt key key-p rest allow-others-p aux whole env)
168  parsed-lambda-list
169      (declare (ignore whole env))
170      (let (req-bindings temp-bindings bindings ignorables)
171  ;;Required arguments.
172  (setf req-bindings
173        (loop :for var :in req :collect `(,var ,(pop-required-argument))))
174
175  ;;Optional arguments.
176  (when opt
177    (dolist (var-info opt)
178      (if arguments
179    (progn
180      (push-argument-binding (var var-info) (pop arguments)
181           temp-bindings bindings)
182      (when (p-var var-info)
183        (push `(,(p-var var-info) t) bindings)))
184    (progn
185      (push `(,(var var-info) ,(initform var-info)) bindings)
186      (when (p-var var-info)
187        (push `(,(p-var var-info) nil) bindings)))))
188    (setf bindings (nreverse bindings)))
189 
190  (unless (or key-p rest (null arguments))
191    (error 'lambda-list-mismatch :mismatch-type :too-many-arguments))
192
193  ;;Keyword and rest arguments.
194  (if key-p
195      (multiple-value-bind (kbindings ktemps kignor)
196    (match-keyword-and-rest-args 
197     key allow-others-p rest arguments)
198        (setf bindings (append bindings kbindings)
199        temp-bindings (append temp-bindings ktemps)
200        ignorables (append kignor ignorables)))
201      (when rest
202        (let (rest-binding)
203    (push-argument-binding (var rest) `(list ,@arguments)
204               temp-bindings rest-binding)
205    (setf bindings (append bindings rest-binding)))))
206  ;;Aux parameters.
207  (when aux
208    (setf bindings
209    `(,@bindings
210      ,@(loop
211           :for var-info :in aux
212           :collect `(,(var var-info) ,(initform var-info))))))
213  (values (append req-bindings temp-bindings bindings)
214    ignorables)))))
215
216(defun match-keyword-and-rest-args (key allow-others-p rest arguments)
217  (flet ((var (var-info) (car var-info))
218   (initform (var-info) (cadr var-info))
219   (p-var (var-info) (caddr var-info))
220   (keyword (var-info) (cadddr var-info)))
221    (when (oddp (list-length arguments))
222      (error 'lambda-list-mismatch
223       :mismatch-type :odd-number-of-keyword-arguments))
224   
225    (let (temp-bindings bindings other-keys-found-p ignorables already-seen
226    args)
227      ;;If necessary, make up a fake argument to hold :allow-other-keys,
228      ;;needed later. This also handles nicely:
229      ;;  3.4.1.4.1 Suppressing Keyword Argument Checking
230      ;;third statement.
231      (unless (find :allow-other-keys key :key #'keyword)
232  (let ((allow-other-keys-temp (gensym (symbol-name :allow-other-keys))))
233    (push allow-other-keys-temp ignorables)
234    (push (list allow-other-keys-temp nil nil :allow-other-keys) key)))
235     
236      ;;First, let's bind the keyword arguments that have been passed by
237      ;;the caller. If we encounter an unknown keyword, remember it.
238      ;;As per the above, :allow-other-keys will never be considered
239      ;;an unknown keyword.
240      (loop
241   :for var :in arguments :by #'cddr
242   :for value :in (cdr arguments) :by #'cddr
243   :do (let ((var-info (find var key :key #'keyword)))
244         (if (and var-info (not (member var already-seen)))
245       ;;var is one of the declared keyword arguments
246       (progn
247         (push-argument-binding (var var-info) value
248              temp-bindings bindings)
249         (when (p-var var-info)
250           (push `(,(p-var var-info) t) bindings))
251         (push var args)
252         (push (var var-info) args)
253         (push var already-seen))
254       (let ((g (gensym)))
255         (push `(,g ,value) temp-bindings)
256         (push var args)
257         (push g args)
258         (push g ignorables)
259         (unless var-info
260           (setf other-keys-found-p t))))))
261     
262      ;;Then, let's bind those arguments that haven't been passed in
263      ;;to their default value, in declaration order.
264      (let (defaults)
265  (loop
266     :for var-info :in key
267     :do (unless (find (var var-info) bindings :key #'car)
268     (push `(,(var var-info) ,(initform var-info)) defaults)
269     (when (p-var var-info)
270       (push `(,(p-var var-info) nil) defaults))))
271  (setf bindings (append (nreverse defaults) bindings)))
272     
273      ;;If necessary, check for unrecognized keyword arguments.
274      (when (and other-keys-found-p (not allow-others-p))
275  (if (loop
276         :for var :in arguments :by #'cddr
277         :if (eq var :allow-other-keys)
278         :do (return t))
279      ;;We know that :allow-other-keys has been passed, so we
280      ;;can access the binding for it and be sure to get the
281      ;;value passed by the user and not an initform.
282      (let* ((arg (var (find :allow-other-keys key :key #'keyword)))
283       (binding (find arg bindings :key #'car))
284       (form (cadr binding)))
285        (if (constantp form)
286      (unless (eval form)
287        (error 'lambda-list-mismatch
288         :mismatch-type :unknown-keyword))
289      (setf (cadr binding)
290      `(or ,(cadr binding)
291           (error 'program-error
292            "Unrecognized keyword argument")))))
293      ;;TODO: it would be nice to report *which* keyword
294      ;;is unknown
295      (error 'lambda-list-mismatch :mismatch-type :unknown-keyword)))
296      (when rest
297  (setf bindings (append bindings `((,(var rest) (list ,@(nreverse args)))))))
298      (values bindings temp-bindings ignorables))))
299
300#||test for the above
301(handler-case
302    (let ((lambda-list
303     (multiple-value-list
304      (jvm::parse-lambda-list
305       '(a b &optional (c 42) &rest foo &key (bar c) baz ((kaz kuz) bar))))))
306      (jvm::match-lambda-list
307       lambda-list
308       '((print 1) 3 (print 32) :bar 2)))
309  (jvm::lambda-list-mismatch (x) (jvm::lambda-list-mismatch-type x)))
310||#
311
312(defun expand-function-call-inline (form lambda-list body args)
313  (handler-case
314      (multiple-value-bind (bindings ignorables)
315    (match-lambda-list (multiple-value-list
316            (parse-lambda-list lambda-list))
317           args)
318  `(let* ,bindings
319     ,@(when ignorables
320       `((declare (ignorable ,@ignorables))))
321     ,@body))
322    (lambda-list-mismatch (x)
323      (compiler-warn "Invalid function call: ~S (mismatch type: ~A)"
324         form (lambda-list-mismatch-type x))
325      form)))
326
327;; Returns a list of declared free specials, if any are found.
328(declaim (ftype (function (list list block-node) list)
329                process-declarations-for-vars))
330(defun process-declarations-for-vars (body variables block)
331  (let ((free-specials '()))
332    (dolist (subform body)
333      (unless (and (consp subform) (eq (%car subform) 'DECLARE))
334        (return))
335      (let ((decls (%cdr subform)))
336        (dolist (decl decls)
337          (case (car decl)
338            ((DYNAMIC-EXTENT FTYPE INLINE NOTINLINE OPTIMIZE)
339             ;; Nothing to do here.
340             )
341            ((IGNORE IGNORABLE)
342             (process-ignore/ignorable (%car decl) (%cdr decl) variables))
343            (SPECIAL
344             (dolist (name (%cdr decl))
345               (let ((variable (find-variable name variables)))
346                 (cond ((and variable
347                             ;; see comment below (and DO-ALL-SYMBOLS.11)
348                             (eq (variable-compiland variable)
349                                 *current-compiland*))
350                        (setf (variable-special-p variable) t))
351                       (t
352                        (dformat t "adding free special ~S~%" name)
353                        (push (make-variable :name name :special-p t
354                                             :block block)
355                              free-specials))))))
356            (TYPE
357             (dolist (name (cddr decl))
358               (let ((variable (find-variable name variables)))
359                 (when (and variable
360                            ;; Don't apply a declaration in a local function to
361                            ;; a variable defined in its parent. For an example,
362                            ;; see CREATE-GREEDY-NO-ZERO-MATCHER in cl-ppcre.
363                            ;; FIXME suboptimal, since we ignore the declaration
364                            (eq (variable-compiland variable)
365                                *current-compiland*))
366                   (setf (variable-declared-type variable)
367                         (make-compiler-type (cadr decl)))))))
368            (t
369             (dolist (name (cdr decl))
370               (let ((variable (find-variable name variables)))
371                 (when variable
372                   (setf (variable-declared-type variable)
373                         (make-compiler-type (%car decl)))))))))))
374    free-specials))
375
376(defun check-name (name)
377  ;; FIXME Currently this error is signalled by the precompiler.
378  (unless (symbolp name)
379    (compiler-error "The variable ~S is not a symbol." name))
380  (when (constantp name)
381    (compiler-error "The name of the variable ~S is already in use to name a constant." name))
382  name)
383
384(declaim (ftype (function (t) t) p1-body))
385(defun p1-body (body)
386  (declare (optimize speed))
387  (let ((tail body))
388    (loop
389      (when (endp tail)
390        (return))
391      (setf (car tail) (p1 (%car tail)))
392      (setf tail (%cdr tail))))
393  body)
394
395(defknown p1-default (t) t)
396(declaim (inline p1-default))
397(defun p1-default (form)
398  (setf (cdr form) (p1-body (cdr form)))
399  form)
400
401(defmacro p1-let/let*-vars
402    (block varlist variables-var var body1 body2)
403  (let ((varspec (gensym))
404  (initform (gensym))
405  (name (gensym)))
406    `(let ((,variables-var ()))
407       (dolist (,varspec ,varlist)
408   (cond ((consp ,varspec)
409                ;; Even though the precompiler already signals this
410                ;; error, double checking can't hurt; after all, we're
411                ;; also rewriting &AUX into LET* bindings.
412    (unless (<= 1 (length ,varspec) 2)
413      (compiler-error "The LET/LET* binding specification ~S is invalid."
414          ,varspec))
415    (let* ((,name (%car ,varspec))
416           (,initform (p1 (%cadr ,varspec)))
417           (,var (make-variable :name (check-name ,name)
418                                            :initform ,initform
419                                            :block ,block)))
420      (when (neq ,initform (cadr ,varspec))
421        (setf (cadr ,varspec) ,initform))
422      (push ,var ,variables-var)
423      ,@body1))
424         (t
425    (let ((,var (make-variable :name (check-name ,varspec)
426                                           :block ,block)))
427      (push ,var ,variables-var)
428      ,@body1))))
429       ,@body2)))
430
431(defknown p1-let-vars (t) t)
432(defun p1-let-vars (block varlist)
433  (p1-let/let*-vars block
434   varlist vars var
435   ()
436   ((setf vars (nreverse vars))
437    (dolist (variable vars)
438      (push variable *visible-variables*)
439      (push variable *all-variables*))
440    vars)))
441
442(defknown p1-let*-vars (t) t)
443(defun p1-let*-vars (block varlist)
444  (p1-let/let*-vars block
445   varlist vars var
446   ((push var *visible-variables*)
447    (push var *all-variables*))
448   ((nreverse vars))))
449
450(defun p1-let/let* (form)
451  (declare (type cons form))
452  (let* ((*visible-variables* *visible-variables*)
453         (block (make-let/let*-node))
454   (*block* block)
455         (op (%car form))
456         (varlist (cadr form))
457         (body (cddr form)))
458    (aver (or (eq op 'LET) (eq op 'LET*)))
459    (when (eq op 'LET)
460      ;; Convert to LET* if possible.
461      (if (null (cdr varlist))
462          (setf op 'LET*)
463          (dolist (varspec varlist (setf op 'LET*))
464            (or (atom varspec)
465                (constantp (cadr varspec))
466                (eq (car varspec) (cadr varspec))
467                (return)))))
468    (let ((vars (if (eq op 'LET)
469                    (p1-let-vars block varlist)
470                    (p1-let*-vars block varlist))))
471      ;; Check for globally declared specials.
472      (dolist (variable vars)
473        (when (special-variable-p (variable-name variable))
474          (setf (variable-special-p variable) t
475                (let-environment-register block) t)))
476      ;; For processing declarations, we want to walk the variable list from
477      ;; last to first, since declarations apply to the last-defined variable
478      ;; with the specified name.
479      (setf (let-free-specials block)
480            (process-declarations-for-vars body (reverse vars) block))
481      (setf (let-vars block) vars)
482      ;; Make free specials visible.
483      (dolist (variable (let-free-specials block))
484        (push variable *visible-variables*)))
485    (let ((*blocks* (cons block *blocks*)))
486      (setf body (p1-body body)))
487    (setf (let-form block) (list* op varlist body))
488    block))
489
490(defun p1-locally (form)
491  (let* ((*visible-variables* *visible-variables*)
492         (block (make-locally-node))
493   (*block* block)
494         (free-specials (process-declarations-for-vars (cdr form) nil block)))
495    (setf (locally-free-specials block) free-specials)
496    (dolist (special free-specials)
497;;       (format t "p1-locally ~S is special~%" name)
498      (push special *visible-variables*))
499    (let ((*blocks* (cons block *blocks*)))
500      (setf (locally-form block)
501            (list* 'LOCALLY (p1-body (cdr form))))
502      block)))
503
504(defknown p1-m-v-b (t) t)
505(defun p1-m-v-b (form)
506  (when (= (length (cadr form)) 1)
507    (let ((new-form `(let* ((,(caadr form) ,(caddr form))) ,@(cdddr form))))
508      (return-from p1-m-v-b (p1-let/let* new-form))))
509  (let* ((*visible-variables* *visible-variables*)
510         (block (make-m-v-b-node))
511   (*block* block)
512         (varlist (cadr form))
513         ;; Process the values-form first. ("The scopes of the name binding and
514         ;; declarations do not include the values-form.")
515         (values-form (p1 (caddr form)))
516         (*blocks* (cons block *blocks*))
517         (body (cdddr form)))
518    (let ((vars ()))
519      (dolist (symbol varlist)
520        (let ((var (make-variable :name symbol :block block)))
521          (push var vars)
522          (push var *visible-variables*)
523          (push var *all-variables*)))
524      ;; Check for globally declared specials.
525      (dolist (variable vars)
526        (when (special-variable-p (variable-name variable))
527          (setf (variable-special-p variable) t
528                (m-v-b-environment-register block) t)))
529      (setf (m-v-b-free-specials block)
530            (process-declarations-for-vars body vars block))
531      (dolist (special (m-v-b-free-specials block))
532        (push special *visible-variables*))
533      (setf (m-v-b-vars block) (nreverse vars)))
534    (setf body (p1-body body))
535    (setf (m-v-b-form block)
536          (list* 'MULTIPLE-VALUE-BIND varlist values-form body))
537    block))
538
539(defun p1-block (form)
540  (let* ((block (make-block-node (cadr form)))
541   (*block* block)
542         (*blocks* (cons block *blocks*)))
543    (setf (cddr form) (p1-body (cddr form)))
544    (setf (block-form block) form)
545    (when (block-non-local-return-p block)
546      ;; Add a closure variable for RETURN-FROM to use
547      (push (setf (block-id-variable block)
548                  (make-variable :name (gensym)
549                                 :block block
550                                 :used-non-locally-p t))
551            *all-variables*))
552    block))
553
554(defun p1-catch (form)
555  (let* ((tag (p1 (cadr form)))
556         (body (cddr form))
557         (block (make-catch-node))
558   (*block* block)
559         ;; our subform processors need to know
560         ;; they're enclosed in a CATCH block
561         (*blocks* (cons block *blocks*))
562         (result '()))
563    (dolist (subform body)
564      (let ((op (and (consp subform) (%car subform))))
565        (push (p1 subform) result)
566        (when (memq op '(GO RETURN-FROM THROW))
567          (return))))
568    (setf result (nreverse result))
569    (when (and (null (cdr result))
570               (consp (car result))
571               (eq (caar result) 'GO))
572      (return-from p1-catch (car result)))
573    (push tag result)
574    (push 'CATCH result)
575    (setf (catch-form block) result)
576    block))
577
578(defun p1-threads-synchronized-on (form)
579  (let* ((synchronized-object (p1 (cadr form)))
580         (body (cddr form))
581         (block (make-synchronized-node))
582   (*block* block)
583         (*blocks* (cons block *blocks*))
584         result)
585    (dolist (subform body)
586      (let ((op (and (consp subform) (%car subform))))
587        (push (p1 subform) result)
588        (when (memq op '(GO RETURN-FROM THROW))
589          (return))))
590    (setf (synchronized-form block)
591          (list* 'threads:synchronized-on synchronized-object
592                 (nreverse result)))
593    block))
594
595(defun p1-unwind-protect (form)
596  (if (= (length form) 2)
597      (p1 (second form)) ; No cleanup forms: (unwind-protect (...)) => (...)
598
599      ;; in order to compile the cleanup forms twice (see
600      ;; p2-unwind-protect-node), we need to p1 them twice; p1 outcomes
601      ;; can be compiled (in the same compiland?) only once.
602      ;;
603      ;; However, p1 transforms the forms being processed, so, we
604      ;; need to copy the forms to create a second copy.
605      (let* ((block (make-unwind-protect-node))
606       (*block* block)
607             ;; a bit of jumping through hoops...
608             (unwinding-forms (p1-body (copy-tree (cddr form))))
609             (unprotected-forms (p1-body (cddr form)))
610             ;; ... because only the protected form is
611             ;; protected by the UNWIND-PROTECT block
612             (*blocks* (cons block *blocks*))
613             (protected-form (p1 (cadr form))))
614        (setf (unwind-protect-form block)
615              `(unwind-protect ,protected-form
616                 (progn ,@unwinding-forms)
617                 ,@unprotected-forms))
618        block)))
619
620(defknown p1-return-from (t) t)
621(defun p1-return-from (form)
622  (let* ((name (second form))
623         (block (find-block name))
624         non-local-p)
625    (when (null block)
626      (compiler-error "RETURN-FROM ~S: no block named ~S is currently visible."
627                      name name))
628    (dformat t "p1-return-from block = ~S~%" (block-name block))
629    (cond ((eq (block-compiland block) *current-compiland*)
630           ;; Local case. If the RETURN is nested inside an UNWIND-PROTECT
631           ;; which is inside the block we're returning from, we'll do a non-
632           ;; local return anyway so that UNWIND-PROTECT can catch it and run
633           ;; its cleanup forms.
634           ;;(dformat t "*blocks* = ~S~%" (mapcar #'node-name *blocks*))
635           (let ((protected (enclosed-by-protected-block-p block)))
636             (dformat t "p1-return-from protected = ~S~%" protected)
637             (if protected
638                 (setf (block-non-local-return-p block) t
639                       non-local-p t)
640                 ;; non-local GO's ensure environment restoration
641                 ;; find out about this local GO
642                 (when (null (block-needs-environment-restoration block))
643                   (setf (block-needs-environment-restoration block)
644                         (enclosed-by-environment-setting-block-p block))))))
645          (t
646           (setf (block-non-local-return-p block) t
647                 non-local-p t)))
648    (when (block-non-local-return-p block)
649      (dformat t "non-local return from block ~S~%" (block-name block)))
650    (let ((value-form (p1 (caddr form))))
651      (push value-form (block-return-value-forms block))
652      (make-jump-node (list 'RETURN-FROM name value-form)
653                      non-local-p block))))
654
655(defun p1-tagbody (form)
656  (let* ((block (make-tagbody-node))
657   (*block* block)
658         (*blocks* (cons block *blocks*))
659         (*visible-tags* *visible-tags*)
660         (local-tags '())
661         (body (cdr form)))
662    ;; Make all the tags visible before processing the body forms.
663    (dolist (subform body)
664      (when (or (symbolp subform) (integerp subform))
665        (let* ((tag (make-tag :name subform :label (gensym) :block block)))
666          (push tag local-tags)
667          (push tag *visible-tags*))))
668    (let ((new-body '())
669          (live t))
670      (dolist (subform body)
671        (cond ((or (symbolp subform) (integerp subform))
672               (push subform new-body)
673               (push (find subform local-tags :key #'tag-name :test #'eql)
674                     (tagbody-tags block))
675               (setf live t))
676              ((not live)
677               ;; Nothing to do.
678               )
679              (t
680               (when (and (consp subform)
681                          (memq (%car subform) '(GO RETURN-FROM THROW)))
682                 ;; Subsequent subforms are unreachable until we see another
683                 ;; tag.
684                 (setf live nil))
685               (push (p1 subform) new-body))))
686      (setf (tagbody-form block) (list* 'TAGBODY (nreverse new-body))))
687    (when (some #'tag-used-non-locally (tagbody-tags block))
688      (push (setf (tagbody-id-variable block)
689                  (make-variable :name (gensym)
690                                 :block block
691                                 :used-non-locally-p t))
692            *all-variables*))
693    block))
694
695(defknown p1-go (t) t)
696(defun p1-go (form)
697  (let* ((name (cadr form))
698         (tag (find-tag name)))
699    (unless tag
700      (error "p1-go: tag not found: ~S" name))
701    (setf (tag-used tag) t)
702    (let ((tag-block (tag-block tag))
703          non-local-p)
704      (cond ((eq (tag-compiland tag) *current-compiland*)
705             ;; Does the GO leave an enclosing UNWIND-PROTECT or CATCH?
706             (if (enclosed-by-protected-block-p tag-block)
707                 (setf (tagbody-non-local-go-p tag-block) t
708                       (tag-used-non-locally tag) t
709                       non-local-p t)
710                 ;; non-local GO's ensure environment restoration
711                 ;; find out about this local GO
712                 (when (null (tagbody-needs-environment-restoration tag-block))
713                   (setf (tagbody-needs-environment-restoration tag-block)
714                         (enclosed-by-environment-setting-block-p tag-block)))))
715            (t
716             (setf (tagbody-non-local-go-p tag-block) t
717                   (tag-used-non-locally tag) t
718                   non-local-p t)))
719      (make-jump-node form non-local-p tag-block tag))))
720
721(defun validate-function-name (name)
722  (unless (or (symbolp name) (setf-function-name-p name))
723    (compiler-error "~S is not a valid function name." name)))
724
725(defmacro with-local-functions-for-flet/labels
726    (form local-functions-var lambda-list-var name-var body-var body1 body2)
727  `(progn (incf (compiland-children *current-compiland*) (length (cadr ,form)))
728    (let ((*visible-variables* *visible-variables*)
729    (*local-functions* *local-functions*)
730    (*current-compiland* *current-compiland*)
731    (,local-functions-var '()))
732      (dolist (definition (cadr ,form))
733        (let ((,name-var (car definition))
734        (,lambda-list-var (cadr definition)))
735    (validate-function-name ,name-var)
736    (let* ((,body-var (cddr definition))
737           (compiland (make-compiland :name ,name-var
738              :parent *current-compiland*)))
739      ,@body1)))
740      (setf ,local-functions-var (nreverse ,local-functions-var))
741      ;; Make the local functions visible.
742      (dolist (local-function ,local-functions-var)
743        (push local-function *local-functions*)
744        (let ((variable (local-function-variable local-function)))
745    (when variable
746      (push variable *visible-variables*))))
747      ,@body2)))
748
749(defun split-decls (forms specific-vars)
750  (let ((other-decls nil)
751        (specific-decls nil))
752    (dolist (form forms)
753      (unless (and (consp form) (eq (car form) 'DECLARE)) ; shouldn't happen
754        (return))
755      (dolist (decl (cdr form))
756        (case (car decl)
757          ((OPTIMIZE DECLARATION DYNAMIC-EXTENT FTYPE INLINE NOTINLINE)
758           (push (list 'DECLARE decl) other-decls))
759          (SPECIAL
760           (dolist (name (cdr decl))
761             (if (memq name specific-vars)
762                 (push `(DECLARE (SPECIAL ,name)) specific-decls)
763                 (push `(DECLARE (SPECIAL ,name)) other-decls))))
764          (TYPE
765           (dolist (name (cddr decl))
766             (if (memq name specific-vars)
767                 (push `(DECLARE (TYPE ,(cadr decl) ,name)) specific-decls)
768                 (push `(DECLARE (TYPE ,(cadr decl) ,name)) other-decls))))
769          (t
770           (dolist (name (cdr decl))
771             (if (memq name specific-vars)
772                 (push `(DECLARE (,(car decl) ,name)) specific-decls)
773                 (push `(DECLARE (,(car decl) ,name)) other-decls)))))))
774    (values (nreverse other-decls)
775            (nreverse specific-decls))))
776
777(defun rewrite-aux-vars (form)
778  (let* ((lambda-list (cadr form))
779         (aux-p (memq '&AUX lambda-list))
780         (lets (cdr aux-p))
781         aux-vars)
782    (unless aux-p
783      ;; no rewriting required
784      (return-from rewrite-aux-vars form))
785    (multiple-value-bind (body decls)
786        (parse-body (cddr form))
787      (dolist (form lets)
788        (cond ((consp form)
789               (push (car form) aux-vars))
790              (t
791               (push form aux-vars))))
792      (setf lambda-list (subseq lambda-list 0 (position '&AUX lambda-list)))
793      (multiple-value-bind (let-decls lambda-decls)
794          (split-decls decls (lambda-list-names lambda-list))
795        `(lambda ,lambda-list
796           ,@lambda-decls
797           (let* ,lets
798             ,@let-decls
799             ,@body))))))
800
801(defun rewrite-lambda (form)
802  (setf form (rewrite-aux-vars form))
803  (let* ((lambda-list (cadr form)))
804    (if (not (or (memq '&optional lambda-list)
805                 (memq '&key lambda-list)))
806        ;; no need to rewrite: no arguments with possible initforms anyway
807        form
808      (multiple-value-bind (body decls doc)
809          (parse-body (cddr form))
810        (let (state let-bindings new-lambda-list
811                    (non-constants 0))
812          (do* ((vars lambda-list (cdr vars))
813                (var (car vars) (car vars)))
814               ((endp vars))
815            (push (car vars) new-lambda-list)
816            (let ((replacement (gensym)))
817              (flet ((parse-compound-argument (arg)
818                       "Returns the values NAME, KEYWORD, INITFORM, INITFORM-P,
819   SUPPLIED-P and SUPPLIED-P-P assuming ARG is a compound argument."
820                       (destructuring-bind
821                             (name &optional (initform nil initform-supplied-p)
822                                   (supplied-p nil supplied-p-supplied-p))
823                           (if (listp arg) arg (list arg))
824                         (if (listp name)
825                             (values (cadr name) (car name)
826                                     initform initform-supplied-p
827                                     supplied-p supplied-p-supplied-p)
828                             (values name (make-keyword name)
829                                     initform initform-supplied-p
830                                     supplied-p supplied-p-supplied-p)))))
831                (case var
832                  (&optional (setf state :optional))
833                  (&key (setf state :key))
834                  ((&whole &environment &rest &body &allow-other-keys)
835                   ;; do nothing special
836                   )
837                  (t
838                   (cond
839                     ((atom var)
840                      (setf (car new-lambda-list)
841                            (if (eq state :key)
842                                (list (list (make-keyword var) replacement))
843                                replacement))
844                      (push (list var replacement) let-bindings))
845                     ((constantp (second var))
846                      ;; so, we must have a consp-type var we're looking at
847                      ;; and it has a constantp initform
848                      (multiple-value-bind
849                            (name keyword initform initform-supplied-p
850                                  supplied-p supplied-p-supplied-p)
851                          (parse-compound-argument var)
852                        (let ((var-form (if (eq state :key)
853                                            (list keyword replacement)
854                                            replacement))
855                              (supplied-p-replacement (gensym)))
856                          (setf (car new-lambda-list)
857                                (cond
858                                  ((not initform-supplied-p)
859                                   (list var-form))
860                                  ((not supplied-p-supplied-p)
861                                   (list var-form initform))
862                                  (t
863                                   (list var-form initform
864                                         supplied-p-replacement))))
865                          (push (list name replacement) let-bindings)
866                          ;; if there was a 'supplied-p' variable, it might
867                          ;; be used in the declarations. Since those will be
868                          ;; moved below the LET* block, we need to move the
869                          ;; supplied-p parameter too.
870                          (when supplied-p-supplied-p
871                            (push (list supplied-p supplied-p-replacement)
872                                  let-bindings)))))
873                     (t
874                      (incf non-constants)
875                      ;; this is either a keyword or an optional argument
876                      ;; with a non-constantp initform
877                      (multiple-value-bind
878                            (name keyword initform initform-supplied-p
879                                  supplied-p supplied-p-supplied-p)
880                          (parse-compound-argument var)
881                        (declare (ignore initform-supplied-p))
882                        (let ((var-form (if (eq state :key)
883                                            (list keyword replacement)
884                                            replacement))
885                              (supplied-p-replacement (gensym)))
886                          (setf (car new-lambda-list)
887                                (list var-form nil supplied-p-replacement))
888                          (push (list name `(if ,supplied-p-replacement
889                                                ,replacement ,initform))
890                                let-bindings)
891                          (when supplied-p-supplied-p
892                            (push (list supplied-p supplied-p-replacement)
893                                  let-bindings)))))))))))
894          (if (zerop non-constants)
895              ;; there was no reason to rewrite...
896              form
897              (let ((rv
898                     `(lambda ,(nreverse new-lambda-list)
899                        ,@(when doc (list doc))
900                        (let* ,(nreverse let-bindings)
901                          ,@decls ,@body))))
902                rv)))))))
903
904(defun p1-flet (form)
905  (with-local-functions-for-flet/labels
906      form local-functions lambda-list name body
907      ((let ((local-function (make-local-function :name name
908                                                  :compiland compiland))
909       (definition (cons lambda-list body)))
910   (multiple-value-bind (body decls) (parse-body body)
911     (let* ((block-name (fdefinition-block-name name))
912      (lambda-expression
913       (rewrite-lambda `(lambda ,lambda-list ,@decls (block ,block-name ,@body))))
914      (*visible-variables* *visible-variables*)
915      (*local-functions* *local-functions*)
916      (*current-compiland* compiland))
917       (setf (compiland-lambda-expression compiland) lambda-expression)
918       (setf (local-function-definition local-function)
919       (copy-tree definition))
920       ;(setf (local-function-inline-expansion local-function)
921       ;(generate-inline-expansion block-name lambda-list body))
922       (p1-compiland compiland)))
923   (push local-function local-functions)))
924      ((with-saved-compiler-policy
925   (process-optimization-declarations (cddr form))
926   (let* ((block (make-flet-node))
927    (*block* block)
928    (*blocks* (cons block *blocks*))
929    (body (cddr form))
930    (*visible-variables* *visible-variables*))
931     (setf (flet-free-specials block)
932     (process-declarations-for-vars body nil block))
933     (dolist (special (flet-free-specials block))
934       (push special *visible-variables*))
935           (let ((body (p1-body (cddr form))))
936             (setf (flet-form block)
937                   (list* (car form)
938                          (remove-if (lambda (fn)
939                                       (and (inline-p (local-function-name fn))
940                                            (not (local-function-references-needed-p fn))))
941                                     local-functions)
942                          body)))
943           block)))))
944
945
946(defun p1-labels (form)
947  (with-local-functions-for-flet/labels
948      form local-functions lambda-list name body
949      ((let* ((variable (make-variable :name (gensym)))
950        (local-function (make-local-function :name name
951               :compiland compiland
952               :variable variable))
953              (block-name (fdefinition-block-name name)))
954   (setf (local-function-definition local-function)
955         (copy-tree (cons lambda-list body)))
956   (multiple-value-bind (body decls) (parse-body body)
957     (setf (compiland-lambda-expression compiland)
958                 (rewrite-lambda
959     `(lambda ,lambda-list ,@decls (block ,block-name ,@body)))))
960   (push variable *all-variables*)
961   (push local-function local-functions)))
962      ((dolist (local-function local-functions)
963   (let ((*visible-variables* *visible-variables*)
964         (*current-compiland* (local-function-compiland local-function)))
965     (p1-compiland (local-function-compiland local-function))))
966       (let* ((block (make-labels-node))
967        (*block* block)
968              (*blocks* (cons block *blocks*))
969              (body (cddr form))
970              (*visible-variables* *visible-variables*))
971         (setf (labels-free-specials block)
972               (process-declarations-for-vars body nil block))
973         (dolist (special (labels-free-specials block))
974           (push special *visible-variables*))
975         (setf (labels-form block)
976               (list* (car form) local-functions (p1-body (cddr form))))
977         block))))
978
979(defknown p1-funcall (t) t)
980(defun p1-funcall (form)
981  (unless (> (length form) 1)
982    (compiler-warn "Wrong number of arguments for ~A." (car form))
983    (return-from p1-funcall form))
984  (let ((function-form (%cadr form)))
985    (when (and (consp function-form)
986               (eq (%car function-form) 'FUNCTION))
987      (let ((name (%cadr function-form)))
988;;         (format t "p1-funcall name = ~S~%" name)
989        (let ((source-transform (source-transform name)))
990          (when source-transform
991;;             (format t "found source transform for ~S~%" name)
992;;             (format t "old form = ~S~%" form)
993;;             (let ((new-form (expand-source-transform form)))
994;;               (when (neq new-form form)
995;;                 (format t "new form = ~S~%" new-form)
996;;                 (return-from p1-funcall (p1 new-form))))
997            (let ((new-form (expand-source-transform (list* name (cddr form)))))
998;;               (format t "new form = ~S~%" new-form)
999              (return-from p1-funcall (p1 new-form)))
1000            )))))
1001  ;; Otherwise...
1002  (p1-function-call form))
1003
1004(defun p1-function (form)
1005  (let ((form (copy-tree form))
1006        local-function)
1007    (cond ((and (consp (cadr form))
1008                (or (eq (caadr form) 'LAMBDA)
1009                    (eq (caadr form) 'NAMED-LAMBDA)))
1010           (let* ((named-lambda-p (eq (caadr form) 'NAMED-LAMBDA))
1011                  (named-lambda-form (when named-lambda-p
1012                                       (cadr form)))
1013                  (name (when named-lambda-p
1014                          (cadr named-lambda-form)))
1015                  (lambda-form (if named-lambda-p
1016                                   (cons 'LAMBDA (cddr named-lambda-form))
1017                                   (cadr form)))
1018                  (lambda-list (cadr lambda-form))
1019                  (body (cddr lambda-form))
1020                  (compiland (make-compiland :name (if named-lambda-p
1021                                                       name (gensym "ANONYMOUS-LAMBDA-"))
1022                                             :lambda-expression lambda-form
1023                                             :parent *current-compiland*)))
1024             (when *current-compiland*
1025               (incf (compiland-children *current-compiland*)))
1026             (multiple-value-bind (body decls)
1027                 (parse-body body)
1028               (setf (compiland-lambda-expression compiland)
1029                     ;; if there still was a doc-string present, remove it
1030                     (rewrite-lambda
1031                      `(lambda ,lambda-list ,@decls ,@body)))
1032               (let ((*visible-variables* *visible-variables*)
1033                     (*current-compiland* compiland))
1034                 (p1-compiland compiland)))
1035             (list 'FUNCTION compiland)))
1036          ((setf local-function (find-local-function (cadr form)))
1037           (dformat "p1-function local function ~S~%" (cadr form))
1038           ;;we found out that the function needs a reference
1039           (setf (local-function-references-needed-p local-function) t)
1040           (let ((variable (local-function-variable local-function)))
1041             (when variable
1042                 (dformat t "p1-function ~S used non-locally~%"
1043                          (variable-name variable))
1044                 (setf (variable-used-non-locally-p variable) t)))
1045           form)
1046          (t
1047           form))))
1048
1049(defun p1-lambda (form)
1050  (setf form (rewrite-lambda form))
1051  (let* ((lambda-list (cadr form)))
1052    (when (or (memq '&optional lambda-list)
1053              (memq '&key lambda-list))
1054      (let ((state nil))
1055        (dolist (arg lambda-list)
1056          (cond ((memq arg lambda-list-keywords)
1057                 (setf state arg))
1058                ((memq state '(&optional &key))
1059                 (when (and (consp arg)
1060                            (not (constantp (second arg))))
1061                   (compiler-unsupported
1062                    "P1-LAMBDA: can't handle optional argument with non-constant initform.")))))))
1063    (p1-function (list 'FUNCTION form))))
1064
1065(defun p1-eval-when (form)
1066  (list* (car form) (cadr form) (mapcar #'p1 (cddr form))))
1067
1068(defknown p1-progv (t) t)
1069(defun p1-progv (form)
1070  ;; We've already checked argument count in PRECOMPILE-PROGV.
1071  (let* ((symbols-form (p1 (cadr form)))
1072         (values-form (p1 (caddr form)))
1073         (block (make-progv-node))
1074   (*block* block)
1075         (*blocks* (cons block *blocks*))
1076         (body (cdddr form)))
1077;;  The (commented out) block below means to detect compile-time
1078;;  enumeration of bindings to be created (a quoted form in the symbols
1079;;  position).
1080;;    (when (and (quoted-form-p symbols-form)
1081;;               (listp (second symbols-form)))
1082;;      (dolist (name (second symbols-form))
1083;;        (let ((variable (make-variable :name name :special-p t)))
1084;;          (push
1085    (setf (progv-environment-register block) t
1086          (progv-form block)
1087          `(progv ,symbols-form ,values-form ,@(p1-body body)))
1088    block))
1089
1090(defun p1-quote (form)
1091  (unless (= (length form) 2)
1092    (compiler-error "Wrong number of arguments for special operator ~A (expected 1, but received ~D)."
1093                    'QUOTE
1094                    (1- (length form))))
1095  (let ((arg (%cadr form)))
1096    (if (or (numberp arg) (characterp arg))
1097        arg
1098        form)))
1099
1100(defun p1-setq (form)
1101  (unless (= (length form) 3)
1102    (error "Too many arguments for SETQ."))
1103  (let ((arg1 (%cadr form))
1104        (arg2 (%caddr form)))
1105    (let ((variable (find-visible-variable arg1)))
1106      (if variable
1107          (progn
1108            (when (variable-ignore-p variable)
1109              (compiler-style-warn
1110               "Variable ~S is assigned even though it was declared to be ignored."
1111               (variable-name variable)))
1112            (incf (variable-writes variable))
1113            (cond ((eq (variable-compiland variable) *current-compiland*)
1114                   (dformat t "p1-setq: write ~S~%" arg1))
1115                  (t
1116                   (dformat t "p1-setq: non-local write ~S~%" arg1)
1117                   (setf (variable-used-non-locally-p variable) t))))
1118          (dformat t "p1-setq: unknown variable ~S~%" arg1)))
1119    (list 'SETQ arg1 (p1 arg2))))
1120
1121(defun p1-the (form)
1122  (unless (= (length form) 3)
1123    (compiler-error "Wrong number of arguments for special operator ~A (expected 2, but received ~D)."
1124                    'THE
1125                    (1- (length form))))
1126  (let ((type (%cadr form))
1127        (expr (%caddr form)))
1128    (cond ((and (listp type) (eq (car type) 'VALUES))
1129           ;; FIXME
1130           (p1 expr))
1131          ((= *safety* 3)
1132           (let* ((sym (gensym))
1133                  (new-expr `(let ((,sym ,expr))
1134                               (require-type ,sym ',type)
1135                               ,sym)))
1136             (p1 new-expr)))
1137          ((and (<= 1 *safety* 2) ;; at safety 1 or 2 check relatively
1138                (symbolp type))   ;; simple types (those specified by a single symbol)
1139           (let* ((sym (gensym))
1140                  (new-expr `(let ((,sym ,expr))
1141                               (require-type ,sym ',type)
1142                               ,sym)))
1143             (p1 new-expr)))
1144          (t
1145           (list 'THE type (p1 expr))))))
1146
1147(defun p1-truly-the (form)
1148  (unless (= (length form) 3)
1149    (compiler-error "Wrong number of arguments for special operator ~A (expected 2, but received ~D)."
1150                    'TRULY-THE
1151                    (1- (length form))))
1152  (list 'TRULY-THE (%cadr form) (p1 (%caddr form))))
1153
1154(defknown p1-throw (t) t)
1155(defun p1-throw (form)
1156  (list* 'THROW (mapcar #'p1 (cdr form))))
1157
1158(defknown rewrite-function-call (t) t)
1159(defun rewrite-function-call (form)
1160  (let ((op (car form)) (args (cdr form)))
1161    (cond
1162      ((and (eq op 'funcall) (listp (car args)) (eq (caar args) 'lambda))
1163       ;;(funcall (lambda (...) ...) ...)
1164       (let ((op (car args)) (args (cdr args)))
1165         (expand-function-call-inline form (cadr op) (copy-tree (cddr op))
1166                                      args)))
1167      ((and (listp op) (eq (car op) 'lambda))
1168       ;;((lambda (...) ...) ...)
1169       (expand-function-call-inline form (cadr op) (copy-tree (cddr op)) args))
1170      (t form))))
1171
1172(defknown p1-function-call (t) t)
1173(defun p1-function-call (form)
1174  (let ((new-form (rewrite-function-call form)))
1175    (when (neq new-form form)
1176      (return-from p1-function-call (p1 new-form))))
1177  (let* ((op (car form))
1178         (local-function (find-local-function op)))
1179    (when local-function
1180;;            (format t "p1 local call to ~S~%" op)
1181;;            (format t "inline-p = ~S~%" (inline-p op))
1182
1183      (when (and *enable-inline-expansion* (inline-p op)
1184                 (local-function-definition local-function))
1185        (let* ((definition (local-function-definition local-function))
1186               (lambda-list (car definition))
1187               (body (cdr definition))
1188               (expansion (generate-inline-expansion op lambda-list body
1189                                                     (cdr form))))
1190          (when expansion
1191            (let ((explain *explain*))
1192              (when (and explain (memq :calls explain))
1193                (format t ";   inlining call to local function ~S~%" op)))
1194            (return-from p1-function-call
1195                         (let ((*inline-declarations*
1196                                (remove op *inline-declarations* :key #'car :test #'equal)))
1197                           (p1 expansion))))))
1198
1199      (let ((variable (local-function-variable local-function)))
1200        (when variable
1201          (dformat t "p1 ~S used non-locally~%" (variable-name variable))
1202          (setf (variable-used-non-locally-p variable) t)))))
1203  (p1-default form))
1204
1205(defun %funcall (fn &rest args)
1206  "Dummy FUNCALL wrapper to force p1 not to optimize the call."
1207  (apply fn args))
1208
1209(defknown p1 (t) t)
1210(defun p1 (form)
1211  (cond ((symbolp form)
1212         (let (value)
1213           (cond ((null form)
1214                  form)
1215                 ((eq form t)
1216                  form)
1217                 ((keywordp form)
1218                  form)
1219                 ((and (constantp form)
1220                       (progn
1221                         (setf value (symbol-value form))
1222                         (or (numberp value)
1223                             (stringp value)
1224                             (pathnamep value))))
1225                  (setf form value))
1226                 (t
1227                  (let ((variable (find-visible-variable form)))
1228                    (when (null variable)
1229          (unless (or (special-variable-p form)
1230                                  (memq form *undefined-variables*))
1231      (compiler-style-warn
1232                         "Undefined variable ~S assumed special" form)
1233      (push form *undefined-variables*))
1234                      (setf variable (make-variable :name form :special-p t))
1235                      (push variable *visible-variables*))
1236                    (let ((ref (make-var-ref variable)))
1237                      (unless (variable-special-p variable)
1238                        (when (variable-ignore-p variable)
1239                          (compiler-style-warn
1240                           "Variable ~S is read even though it was declared to be ignored."
1241                           (variable-name variable)))
1242                        (push ref (variable-references variable))
1243                        (incf (variable-reads variable))
1244                        (cond ((eq (variable-compiland variable) *current-compiland*)
1245                               (dformat t "p1: read ~S~%" form))
1246                              (t
1247                               (dformat t "p1: non-local read ~S variable-compiland = ~S current compiland = ~S~%"
1248                                        form
1249                                        (compiland-name (variable-compiland variable))
1250                                        (compiland-name *current-compiland*))
1251                               (setf (variable-used-non-locally-p variable) t))))
1252                      (setf form ref)))
1253                  form))))
1254        ((atom form)
1255         form)
1256        (t
1257         (let ((op (%car form))
1258               handler)
1259           (cond ((symbolp op)
1260                  (when (compiler-macro-function op)
1261                    (unless (notinline-p op)
1262                      (multiple-value-bind (expansion expanded-p)
1263                          (compiler-macroexpand form)
1264                        ;; Fall through if no change...
1265                        (when expanded-p
1266                          (return-from p1 (p1 expansion))))))
1267                  (cond ((setf handler (get op 'p1-handler))
1268                         (funcall handler form))
1269                        ((macro-function op *compile-file-environment*)
1270                         (p1 (macroexpand form *compile-file-environment*)))
1271                        ((special-operator-p op)
1272                         (compiler-unsupported "P1: unsupported special operator ~S" op))
1273                        (t
1274                         (p1-function-call form))))
1275                 ((and (consp op) (eq (%car op) 'LAMBDA))
1276      (let ((maybe-optimized-call (rewrite-function-call form)))
1277        (if (eq maybe-optimized-call form)
1278      (p1 `(%funcall (function ,op) ,@(cdr form)))
1279      (p1 maybe-optimized-call))))
1280                 (t
1281                  form))))))
1282
1283(defun install-p1-handler (symbol handler)
1284  (setf (get symbol 'p1-handler) handler))
1285
1286(defun initialize-p1-handlers ()
1287  (dolist (pair '((AND                  p1-default)
1288                  (BLOCK                p1-block)
1289                  (CATCH                p1-catch)
1290                  (DECLARE              identity)
1291                  (EVAL-WHEN            p1-eval-when)
1292                  (FLET                 p1-flet)
1293                  (FUNCALL              p1-funcall)
1294                  (FUNCTION             p1-function)
1295                  (GO                   p1-go)
1296                  (IF                   p1-default)
1297                  ;; used to be p1-if, which was used to rewrite the test
1298                  ;; form to a LET-binding; that's not necessary, because
1299                  ;; the test form doesn't lead to multiple operands on the
1300                  ;; operand stack
1301                  (LABELS               p1-labels)
1302                  (LAMBDA               p1-lambda)
1303                  (LET                  p1-let/let*)
1304                  (LET*                 p1-let/let*)
1305                  (LOAD-TIME-VALUE      identity)
1306                  (LOCALLY              p1-locally)
1307                  (MULTIPLE-VALUE-BIND  p1-m-v-b)
1308                  (MULTIPLE-VALUE-CALL  p1-default)
1309                  (MULTIPLE-VALUE-LIST  p1-default)
1310                  (MULTIPLE-VALUE-PROG1 p1-default)
1311                  (OR                   p1-default)
1312                  (PROGN                p1-default)
1313                  (PROGV                p1-progv)
1314                  (QUOTE                p1-quote)
1315                  (RETURN-FROM          p1-return-from)
1316                  (SETQ                 p1-setq)
1317                  (SYMBOL-MACROLET      identity)
1318                  (TAGBODY              p1-tagbody)
1319                  (THE                  p1-the)
1320                  (THROW                p1-throw)
1321                  (TRULY-THE            p1-truly-the)
1322                  (UNWIND-PROTECT       p1-unwind-protect)
1323                  (THREADS:SYNCHRONIZED-ON
1324                                        p1-threads-synchronized-on)
1325      (JVM::WITH-INLINE-CODE identity)))
1326    (install-p1-handler (%car pair) (%cadr pair))))
1327
1328(initialize-p1-handlers)
1329
1330(defun p1-compiland (compiland)
1331;;   (format t "p1-compiland name = ~S~%" (compiland-name compiland))
1332  (let ((form (compiland-lambda-expression compiland)))
1333    (aver (eq (car form) 'LAMBDA))
1334    (setf form (rewrite-lambda form))
1335    (process-optimization-declarations (cddr form))
1336
1337    (let* ((lambda-list (cadr form))
1338           (body (cddr form))
1339           (*visible-variables* *visible-variables*)
1340           (closure (make-closure `(lambda ,lambda-list nil) nil))
1341           (syms (sys::varlist closure))
1342           (vars nil)
1343           compiland-result)
1344      (dolist (sym syms)
1345        (let ((var (make-variable :name sym
1346                                  :special-p (special-variable-p sym))))
1347          (push var vars)
1348          (push var *all-variables*)
1349          (push var *visible-variables*)))
1350      (setf (compiland-arg-vars compiland) (nreverse vars))
1351      (let ((free-specials (process-declarations-for-vars body vars nil)))
1352        (setf (compiland-free-specials compiland) free-specials)
1353        (dolist (var free-specials)
1354          (push var *visible-variables*)))
1355      (setf compiland-result
1356            (list* 'LAMBDA lambda-list (p1-body body)))
1357      (setf (compiland-%single-valued-p compiland)
1358            (single-valued-p compiland-result))
1359      (setf (compiland-p1-result compiland)
1360            compiland-result))))
1361
1362(provide "COMPILER-PASS1")
Note: See TracBrowser for help on using the repository browser.