source: trunk/abcl/src/org/armedbear/lisp/precompiler.lisp @ 11794

Last change on this file since 11794 was 11794, checked in by ehuelsmann, 14 years ago

Precompile lambda-list initforms.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 47.9 KB
Line 
1;;; precompiler.lisp
2;;;
3;;; Copyright (C) 2003-2008 Peter Graves <peter@armedbear.org>
4;;; $Id: precompiler.lisp 11794 2009-04-28 21:09:29Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package "SYSTEM")
33
34(export '(*inline-declarations*
35          process-optimization-declarations
36          process-special-declarations
37          inline-p notinline-p inline-expansion expand-inline
38          *defined-functions* *undefined-functions* note-name-defined))
39
40(defvar *inline-declarations* nil)
41
42(declaim (ftype (function (t) t) process-optimization-declarations))
43(defun process-optimization-declarations (forms)
44  (dolist (form forms)
45    (unless (and (consp form) (eq (%car form) 'DECLARE))
46      (return))
47    (dolist (decl (%cdr form))
48      (case (car decl)
49        (OPTIMIZE
50         (dolist (spec (%cdr decl))
51           (let ((val 3)
52                 (quality spec))
53             (when (consp spec)
54               (setf quality (%car spec)
55                     val (cadr spec)))
56             (when (and (fixnump val)
57                        (<= 0 val 3))
58               (case quality
59                 (speed
60                  (setf *speed* val))
61                 (safety
62                  (setf *safety* val))
63                 (debug
64                  (setf *debug* val))
65                 (space
66                  (setf *space* val))
67                 (compilation-speed) ;; Ignored.
68                 (t
69                  (compiler-warn "Ignoring unknown optimization quality ~S in ~S." quality decl)))))))
70        ((INLINE NOTINLINE)
71         (dolist (symbol (%cdr decl))
72           (push (cons symbol (%car decl)) *inline-declarations*)))
73        (:explain
74         (dolist (spec (%cdr decl))
75           (let ((val t)
76                 (quality spec))
77             (when (consp spec)
78               (setf quality (%car spec))
79               (when (= (length spec) 2)
80                 (setf val (%cadr spec))))
81             (if val
82                 (pushnew quality *explain*)
83                 (setf *explain* (remove quality *explain*)))))))))
84  t)
85
86;; Returns list of declared specials.
87(declaim (ftype (function (list) list) process-special-declarations))
88(defun process-special-declarations (forms)
89  (let ((specials nil))
90    (dolist (form forms)
91      (unless (and (consp form) (eq (%car form) 'DECLARE))
92        (return))
93      (let ((decls (%cdr form)))
94        (dolist (decl decls)
95          (when (eq (car decl) 'special)
96            (setq specials (append (cdr decl) specials))))))
97    specials))
98
99(declaim (ftype (function (t) t) inline-p))
100(defun inline-p (name)
101  (declare (optimize speed))
102  (let ((entry (assoc name *inline-declarations*)))
103    (if entry
104        (eq (cdr entry) 'INLINE)
105        (and (symbolp name) (eq (get name '%inline) 'INLINE)))))
106
107(declaim (ftype (function (t) t) notinline-p))
108(defun notinline-p (name)
109  (declare (optimize speed))
110  (let ((entry (assoc name *inline-declarations*)))
111    (if entry
112        (eq (cdr entry) 'NOTINLINE)
113        (and (symbolp name) (eq (get name '%inline) 'NOTINLINE)))))
114
115(defun expand-inline (form expansion)
116;;   (format t "expand-inline form = ~S~%" form)
117;;   (format t "expand-inline expansion = ~S~%" expansion)
118  (let* ((op (car form))
119         (proclaimed-ftype (proclaimed-ftype op))
120         (args (cdr form))
121         (vars (cadr expansion))
122         (varlist ())
123         new-form)
124;;     (format t "op = ~S proclaimed-ftype = ~S~%" op (proclaimed-ftype op))
125    (do ((vars vars (cdr vars))
126         (args args (cdr args)))
127        ((null vars))
128      (push (list (car vars) (car args)) varlist))
129    (setf new-form (list* 'LET (nreverse varlist)
130                          (copy-tree (cddr expansion))))
131    (when proclaimed-ftype
132      (let ((result-type (ftype-result-type proclaimed-ftype)))
133        (when (and result-type
134                   (neq result-type t)
135                   (neq result-type '*))
136          (setf new-form (list 'TRULY-THE result-type new-form)))))
137;;     (format t "expand-inline new form = ~S~%" new-form)
138    new-form))
139
140(define-compiler-macro assoc (&whole form &rest args)
141  (cond ((and (= (length args) 4)
142              (eq (third args) :test)
143              (or (equal (fourth args) '(quote eq))
144                  (equal (fourth args) '(function eq))))
145         `(assq ,(first args) ,(second args)))
146        ((= (length args) 2)
147         `(assql ,(first args) ,(second args)))
148        (t form)))
149
150(define-compiler-macro member (&whole form &rest args)
151  (let ((arg1 (first args))
152        (arg2 (second args)))
153    (case (length args)
154      (2
155       `(memql ,arg1 ,arg2))
156      (4
157       (let ((arg3 (third args))
158             (arg4 (fourth args)))
159         (cond ((and (eq arg3 :test)
160                     (or (equal arg4 '(quote eq))
161                         (equal arg4 '(function eq))))
162                `(memq ,arg1 ,arg2))
163               ((and (eq arg3 :test)
164                     (or (equal arg4 '(quote eql))
165                         (equal arg4 '(function eql))
166                         (equal arg4 '(quote char=))
167                         (equal arg4 '(function char=))))
168                `(memql ,arg1 ,arg2))
169               (t
170                form))))
171      (t
172       form))))
173
174(define-compiler-macro search (&whole form &rest args)
175  (if (= (length args) 2)
176      `(simple-search ,@args)
177      form))
178
179(define-compiler-macro identity (&whole form &rest args)
180  (if (= (length args) 1)
181      `(progn ,(car args))
182      form))
183
184(defun quoted-form-p (form)
185  (and (consp form) (eq (%car form) 'QUOTE) (= (length form) 2)))
186
187(define-compiler-macro eql (&whole form &rest args)
188  (let ((first (car args))
189        (second (cadr args)))
190    (if (or (and (quoted-form-p first) (symbolp (cadr first)))
191            (and (quoted-form-p second) (symbolp (cadr second))))
192        `(eq ,first ,second)
193        form)))
194
195(define-compiler-macro not (&whole form arg)
196  (if (atom arg)
197      form
198      (let ((op (case (car arg)
199                  (>= '<)
200                  (<  '>=)
201                  (<= '>)
202                  (>  '<=)
203                  (t  nil))))
204        (if (and op (= (length arg) 3))
205            (cons op (cdr arg))
206            form))))
207
208(defun predicate-for-type (type)
209  (cdr (assq type '((ARRAY             . arrayp)
210                    (ATOM              . atom)
211                    (BIT-VECTOR        . bit-vector-p)
212                    (CHARACTER         . characterp)
213                    (COMPLEX           . complexp)
214                    (CONS              . consp)
215                    (FIXNUM            . fixnump)
216                    (FLOAT             . floatp)
217                    (FUNCTION          . functionp)
218                    (HASH-TABLE        . hash-table-p)
219                    (INTEGER           . integerp)
220                    (LIST              . listp)
221                    (NULL              . null)
222                    (NUMBER            . numberp)
223                    (NUMBER            . numberp)
224                    (PACKAGE           . packagep)
225                    (RATIONAL          . rationalp)
226                    (REAL              . realp)
227                    (SIMPLE-BIT-VECTOR . simple-bit-vector-p)
228                    (SIMPLE-STRING     . simple-string-p)
229                    (SIMPLE-VECTOR     . simple-vector-p)
230                    (STREAM            . streamp)
231                    (STRING            . stringp)
232                    (SYMBOL            . symbolp)))))
233
234(define-compiler-macro typep (&whole form &rest args)
235  (if (= (length args) 2) ; no environment arg
236      (let* ((object (%car args))
237             (type-specifier (%cadr args))
238             (type (and (consp type-specifier)
239                        (eq (%car type-specifier) 'QUOTE)
240                        (%cadr type-specifier)))
241             (predicate (and type (predicate-for-type type))))
242        (if predicate
243            `(,predicate ,object)
244            `(%typep ,@args)))
245      form))
246
247(define-compiler-macro subtypep (&whole form &rest args)
248  (if (= (length args) 2)
249      `(%subtypep ,@args)
250      form))
251
252(define-compiler-macro funcall (&whole form &rest args)
253  (let ((callee (car args)))
254    (if (and (>= *speed* *debug*)
255             (consp callee)
256             (eq (%car callee) 'function)
257             (symbolp (cadr callee))
258             (not (special-operator-p (cadr callee)))
259             (not (macro-function (cadr callee) sys:*compile-file-environment*))
260             (memq (symbol-package (cadr callee))
261                   (list (find-package "CL") (find-package "SYS"))))
262        `(,(cadr callee) ,@(cdr args))
263        form)))
264
265(define-compiler-macro byte (size position)
266  `(cons ,size ,position))
267
268(define-compiler-macro byte-size (bytespec)
269  `(car ,bytespec))
270
271(define-compiler-macro byte-position (bytespec)
272  `(cdr ,bytespec))
273
274(define-source-transform concatenate (&whole form result-type &rest sequences)
275  (if (equal result-type '(quote STRING))
276      `(sys::concatenate-to-string (list ,@sequences))
277      form))
278
279(define-source-transform ldb (&whole form bytespec integer)
280  (if (and (consp bytespec)
281           (eq (%car bytespec) 'byte)
282           (= (length bytespec) 3))
283      (let ((size (%cadr bytespec))
284            (position (%caddr bytespec)))
285        `(%ldb ,size ,position ,integer))
286      form))
287
288(define-source-transform find (&whole form item sequence &key from-end test test-not start end key)
289  (cond ((and (>= (length form) 3) (null start) (null end))
290         (cond ((and (stringp sequence)
291                     (null from-end)
292                     (member test '(#'eql #'char=) :test #'equal)
293                     (null test-not)
294                     (null key))
295                `(string-find ,item ,sequence))
296               (t
297                (let ((item-var (gensym))
298                      (seq-var (gensym)))
299                  `(let ((,item-var ,item)
300                         (,seq-var ,sequence))
301                     (if (listp ,seq-var)
302                         (list-find* ,item-var ,seq-var ,from-end ,test ,test-not 0 (length ,seq-var) ,key)
303                         (vector-find* ,item-var ,seq-var ,from-end ,test ,test-not 0 (length ,seq-var) ,key)))))))
304        (t
305         form)))
306
307(define-source-transform adjoin (&whole form &rest args)
308  (if (= (length args) 2)
309      `(adjoin-eql ,(first args) ,(second args))
310      form))
311
312(define-compiler-macro catch (&whole form tag &rest args)
313  (declare (ignore tag))
314  (if (and (null (cdr args))
315           (constantp (car args)))
316      (car args)
317      form))
318
319(define-compiler-macro string= (&whole form &rest args)
320  (if (= (length args) 2)
321      `(sys::%%string= ,@args)
322      form))
323
324(define-compiler-macro <= (&whole form &rest args)
325  (cond ((and (= (length args) 3)
326              (numberp (first args))
327              (numberp (third args))
328              (= (first args) (third args)))
329         `(= ,(second args) ,(first args)))
330        (t
331         form)))
332
333(in-package "EXTENSIONS")
334
335(export '(precompile-form precompile))
336
337(unless (find-package "PRECOMPILER")
338  (make-package "PRECOMPILER"
339                :nicknames '("PRE")
340                :use '("COMMON-LISP" "EXTENSIONS" "SYSTEM")))
341
342(in-package "PRECOMPILER")
343
344(defvar *in-jvm-compile* nil)
345
346(defvar *local-variables* nil)
347
348(declaim (ftype (function (t) t) find-varspec))
349(defun find-varspec (sym)
350  (dolist (varspec *local-variables*)
351    (when (eq sym (car varspec))
352      (return varspec))))
353
354(declaim (ftype (function (t) t) precompile1))
355(defun precompile1 (form)
356  (cond ((symbolp form)
357         (let ((varspec (find-varspec form)))
358           (cond ((and varspec (eq (second varspec) :symbol-macro))
359                  (precompile1 (copy-tree (third varspec))))
360                 ((null varspec)
361                  (let ((expansion (expand-macro form)))
362                    (if (eq expansion form)
363                        form
364                        (precompile1 expansion))))
365                 (t
366                  form))))
367        ((atom form)
368         form)
369        (t
370         (let ((op (%car form))
371               handler)
372           (when (symbolp op)
373             (cond ((setf handler (get op 'precompile-handler))
374                    (return-from precompile1 (funcall handler form)))
375                   ((macro-function op *compile-file-environment*)
376                    (return-from precompile1 (precompile1 (expand-macro form))))
377                   ((special-operator-p op)
378                    (error "PRECOMPILE1: unsupported special operator ~S." op))))
379           (precompile-function-call form)))))
380
381(defun precompile-identity (form)
382  (declare (optimize speed))
383  form)
384
385(declaim (ftype (function (t) cons) precompile-cons))
386(defun precompile-cons (form)
387  (cons (car form) (mapcar #'precompile1 (cdr form))))
388
389(declaim (ftype (function (t t) t) precompile-function-call))
390(defun precompile-function-call (form)
391  (let ((op (car form)))
392    (when (and (consp op) (eq (%car op) 'LAMBDA))
393      (return-from precompile-function-call
394                   (cons (precompile-lambda op)
395                         (mapcar #'precompile1 (cdr form)))))
396    (when (or (not *in-jvm-compile*) (notinline-p op))
397      (return-from precompile-function-call (precompile-cons form)))
398    (when (source-transform op)
399      (let ((new-form (expand-source-transform form)))
400        (when (neq new-form form)
401          (return-from precompile-function-call (precompile1 new-form)))))
402    (when *enable-inline-expansion*
403      (let ((expansion (inline-expansion op)))
404        (when expansion
405          (let ((explain *explain*))
406            (when (and explain (memq :calls explain))
407              (format t ";   inlining call to ~S~%" op)))
408          (return-from precompile-function-call (precompile1 (expand-inline form expansion))))))
409    (cons op (mapcar #'precompile1 (cdr form)))))
410
411(defun precompile-locally (form)
412  (let ((*inline-declarations* *inline-declarations*))
413    (process-optimization-declarations (cdr form))
414  (cons 'LOCALLY (mapcar #'precompile1 (cdr form)))))
415
416(defun precompile-block (form)
417  (let ((args (cdr form)))
418    (if (null (cdr args))
419        nil
420        (list* 'BLOCK (car args) (mapcar #'precompile1 (cdr args))))))
421
422(defun precompile-dolist (form)
423  (if *in-jvm-compile*
424      (precompile1 (macroexpand form *compile-file-environment*))
425      (cons 'DOLIST (cons (mapcar #'precompile1 (cadr form))
426                          (mapcar #'precompile1 (cddr form))))))
427
428(defun precompile-dotimes (form)
429  (if *in-jvm-compile*
430      (precompile1 (macroexpand form *compile-file-environment*))
431      (cons 'DOTIMES (cons (mapcar #'precompile1 (cadr form))
432                           (mapcar #'precompile1 (cddr form))))))
433
434(defun precompile-do/do*-vars (varlist)
435  (let ((result nil))
436    (dolist (varspec varlist)
437      (if (atom varspec)
438          (push varspec result)
439          (case (length varspec)
440            (1
441             (push (%car varspec) result))
442            (2
443             (let* ((var (%car varspec))
444                    (init-form (%cadr varspec)))
445               (unless (symbolp var)
446                 (error 'type-error))
447               (push (list var (precompile1 init-form))
448                     result)))
449            (3
450             (let* ((var (%car varspec))
451                    (init-form (%cadr varspec))
452                    (step-form (%caddr varspec)))
453               (unless (symbolp var)
454                 (error 'type-error))
455               (push (list var (precompile1 init-form) (precompile1 step-form))
456                     result))))))
457    (nreverse result)))
458
459(defun precompile-do/do*-end-form (end-form)
460  (let ((end-test-form (car end-form))
461        (result-forms (cdr end-form)))
462    (list* end-test-form (mapcar #'precompile1 result-forms))))
463
464(defun precompile-do/do* (form)
465  (if *in-jvm-compile*
466      (precompile1 (macroexpand form *compile-file-environment*))
467      (list* (car form)
468             (precompile-do/do*-vars (cadr form))
469             (precompile-do/do*-end-form (caddr form))
470             (mapcar #'precompile1 (cdddr form)))))
471
472(defun precompile-do-symbols (form)
473  (list* (car form) (cadr form) (mapcar #'precompile1 (cddr form))))
474
475(defun precompile-load-time-value (form)
476  form)
477
478(defun precompile-progn (form)
479  (let ((body (cdr form)))
480    (if (eql (length body) 1)
481        (let ((res (precompile1 (%car body))))
482          ;; If the result turns out to be a bare symbol, leave it wrapped
483          ;; with PROGN so it won't be mistaken for a tag in an enclosing
484          ;; TAGBODY.
485          (if (symbolp res)
486              (list 'progn res)
487              res))
488        (cons 'PROGN (mapcar #'precompile1 body)))))
489
490(defun precompile-progv (form)
491  (if (< (length form) 3)
492      (compiler-error "Not enough arguments for ~S." 'progv)
493      (list* 'PROGV (mapcar #'precompile1 (%cdr form)))))
494
495(defun precompile-setf (form)
496  (let ((place (second form)))
497    (cond ((and (consp place)
498                (eq (%car place) 'VALUES))
499     (setf form
500     (list* 'SETF
501      (list* 'VALUES
502             (mapcar #'precompile1 (%cdr place)))
503      (cddr form)))
504     (precompile1 (expand-macro form)))
505    ((symbolp place)
506           (let ((varspec (find-varspec place)))
507             (if (and varspec (eq (second varspec) :symbol-macro))
508                 (precompile1 (list* 'SETF (copy-tree (third varspec)) (cddr form)))
509                 (precompile1 (expand-macro form)))))
510          (t
511           (precompile1 (expand-macro form))))))
512
513(defun precompile-setq (form)
514  (let* ((args (cdr form))
515         (len (length args)))
516    (when (oddp len)
517      (error 'simple-program-error
518             :format-control "Odd number of arguments to SETQ."))
519    (if (= len 2)
520        (let* ((sym (%car args))
521               (val (%cadr args))
522               (varspec (find-varspec sym)))
523          (if (and varspec (eq (second varspec) :symbol-macro))
524              (precompile1 (list 'SETF (copy-tree (third varspec)) val))
525              (list 'SETQ sym (precompile1 val))))
526        (let ((result ()))
527          (loop
528            (when (null args)
529              (return))
530            (push (precompile-setq (list 'SETQ (car args) (cadr args))) result)
531            (setq args (cddr args)))
532          (setq result (nreverse result))
533          (push 'PROGN result)
534          result))))
535
536(defun precompile-psetf (form)
537  (setf form
538        (list* 'PSETF
539               (mapcar #'precompile1 (cdr form))))
540  (precompile1 (expand-macro form)))
541
542(defun precompile-psetq (form)
543  ;; Make sure all the vars are symbols.
544  (do* ((rest (cdr form) (cddr rest))
545        (var (car rest)))
546       ((null rest))
547    (unless (symbolp var)
548      (error 'simple-error
549             :format-control "~S is not a symbol."
550             :format-arguments (list var))))
551  ;; Delegate to PRECOMPILE-PSETF so symbol macros are handled correctly.
552  (precompile-psetf form))
553
554(defun rewrite-aux-vars-process-decls (forms arg-vars aux-vars)
555  (declare (ignore aux-vars))
556  (let ((lambda-decls nil)
557        (let-decls nil))
558    (dolist (form forms)
559      (unless (and (consp form) (eq (car form) 'DECLARE)) ; shouldn't happen
560        (return))
561      (dolist (decl (cdr form))
562        (case (car decl)
563          ((OPTIMIZE DECLARATION DYNAMIC-EXTENT FTYPE INLINE NOTINLINE)
564           (push (list 'DECLARE decl) lambda-decls))
565          (SPECIAL
566           (dolist (name (cdr decl))
567             (if (memq name arg-vars)
568                 (push (list 'DECLARE (list 'SPECIAL name)) lambda-decls)
569                 (push (list 'DECLARE (list 'SPECIAL name)) let-decls))))
570          (TYPE
571           (dolist (name (cddr decl))
572             (if (memq name arg-vars)
573                 (push (list 'DECLARE (list 'TYPE (cadr decl) name)) lambda-decls)
574                 (push (list 'DECLARE (list 'TYPE (cadr decl) name)) let-decls))))
575          (t
576           (dolist (name (cdr decl))
577             (if (memq name arg-vars)
578                 (push (list 'DECLARE (list (car decl) name)) lambda-decls)
579                 (push (list 'DECLARE (list (car decl) name)) let-decls)))))))
580    (setq lambda-decls (nreverse lambda-decls))
581    (setq let-decls (nreverse let-decls))
582    (values lambda-decls let-decls)))
583
584(defun rewrite-aux-vars (form)
585  (multiple-value-bind (body decls doc)
586      (parse-body (cddr form))
587    (declare (ignore doc)) ; FIXME
588    (let* ((lambda-list (cadr form))
589           (lets (cdr (memq '&AUX lambda-list)))
590           aux-vars)
591      (dolist (form lets)
592        (cond ((consp form)
593               (push (%car form) aux-vars))
594              (t
595               (push form aux-vars))))
596      (setq aux-vars (nreverse aux-vars))
597      (setq lambda-list (subseq lambda-list 0 (position '&AUX lambda-list)))
598      (multiple-value-bind (lambda-decls let-decls)
599          (rewrite-aux-vars-process-decls decls
600                                          (lambda-list-names lambda-list)
601                                          aux-vars)
602        `(lambda ,lambda-list
603           ,@lambda-decls
604           (let* ,lets
605             ,@let-decls
606             ,@body))))))
607
608(defun maybe-rewrite-lambda (form)
609  (let* ((lambda-list (cadr form)))
610    (when (memq '&AUX lambda-list)
611      (setq form (rewrite-aux-vars form))
612      (setq lambda-list (cadr form)))
613    (multiple-value-bind (body decls doc)
614        (parse-body (cddr form))
615      (let (state let-bindings new-lambda-list
616            (non-constants 0))
617        (do* ((vars lambda-list (cdr vars))
618              (var (car vars) (car vars)))
619             ((endp vars))
620          (push (car vars) new-lambda-list)
621          (let ((replacement (gensym)))
622            (flet ((parse-compound-argument (arg)
623                     "Returns the values NAME, KEYWORD, INITFORM, INITFORM-P,
624   SUPPLIED-P and SUPPLIED-P-P assuming ARG is a compound argument."
625                     (destructuring-bind
626                           (name &optional (initform nil initform-supplied-p)
627                                 (supplied-p nil supplied-p-supplied-p))
628                         (if (listp arg) arg (list arg))
629                       (if (listp name)
630                           (values (cadr name) (car name)
631                                   initform initform-supplied-p
632                                   supplied-p supplied-p-supplied-p)
633                           (values name (make-keyword name)
634                                   initform initform-supplied-p
635                                   supplied-p supplied-p-supplied-p)))))
636            (case var
637              (&optional (setf state :optional))
638              (&key (setf state :key))
639              ((&whole &environment &rest &body &allow-other-keys)
640               ;; do nothing special
641               )
642              (t
643               (cond
644                 ((atom var)
645                  (setf (car new-lambda-list)
646                        (if (eq state :key)
647                            (list (list (make-keyword var) replacement))
648                            replacement))
649                  (push (list var replacement) let-bindings))
650                 ((constantp (second var))
651                  ;; so, we must have a consp-type var we're looking at
652                  ;; and it has a constantp initform
653                  (multiple-value-bind
654                        (name keyword initform initform-supplied-p
655                              supplied-p supplied-p-supplied-p)
656                      (parse-compound-argument var)
657                    (let ((var-form (if (eq state :key)
658                                        (list keyword replacement)
659                                        replacement))
660                          (supplied-p-replacement (gensym)))
661                      (setf (car new-lambda-list)
662                            (cond
663                              ((not initform-supplied-p)
664                               (list var-form))
665                              ((not supplied-p-supplied-p)
666                               (list var-form initform))
667                              (t
668                               (list var-form initform
669                                     supplied-p-replacement))))
670                      (push (list name replacement) let-bindings)
671                      ;; if there was a 'supplied-p' variable, it might
672                      ;; be used in the declarations. Since those will be
673                      ;; moved below the LET* block, we need to move the
674                      ;; supplied-p parameter too.
675                      (when supplied-p-supplied-p
676                        (push (list supplied-p supplied-p-replacement)
677                              let-bindings)))))
678                 (t
679                  (incf non-constants)
680                  ;; this is either a keyword or an optional argument
681                  ;; with a non-constantp initform
682                  (multiple-value-bind
683                        (name keyword initform initform-supplied-p
684                              supplied-p supplied-p-supplied-p)
685                      (parse-compound-argument var)
686                    (declare (ignore initform-supplied-p))
687                    (let ((var-form (if (eq state :key)
688                                        (list keyword replacement)
689                                        replacement))
690                          (supplied-p-replacement (gensym)))
691                      (setf (car new-lambda-list)
692                            (list var-form nil supplied-p-replacement))
693                      (push (list name `(if ,supplied-p-replacement
694                                            ,replacement ,initform))
695                                  let-bindings)
696                      (when supplied-p-supplied-p
697                        (push (list supplied-p supplied-p-replacement)
698                              let-bindings)))))))))))
699        (if (zerop non-constants)
700            ;; there was no reason to rewrite...
701            form
702            (let ((rv
703                   `(lambda ,(nreverse new-lambda-list)
704                      ,@(when doc (list doc))
705                      (let* ,(nreverse let-bindings)
706                        ,@decls ,@body))))
707              rv))))))
708
709(defun precompile-lambda-list (form)
710  (let (new)
711    (dolist (arg form (nreverse new))
712       (if (or (atom arg) (> 2 (length arg)))
713          (push arg new)
714          ;; must be a cons of more than 1 cell
715          (let ((new-arg (copy-list arg)))
716             (setf (second new-arg)
717                   (precompile1 (second arg)))
718             (push new-arg new))))))
719
720(defun precompile-lambda (form)
721  (setq form (maybe-rewrite-lambda form))
722  (let ((body (cddr form))
723        (precompiled-lambda-list
724           (precompile-lambda-list (cadr form)))
725        (*inline-declarations* *inline-declarations*))
726    (process-optimization-declarations body)
727    (list* 'LAMBDA precompiled-lambda-list
728           (mapcar #'precompile1 body))))
729
730(defun precompile-named-lambda (form)
731  (let ((lambda-form (list* 'LAMBDA (caddr form) (cdddr form))))
732    (setf lambda-form (maybe-rewrite-lambda lambda-form))
733    (let ((body (cddr lambda-form))
734          (precompiled-lambda-list
735           (precompile-lambda-list (cadr lambda-form)))
736          (*inline-declarations* *inline-declarations*))
737      (process-optimization-declarations body)
738      (list* 'NAMED-LAMBDA (cadr form) precompiled-lambda-list
739             (mapcar #'precompile1 body)))))
740
741(defun precompile-defun (form)
742  (if *in-jvm-compile*
743      (precompile1 (expand-macro form))
744      form))
745
746(defvar *local-functions-and-macros* ())
747
748(defun precompile-macrolet (form)
749  (let ((*compile-file-environment*
750         (make-environment *compile-file-environment*)))
751    (dolist (definition (cadr form))
752      (environment-add-macro-definition
753       *compile-file-environment*
754       (car definition)
755       (make-macro (car definition)
756                   (make-closure
757                    (make-expander-for-macrolet definition)
758                    NIL))))
759    (multiple-value-bind (body decls)
760        (parse-body (cddr form) nil)
761      `(locally ,@decls ,@(mapcar #'precompile1 body)))))
762
763(defun precompile-symbol-macrolet (form)
764  (let ((*local-variables* *local-variables*)
765        (*compile-file-environment*
766         (make-environment *compile-file-environment*))
767        (defs (cadr form)))
768    (dolist (def defs)
769      (let ((sym (car def))
770            (expansion (cadr def)))
771        (when (special-variable-p sym)
772          (error 'program-error
773                 :format-control "Attempt to bind the special variable ~S with SYMBOL-MACROLET."
774                 :format-arguments (list sym)))
775        (push (list sym :symbol-macro expansion) *local-variables*)
776        (environment-add-symbol-binding *compile-file-environment*
777                                        sym
778                                        (sys::make-symbol-macro expansion))
779        ))
780    (multiple-value-bind (body decls)
781        (parse-body (cddr form) nil)
782      (when decls
783        (let ((specials ()))
784          (dolist (decl decls)
785            (when (eq (car decl) 'DECLARE)
786              (dolist (declspec (cdr decl))
787                (when (eq (car declspec) 'SPECIAL)
788                  (setf specials (append specials (cdr declspec)))))))
789          (when specials
790            (let ((syms (mapcar #'car (cadr form))))
791              (dolist (special specials)
792                (when (memq special syms)
793                  (error 'program-error
794                         :format-control "~S is a symbol-macro and may not be declared special."
795                         :format-arguments (list special))))))))
796      `(locally ,@decls ,@(mapcar #'precompile1 body)))))
797
798(defun precompile-the (form)
799  (list 'THE
800        (second form)
801        (precompile1 (third form))))
802
803(defun precompile-truly-the (form)
804  (list 'TRULY-THE
805        (second form)
806        (precompile1 (third form))))
807
808(defun precompile-let/let*-vars (vars)
809  (let ((result nil))
810    (dolist (var vars)
811      (cond ((consp var)
812;;              (when (> (length var) 2)
813;;                (error 'program-error
814;;                       :format-control "The LET/LET* binding specification ~S is invalid."
815;;                       :format-arguments (list var)))
816             (let ((v (%car var))
817                   (expr (cadr var)))
818               (unless (symbolp v)
819                 (error 'simple-type-error
820                        :format-control "The variable ~S is not a symbol."
821                        :format-arguments (list v)))
822               (push (list v (precompile1 expr)) result)
823               (push (list v :variable) *local-variables*)))
824            (t
825             (push var result)
826             (push (list var :variable) *local-variables*))))
827    (nreverse result)))
828
829(defun precompile-let (form)
830  (let ((*local-variables* *local-variables*))
831    (list* 'LET
832           (precompile-let/let*-vars (cadr form))
833           (mapcar #'precompile1 (cddr form)))))
834
835;; (LET* ((X 1)) (LET* ((Y 2)) (LET* ((Z 3)) (+ X Y Z)))) =>
836;; (LET* ((X 1) (Y 2) (Z 3)) (+ X Y Z))
837(defun maybe-fold-let* (form)
838  (if (and (= (length form) 3)
839           (consp (%caddr form))
840           (eq (%car (%caddr form)) 'LET*))
841      (let ((third (maybe-fold-let* (%caddr form))))
842        (list* 'LET* (append (%cadr form) (cadr third)) (cddr third)))
843      form))
844
845(defun precompile-let* (form)
846  (setf form (maybe-fold-let* form))
847  (let ((*local-variables* *local-variables*))
848    (list* 'LET*
849           (precompile-let/let*-vars (cadr form))
850           (mapcar #'precompile1 (cddr form)))))
851
852(defun precompile-case (form)
853  (if *in-jvm-compile*
854      (precompile1 (macroexpand form *compile-file-environment*))
855      (let* ((keyform (cadr form))
856             (clauses (cddr form))
857             (result (list (precompile1 keyform))))
858        (dolist (clause clauses)
859          (push (precompile-case-clause clause) result))
860        (cons (car form) (nreverse result)))))
861
862(defun precompile-case-clause (clause)
863  (let ((keys (car clause))
864        (forms (cdr clause)))
865    (cons keys (mapcar #'precompile1 forms))))
866
867(defun precompile-cond (form)
868  (if *in-jvm-compile*
869      (precompile1 (macroexpand form *compile-file-environment*))
870      (let ((clauses (cdr form))
871            (result nil))
872        (dolist (clause clauses)
873          (push (precompile-cond-clause clause) result))
874        (cons 'COND (nreverse result)))))
875
876(defun precompile-cond-clause (clause)
877  (let ((test (car clause))
878        (forms (cdr clause)))
879    (cons (precompile1 test) (mapcar #'precompile1 forms))))
880
881(defun precompile-local-function-def (def)
882  (let ((name (car def))
883        (arglist (cadr def))
884        (body (cddr def)))
885    ;; Macro names are shadowed by local functions.
886    (environment-add-function-definition *compile-file-environment* name body)
887    (list* name arglist (mapcar #'precompile1 body))))
888
889(defun precompile-local-functions (defs)
890  (let ((result nil))
891    (dolist (def defs (nreverse result))
892      (push (precompile-local-function-def def) result))))
893
894(defun find-use (name expression)
895  (cond ((atom expression)
896         nil)
897        ((eq (%car expression) name)
898         t)
899        ((consp name)
900         t) ;; FIXME Recognize use of SETF functions!
901        (t
902         (or (find-use name (%car expression))
903             (find-use name (%cdr expression))))))
904
905(defun precompile-flet/labels (form)
906  (let ((*compile-file-environment*
907         (make-environment *compile-file-environment*))
908        (operator (car form))
909        (locals (cadr form))
910        (body (cddr form)))
911    (dolist (local locals)
912      (let* ((name (car local))
913             (used-p (find-use name body)))
914        (unless used-p
915          (when (eq operator 'LABELS)
916            (dolist (local locals)
917              (when (neq name (car local))
918                (when (find-use name (cddr local))
919                  (setf used-p t)
920                  (return))
921                ;; Scope of defined function names includes
922                ;; &OPTIONAL, &KEY and &AUX parameters
923                ;; (LABELS.7B, LABELS.7C and LABELS.7D).
924                (let ((vars (or
925                             (cdr (memq '&optional (cadr local)))
926                             (cdr (memq '&key (cadr local)))
927                             (cdr (memq '&aux (cadr local))))))
928                  (when (and vars (find-use name vars)
929                             (setf used-p t)
930                             (return))))))))
931        (unless used-p
932          (format t "; Note: deleting unused local function ~A ~S~%" operator name)
933          (let* ((new-locals (remove local locals :test 'eq))
934                 (new-form
935                  (if new-locals
936                      (list* operator new-locals body)
937                      (list* 'PROGN body))))
938            (return-from precompile-flet/labels (precompile1 new-form))))))
939    (list* (car form)
940           (precompile-local-functions locals)
941           (mapcar #'precompile1 body))))
942
943(defun precompile-function (form)
944  (if (and (consp (cadr form)) (eq (caadr form) 'LAMBDA))
945      (list 'FUNCTION (precompile-lambda (%cadr form)))
946      form))
947
948(defun precompile-if (form)
949  (let ((args (cdr form)))
950    (case (length args)
951      (2
952       (let ((test (precompile1 (%car args))))
953         (cond ((null test)
954                nil)
955               (;;(constantp test)
956                (eq test t)
957                (precompile1 (%cadr args)))
958               (t
959                (list 'IF
960                      test
961                      (precompile1 (%cadr args)))))))
962      (3
963       (let ((test (precompile1 (%car args))))
964         (cond ((null test)
965                (precompile1 (%caddr args)))
966               (;;(constantp test)
967                (eq test t)
968                (precompile1 (%cadr args)))
969               (t
970                (list 'IF
971                      test
972                      (precompile1 (%cadr args))
973                      (precompile1 (%caddr args)))))))
974      (t
975       (error "wrong number of arguments for IF")))))
976
977(defun precompile-when (form)
978  (if *in-jvm-compile*
979      (precompile1 (macroexpand form *compile-file-environment*))
980      (precompile-cons form)))
981
982(defun precompile-unless (form)
983  (if *in-jvm-compile*
984      (precompile1 (macroexpand form *compile-file-environment*))
985      (precompile-cons form)))
986
987;; MULTIPLE-VALUE-BIND is handled explicitly by the JVM compiler.
988(defun precompile-multiple-value-bind (form)
989  (let ((vars (cadr form))
990        (values-form (caddr form))
991        (body (cdddr form)))
992    (list* 'MULTIPLE-VALUE-BIND
993           vars
994           (precompile1 values-form)
995           (mapcar #'precompile1 body))))
996
997;; MULTIPLE-VALUE-LIST is handled explicitly by the JVM compiler.
998(defun precompile-multiple-value-list (form)
999  (list 'MULTIPLE-VALUE-LIST (precompile1 (cadr form))))
1000
1001(defun precompile-nth-value (form)
1002  (if *in-jvm-compile*
1003      (precompile1 (macroexpand form *compile-file-environment*))
1004      form))
1005
1006(defun precompile-return (form)
1007  (if *in-jvm-compile*
1008      (precompile1 (macroexpand form *compile-file-environment*))
1009      (list 'RETURN (precompile1 (cadr form)))))
1010
1011(defun precompile-return-from (form)
1012  (list 'RETURN-FROM (cadr form) (precompile1 (caddr form))))
1013
1014(defun precompile-tagbody (form)
1015  (do ((body (cdr form) (cdr body))
1016       (result ()))
1017      ((null body) (cons 'TAGBODY (nreverse result)))
1018    (if (atom (car body))
1019        (push (car body) result)
1020        (push (let* ((first-form (car body))
1021                     (expanded (precompile1 first-form)))
1022                (if (and (symbolp expanded)
1023                         (neq expanded first-form))
1024                    ;; Workaround:
1025                    ;;  Since our expansion/compilation order
1026                    ;;   is out of sync with the definition of
1027                    ;;   TAGBODY (which requires the compiler
1028                    ;;   to look for tags before expanding),
1029                    ;;   we need to disguise anything which might
1030                    ;;   look like a tag. We do this by wrapping
1031                    ;;   it in a PROGN form.
1032                    (list 'PROGN expanded)
1033                    expanded)) result))))
1034
1035(defun precompile-eval-when (form)
1036  (list* 'EVAL-WHEN (cadr form) (mapcar #'precompile1 (cddr form))))
1037
1038(defun precompile-unwind-protect (form)
1039  (list* 'UNWIND-PROTECT
1040         (precompile1 (cadr form))
1041         (mapcar #'precompile1 (cddr form))))
1042
1043;; EXPAND-MACRO is like MACROEXPAND, but EXPAND-MACRO quits if *IN-JVM-COMPILE*
1044;; is false and a macro is encountered that is also implemented as a special
1045;; operator, so interpreted code can use the special operator implementation.
1046(defun expand-macro (form)
1047  (loop
1048    (unless *in-jvm-compile*
1049      (when (and (consp form)
1050                 (symbolp (%car form))
1051                 (special-operator-p (%car form)))
1052        (return-from expand-macro form)))
1053    (multiple-value-bind (result expanded)
1054        (macroexpand-1 form *compile-file-environment*)
1055      (unless expanded
1056        (return-from expand-macro result))
1057      (setf form result))))
1058
1059(declaim (ftype (function (t t) t) precompile-form))
1060(defun precompile-form (form in-jvm-compile)
1061  (let ((*in-jvm-compile* in-jvm-compile)
1062        (*inline-declarations* *inline-declarations*)
1063        (*local-functions-and-macros* ()))
1064    (precompile1 form)))
1065
1066(defun install-handler (symbol &optional handler)
1067  (declare (type symbol symbol))
1068  (let ((handler (or handler
1069                     (find-symbol (sys::%format nil "PRECOMPILE-~A" (symbol-name symbol))
1070                                  'precompiler))))
1071    (unless (and handler (fboundp handler))
1072      (error "No handler for ~S." symbol))
1073    (setf (get symbol 'precompile-handler) handler)))
1074
1075(defun install-handlers ()
1076  (mapcar #'install-handler '(BLOCK
1077                              CASE
1078                              COND
1079                              DOLIST
1080                              DOTIMES
1081                              EVAL-WHEN
1082                              FUNCTION
1083                              IF
1084                              LAMBDA
1085                              MACROLET
1086                              MULTIPLE-VALUE-BIND
1087                              MULTIPLE-VALUE-LIST
1088                              NAMED-LAMBDA
1089                              NTH-VALUE
1090                              PROGN
1091                              PROGV
1092                              PSETF
1093                              PSETQ
1094                              RETURN
1095                              RETURN-FROM
1096                              SETF
1097                              SETQ
1098                              SYMBOL-MACROLET
1099                              TAGBODY
1100                              UNWIND-PROTECT
1101                              UNLESS
1102                              WHEN))
1103
1104  (dolist (pair '((ECASE                precompile-case)
1105
1106                  (AND                  precompile-cons)
1107                  (OR                   precompile-cons)
1108
1109                  (CATCH                precompile-cons)
1110                  (MULTIPLE-VALUE-CALL  precompile-cons)
1111                  (MULTIPLE-VALUE-PROG1 precompile-cons)
1112
1113                  (DO                   precompile-do/do*)
1114                  (DO*                  precompile-do/do*)
1115
1116                  (LET                  precompile-let)
1117                  (LET*                 precompile-let*)
1118
1119                  (LOCALLY              precompile-locally)
1120
1121                  (FLET                 precompile-flet/labels)
1122                  (LABELS               precompile-flet/labels)
1123
1124                  (LOAD-TIME-VALUE      precompile-load-time-value)
1125
1126                  (DECLARE              precompile-identity)
1127;;                   (DEFMETHOD            precompile-identity)
1128                  (DEFUN                precompile-defun)
1129                  (GO                   precompile-identity)
1130                  (QUOTE                precompile-identity)
1131                  (THE                  precompile-the)
1132                  (THROW                precompile-cons)
1133                  (TRULY-THE            precompile-truly-the)))
1134    (install-handler (first pair) (second pair))))
1135
1136(install-handlers)
1137
1138(in-package #:system)
1139
1140(defun macroexpand-all (form &optional env)
1141  (let ((*compile-file-environment* env))
1142    (precompile-form form nil)))
1143
1144(defmacro compiler-let (bindings &body forms &environment env)
1145  (let ((bindings (mapcar #'(lambda (binding)
1146                              (if (atom binding) (list binding) binding))
1147                          bindings)))
1148    (progv (mapcar #'car bindings)
1149           (mapcar #'(lambda (binding)
1150                       (eval (cadr binding))) bindings)
1151      (macroexpand-all `(progn ,@forms) env))))
1152
1153(defun precompile (name &optional definition)
1154  (unless definition
1155    (setq definition (or (and (symbolp name) (macro-function name))
1156                         (fdefinition name))))
1157  (let (expr result)
1158    (cond ((functionp definition)
1159           (multiple-value-bind (form closure-p)
1160             (function-lambda-expression definition)
1161             (unless form
1162;;                (format t "; No lambda expression available for ~S.~%" name)
1163               (return-from precompile (values nil t t)))
1164             (when closure-p
1165               (format t "; Unable to compile function ~S defined in non-null lexical environment.~%" name)
1166               (finish-output)
1167               (return-from precompile (values nil t t)))
1168             (setq expr form)))
1169          ((and (consp definition) (eq (%car definition) 'lambda))
1170           (setq expr definition))
1171          (t
1172;;            (error 'type-error)))
1173           (format t "Unable to precompile ~S.~%" name)
1174           (return-from precompile (values nil t t))))
1175    (setf result (coerce-to-function (precompile-form expr nil)))
1176    (when (and name (functionp result))
1177      (%set-lambda-name result name)
1178      (set-call-count result (call-count definition))
1179      (let ((*warn-on-redefinition* nil))
1180        (if (and (symbolp name) (macro-function name))
1181            (let ((mac (make-macro name result)))
1182              (%set-arglist mac (arglist (symbol-function name)))
1183              (setf (fdefinition name) mac))
1184            (progn
1185              (setf (fdefinition name) result)
1186              (%set-arglist result (arglist definition))))))
1187    (values (or name result) nil nil)))
1188
1189(defun precompile-package (pkg &key verbose)
1190  (dolist (sym (package-symbols pkg))
1191    (when (fboundp sym)
1192      (unless (special-operator-p sym)
1193        (let ((f (fdefinition sym)))
1194          (unless (compiled-function-p f)
1195            (when verbose
1196              (format t "Precompiling ~S~%" sym)
1197              (finish-output))
1198            (precompile sym))))))
1199  t)
1200
1201(defun %compile (name definition)
1202  (if (and name (fboundp name) (%typep (symbol-function name) 'generic-function))
1203      (values name nil nil)
1204      (precompile name definition)))
1205
1206;; ;; Redefine EVAL to precompile its argument.
1207;; (defun eval (form)
1208;;   (%eval (precompile-form form nil)))
1209
1210;; ;; Redefine DEFMACRO to precompile the expansion function on the fly.
1211;; (defmacro defmacro (name lambda-list &rest body)
1212;;   (let* ((form (gensym "WHOLE-"))
1213;;          (env (gensym "ENVIRONMENT-")))
1214;;     (multiple-value-bind (body decls)
1215;;         (parse-defmacro lambda-list form body name 'defmacro :environment env)
1216;;       (let ((expander `(lambda (,form ,env) ,@decls (block ,name ,body))))
1217;;         `(progn
1218;;            (let ((macro (make-macro ',name
1219;;                                     (or (precompile nil ,expander) ,expander))))
1220;;              ,@(if (special-operator-p name)
1221;;                    `((put ',name 'macroexpand-macro macro))
1222;;                    `((fset ',name macro)))
1223;;              (%set-arglist macro ',lambda-list)
1224;;              ',name))))))
1225
1226;; Make an exception just this one time...
1227(when (get 'defmacro 'macroexpand-macro)
1228  (fset 'defmacro (get 'defmacro 'macroexpand-macro))
1229  (remprop 'defmacro 'macroexpand-macro))
1230
1231(defvar *defined-functions*)
1232
1233(defvar *undefined-functions*)
1234
1235(defun note-name-defined (name)
1236  (when (boundp '*defined-functions*)
1237    (push name *defined-functions*))
1238  (when (and (boundp '*undefined-functions*) (not (null *undefined-functions*)))
1239    (setf *undefined-functions* (remove name *undefined-functions*))))
1240
1241;; Redefine DEFUN to precompile the definition on the fly.
1242(defmacro defun (name lambda-list &body body &environment env)
1243  (note-name-defined name)
1244  (multiple-value-bind (body decls doc)
1245      (parse-body body)
1246    (let* ((block-name (fdefinition-block-name name))
1247           (lambda-expression
1248            `(named-lambda ,name ,lambda-list
1249                           ,@decls
1250                           ,@(when doc `(,doc))
1251                           (block ,block-name ,@body))))
1252      (cond ((and (boundp 'jvm::*file-compilation*)
1253                  ;; when JVM.lisp isn't loaded yet, this variable isn't bound
1254                  ;; meaning that we're not trying to compile to a file:
1255                  ;; Both COMPILE and COMPILE-FILE bind this variable.
1256                  ;; This function is also triggered by MACROEXPAND, though
1257                  jvm::*file-compilation*)
1258             `(fset ',name ,lambda-expression))
1259            (t
1260             (when (and env (empty-environment-p env))
1261               (setf env nil))
1262             (when (null env)
1263               (setf lambda-expression (precompile-form lambda-expression nil)))
1264             `(progn
1265                (%defun ',name ,lambda-expression)
1266                ,@(when doc
1267                   `((%set-documentation ',name 'function ,doc)))))))))
Note: See TracBrowser for help on using the repository browser.