source: trunk/abcl/src/org/armedbear/lisp/defstruct.lisp @ 13188

Last change on this file since 13188 was 13188, checked in by ehuelsmann, 11 years ago

Fix DEFSTRUCT trying to generate accessors named NIL.

Note: Especially in case of LIST type structures,
DEFSTRUCT generates fake slot definitions with name NIL.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 26.7 KB
Line 
1;;; defstruct.lisp
2;;;
3;;; Copyright (C) 2003-2007 Peter Graves <peter@armedbear.org>
4;;; $Id: defstruct.lisp 13188 2011-01-27 22:48:10Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package "SYSTEM")
33
34(export 'compiler-defstruct)
35
36;;; DEFSTRUCT-DESCRIPTION
37
38(defmacro dd-name (x)                `(aref ,x  0))
39(defmacro dd-conc-name (x)           `(aref ,x  1))
40(defmacro dd-default-constructor (x) `(aref ,x  2))
41(defmacro dd-constructors (x)        `(aref ,x  3))
42(defmacro dd-copier (x)              `(aref ,x  4))
43(defmacro dd-include (x)             `(aref ,x  5))
44(defmacro dd-type (x)                `(aref ,x  6))
45(defmacro dd-named (x)               `(aref ,x  7))
46(defmacro dd-initial-offset (x)      `(aref ,x  8))
47(defmacro dd-predicate (x)           `(aref ,x  9))
48(defmacro dd-print-function (x)      `(aref ,x 10))
49(defmacro dd-print-object (x)        `(aref ,x 11))
50(defmacro dd-direct-slots (x)        `(aref ,x 12))
51(defmacro dd-slots (x)               `(aref ,x 13))
52(defmacro dd-inherited-accessors (x) `(aref ,x 14))
53
54(defun make-defstruct-description (&key name
55                                        conc-name
56                                        default-constructor
57                                        constructors
58                                        copier
59                                        include
60                                        type
61                                        named
62                                        initial-offset
63                                        predicate
64                                        print-function
65                                        print-object
66                                        direct-slots
67                                        slots
68                                        inherited-accessors)
69  (let ((dd (make-array 15)))
70    (setf (dd-name dd) name
71          (dd-conc-name dd) conc-name
72          (dd-default-constructor dd) default-constructor
73          (dd-constructors dd) constructors
74          (dd-copier dd) copier
75          (dd-include dd) include
76          (dd-type dd) type
77          (dd-named dd) named
78          (dd-initial-offset dd) initial-offset
79          (dd-predicate dd) predicate
80          (dd-print-function dd) print-function
81          (dd-print-object dd) print-object
82          (dd-direct-slots dd) direct-slots
83          (dd-slots dd) slots
84          (dd-inherited-accessors dd) inherited-accessors)
85    dd))
86
87;;; DEFSTRUCT-SLOT-DESCRIPTION
88
89(defmacro dsd-name (x)      `(aref ,x 1))
90(defmacro dsd-index (x)     `(aref ,x 2))
91(defmacro dsd-reader (x)    `(aref ,x 3))
92(defmacro dsd-initform (x)  `(aref ,x 4))
93(defmacro dsd-type (x)      `(aref ,x 5))
94(defmacro dsd-read-only (x) `(aref ,x 6))
95
96(defun make-defstruct-slot-description (&key name
97                                             index
98                                             reader
99                                             initform
100                                             (type t)
101                                             read-only)
102  (let ((dsd (make-array 7)))
103    (setf (aref dsd 0) 'defstruct-slot-description
104          (dsd-name dsd) name
105          (dsd-index dsd) index
106          (dsd-reader dsd) reader
107          (dsd-initform dsd) initform
108          (dsd-type dsd) type
109          (dsd-read-only dsd) read-only)
110    dsd))
111
112(defvar *dd-name*)
113(defvar *dd-conc-name*)
114(defvar *dd-default-constructor*)
115(defvar *dd-constructors*)
116(defvar *dd-copier*)
117(defvar *dd-include*)
118(defvar *dd-type*)
119(defvar *dd-default-slot-type* t)
120(defvar *dd-named*)
121(defvar *dd-initial-offset*)
122(defvar *dd-predicate*)
123(defvar *dd-print-function*)
124(defvar *dd-print-object*)
125(defvar *dd-direct-slots*)
126(defvar *dd-slots*)
127(defvar *dd-inherited-accessors*)
128
129(defun keywordify (symbol)
130  (intern (symbol-name symbol) +keyword-package+))
131
132(defun define-keyword-constructor (constructor)
133  (let* ((constructor-name (car constructor))
134         (keys ())
135         (values ()))
136    (dolist (slot *dd-slots*)
137      (let ((name (dsd-name slot))
138            (initform (dsd-initform slot)))
139        (if (or name (dsd-reader slot))
140            (let ((dummy (gensym)))
141              (push (list (list (keywordify name) dummy) initform) keys)
142              (push dummy values))
143            (push initform values))))
144    (setf keys (cons '&key (nreverse keys))
145          values (nreverse values))
146    (cond ((eq *dd-type* 'list)
147           `((defun ,constructor-name ,keys
148               (list ,@values))))
149          ((or (eq *dd-type* 'vector)
150               (and (consp *dd-type*) (eq (car *dd-type*) 'vector)))
151           (let ((element-type (if (consp *dd-type*) (cadr *dd-type*) t)))
152             `((defun ,constructor-name ,keys
153                 (make-array ,(length values)
154                             :element-type ',element-type
155                             :initial-contents (list ,@values))))))
156          ((<= 1 (length values) 6)
157           `((defun ,constructor-name ,keys
158               (make-structure (truly-the symbol ',*dd-name*) ,@values))))
159          (t
160           `((defun ,constructor-name ,keys
161               (%make-structure (truly-the symbol ',*dd-name*) (list ,@values))))))))
162
163(defun find-dsd (name)
164  (dolist (dsd *dd-slots*)
165    (when (string= name (dsd-name dsd))
166      (return dsd))))
167
168(defun get-slot (name)
169;;   (let ((res (find name (dd-slots defstruct) :test #'string= :key #'dsd-name)))
170  (let ((res nil))
171    (dolist (dsd *dd-slots*)
172      (when (string= name (dsd-name dsd))
173        (setf res dsd)
174        (return)))
175    (if res
176        (values (dsd-type res) (dsd-initform res))
177        (values t nil))))
178
179(defun define-boa-constructor (constructor)
180  (multiple-value-bind (req opt restp rest keyp keys allowp auxp aux)
181    (parse-lambda-list (cadr constructor))
182    (let ((arglist ())
183          (vars ())
184          (types ())
185          (skipped-vars ()))
186      (dolist (arg req)
187        (push arg arglist)
188        (push arg vars)
189        (push (get-slot arg) types))
190      (when opt
191        (push '&optional arglist)
192        (dolist (arg opt)
193          (cond ((consp arg)
194                 (destructuring-bind
195                  (name
196                   &optional
197                   (def (nth-value 1 (get-slot name)))
198                   (supplied-test nil supplied-test-p))
199                  arg
200                  (push `(,name ,def ,@(if supplied-test-p `(,supplied-test) nil)) arglist)
201                  (push name vars)
202                  (push (get-slot name) types)))
203                (t
204                 (multiple-value-bind (type default) (get-slot arg)
205                   (push `(,arg ,default) arglist)
206                   (push arg vars)
207                   (push type types))))))
208      (when restp
209        (push '&rest arglist)
210        (push rest arglist)
211        (push rest vars)
212        (push 'list types))
213      (when keyp
214        (push '&key arglist)
215        (dolist (key keys)
216          (if (consp key)
217              (destructuring-bind (wot
218                                   &optional
219                                   (def nil def-p)
220                                   (supplied-test nil supplied-test-p))
221                                  key
222                                  (let ((name (if (consp wot)
223                                                  (destructuring-bind (key var) wot
224                                                                      (declare (ignore key))
225                                                                      var)
226                                                  wot)))
227                                    (multiple-value-bind (type slot-def)
228                                      (get-slot name)
229                                      (push `(,wot ,(if def-p def slot-def)
230                                                   ,@(if supplied-test-p `(,supplied-test) nil))
231                                            arglist)
232                                      (push name vars)
233                                      (push type types))))
234              (multiple-value-bind (type default) (get-slot key)
235                (push `(,key ,default) arglist)
236                (push key vars)
237                (push type types)))))
238      (when allowp
239        (push '&allow-other-keys arglist))
240      (when auxp
241        (push '&aux arglist)
242        (dolist (arg aux)
243          (push arg arglist)
244          (if (and (consp arg) (eql (length arg) 2))
245              (let ((var (first arg)))
246                (push var vars)
247                (push (get-slot var) types))
248              (push (if (consp arg) (first arg) arg) skipped-vars))))
249      (setq arglist (nreverse arglist))
250      (setq vars (nreverse vars))
251      (setq types (nreverse types))
252      (setq skipped-vars (nreverse skipped-vars))
253      (let ((values ()))
254        (dolist (dsd *dd-slots*)
255          (let ((name (dsd-name dsd))
256                var)
257            (cond ((find name skipped-vars :test #'string=)
258                   (push nil values))
259                  ((setf var (find name vars :test #'string=))
260                   (push var values))
261                  (t
262                   (push (dsd-initform dsd) values)))))
263        (setf values (nreverse values))
264        (let* ((constructor-name (car constructor)))
265          (cond ((eq *dd-type* 'list)
266                 `((defun ,constructor-name ,arglist
267                     (list ,@values))))
268                ((or (eq *dd-type* 'vector)
269                     (and (consp *dd-type*) (eq (car *dd-type*) 'vector)))
270                 (let ((element-type (if (consp *dd-type*) (cadr *dd-type*) t)))
271                   `((defun ,constructor-name ,arglist
272                       (make-array ,(length values)
273                                   :element-type ',element-type
274                                   :initial-contents (list ,@values))))))
275                ((<= 1 (length values) 6)
276                 `((declaim (inline ,constructor-name))
277                   (defun ,constructor-name ,arglist
278                     (make-structure (truly-the symbol ',*dd-name*) ,@values))))
279                (t
280                 `((declaim (inline ,constructor-name))
281                   (defun ,constructor-name ,arglist
282                     (%make-structure (truly-the symbol ',*dd-name*) (list ,@values)))))))))))
283
284(defun default-constructor-name ()
285  (intern (concatenate 'string "MAKE-" (symbol-name *dd-name*))))
286
287(defun define-constructors ()
288  (if *dd-constructors*
289      (let ((results ()))
290        (dolist (constructor *dd-constructors*)
291          (when (car constructor)
292            (setf results (nconc results
293                                 (if (cadr constructor)
294                                     (define-boa-constructor constructor)
295                                     (define-keyword-constructor constructor))))))
296        results)
297      (define-keyword-constructor (cons (default-constructor-name) nil))))
298
299(defun name-index ()
300  (dolist (dsd *dd-slots*)
301    (let ((name (dsd-name dsd))
302          (initform (dsd-initform dsd)))
303      (when (and (null name)
304                 (equal initform (list 'quote *dd-name*)))
305        (return-from name-index (dsd-index dsd)))))
306  ;; We shouldn't get here.
307  nil)
308
309(defun define-predicate ()
310  (when (and *dd-predicate*
311             (or *dd-named* (null *dd-type*)))
312    (let ((pred (if (symbolp *dd-predicate*)
313                    *dd-predicate*
314                    (intern *dd-predicate*))))
315      (cond ((eq *dd-type* 'list)
316             (let ((index (name-index)))
317               `((defun ,pred (object)
318                   (and (consp object)
319                        (> (length object) ,index)
320                        (eq (nth ,index object) ',*dd-name*))))))
321            ((or (eq *dd-type* 'vector)
322                 (and (consp *dd-type*) (eq (car *dd-type*) 'vector)))
323             (let ((index (name-index)))
324               `((defun ,pred (object)
325                   (and (vectorp object)
326                        (> (length object) ,index)
327                        (eq (aref object ,index) ',*dd-name*))))))
328            (t
329             `((defun ,pred (object)
330                 (simple-typep object ',*dd-name*))))))))
331
332(defun define-reader (slot)
333  (let ((accessor-name (dsd-reader slot))
334        (index (dsd-index slot))
335        (type (dsd-type slot)))
336    (cond ((eq *dd-type* 'list)
337           `((declaim (ftype (function * ,type) ,accessor-name))
338             (defun ,accessor-name (instance) (elt instance ,index))))
339          ((or (eq *dd-type* 'vector)
340               (and (consp *dd-type*) (eq (car *dd-type*) 'vector)))
341           `((declaim (ftype (function * ,type) ,accessor-name))
342             (defun ,accessor-name (instance) (aref instance ,index))
343             (define-source-transform ,accessor-name (instance)
344               `(aref (truly-the ,',*dd-type* ,instance) ,,index))))
345          (t
346           `((declaim (ftype (function * ,type) ,accessor-name))
347             (defun ,accessor-name (instance)
348               (structure-ref (the ,*dd-name* instance) ,index))
349             (define-source-transform ,accessor-name (instance)
350               ,(if (eq type 't)
351                    ``(structure-ref (the ,',*dd-name* ,instance) ,,index)
352                    ``(the ,',type
353                        (structure-ref (the ,',*dd-name* ,instance) ,,index)))))))))
354
355(defun define-writer (slot)
356  (let ((accessor-name (dsd-reader slot))
357        (index (dsd-index slot)))
358    (cond ((eq *dd-type* 'list)
359           `((defun (setf ,accessor-name) (value instance)
360               (%set-elt instance ,index value))))
361          ((or (eq *dd-type* 'vector)
362               (and (consp *dd-type*) (eq (car *dd-type*) 'vector)))
363           `((defun (setf ,accessor-name) (value instance)
364               (aset instance ,index value))
365             (define-source-transform (setf ,accessor-name) (value instance)
366               `(aset (truly-the ,',*dd-type* ,instance) ,,index ,value))))
367          (t
368           `((defun (setf ,accessor-name) (value instance)
369               (structure-set (the ,*dd-name* instance) ,index value))
370             (define-source-transform (setf ,accessor-name) (value instance)
371               `(structure-set (the ,',*dd-name* ,instance)
372                               ,,index ,value)))))))
373
374(defun define-access-functions ()
375  (let ((result ()))
376    (dolist (slot *dd-slots*)
377      (let ((accessor-name (dsd-reader slot)))
378        (unless (null accessor-name)
379          (unless (assoc accessor-name *dd-inherited-accessors*)
380            (setf result (nconc result (define-reader slot)))
381            (unless (dsd-read-only slot)
382              (setf result (nconc result (define-writer slot))))))))
383    result))
384
385(defun define-copier ()
386  (when *dd-copier*
387    (cond ((eq *dd-type* 'list)
388           `((setf (fdefinition ',*dd-copier*) #'copy-list)))
389          ((or (eq *dd-type* 'vector)
390               (and (consp *dd-type*) (eq (car *dd-type*) 'vector)))
391           `((setf (fdefinition ',*dd-copier*) #'copy-seq)))
392          (t
393           `((setf (fdefinition ',*dd-copier*) #'copy-structure))))))
394
395(defun define-print-function ()
396  (cond (*dd-print-function*
397         (if (cadr *dd-print-function*)
398             `((defmethod print-object ((instance ,*dd-name*) stream)
399                 (funcall (function ,(cadr *dd-print-function*))
400                          instance stream *current-print-level*)))
401             `((defmethod print-object ((instance ,*dd-name*) stream)
402                 (write-string (%write-to-string instance) stream)))))
403        (*dd-print-object*
404         (if (cadr *dd-print-object*)
405             `((defmethod print-object ((instance ,*dd-name*) stream)
406                 (funcall (function ,(cadr *dd-print-object*))
407                          instance stream)))
408             `((defmethod print-object ((instance ,*dd-name*) stream)
409                 (write-string (%write-to-string instance) stream)))))
410        (t
411         nil)))
412
413(defun parse-1-option (option)
414  (case (car option)
415    (:conc-name
416     (setf *dd-conc-name* (if (symbolp (cadr option))
417                              (cadr option)
418                              (make-symbol (string (cadr option))))))
419    (:constructor
420     (let* ((args (cdr option))
421            (numargs (length args)))
422       (case numargs
423         (0 ; Use default name.
424          (push (list (default-constructor-name) nil) *dd-constructors*))
425         (1
426          (push (list (car args) nil) *dd-constructors*))
427         (2
428          (push args *dd-constructors*)))))
429    (:copier
430     (when (eql (length option) 2)
431       (setf *dd-copier* (cadr option))))
432    (:include
433     (setf *dd-include* (cdr option)))
434    (:initial-offset
435     (setf *dd-initial-offset* (cadr option)))
436    (:predicate
437     (when (eql (length option) 2)
438       (setf *dd-predicate* (cadr option))))
439    (:print-function
440     (setf *dd-print-function* option))
441    (:print-object
442     (setf *dd-print-object* option))
443    (:type
444     (setf *dd-type* (cadr option))
445     (when (and (consp *dd-type*) (eq (car *dd-type*) 'vector))
446       (unless (eq (second *dd-type*) '*)
447         (setf *dd-default-slot-type* (second *dd-type*)))))))
448
449(defun parse-name-and-options (name-and-options)
450  (setf *dd-name* (the symbol (car name-and-options)))
451  (setf *dd-conc-name* (make-symbol (concatenate 'string (symbol-name *dd-name*) "-")))
452  (setf *dd-copier* (intern (concatenate 'string "COPY-" (symbol-name *dd-name*))))
453  (setf *dd-predicate* (concatenate 'string (symbol-name *dd-name*) "-P"))
454  (let ((options (cdr name-and-options)))
455    (dolist (option options)
456      (cond ((consp option)
457             (parse-1-option option))
458            ((eq option :named)
459             (setf *dd-named* t))
460            ((member option '(:constructor :copier :predicate :named :conc-name))
461             (parse-1-option (list option)))
462            (t
463             (error "Unrecognized DEFSTRUCT option: ~S." option))))))
464
465(defun compiler-defstruct (name &key
466                                conc-name
467                                default-constructor
468                                constructors
469                                copier
470                                include
471                                type
472                                named
473                                initial-offset
474                                predicate
475                                print-function
476                                print-object
477                                direct-slots
478                                slots
479                                inherited-accessors)
480  (setf (get name 'structure-definition)
481        (make-defstruct-description :name name
482                                    :conc-name conc-name
483                                    :default-constructor default-constructor
484                                    :constructors constructors
485                                    :copier copier
486                                    :include include
487                                    :type type
488                                    :named named
489                                    :initial-offset initial-offset
490                                    :predicate predicate
491                                    :print-function print-function
492                                    :print-object print-object
493                                    :direct-slots direct-slots
494                                    :slots slots
495                                    :inherited-accessors inherited-accessors))
496  (when (or (null type) named)
497    (make-structure-class name direct-slots slots (car include)))
498  (when default-constructor
499    (proclaim `(ftype (function * t) ,default-constructor))))
500
501(defmacro defstruct (name-and-options &rest slots)
502  (let ((*dd-name* nil)
503        (*dd-conc-name* nil)
504        (*dd-default-constructor* nil)
505        (*dd-constructors* nil)
506        (*dd-copier* nil)
507        (*dd-include* nil)
508        (*dd-type* nil)
509        (*dd-default-slot-type* t)
510        (*dd-named* nil)
511        (*dd-initial-offset* nil)
512        (*dd-predicate* nil)
513        (*dd-print-function* nil)
514        (*dd-print-object* nil)
515        (*dd-direct-slots* ())
516        (*dd-slots* ())
517        (*dd-inherited-accessors* ()))
518    (parse-name-and-options (if (atom name-and-options)
519                                (list name-and-options)
520                                name-and-options))
521    (check-declaration-type *dd-name*)
522    (if *dd-constructors*
523        (dolist (constructor *dd-constructors*)
524          (unless (cadr constructor)
525            (setf *dd-default-constructor* (car constructor))
526            (return)))
527        (setf *dd-default-constructor* (default-constructor-name)))
528    (when (stringp (car slots))
529      (%set-documentation *dd-name* 'structure (pop slots)))
530    (dolist (slot slots)
531      (let* ((name (if (atom slot) slot (car slot)))
532             (reader (if *dd-conc-name*
533                         (intern (concatenate 'string
534                                              (symbol-name *dd-conc-name*)
535                                              (symbol-name name)))
536                         name))
537             (initform (if (atom slot) nil (cadr slot)))
538             (dsd (apply #'make-defstruct-slot-description
539                         :name name
540                         :reader reader
541                         :initform initform
542                         (cond
543                           ((atom slot)
544                            (list :type *dd-default-slot-type*))
545                           ((getf (cddr slot) :type)
546                            (cddr slot))
547                           (t
548                            (list* :type *dd-default-slot-type* (cddr slot)))))))
549        (push dsd *dd-direct-slots*)))
550    (setf *dd-direct-slots* (nreverse *dd-direct-slots*))
551    (let ((index 0))
552      (when *dd-include*
553        (let ((dd (get (car *dd-include*) 'structure-definition)))
554          (unless dd
555            (error 'simple-error
556                   :format-control "Class ~S is undefined."
557                   :format-arguments (list (car *dd-include*))))
558          (dolist (dsd (dd-slots dd))
559            ;; MUST COPY SLOT DESCRIPTION!
560            (setf dsd (copy-seq dsd))
561            (setf (dsd-index dsd) index
562                  (dsd-reader dsd)
563                  (if *dd-conc-name*
564                      (intern (concatenate 'string
565                                           (symbol-name *dd-conc-name*)
566                                           (symbol-name (dsd-name dsd))))
567                      (dsd-name dsd)))
568            (push dsd *dd-slots*)
569            (incf index))
570          (setf *dd-inherited-accessors* (dd-inherited-accessors dd))
571          (dolist (dsd (dd-direct-slots dd))
572            (push (cons (dsd-reader dsd) (dsd-name dsd))
573                  *dd-inherited-accessors*)))
574        (when (cdr *dd-include*)
575          (dolist (slot (cdr *dd-include*))
576            (let* ((name (if (atom slot) slot (car slot)))
577                   (initform (if (atom slot) nil (cadr slot)))
578                   (dsd (find-dsd name)))
579              (when dsd
580                (setf (dsd-initform dsd) initform))))))
581      (when *dd-initial-offset*
582        (dotimes (i *dd-initial-offset*)
583          (push (make-defstruct-slot-description :name nil
584                                                 :index index
585                                                 :reader nil
586                                                 :initform nil
587                                                 :type t
588                                                 :read-only t)
589                *dd-slots*)
590          (incf index)))
591      (when *dd-named*
592        (push (make-defstruct-slot-description :name nil
593                                               :index index
594                                               :reader nil
595                                               :initform (list 'quote *dd-name*)
596                                               :type t
597                                               :read-only t)
598              *dd-slots*)
599        (incf index))
600      (dolist (dsd *dd-direct-slots*)
601        (setf (dsd-index dsd) index)
602        (push dsd *dd-slots*)
603        (incf index)))
604    (setf *dd-slots* (nreverse *dd-slots*))
605    `(progn
606       (eval-when (:compile-toplevel :load-toplevel :execute)
607         (compiler-defstruct ',*dd-name*
608                             :conc-name ',*dd-conc-name*
609                             :default-constructor ',*dd-default-constructor*
610                             ,@(if *dd-constructors* `(:constructors ',*dd-constructors*))
611                             :copier ',*dd-copier*
612                             ,@(if *dd-include* `(:include ',*dd-include*))
613                             ,@(if *dd-type* `(:type ',*dd-type*))
614                             ,@(if *dd-named* `(:named ,*dd-named*))
615                             ,@(if *dd-initial-offset* `(:initial-offset ,*dd-initial-offset*))
616                             :predicate ',*dd-predicate*
617                             ,@(if *dd-print-function* `(:print-function ',*dd-print-function*))
618                             ,@(if *dd-print-object* `(:print-object ',*dd-print-object*))
619                             :direct-slots ',*dd-direct-slots*
620                             :slots ',*dd-slots*
621                             :inherited-accessors ',*dd-inherited-accessors*))
622       ,@(define-constructors)
623       ,@(define-predicate)
624       ,@(define-access-functions)
625       ,@(define-copier)
626       ,@(define-print-function)
627       ',*dd-name*)))
628
629(defun defstruct-default-constructor (arg)
630  (let ((type (cond ((symbolp arg)
631                     arg)
632                    ((classp arg)
633                     (class-name arg))
634                    (t
635                     (type-of arg)))))
636    (when type
637      (let ((dd (get type 'structure-definition)))
638        (and dd (dd-default-constructor dd))))))
Note: See TracBrowser for help on using the repository browser.