source: trunk/abcl/src/org/armedbear/lisp/compiler-pass1.lisp @ 14138

Last change on this file since 14138 was 14138, checked in by ehuelsmann, 9 years ago

Re #241: Fix cases

(compile nil '(lambda (&rest foo &aux x)))

and (compile nil '(lambda (&aux x &rest)))

Note: Since the other 2 cases mentioned in the ticket are still

open, this commit doesn't actually close it.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 56.6 KB
Line 
1;;; compiler-pass1.lisp
2;;;
3;;; Copyright (C) 2003-2008 Peter Graves
4;;; $Id: compiler-pass1.lisp 14138 2012-08-26 21:43:53Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package "JVM")
33
34(require "LOOP")
35(require "FORMAT")
36(require "CLOS")
37(require "PRINT-OBJECT")
38(require "COMPILER-TYPES")
39(require "KNOWN-FUNCTIONS")
40(require "KNOWN-SYMBOLS")
41(require "DUMP-FORM")
42(require "JAVA")
43
44
45(defun generate-inline-expansion (name lambda-list body
46                                  &optional (args nil args-p))
47  "Generates code that can be used to expand a named local function inline.
48It can work either per-function (no args provided) or per-call."
49  (if args-p
50      (multiple-value-bind
51            (body decls)
52          (parse-body body)
53        (expand-function-call-inline nil lambda-list
54                                     ;; the forms below get wrapped
55                                     ;; in a LET, making the decls
56                                     ;; part of the decls of the LET.
57                                     (copy-tree `(,@decls (block ,name ,@body)))
58                                     args))
59      (cond ((intersection lambda-list
60                           '(&optional &rest &key &allow-other-keys &aux)
61                           :test #'eq)
62             nil)
63            (t
64             (multiple-value-bind
65                   (body decls)
66                 (parse-body body)
67               (setf body (copy-tree body))
68               `(lambda ,lambda-list ,@decls
69                        (block ,name ,@body)))))))
70
71
72;;; Pass 1.
73
74(defun parse-lambda-list (lambda-list)
75  "Breaks the lambda list into the different elements, returning the values
76
77 required-vars
78 optional-vars
79 key-vars
80 key-p
81 rest-var
82 allow-other-keys-p
83 aux-vars
84 whole-var
85 env-var
86
87where each of the vars returned is a list with these elements:
88
89 var      - the actual variable name
90 initform - the init form if applicable; optional, keyword and aux vars
91 p-var    - variable indicating presence
92 keyword  - the keyword argument to match against
93
94"
95  (let ((remaining lambda-list)
96        (state :req)
97        req opt key rest whole env aux key-p allow-others-p)
98    (when (eq (car lambda-list) '&WHOLE)
99      (let ((var (second lambda-list)))
100        (when (memq var lambda-list-keywords)
101          (error 'program-error
102                 :format-control "Lambda list keyword ~A found where &WHOLE ~
103                                  variable expected in lambda list ~A."
104                 :format-arguments (list var lambda-list)))
105        (setf whole (list var))
106        (setf remaining (nthcdr 2 lambda-list))))
107    (dolist (arg remaining)
108      (case arg
109        (&optional (setf state :opt))
110        (&key (setf state :key
111                    key-p t))
112        (&rest (setf state :rest))
113        (&aux (setf state :aux))
114        (&allow-other-keys (setf state :none
115                                 allow-others-p t))
116        (&whole (setf state :whole))
117        (&environment (setf state :env))
118        (&whole
119         (error 'program-error
120                :format-control "&WHOLE must appear first in lambda list ~A."
121                :format-arguments (list lambda-list)))
122        (t
123         (case state
124           (:req (push (list arg) req))
125           (:rest (setf rest (list arg)
126                        state :none))
127           (:env (setf env (list arg)
128                       state :req))
129           (:none
130            (error "Invalid lambda list: argument found in :none state."))
131           (:opt
132            (cond
133              ((symbolp arg)
134               (push (list arg nil nil nil) opt))
135              ((consp arg)
136               (push (list (car arg) (cadr arg) (caddr arg)) opt))
137              (t
138               (error "Invalid state."))))
139           (:aux
140            (cond
141              ((symbolp arg)
142               (push (list arg nil nil nil) aux))
143              ((consp arg)
144               (push (list (car arg) (cadr arg) nil nil) aux))
145              (t
146               (error "Invalid :aux state."))))
147           (:key
148            (cond
149              ((symbolp arg)
150               (push (list arg nil nil (sys::keywordify arg)) key))
151              ((and (consp arg)
152                    (consp (car arg)))
153               (push (list (cadar arg) (cadr arg) (caddr arg) (caar arg)) key))
154              ((consp arg)
155               (push (list (car arg) (cadr arg) (caddr arg)
156                           (sys::keywordify (car arg))) key))
157              (t
158               (error "Invalid :key state."))))
159           (t (error "Invalid state found."))))))
160    (values
161     (nreverse req)
162     (nreverse opt)
163     (nreverse key)
164     key-p
165     rest allow-others-p
166     (nreverse aux) whole env)))
167
168(define-condition lambda-list-mismatch (error)
169  ((mismatch-type :reader lambda-list-mismatch-type :initarg :mismatch-type)))
170
171(defmacro push-argument-binding (var form temp-bindings bindings)
172  (let ((g (gensym)))
173    `(let ((,g (gensym (symbol-name '#:temp))))
174       (push (list ,g ,form) ,temp-bindings)
175       (push (list ,var ,g) ,bindings))))
176
177(defun match-lambda-list (parsed-lambda-list arguments)
178  (flet ((pop-required-argument ()
179           (if (null arguments)
180               (error 'lambda-list-mismatch :mismatch-type :too-few-arguments)
181               (pop arguments)))
182         (var (var-info) (car var-info))
183         (initform (var-info) (cadr var-info))
184         (p-var (var-info) (caddr var-info)))
185    (destructuring-bind (req opt key key-p rest allow-others-p aux whole env)
186        parsed-lambda-list
187      (declare (ignore whole env))
188      (let (req-bindings temp-bindings bindings ignorables)
189        ;;Required arguments.
190        (setf req-bindings
191              (loop :for (var) :in req
192                 :collect `(,var ,(pop-required-argument))))
193
194        ;;Optional arguments.
195        (when opt
196          (dolist (var-info opt)
197            (if arguments
198                (progn
199                  (push-argument-binding (var var-info) (pop arguments)
200                                         temp-bindings bindings)
201                  (when (p-var var-info)
202                    (push `(,(p-var var-info) t) bindings)))
203                (progn
204                  (push `(,(var var-info) ,(initform var-info)) bindings)
205                  (when (p-var var-info)
206                    (push `(,(p-var var-info) nil) bindings)))))
207          (setf bindings (nreverse bindings)))
208       
209        (unless (or key-p rest (null arguments))
210          (error 'lambda-list-mismatch :mismatch-type :too-many-arguments))
211
212        ;;Keyword and rest arguments.
213        (if key-p
214            (multiple-value-bind (kbindings ktemps kignor)
215                (match-keyword-and-rest-args 
216                 key allow-others-p rest arguments)
217              (setf bindings (append bindings kbindings)
218                    temp-bindings (append temp-bindings ktemps)
219                    ignorables (append kignor ignorables)))
220            (when rest
221              (let (rest-binding)
222                (push-argument-binding (var rest) `(list ,@arguments)
223                                       temp-bindings rest-binding)
224                (setf bindings (append bindings rest-binding)))))
225        ;;Aux parameters.
226        (when aux
227          (setf bindings
228                `(,@bindings
229                  ,@(loop
230                       :for var-info :in aux
231                       :collect `(,(var var-info) ,(initform var-info))))))
232        (values (append req-bindings temp-bindings bindings)
233                ignorables)))))
234
235(defun match-keyword-and-rest-args (key allow-others-p rest arguments)
236  (flet ((var (var-info) (car var-info))
237         (initform (var-info) (cadr var-info))
238         (p-var (var-info) (caddr var-info))
239         (keyword (var-info) (cadddr var-info)))
240    (when (oddp (list-length arguments))
241      (error 'lambda-list-mismatch
242             :mismatch-type :odd-number-of-keyword-arguments))
243   
244    (let (temp-bindings bindings other-keys-found-p ignorables already-seen
245          args)
246      ;;If necessary, make up a fake argument to hold :allow-other-keys,
247      ;;needed later. This also handles nicely:
248      ;;  3.4.1.4.1 Suppressing Keyword Argument Checking
249      ;;third statement.
250      (unless (find :allow-other-keys key :key #'keyword)
251        (let ((allow-other-keys-temp (gensym (symbol-name :allow-other-keys))))
252          (push allow-other-keys-temp ignorables)
253          (push (list allow-other-keys-temp nil nil :allow-other-keys) key)))
254     
255      ;;First, let's bind the keyword arguments that have been passed by
256      ;;the caller. If we encounter an unknown keyword, remember it.
257      ;;As per the above, :allow-other-keys will never be considered
258      ;;an unknown keyword.
259      (loop
260         :for var :in arguments :by #'cddr
261         :for value :in (cdr arguments) :by #'cddr
262         :do (let ((var-info (find var key :key #'keyword)))
263               (if (and var-info (not (member var already-seen)))
264                   ;;var is one of the declared keyword arguments
265                   (progn
266                     (push-argument-binding (var var-info) value
267                                            temp-bindings bindings)
268                     (when (p-var var-info)
269                       (push `(,(p-var var-info) t) bindings))
270                     (push var args)
271                     (push (var var-info) args)
272                     (push var already-seen))
273                   (let ((g (gensym)))
274                     (push `(,g ,value) temp-bindings)
275                     (push var args)
276                     (push g args)
277                     (push g ignorables)
278                     (unless var-info
279                       (setf other-keys-found-p t))))))
280     
281      ;;Then, let's bind those arguments that haven't been passed in
282      ;;to their default value, in declaration order.
283      (let (defaults)
284        (loop
285           :for var-info :in key
286           :do (unless (find (var var-info) bindings :key #'car)
287                 (push `(,(var var-info) ,(initform var-info)) defaults)
288                 (when (p-var var-info)
289                   (push `(,(p-var var-info) nil) defaults))))
290        (setf bindings (append (nreverse defaults) bindings)))
291     
292      ;;If necessary, check for unrecognized keyword arguments.
293      (when (and other-keys-found-p (not allow-others-p))
294        (if (loop
295               :for var :in arguments :by #'cddr
296               :if (eq var :allow-other-keys)
297               :do (return t))
298            ;;We know that :allow-other-keys has been passed, so we
299            ;;can access the binding for it and be sure to get the
300            ;;value passed by the user and not an initform.
301            (let* ((arg (var (find :allow-other-keys key :key #'keyword)))
302                   (binding (find arg bindings :key #'car))
303                   (form (cadr binding)))
304              (if (constantp form)
305                  (unless (eval form)
306                    (error 'lambda-list-mismatch
307                           :mismatch-type :unknown-keyword))
308                  (setf (cadr binding)
309                        `(or ,(cadr binding)
310                             (error 'program-error
311                                    "Unrecognized keyword argument")))))
312            ;;TODO: it would be nice to report *which* keyword
313            ;;is unknown
314            (error 'lambda-list-mismatch :mismatch-type :unknown-keyword)))
315      (when rest
316        (setf bindings (append bindings `((,(var rest) (list ,@(nreverse args)))))))
317      (values bindings temp-bindings ignorables))))
318
319#||test for the above
320(handler-case
321    (let ((lambda-list
322           (multiple-value-list
323            (jvm::parse-lambda-list
324             '(a b &optional (c 42) &rest foo &key (bar c) baz ((kaz kuz) bar))))))
325      (jvm::match-lambda-list
326       lambda-list
327       '((print 1) 3 (print 32) :bar 2)))
328  (jvm::lambda-list-mismatch (x) (jvm::lambda-list-mismatch-type x)))
329||#
330
331(defun expand-function-call-inline (form lambda-list body args)
332  (handler-case
333      (multiple-value-bind (bindings ignorables)
334          (match-lambda-list (multiple-value-list
335                              (parse-lambda-list lambda-list))
336                             args)
337        `(let* ,bindings
338           ,@(when ignorables
339                   `((declare (ignorable ,@ignorables))))
340           ,@body))
341    (lambda-list-mismatch (x)
342      (compiler-warn "Invalid function call: ~S (mismatch type: ~A)"
343                     form (lambda-list-mismatch-type x))
344      form)))
345
346;; Returns a list of declared free specials, if any are found.
347(declaim (ftype (function (list list block-node) list)
348                process-declarations-for-vars))
349(defun process-declarations-for-vars (body variables block)
350  (let ((free-specials '()))
351    (dolist (subform body)
352      (unless (and (consp subform) (eq (%car subform) 'DECLARE))
353        (return))
354      (let ((decls (%cdr subform)))
355        (dolist (decl decls)
356          (case (car decl)
357            ((DYNAMIC-EXTENT FTYPE INLINE NOTINLINE OPTIMIZE)
358             ;; Nothing to do here.
359             )
360            ((IGNORE IGNORABLE)
361             (process-ignore/ignorable (%car decl) (%cdr decl) variables))
362            (SPECIAL
363             (dolist (name (%cdr decl))
364               (let ((variable (find-variable name variables)))
365                 (cond ((and variable
366                             ;; see comment below (and DO-ALL-SYMBOLS.11)
367                             (eq (variable-compiland variable)
368                                 *current-compiland*))
369                        (setf (variable-special-p variable) t))
370                       (t
371                        (dformat t "adding free special ~S~%" name)
372                        (push (make-variable :name name :special-p t
373                                             :block block)
374                              free-specials))))))
375            (TYPE
376             (dolist (name (cddr decl))
377               (let ((variable (find-variable name variables)))
378                 (when (and variable
379                            ;; Don't apply a declaration in a local function to
380                            ;; a variable defined in its parent. For an example,
381                            ;; see CREATE-GREEDY-NO-ZERO-MATCHER in cl-ppcre.
382                            ;; FIXME suboptimal, since we ignore the declaration
383                            (eq (variable-compiland variable)
384                                *current-compiland*))
385                   (setf (variable-declared-type variable)
386                         (make-compiler-type (cadr decl)))))))
387            (t
388             (dolist (name (cdr decl))
389               (let ((variable (find-variable name variables)))
390                 (when variable
391                   (setf (variable-declared-type variable)
392                         (make-compiler-type (%car decl)))))))))))
393    free-specials))
394
395(defun check-name (name)
396  ;; FIXME Currently this error is signalled by the precompiler.
397  (unless (symbolp name)
398    (compiler-error "The variable ~S is not a symbol." name))
399  (when (constantp name)
400    (compiler-error "The name of the variable ~S is already in use to name a constant." name))
401  name)
402
403(declaim (ftype (function (t) t) p1-body))
404(defun p1-body (body)
405  (declare (optimize speed))
406  (let ((tail body))
407    (loop
408      (when (endp tail)
409        (return))
410      (setf (car tail) (p1 (%car tail)))
411      (setf tail (%cdr tail))))
412  body)
413
414(defknown p1-default (t) t)
415(declaim (inline p1-default))
416(defun p1-default (form)
417  (setf (cdr form) (p1-body (cdr form)))
418  form)
419
420(defmacro p1-let/let*-vars
421    (block varlist variables-var var body1 body2)
422  (let ((varspec (gensym))
423        (initform (gensym))
424        (name (gensym)))
425    `(let ((,variables-var ()))
426       (dolist (,varspec ,varlist)
427         (cond ((consp ,varspec)
428                ;; Even though the precompiler already signals this
429                ;; error, double checking can't hurt; after all, we're
430                ;; also rewriting &AUX into LET* bindings.
431                (unless (<= 1 (length ,varspec) 2)
432                  (compiler-error "The LET/LET* binding specification ~S is invalid."
433                                  ,varspec))
434                (let* ((,name (%car ,varspec))
435                       (,initform (p1 (%cadr ,varspec)))
436                       (,var (make-variable :name (check-name ,name)
437                                            :initform ,initform
438                                            :block ,block)))
439                  (when (neq ,initform (cadr ,varspec))
440                    (setf (cadr ,varspec) ,initform))
441                  (push ,var ,variables-var)
442                  ,@body1))
443               (t
444                (let ((,var (make-variable :name (check-name ,varspec)
445                                           :block ,block)))
446                  (push ,var ,variables-var)
447                  ,@body1))))
448       ,@body2)))
449
450(defknown p1-let-vars (t) t)
451(defun p1-let-vars (block varlist)
452  (p1-let/let*-vars block
453   varlist vars var
454   ()
455   ((setf vars (nreverse vars))
456    (dolist (variable vars)
457      (push variable *visible-variables*)
458      (push variable *all-variables*))
459    vars)))
460
461(defknown p1-let*-vars (t) t)
462(defun p1-let*-vars (block varlist)
463  (p1-let/let*-vars block
464   varlist vars var
465   ((push var *visible-variables*)
466    (push var *all-variables*))
467   ((nreverse vars))))
468
469(defun p1-let/let* (form)
470  (declare (type cons form))
471  (let* ((*visible-variables* *visible-variables*)
472         (block (make-let/let*-node))
473         (*block* block)
474         (op (%car form))
475         (varlist (cadr form))
476         (body (cddr form)))
477    (aver (or (eq op 'LET) (eq op 'LET*)))
478    (when (eq op 'LET)
479      ;; Convert to LET* if possible.
480      (if (null (cdr varlist))
481          (setf op 'LET*)
482          (dolist (varspec varlist (setf op 'LET*))
483            (or (atom varspec)
484                (constantp (cadr varspec))
485                (eq (car varspec) (cadr varspec))
486                (return)))))
487    (let ((vars (if (eq op 'LET)
488                    (p1-let-vars block varlist)
489                    (p1-let*-vars block varlist))))
490      ;; Check for globally declared specials.
491      (dolist (variable vars)
492        (when (special-variable-p (variable-name variable))
493          (setf (variable-special-p variable) t
494                (let-environment-register block) t)))
495      ;; For processing declarations, we want to walk the variable list from
496      ;; last to first, since declarations apply to the last-defined variable
497      ;; with the specified name.
498      (setf (let-free-specials block)
499            (process-declarations-for-vars body (reverse vars) block))
500      (setf (let-vars block) vars)
501      ;; Make free specials visible.
502      (dolist (variable (let-free-specials block))
503        (push variable *visible-variables*)))
504    (with-saved-compiler-policy
505      (process-optimization-declarations body)
506      (let ((*blocks* (cons block *blocks*)))
507        (setf body (p1-body body)))
508      (setf (let-form block) (list* op varlist body))
509      block)))
510
511(defun p1-locally (form)
512  (let* ((*visible-variables* *visible-variables*)
513         (block (make-locally-node))
514         (*block* block)
515         (free-specials (process-declarations-for-vars (cdr form) nil block)))
516    (setf (locally-free-specials block) free-specials)
517    (dolist (special free-specials)
518;;       (format t "p1-locally ~S is special~%" name)
519      (push special *visible-variables*))
520    (let ((*blocks* (cons block *blocks*)))
521      (with-saved-compiler-policy
522        (process-optimization-declarations (cdr form))
523        (setf (locally-form block)
524              (list* 'LOCALLY (p1-body (cdr form))))
525        block))))
526
527(defknown p1-m-v-b (t) t)
528(defun p1-m-v-b (form)
529  (when (= (length (cadr form)) 1)
530    (let ((new-form `(let* ((,(caadr form) ,(caddr form))) ,@(cdddr form))))
531      (return-from p1-m-v-b (p1-let/let* new-form))))
532  (let* ((*visible-variables* *visible-variables*)
533         (block (make-m-v-b-node))
534         (*block* block)
535         (varlist (cadr form))
536         ;; Process the values-form first. ("The scopes of the name binding and
537         ;; declarations do not include the values-form.")
538         (values-form (p1 (caddr form)))
539         (*blocks* (cons block *blocks*))
540         (body (cdddr form)))
541    (let ((vars ()))
542      (dolist (symbol varlist)
543        (let ((var (make-variable :name symbol :block block)))
544          (push var vars)
545          (push var *visible-variables*)
546          (push var *all-variables*)))
547      ;; Check for globally declared specials.
548      (dolist (variable vars)
549        (when (special-variable-p (variable-name variable))
550          (setf (variable-special-p variable) t
551                (m-v-b-environment-register block) t)))
552      (setf (m-v-b-free-specials block)
553            (process-declarations-for-vars body vars block))
554      (dolist (special (m-v-b-free-specials block))
555        (push special *visible-variables*))
556      (setf (m-v-b-vars block) (nreverse vars)))
557    (with-saved-compiler-policy
558      (process-optimization-declarations body)
559      (setf body (p1-body body))
560      (setf (m-v-b-form block)
561            (list* 'MULTIPLE-VALUE-BIND varlist values-form body))
562      block)))
563
564(defun p1-block (form)
565  (let* ((block (make-block-node (cadr form)))
566         (*block* block)
567         (*blocks* (cons block *blocks*)))
568    (setf (cddr form) (p1-body (cddr form)))
569    (setf (block-form block) form)
570    (when (block-non-local-return-p block)
571      ;; Add a closure variable for RETURN-FROM to use
572      (push (setf (block-id-variable block)
573                  (make-variable :name (gensym)
574                                 :block block
575                                 :used-non-locally-p t))
576            *all-variables*))
577    block))
578
579(defun p1-catch (form)
580  (let* ((tag (p1 (cadr form)))
581         (body (cddr form))
582         (block (make-catch-node))
583         (*block* block)
584         ;; our subform processors need to know
585         ;; they're enclosed in a CATCH block
586         (*blocks* (cons block *blocks*))
587         (result '()))
588    (dolist (subform body)
589      (let ((op (and (consp subform) (%car subform))))
590        (push (p1 subform) result)
591        (when (memq op '(GO RETURN-FROM THROW))
592          (return))))
593    (setf result (nreverse result))
594    (when (and (null (cdr result))
595               (consp (car result))
596               (eq (caar result) 'GO))
597      (return-from p1-catch (car result)))
598    (push tag result)
599    (push 'CATCH result)
600    (setf (catch-form block) result)
601    block))
602
603(defun p1-threads-synchronized-on (form)
604  (let* ((synchronized-object (p1 (cadr form)))
605         (body (cddr form))
606         (block (make-synchronized-node))
607         (*block* block)
608         (*blocks* (cons block *blocks*))
609         result)
610    (dolist (subform body)
611      (let ((op (and (consp subform) (%car subform))))
612        (push (p1 subform) result)
613        (when (memq op '(GO RETURN-FROM THROW))
614          (return))))
615    (setf (synchronized-form block)
616          (list* 'threads:synchronized-on synchronized-object
617                 (nreverse result)))
618    block))
619
620(defun p1-unwind-protect (form)
621  (if (= (length form) 2)
622      (p1 (second form)) ; No cleanup forms: (unwind-protect (...)) => (...)
623
624      ;; in order to compile the cleanup forms twice (see
625      ;; p2-unwind-protect-node), we need to p1 them twice; p1 outcomes
626      ;; can be compiled (in the same compiland?) only once.
627      ;;
628      ;; However, p1 transforms the forms being processed, so, we
629      ;; need to copy the forms to create a second copy.
630      (let* ((block (make-unwind-protect-node))
631             (*block* block)
632             ;; a bit of jumping through hoops...
633             (unwinding-forms (p1-body (copy-tree (cddr form))))
634             (unprotected-forms (p1-body (cddr form)))
635             ;; ... because only the protected form is
636             ;; protected by the UNWIND-PROTECT block
637             (*blocks* (cons block *blocks*))
638             (protected-form (p1 (cadr form))))
639        (setf (unwind-protect-form block)
640              `(unwind-protect ,protected-form
641                 (progn ,@unwinding-forms)
642                 ,@unprotected-forms))
643        block)))
644
645(defknown p1-return-from (t) t)
646(defun p1-return-from (form)
647  (let* ((name (second form))
648         (block (find-block name))
649         non-local-p)
650    (when (null block)
651      (compiler-error "RETURN-FROM ~S: no block named ~S is currently visible."
652                      name name))
653    (dformat t "p1-return-from block = ~S~%" (block-name block))
654    (cond ((eq (block-compiland block) *current-compiland*)
655           ;; Local case. If the RETURN is nested inside an UNWIND-PROTECT
656           ;; which is inside the block we're returning from, we'll do a non-
657           ;; local return anyway so that UNWIND-PROTECT can catch it and run
658           ;; its cleanup forms.
659           ;;(dformat t "*blocks* = ~S~%" (mapcar #'node-name *blocks*))
660           (let ((protected (enclosed-by-protected-block-p block)))
661             (dformat t "p1-return-from protected = ~S~%" protected)
662             (if protected
663                 (setf (block-non-local-return-p block) t
664                       non-local-p t)
665                 ;; non-local GO's ensure environment restoration
666                 ;; find out about this local GO
667                 (when (null (block-needs-environment-restoration block))
668                   (setf (block-needs-environment-restoration block)
669                         (enclosed-by-environment-setting-block-p block))))))
670          (t
671           (setf (block-non-local-return-p block) t
672                 non-local-p t)))
673    (when (block-non-local-return-p block)
674      (dformat t "non-local return from block ~S~%" (block-name block)))
675    (let ((value-form (p1 (caddr form))))
676      (push value-form (block-return-value-forms block))
677      (make-jump-node (list 'RETURN-FROM name value-form)
678                      non-local-p block))))
679
680(defun p1-tagbody (form)
681  (let* ((block (make-tagbody-node))
682         (*block* block)
683         (*blocks* (cons block *blocks*))
684         (*visible-tags* *visible-tags*)
685         (local-tags '())
686         (body (cdr form)))
687    ;; Make all the tags visible before processing the body forms.
688    (dolist (subform body)
689      (when (or (symbolp subform) (integerp subform))
690        (let* ((tag (make-tag :name subform :label (gensym) :block block)))
691          (push tag local-tags)
692          (push tag *visible-tags*))))
693    (let ((new-body '())
694          (live t))
695      (dolist (subform body)
696        (cond ((or (symbolp subform) (integerp subform))
697               (push subform new-body)
698               (push (find subform local-tags :key #'tag-name :test #'eql)
699                     (tagbody-tags block))
700               (setf live t))
701              ((not live)
702               ;; Nothing to do.
703               )
704              (t
705               (when (and (consp subform)
706                          (memq (%car subform) '(GO RETURN-FROM THROW)))
707                 ;; Subsequent subforms are unreachable until we see another
708                 ;; tag.
709                 (setf live nil))
710               (push (p1 subform) new-body))))
711      (setf (tagbody-form block) (list* 'TAGBODY (nreverse new-body))))
712    (when (some #'tag-used-non-locally (tagbody-tags block))
713      (push (setf (tagbody-id-variable block)
714                  (make-variable :name (gensym)
715                                 :block block
716                                 :used-non-locally-p t))
717            *all-variables*))
718    block))
719
720(defknown p1-go (t) t)
721(defun p1-go (form)
722  (let* ((name (cadr form))
723         (tag (find-tag name)))
724    (unless tag
725      (error "p1-go: tag not found: ~S" name))
726    (setf (tag-used tag) t)
727    (let ((tag-block (tag-block tag))
728          non-local-p)
729      (cond ((eq (tag-compiland tag) *current-compiland*)
730             ;; Does the GO leave an enclosing UNWIND-PROTECT or CATCH?
731             (if (enclosed-by-protected-block-p tag-block)
732                 (setf (tagbody-non-local-go-p tag-block) t
733                       (tag-used-non-locally tag) t
734                       non-local-p t)
735                 ;; non-local GO's ensure environment restoration
736                 ;; find out about this local GO
737                 (when (null (tagbody-needs-environment-restoration tag-block))
738                   (setf (tagbody-needs-environment-restoration tag-block)
739                         (enclosed-by-environment-setting-block-p tag-block)))))
740            (t
741             (setf (tagbody-non-local-go-p tag-block) t
742                   (tag-used-non-locally tag) t
743                   non-local-p t)))
744      (make-jump-node form non-local-p tag-block tag))))
745
746(defun split-decls (forms specific-vars)
747  (let ((other-decls nil)
748        (specific-decls nil))
749    (dolist (form forms)
750      (unless (and (consp form) (eq (car form) 'DECLARE)) ; shouldn't happen
751        (return))
752      (dolist (decl (cdr form))
753        (case (car decl)
754          ((OPTIMIZE DECLARATION DYNAMIC-EXTENT FTYPE INLINE NOTINLINE)
755           (push (list 'DECLARE decl) other-decls))
756          (SPECIAL
757           (dolist (name (cdr decl))
758             (if (memq name specific-vars)
759                 (push `(DECLARE (SPECIAL ,name)) specific-decls)
760                 (push `(DECLARE (SPECIAL ,name)) other-decls))))
761          (TYPE
762           (dolist (name (cddr decl))
763             (if (memq name specific-vars)
764                 (push `(DECLARE (TYPE ,(cadr decl) ,name)) specific-decls)
765                 (push `(DECLARE (TYPE ,(cadr decl) ,name)) other-decls))))
766          (t
767           (dolist (name (cdr decl))
768             (if (memq name specific-vars)
769                 (push `(DECLARE (,(car decl) ,name)) specific-decls)
770                 (push `(DECLARE (,(car decl) ,name)) other-decls)))))))
771    (values (nreverse other-decls)
772            (nreverse specific-decls))))
773
774(defun lambda-list-names (lambda-list)
775  "Returns a list of variable names extracted from `lambda-list'."
776  (multiple-value-bind
777        (req opt key key-p rest allow-key-p aux whole env)
778      (parse-lambda-list lambda-list)
779    (declare (ignore key-p allow-key-p))
780    (mapcan (lambda (x)
781              (mapcar #'first x))
782            (list req opt key aux (list rest) (list whole) (list env)))))
783
784(defun lambda-list-keyword-p (x)
785  (memq x lambda-list-keywords))
786
787(defun rewrite-aux-vars (form)
788  (let* ((lambda-list (cadr form))
789         (aux-p (memq '&AUX lambda-list))
790         (post-aux-&environment (memq '&ENVIRONMENT aux-p))
791         (lets (ldiff (cdr aux-p) post-aux-&environment)) ; strip trailing &environment
792         aux-vars)
793    (unless aux-p
794      ;; no rewriting required
795      (return-from rewrite-aux-vars form))
796    (dolist (var lets)
797      (when (lambda-list-keyword-p var)
798        (error 'program-error
799               :format-control "Lambda list keyword ~A not allowed after &AUX in ~A."
800               :format-arguments (list var lambda-list))))
801    (multiple-value-bind (body decls)
802        (parse-body (cddr form))
803      (dolist (form lets)
804        (cond ((consp form)
805               (push (car form) aux-vars))
806              (t
807               (push form aux-vars))))
808      (setf lambda-list
809            (append (subseq lambda-list 0 (position '&AUX lambda-list))
810                    post-aux-&environment))
811      (multiple-value-bind (let-decls lambda-decls)
812          (split-decls decls (lambda-list-names lambda-list))
813        `(lambda ,lambda-list
814           ,@lambda-decls
815           (let* ,lets
816             ,@let-decls
817             ,@body))))))
818
819(defun rewrite-lambda (form)
820  (setf form (rewrite-aux-vars form))
821  (let* ((lambda-list (cadr form)))
822    (if (not (or (memq '&optional lambda-list)
823                 (memq '&key lambda-list)))
824        ;; no need to rewrite: no arguments with possible initforms anyway
825        form
826      (multiple-value-bind (body decls doc)
827          (parse-body (cddr form))
828        (let (state let-bindings new-lambda-list
829                    (non-constants 0))
830          (do* ((vars lambda-list (cdr vars))
831                (var (car vars) (car vars)))
832               ((endp vars))
833            (push (car vars) new-lambda-list)
834            (let ((replacement (gensym)))
835              (flet ((parse-compound-argument (arg)
836                       "Returns the values NAME, KEYWORD, INITFORM, INITFORM-P,
837   SUPPLIED-P and SUPPLIED-P-P assuming ARG is a compound argument."
838                       (destructuring-bind
839                             (name &optional (initform nil initform-supplied-p)
840                                   (supplied-p nil supplied-p-supplied-p))
841                           (if (listp arg) arg (list arg))
842                         (if (listp name)
843                             (values (cadr name) (car name)
844                                     initform initform-supplied-p
845                                     supplied-p supplied-p-supplied-p)
846                             (values name (make-keyword name)
847                                     initform initform-supplied-p
848                                     supplied-p supplied-p-supplied-p)))))
849                (case var
850                  (&optional (setf state :optional))
851                  (&key (setf state :key))
852                  ((&whole &environment &rest &body &allow-other-keys)
853                   ;; do nothing special
854                   )
855                  (t
856                   (cond
857                     ((atom var)
858                      (setf (car new-lambda-list)
859                            (if (eq state :key)
860                                (list (list (make-keyword var) replacement))
861                                replacement))
862                      (push (list var replacement) let-bindings))
863                     ((constantp (second var))
864                      ;; so, we must have a consp-type var we're looking at
865                      ;; and it has a constantp initform
866                      (multiple-value-bind
867                            (name keyword initform initform-supplied-p
868                                  supplied-p supplied-p-supplied-p)
869                          (parse-compound-argument var)
870                        (let ((var-form (if (eq state :key)
871                                            (list keyword replacement)
872                                            replacement))
873                              (supplied-p-replacement (gensym)))
874                          (setf (car new-lambda-list)
875                                (cond
876                                  ((not initform-supplied-p)
877                                   (list var-form))
878                                  ((not supplied-p-supplied-p)
879                                   (list var-form initform))
880                                  (t
881                                   (list var-form initform
882                                         supplied-p-replacement))))
883                          (push (list name replacement) let-bindings)
884                          ;; if there was a 'supplied-p' variable, it might
885                          ;; be used in the declarations. Since those will be
886                          ;; moved below the LET* block, we need to move the
887                          ;; supplied-p parameter too.
888                          (when supplied-p-supplied-p
889                            (push (list supplied-p supplied-p-replacement)
890                                  let-bindings)))))
891                     (t
892                      (incf non-constants)
893                      ;; this is either a keyword or an optional argument
894                      ;; with a non-constantp initform
895                      (multiple-value-bind
896                            (name keyword initform initform-supplied-p
897                                  supplied-p supplied-p-supplied-p)
898                          (parse-compound-argument var)
899                        (declare (ignore initform-supplied-p))
900                        (let ((var-form (if (eq state :key)
901                                            (list keyword replacement)
902                                            replacement))
903                              (supplied-p-replacement (gensym)))
904                          (setf (car new-lambda-list)
905                                (list var-form nil supplied-p-replacement))
906                          (push (list name `(if ,supplied-p-replacement
907                                                ,replacement ,initform))
908                                let-bindings)
909                          (when supplied-p-supplied-p
910                            (push (list supplied-p supplied-p-replacement)
911                                  let-bindings)))))))))))
912          (if (zerop non-constants)
913              ;; there was no reason to rewrite...
914              form
915              (let ((rv
916                     `(lambda ,(nreverse new-lambda-list)
917                        ,@(when doc (list doc))
918                        (let* ,(nreverse let-bindings)
919                          ,@decls ,@body))))
920                rv)))))))
921
922(defun validate-function-name (name)
923  (unless (or (symbolp name) (setf-function-name-p name))
924    (compiler-error "~S is not a valid function name." name))
925  name)
926
927(defun construct-flet/labels-function (definition)
928  (let* ((name (car definition))
929         (block-name (fdefinition-block-name (validate-function-name name)))
930         (lambda-list (cadr definition))
931         (compiland (make-compiland :name name :parent *current-compiland*))
932         (local-function (make-local-function :name name :compiland compiland)))
933    (push local-function (compiland-children *current-compiland*))
934    (multiple-value-bind
935          (body decls)
936        (parse-body (cddr definition))
937      (setf (local-function-definition local-function)
938            (copy-tree (cdr definition)))
939      (setf (compiland-lambda-expression compiland)
940            (rewrite-lambda `(lambda ,lambda-list
941                               ,@decls
942                               (block ,block-name
943                                 ,@body)))))
944    local-function))
945
946(defun p1-flet (form)
947  (let* ((local-functions
948          (mapcar #'(lambda (definition)
949                      (construct-flet/labels-function definition))
950                  (cadr form)))
951         (*local-functions* *local-functions*))
952    (dolist (local-function local-functions)
953      (p1-compiland (local-function-compiland local-function)))
954    (dolist (local-function local-functions)
955      (push local-function *local-functions*))
956    (with-saved-compiler-policy
957      (process-optimization-declarations (cddr form))
958      (let* ((block (make-flet-node))
959             (*block* block)
960             (*blocks* (cons block *blocks*))
961             (body (cddr form))
962             (*visible-variables* *visible-variables*))
963        (setf (flet-free-specials block)
964              (process-declarations-for-vars body nil block))
965        (dolist (special (flet-free-specials block))
966          (push special *visible-variables*))
967        (setf body (p1-body body) ;; affects the outcome of references-needed-p
968              (flet-form block)
969              (list* (car form)
970                     (remove-if #'(lambda (fn)
971                                    (and (inline-p (local-function-name fn))
972                                         (not (local-function-references-needed-p fn))))
973                                local-functions)
974                     body))
975        block))))
976
977
978(defun p1-labels (form)
979  (let* ((local-functions
980          (mapcar #'(lambda (definition)
981                      (construct-flet/labels-function definition))
982                  (cadr form)))
983         (*local-functions* *local-functions*)
984         (*visible-variables* *visible-variables*))
985    (dolist (local-function local-functions)
986      (push local-function *local-functions*))
987    (dolist (local-function local-functions)
988      (p1-compiland (local-function-compiland local-function)))
989    (let* ((block (make-labels-node))
990           (*block* block)
991           (*blocks* (cons block *blocks*))
992           (body (cddr form))
993           (*visible-variables* *visible-variables*))
994      (setf (labels-free-specials block)
995            (process-declarations-for-vars body nil block))
996      (dolist (special (labels-free-specials block))
997        (push special *visible-variables*))
998      (with-saved-compiler-policy
999        (process-optimization-declarations (cddr form))
1000        (setf (labels-form block)
1001              (list* (car form) local-functions (p1-body (cddr form))))
1002        block))))
1003
1004(defknown p1-funcall (t) t)
1005(defun p1-funcall (form)
1006  (unless (> (length form) 1)
1007    (compiler-warn "Wrong number of arguments for ~A." (car form))
1008    (return-from p1-funcall form))
1009  (let ((function-form (%cadr form)))
1010    (when (and (consp function-form)
1011               (eq (%car function-form) 'FUNCTION))
1012      (let ((name (%cadr function-form)))
1013        (let ((source-transform (source-transform name)))
1014          (when source-transform
1015            (let ((new-form (expand-source-transform (list* name (cddr form)))))
1016              (return-from p1-funcall (p1 new-form)))
1017            )))))
1018  ;; Otherwise...
1019  (p1-function-call form))
1020
1021(defun p1-function (form)
1022  (let ((form (copy-tree form))
1023        local-function)
1024    (cond ((and (consp (cadr form))
1025                (or (eq (caadr form) 'LAMBDA)
1026                    (eq (caadr form) 'NAMED-LAMBDA)))
1027           (let* ((named-lambda-p (eq (caadr form) 'NAMED-LAMBDA))
1028                  (named-lambda-form (when named-lambda-p
1029                                       (cadr form)))
1030                  (name (when named-lambda-p
1031                          (cadr named-lambda-form)))
1032                  (lambda-form (if named-lambda-p
1033                                   (cons 'LAMBDA (cddr named-lambda-form))
1034                                   (cadr form)))
1035                  (lambda-list (cadr lambda-form))
1036                  (body (cddr lambda-form))
1037                  (compiland (make-compiland :name (if named-lambda-p
1038                                                       name (gensym "ANONYMOUS-LAMBDA-"))
1039                                             :lambda-expression lambda-form
1040                                             :parent *current-compiland*))
1041                  (local-function (make-local-function :compiland compiland)))
1042             (push local-function (compiland-children *current-compiland*))
1043             (multiple-value-bind (body decls)
1044                 (parse-body body)
1045               (setf (compiland-lambda-expression compiland)
1046                     ;; if there still was a doc-string present, remove it
1047                     (rewrite-lambda
1048                      `(lambda ,lambda-list ,@decls ,@body)))
1049               (let ((*visible-variables* *visible-variables*)
1050                     (*current-compiland* compiland))
1051                 (p1-compiland compiland)))
1052             (list 'FUNCTION local-function)))
1053          ((setf local-function (find-local-function (cadr form)))
1054           (dformat "p1-function local function ~S~%" (cadr form))
1055           ;;we found out that the function needs a reference
1056           (setf (local-function-references-needed-p local-function) t)
1057           form)
1058          (t
1059           form))))
1060
1061(defun p1-lambda (form)
1062  (setf form (rewrite-lambda form))
1063  (let* ((lambda-list (cadr form)))
1064    (when (or (memq '&optional lambda-list)
1065              (memq '&key lambda-list))
1066      (let ((state nil))
1067        (dolist (arg lambda-list)
1068          (cond ((memq arg lambda-list-keywords)
1069                 (setf state arg))
1070                ((memq state '(&optional &key))
1071                 (when (and (consp arg)
1072                            (not (constantp (second arg))))
1073                   (compiler-unsupported
1074                    "P1-LAMBDA: can't handle optional argument with non-constant initform.")))))))
1075    (p1-function (list 'FUNCTION form))))
1076
1077(defun p1-eval-when (form)
1078  (list* (car form) (cadr form) (mapcar #'p1 (cddr form))))
1079
1080(defknown p1-progv (t) t)
1081(defun p1-progv (form)
1082  ;; We've already checked argument count in PRECOMPILE-PROGV.
1083  (let* ((symbols-form (p1 (cadr form)))
1084         (values-form (p1 (caddr form)))
1085         (block (make-progv-node))
1086         (*block* block)
1087         (*blocks* (cons block *blocks*))
1088         (body (cdddr form)))
1089;;  The (commented out) block below means to detect compile-time
1090;;  enumeration of bindings to be created (a quoted form in the symbols
1091;;  position).
1092;;    (when (and (quoted-form-p symbols-form)
1093;;               (listp (second symbols-form)))
1094;;      (dolist (name (second symbols-form))
1095;;        (let ((variable (make-variable :name name :special-p t)))
1096;;          (push
1097    (setf (progv-environment-register block) t
1098          (progv-form block)
1099          `(progv ,symbols-form ,values-form ,@(p1-body body)))
1100    block))
1101
1102(defun p1-quote (form)
1103  (unless (= (length form) 2)
1104    (compiler-error "Wrong number of arguments for special operator ~A (expected 1, but received ~D)."
1105                    'QUOTE
1106                    (1- (length form))))
1107  (let ((arg (%cadr form)))
1108    (if (or (numberp arg) (characterp arg))
1109        arg
1110        form)))
1111
1112(defun p1-setq (form)
1113  (unless (= (length form) 3)
1114    (error "Too many arguments for SETQ."))
1115  (let ((arg1 (%cadr form))
1116        (arg2 (%caddr form)))
1117    (let ((variable (find-visible-variable arg1)))
1118      (if variable
1119          (progn
1120            (when (variable-ignore-p variable)
1121              (compiler-style-warn
1122               "Variable ~S is assigned even though it was declared to be ignored."
1123               (variable-name variable)))
1124            (incf (variable-writes variable))
1125            (cond ((eq (variable-compiland variable) *current-compiland*)
1126                   (dformat t "p1-setq: write ~S~%" arg1))
1127                  (t
1128                   (dformat t "p1-setq: non-local write ~S~%" arg1)
1129                   (setf (variable-used-non-locally-p variable) t))))
1130          (dformat t "p1-setq: unknown variable ~S~%" arg1)))
1131    (list 'SETQ arg1 (p1 arg2))))
1132
1133(defun p1-the (form)
1134  (unless (= (length form) 3)
1135    (compiler-error "Wrong number of arguments for special operator ~A (expected 2, but received ~D)."
1136                    'THE
1137                    (1- (length form))))
1138  (let ((type (%cadr form))
1139        (expr (%caddr form)))
1140    (cond ((and (listp type) (eq (car type) 'VALUES))
1141           ;; FIXME
1142           (p1 expr))
1143          ((= *safety* 3)
1144           (let* ((sym (gensym))
1145                  (new-expr `(let ((,sym ,expr))
1146                               (require-type ,sym ',type)
1147                               ,sym)))
1148             (p1 new-expr)))
1149          ((and (<= 1 *safety* 2) ;; at safety 1 or 2 check relatively
1150                (symbolp type))   ;; simple types (those specified by a single symbol)
1151           (let* ((sym (gensym))
1152                  (new-expr `(let ((,sym ,expr))
1153                               (require-type ,sym ',type)
1154                               ,sym)))
1155             (p1 new-expr)))
1156          (t
1157           (list 'THE type (p1 expr))))))
1158
1159(defun p1-truly-the (form)
1160  (unless (= (length form) 3)
1161    (compiler-error "Wrong number of arguments for special operator ~A (expected 2, but received ~D)."
1162                    'TRULY-THE
1163                    (1- (length form))))
1164  (list 'TRULY-THE (%cadr form) (p1 (%caddr form))))
1165
1166(defknown p1-throw (t) t)
1167(defun p1-throw (form)
1168  (list* 'THROW (mapcar #'p1 (cdr form))))
1169
1170(defknown rewrite-function-call (t) t)
1171(defun rewrite-function-call (form)
1172  (let ((op (car form)) (args (cdr form)))
1173    (cond
1174      ((and (eq op 'funcall) (listp (car args)) (eq (caar args) 'lambda))
1175       ;;(funcall (lambda (...) ...) ...)
1176       (let ((op (car args)) (args (cdr args)))
1177         (expand-function-call-inline form (cadr op) (copy-tree (cddr op))
1178                                      args)))
1179      ((and (listp op) (eq (car op) 'lambda))
1180       ;;((lambda (...) ...) ...)
1181       (expand-function-call-inline form (cadr op) (copy-tree (cddr op)) args))
1182      (t form))))
1183
1184(defknown p1-function-call (t) t)
1185(defun p1-function-call (form)
1186  (let ((new-form (rewrite-function-call form)))
1187    (when (neq new-form form)
1188      (return-from p1-function-call (p1 new-form))))
1189  (let* ((op (car form))
1190         (local-function (find-local-function op)))
1191    (when local-function
1192      (when (and *enable-inline-expansion* (inline-p op)
1193                 (local-function-definition local-function))
1194        (let* ((definition (local-function-definition local-function))
1195               (lambda-list (car definition))
1196               (body (cdr definition))
1197               (expansion (generate-inline-expansion op lambda-list body
1198                                                     (cdr form))))
1199          (when expansion
1200            (let ((explain *explain*))
1201              (when (and explain (memq :calls explain))
1202                (format t ";   inlining call to local function ~S~%" op)))
1203            (return-from p1-function-call
1204                         (let ((*inline-declarations*
1205                                (remove op *inline-declarations* :key #'car :test #'equal)))
1206                           (p1 expansion))))))))
1207  (p1-default form))
1208
1209(defun %funcall (fn &rest args)
1210  "Dummy FUNCALL wrapper to force p1 not to optimize the call."
1211  (apply fn args))
1212
1213(defun p1-variable-reference (var)
1214  (let ((variable (find-visible-variable var)))
1215    (when (null variable)
1216      (unless (or (special-variable-p var)
1217                  (memq var *undefined-variables*))
1218        (compiler-style-warn
1219         "Undefined variable ~S assumed special" var)
1220        (push var *undefined-variables*))
1221      (setf variable (make-variable :name var :special-p t))
1222      (push variable *visible-variables*))
1223    (let ((ref (make-var-ref variable)))
1224      (unless (variable-special-p variable)
1225        (when (variable-ignore-p variable)
1226          (compiler-style-warn
1227           "Variable ~S is read even though it was declared to be ignored."
1228           (variable-name variable)))
1229        (push ref (variable-references variable))
1230        (incf (variable-reads variable))
1231        (cond
1232          ((eq (variable-compiland variable) *current-compiland*)
1233           (dformat t "p1: read ~S~%" var))
1234          (t
1235           (dformat t "p1: non-local read ~S variable-compiland = ~S current compiland = ~S~%"
1236                    var
1237                    (compiland-name (variable-compiland variable))
1238                    (compiland-name *current-compiland*))
1239           (setf (variable-used-non-locally-p variable) t))))
1240      ref)))
1241
1242(defknown p1 (t) t)
1243(defun p1 (form)
1244  (cond
1245    ((symbolp form)
1246     (let (value)
1247       (cond
1248         ((null form)
1249          form)
1250         ((eq form t)
1251          form)
1252         ((keywordp form)
1253          form)
1254         ((and (constantp form)
1255               (progn
1256                 (setf value (symbol-value form))
1257                 (or (numberp value)
1258                     (stringp value)
1259                     (pathnamep value))))
1260          (setf form value))
1261         (t
1262          (p1-variable-reference form)))))
1263    ((atom form)
1264     form)
1265    (t
1266     (let ((op (%car form))
1267           handler)
1268       (cond
1269         ((symbolp op)
1270          (when (find-local-function op)
1271            ;; local functions shadow macros and functions in
1272            ;; the global environment as well as compiler macros
1273            (return-from p1
1274              (p1-function-call form)))
1275          (when (compiler-macro-function op)
1276            (unless (notinline-p op)
1277              (multiple-value-bind (expansion expanded-p)
1278                  (compiler-macroexpand form)
1279                ;; Fall through if no change...
1280                (when expanded-p
1281                  (return-from p1 (p1 expansion))))))
1282          (cond
1283            ((setf handler (get op 'p1-handler))
1284             (funcall handler form))
1285            ((macro-function op *compile-file-environment*)
1286             (p1 (macroexpand form *compile-file-environment*)))
1287            ((special-operator-p op)
1288             (compiler-unsupported "P1: unsupported special operator ~S" op))
1289            (t
1290             (p1-function-call form))))
1291         ((and (consp op) (eq (%car op) 'LAMBDA))
1292          (let ((maybe-optimized-call (rewrite-function-call form)))
1293            (if (eq maybe-optimized-call form)
1294                (p1 `(%funcall (function ,op) ,@(cdr form)))
1295                (p1 maybe-optimized-call))))
1296         (t
1297          (compiler-unsupported "P1 unhandled case ~S" form)))))))
1298
1299(defun install-p1-handler (symbol handler)
1300  (setf (get symbol 'p1-handler) handler))
1301
1302(defun initialize-p1-handlers ()
1303  (dolist (pair '((AND                  p1-default)
1304                  (BLOCK                p1-block)
1305                  (CATCH                p1-catch)
1306                  (DECLARE              identity)
1307                  (EVAL-WHEN            p1-eval-when)
1308                  (FLET                 p1-flet)
1309                  (FUNCALL              p1-funcall)
1310                  (FUNCTION             p1-function)
1311                  (GO                   p1-go)
1312                  (IF                   p1-default)
1313                  ;; used to be p1-if, which was used to rewrite the test
1314                  ;; form to a LET-binding; that's not necessary, because
1315                  ;; the test form doesn't lead to multiple operands on the
1316                  ;; operand stack
1317                  (LABELS               p1-labels)
1318                  (LAMBDA               p1-lambda)
1319                  (LET                  p1-let/let*)
1320                  (LET*                 p1-let/let*)
1321                  (LOAD-TIME-VALUE      identity)
1322                  (LOCALLY              p1-locally)
1323                  (MULTIPLE-VALUE-BIND  p1-m-v-b)
1324                  (MULTIPLE-VALUE-CALL  p1-default)
1325                  (MULTIPLE-VALUE-LIST  p1-default)
1326                  (MULTIPLE-VALUE-PROG1 p1-default)
1327                  (OR                   p1-default)
1328                  (PROGN                p1-default)
1329                  (PROGV                p1-progv)
1330                  (QUOTE                p1-quote)
1331                  (RETURN-FROM          p1-return-from)
1332                  (SETQ                 p1-setq)
1333                  (SYMBOL-MACROLET      identity)
1334                  (TAGBODY              p1-tagbody)
1335                  (THE                  p1-the)
1336                  (THROW                p1-throw)
1337                  (TRULY-THE            p1-truly-the)
1338                  (UNWIND-PROTECT       p1-unwind-protect)
1339                  (THREADS:SYNCHRONIZED-ON
1340                                        p1-threads-synchronized-on)
1341                  (JVM::WITH-INLINE-CODE identity)))
1342    (install-p1-handler (%car pair) (%cadr pair))))
1343
1344(initialize-p1-handlers)
1345
1346(defun p1-compiland (compiland)
1347  (let ((*current-compiland* compiland)
1348        (*local-functions* *local-functions*)
1349        (*visible-variables* *visible-variables*)
1350        (form (compiland-lambda-expression compiland)))
1351    (aver (eq (car form) 'LAMBDA))
1352    (setf form (rewrite-lambda form))
1353    (with-saved-compiler-policy
1354      (process-optimization-declarations (cddr form))
1355
1356      (let* ((lambda-list (cadr form))
1357             (body (cddr form))
1358             (closure (make-closure `(lambda ,lambda-list nil) nil))
1359             (syms (sys::varlist closure))
1360             (vars nil)
1361             compiland-result)
1362        (dolist (sym syms)
1363          (let ((var (make-variable :name sym
1364                                    :special-p (special-variable-p sym))))
1365            (push var vars)
1366            (push var *all-variables*)
1367            (push var *visible-variables*)))
1368        (setf (compiland-arg-vars compiland) (nreverse vars))
1369        (let ((free-specials (process-declarations-for-vars body vars nil)))
1370          (setf (compiland-free-specials compiland) free-specials)
1371          (dolist (var free-specials)
1372            (push var *visible-variables*)))
1373        (setf compiland-result
1374              (list* 'LAMBDA lambda-list (p1-body body)))
1375        (setf (compiland-%single-valued-p compiland)
1376              (single-valued-p compiland-result))
1377        (setf (compiland-p1-result compiland)
1378              compiland-result)))))
1379
1380(provide "COMPILER-PASS1")
Note: See TracBrowser for help on using the repository browser.