source: trunk/abcl/src/org/armedbear/lisp/jvm.lisp @ 11878

Last change on this file since 11878 was 11878, checked in by ehuelsmann, 12 years ago

Add structure slot documentation.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 16.9 KB
Line 
1;;; jvm.lisp
2;;;
3;;; Copyright (C) 2003-2008 Peter Graves
4;;; $Id: jvm.lisp 11878 2009-05-16 07:26:03Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package "JVM")
33
34(export '(compile-defun *catch-errors* jvm-compile jvm-compile-package
35          derive-compiler-type))
36
37(eval-when (:compile-toplevel :load-toplevel :execute)
38  (require "LOOP")
39  (require "FORMAT")
40  (require "CLOS")
41  (require "PRINT-OBJECT")
42  (require "COMPILER-TYPES")
43  (require "KNOWN-FUNCTIONS")
44  (require "KNOWN-SYMBOLS")
45  (require "DUMP-FORM")
46  (require "OPCODES")
47  (require "JAVA")
48  (require "COMPILER-PASS1")
49  (require "COMPILER-PASS2"))
50
51(defvar *closure-variables* nil)
52
53(defvar *enable-dformat* nil)
54
55#+nil
56(defun dformat (destination control-string &rest args)
57  (when *enable-dformat*
58    (apply #'sys::%format destination control-string args)))
59
60(defmacro dformat (&rest ignored)
61  (declare (ignore ignored)))
62
63
64(defmacro with-saved-compiler-policy (&body body)
65  "Saves compiler policy variables, restoring them after evaluating `body'."
66  `(let ((*speed* *speed*)
67         (*space* *space*)
68         (*safety* *safety*)
69         (*debug* *debug*)
70         (*explain* *explain*)
71         (*inline-declarations* *inline-declarations*))
72     ,@body))
73
74
75
76(defvar *compiler-debug* nil)
77
78(defvar *pool* nil)
79(defvar *pool-count* 1)
80(defvar *pool-entries* nil)
81(defvar *fields* ())
82(defvar *static-code* ())
83
84(defvar *declared-symbols* nil)
85(defvar *declared-functions* nil)
86(defvar *declared-strings* nil)
87(defvar *declared-integers* nil)
88(defvar *declared-floats* nil)
89(defvar *declared-doubles* nil)
90
91(defstruct (class-file (:constructor %make-class-file))
92  pathname ; pathname of output file
93  lambda-name
94  class
95  superclass
96  lambda-list ; as advertised
97  pool
98  (pool-count 1)
99  (pool-entries (make-hash-table :test #'equal))
100  fields
101  methods
102  static-code
103  (symbols (make-hash-table :test 'eq))
104  (functions (make-hash-table :test 'equal))
105  (strings (make-hash-table :test 'eq))
106  (integers (make-hash-table :test 'eql))
107  (floats (make-hash-table :test 'eql))
108  (doubles (make-hash-table :test 'eql)))
109
110(defun class-name-from-filespec (filespec)
111  (let* ((name (pathname-name filespec)))
112    (declare (type string name))
113    (dotimes (i (length name))
114      (declare (type fixnum i))
115      (when (char= (char name i) #\-)
116        (setf (char name i) #\_)))
117    (concatenate 'string "org/armedbear/lisp/" name)))
118
119(defun make-class-file (&key pathname lambda-name lambda-list)
120  (aver (not (null pathname)))
121  (let ((class-file (%make-class-file :pathname pathname
122                                      :lambda-name lambda-name
123                                      :lambda-list lambda-list)))
124    (setf (class-file-class class-file) (class-name-from-filespec pathname))
125    class-file))
126
127(defmacro with-class-file (class-file &body body)
128  (let ((var (gensym)))
129    `(let* ((,var ,class-file)
130            (*pool*               (class-file-pool ,var))
131            (*pool-count*         (class-file-pool-count ,var))
132            (*pool-entries*       (class-file-pool-entries ,var))
133            (*fields*             (class-file-fields ,var))
134            (*static-code*        (class-file-static-code ,var))
135            (*declared-symbols*   (class-file-symbols ,var))
136            (*declared-functions* (class-file-functions ,var))
137            (*declared-strings*   (class-file-strings ,var))
138            (*declared-integers*  (class-file-integers ,var))
139            (*declared-floats*    (class-file-floats ,var))
140            (*declared-doubles*   (class-file-doubles ,var)))
141       (progn ,@body)
142       (setf (class-file-pool ,var)         *pool*
143             (class-file-pool-count ,var)   *pool-count*
144             (class-file-pool-entries ,var) *pool-entries*
145             (class-file-fields ,var)       *fields*
146             (class-file-static-code ,var)  *static-code*
147             (class-file-symbols ,var)      *declared-symbols*
148             (class-file-functions ,var)    *declared-functions*
149             (class-file-strings ,var)      *declared-strings*
150             (class-file-integers ,var)     *declared-integers*
151             (class-file-floats ,var)       *declared-floats*
152             (class-file-doubles ,var)      *declared-doubles*))))
153
154(defstruct compiland
155  name
156  (kind :external)  ; :INTERNAL or :EXTERNAL
157  lambda-expression
158  arg-vars          ; variables for lambda arguments
159  free-specials     ;
160  arity             ; number of args, or NIL if the number of args can vary.
161  p1-result         ; the parse tree as created in pass 1
162  parent            ; the parent for compilands which defined within another
163  (children 0       ; Number of local functions
164            :type fixnum) ; defined with with FLET, LABELS or LAMBDA
165  argument-register
166  closure-register
167  environment-register
168  class-file ; class-file object
169  (%single-valued-p t))
170
171(defknown compiland-single-valued-p (t) t)
172(defun compiland-single-valued-p (compiland)
173  (unless (compiland-parent compiland)
174    (let ((name (compiland-name compiland)))
175      (when name
176        (let ((result-type
177               (or (function-result-type name)
178                   (and (proclaimed-ftype name)
179                        (ftype-result-type (proclaimed-ftype name))))))
180          (when result-type
181            (return-from compiland-single-valued-p
182                         (cond ((eq result-type '*)
183                                nil)
184                               ((atom result-type)
185                                t)
186                               ((eq (%car result-type) 'VALUES)
187                                (= (length result-type) 2))
188                               (t
189                                t))))))))
190  ;; Otherwise...
191  (compiland-%single-valued-p compiland))
192
193(defvar *current-compiland* nil)
194
195(defvar *this-class* nil)
196
197(defvar *code* ())
198
199;; All tags visible at the current point of compilation, some of which may not
200;; be in the current compiland.
201(defvar *visible-tags* ())
202
203;; The next available register.
204(defvar *register* 0)
205
206;; Total number of registers allocated.
207(defvar *registers-allocated* 0)
208
209(defvar *handlers* ())
210
211(defstruct handler
212  from
213  to
214  code
215  catch-type)
216
217;; Variables visible at the current point of compilation.
218(defvar *visible-variables* nil)
219
220;; All variables seen so far.
221(defvar *all-variables* nil)
222
223;; Undefined variables that we've already warned about.
224(defvar *undefined-variables* nil)
225
226(defvar *dump-variables* nil)
227
228(defun dump-1-variable (variable)
229  (sys::%format t "  ~S special-p = ~S register = ~S index = ~S declared-type = ~S~%"
230           (variable-name variable)
231           (variable-special-p variable)
232           (variable-register variable)
233           (variable-index variable)
234           (variable-declared-type variable)))
235
236(defun dump-variables (list caption &optional (force nil))
237  (when (or force *dump-variables*)
238    (write-string caption)
239    (if list
240        (dolist (variable list)
241          (dump-1-variable variable))
242        (sys::%format t "  None.~%"))))
243
244(defstruct (variable-info (:conc-name variable-)
245                          (:constructor make-variable)
246                          (:predicate variable-p))
247  name
248  initform
249  (declared-type :none)
250  (derived-type :none)
251  ignore-p
252  ignorable-p
253  representation
254  special-p     ; indicates whether a variable is special
255  register      ; register number for a local variable
256  index         ; index number for a variable in the argument array
257  closure-index ; index number for a variable in the closure context array
258    ;; a variable can be either special-p *or* have a register *or*
259    ;; have an index *or a closure-index
260  (reads 0 :type fixnum)
261  (writes 0 :type fixnum)
262  references
263  used-non-locally-p
264  (compiland *current-compiland*))
265
266(defstruct (var-ref (:constructor make-var-ref (variable)))
267  ;; The variable this reference refers to. Will be NIL if the VAR-REF has been
268  ;; rewritten to reference a constant value.
269  variable
270  ;; True if the VAR-REF has been rewritten to reference a constant value.
271  constant-p
272  ;; The constant value of this VAR-REF.
273  constant-value)
274
275;; obj can be a symbol or variable
276;; returns variable or nil
277(declaim (ftype (function (t) t) unboxed-fixnum-variable))
278(defun unboxed-fixnum-variable (obj)
279  (cond ((symbolp obj)
280         (let ((variable (find-visible-variable obj)))
281           (if (and variable
282                    (eq (variable-representation variable) :int))
283               variable
284               nil)))
285        ((variable-p obj)
286         (if (eq (variable-representation obj) :int)
287             obj
288             nil))
289        (t
290         nil)))
291
292(defvar *child-p* nil
293  "True for local functions created by FLET, LABELS and (NAMED-)LAMBDA")
294
295(defknown find-variable (symbol list) t)
296(defun find-variable (name variables)
297  (dolist (variable variables)
298    (when (eq name (variable-name variable))
299      (return variable))))
300
301(defknown find-visible-variable (t) t)
302(defun find-visible-variable (name)
303  (dolist (variable *visible-variables*)
304    (when (eq name (variable-name variable))
305      (return variable))))
306
307(defknown allocate-register () (integer 0 65535))
308(defun allocate-register ()
309  (let* ((register *register*)
310         (next-register (1+ register)))
311    (declare (type (unsigned-byte 16) register next-register))
312    (setf *register* next-register)
313    (when (< *registers-allocated* next-register)
314      (setf *registers-allocated* next-register))
315    register))
316
317(defknown allocate-register-pair () (integer 0 65535))
318(defun allocate-register-pair ()
319  (let* ((register *register*)
320         (next-register (+ register 2)))
321    (declare (type (unsigned-byte 16) register next-register))
322    (setf *register* next-register)
323    (when (< *registers-allocated* next-register)
324      (setf *registers-allocated* next-register))
325    register))
326
327(defstruct local-function
328  name
329  compiland
330  inline-expansion
331  function  ;; the function loaded through load-compiled-function
332  class-file
333  variable  ;; the variable which contains the loaded compiled function
334            ;; or compiled closure
335  )
336
337(defvar *local-functions* ())
338
339(defknown find-local-function (t) t)
340(defun find-local-function (name)
341  (dolist (local-function *local-functions* nil)
342    (when (equal name (local-function-name local-function))
343        (return local-function))))
344
345(defvar *using-arg-array* nil)
346(defvar *hairy-arglist-p* nil)
347
348(defstruct node
349  ;; Block name or (TAGBODY) or (LET) or (MULTIPLE-VALUE-BIND).
350  name
351  form
352  (compiland *current-compiland*))
353
354;; Used to wrap TAGBODYs, UNWIND-PROTECTs and LET/LET*/M-V-B forms as well as
355;; BLOCKs per se.
356(defstruct (block-node (:conc-name block-)
357                       (:include node)
358                       (:constructor make-block-node (name)))
359  (exit (gensym))
360  target
361  catch-tag
362  ;; True if there is any RETURN from this block.
363  return-p
364  ;; True if there is a non-local RETURN from this block.
365  non-local-return-p
366  ;; True if a tag in this tagbody is the target of a non-local GO.
367  non-local-go-p
368  ;; If non-nil, the TAGBODY contains local blocks which "contaminate" the
369  ;; environment, with GO forms in them which target tags in this TAGBODY
370  ;; Non-nil if and only if the block doesn't modify the environment
371  needs-environment-restoration
372  ;; If non-nil, register containing saved dynamic environment for this block.
373  environment-register
374  ;; Only used in LET/LET*/M-V-B nodes.
375  vars
376  free-specials
377  ;; Only used in TAGBODY
378  tags
379  )
380
381(defvar *blocks* ())
382
383(defun find-block (name)
384  (dolist (block *blocks*)
385    (when (eq name (block-name block))
386      (return block))))
387
388(defknown node-constant-p (t) boolean)
389(defun node-constant-p (object)
390  (cond ((block-node-p object)
391         nil)
392        ((var-ref-p object)
393         nil)
394        ((constantp object)
395         t)
396        (t
397         nil)))
398
399(defknown block-requires-non-local-exit-p (t) boolean)
400(defun block-requires-non-local-exit-p (object)
401  "A block which *always* requires a 'non-local-exit' is a block which
402requires a transfer control exception to be thrown: e.g. Go and Return.
403
404Non-local exits are required by blocks which do more in their cleanup
405than just restore the lastSpecialBinding (= dynamic environment).
406"
407  (let ((name (block-name object)))
408    (or (equal name '(CATCH))
409        (equal name '(UNWIND-PROTECT)))))
410
411
412(defknown enclosed-by-protected-block-p (&optional t) boolean)
413(defun enclosed-by-protected-block-p (&optional outermost-block)
414  "Indicates whether the code being compiled/analyzed is enclosed in
415a block which requires a non-local transfer of control exception to
416be generated.
417"
418  (dolist (enclosing-block *blocks*)
419    (when (eq enclosing-block outermost-block)
420      (return-from enclosed-by-protected-block-p nil))
421    (when (block-requires-non-local-exit-p enclosing-block)
422      (return-from enclosed-by-protected-block-p t))))
423
424(defknown enclosed-by-environment-setting-block-p (&optional t) boolean)
425(defun enclosed-by-environment-setting-block-p (&optional outermost-block)
426  (dolist (enclosing-block *blocks*)
427    (when (eq enclosing-block outermost-block)
428      (return nil))
429    (when (and (block-environment-register enclosing-block)
430               (not (block-needs-environment-restoration enclosing-block)))
431      (return t))))
432
433(defknown environment-register-to-restore (&optional t) t)
434(defun environment-register-to-restore (&optional outermost-block)
435  "Returns the environment register which contains the
436saved environment from the outermost enclosing block:
437
438That's the one which contains the environment used in the outermost block."
439  (flet ((outermost-register (last-register block)
440           (when (eq block outermost-block)
441             (return-from environment-register-to-restore last-register))
442           (or (block-environment-register block)
443               last-register)))
444    (reduce #'outermost-register *blocks*
445            :initial-value nil)))
446
447(defstruct tag
448  ;; The symbol (or integer) naming the tag
449  name
450  ;; The symbol which is the jump target in JVM byte code
451  label
452  ;; The associated TAGBODY
453  block
454  (compiland *current-compiland*)
455  used)
456
457(defknown find-tag (t) t)
458(defun find-tag (name)
459  (dolist (tag *visible-tags*)
460    (when (eql name (tag-name tag))
461      (return tag))))
462
463(defun process-ignore/ignorable (declaration names variables)
464  (when (memq declaration '(IGNORE IGNORABLE))
465    (let ((what (if (eq declaration 'IGNORE) "ignored" "ignorable")))
466      (dolist (name names)
467        (let ((variable (find-variable name variables)))
468          (cond ((null variable)
469                 (compiler-style-warn "Declaring unknown variable ~S to be ~A."
470                                      name what))
471                ((variable-special-p variable)
472                 (compiler-style-warn "Declaring special variable ~S to be ~A."
473                                      name what))
474                ((eq declaration 'IGNORE)
475                 (setf (variable-ignore-p variable) t))
476                (t
477                 (setf (variable-ignorable-p variable) t))))))))
478
479(defvar *file-compilation* nil)
480(defvar *pathnames-generator* #'make-temp-file)
481
482(defun compile (name &optional definition)
483  (let ((*file-compilation* nil)
484        (*pathnames-generator* #'make-temp-file)
485        (sys::*fasl-anonymous-package* (sys::%make-package)))
486    (jvm-compile name definition)))
487
488(defmacro with-file-compilation (&body body)
489  `(let ((*file-compilation* t)
490         (*pathnames-generator* #'sys::next-classfile-name))
491     ,@body))
492
493(defun finalize-generic-functions ()
494  (dolist (sym '(make-instance
495                 initialize-instance
496                 shared-initialize))
497    (let ((gf (and (fboundp sym) (fdefinition sym))))
498      (when (typep gf 'generic-function)
499        (unless (compiled-function-p gf)
500          (mop::finalize-generic-function gf))))))
501
502(finalize-generic-functions)
503
504(provide 'jvm)
Note: See TracBrowser for help on using the repository browser.