source: trunk/abcl/src/org/armedbear/lisp/precompiler.lisp @ 11915

Last change on this file since 11915 was 11915, checked in by ehuelsmann, 12 years ago

Reuse available infrastructure in Environment,
instead of keeping track of locals (and their
shadowing effect) ourselves.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 41.6 KB
Line 
1;;; precompiler.lisp
2;;;
3;;; Copyright (C) 2003-2008 Peter Graves <peter@armedbear.org>
4;;; $Id: precompiler.lisp 11915 2009-05-21 17:14:40Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package "SYSTEM")
33
34(export '(*inline-declarations*
35          process-optimization-declarations
36          process-special-declarations
37          inline-p notinline-p inline-expansion expand-inline
38          *defined-functions* *undefined-functions* note-name-defined))
39
40(defvar *inline-declarations* nil)
41
42(declaim (ftype (function (t) t) process-optimization-declarations))
43(defun process-optimization-declarations (forms)
44  (dolist (form forms)
45    (unless (and (consp form) (eq (%car form) 'DECLARE))
46      (return))
47    (dolist (decl (%cdr form))
48      (case (car decl)
49        (OPTIMIZE
50         (dolist (spec (%cdr decl))
51           (let ((val 3)
52                 (quality spec))
53             (when (consp spec)
54               (setf quality (%car spec)
55                     val (cadr spec)))
56             (when (and (fixnump val)
57                        (<= 0 val 3))
58               (case quality
59                 (speed
60                  (setf *speed* val))
61                 (safety
62                  (setf *safety* val))
63                 (debug
64                  (setf *debug* val))
65                 (space
66                  (setf *space* val))
67                 (compilation-speed) ;; Ignored.
68                 (t
69                  (compiler-warn "Ignoring unknown optimization quality ~S in ~S." quality decl)))))))
70        ((INLINE NOTINLINE)
71         (dolist (symbol (%cdr decl))
72           (push (cons symbol (%car decl)) *inline-declarations*)))
73        (:explain
74         (dolist (spec (%cdr decl))
75           (let ((val t)
76                 (quality spec))
77             (when (consp spec)
78               (setf quality (%car spec))
79               (when (= (length spec) 2)
80                 (setf val (%cadr spec))))
81             (if val
82                 (pushnew quality *explain*)
83                 (setf *explain* (remove quality *explain*)))))))))
84  t)
85
86;; Returns list of declared specials.
87(declaim (ftype (function (list) list) process-special-declarations))
88(defun process-special-declarations (forms)
89  (let ((specials nil))
90    (dolist (form forms)
91      (unless (and (consp form) (eq (%car form) 'DECLARE))
92        (return))
93      (let ((decls (%cdr form)))
94        (dolist (decl decls)
95          (when (eq (car decl) 'special)
96            (setq specials (append (cdr decl) specials))))))
97    specials))
98
99(declaim (ftype (function (t) t) inline-p))
100(defun inline-p (name)
101  (declare (optimize speed))
102  (let ((entry (assoc name *inline-declarations*)))
103    (if entry
104        (eq (cdr entry) 'INLINE)
105        (and (symbolp name) (eq (get name '%inline) 'INLINE)))))
106
107(declaim (ftype (function (t) t) notinline-p))
108(defun notinline-p (name)
109  (declare (optimize speed))
110  (let ((entry (assoc name *inline-declarations*)))
111    (if entry
112        (eq (cdr entry) 'NOTINLINE)
113        (and (symbolp name) (eq (get name '%inline) 'NOTINLINE)))))
114
115(defun expand-inline (form expansion)
116;;   (format t "expand-inline form = ~S~%" form)
117;;   (format t "expand-inline expansion = ~S~%" expansion)
118  (let* ((op (car form))
119         (proclaimed-ftype (proclaimed-ftype op))
120         (args (cdr form))
121         (vars (cadr expansion))
122         (varlist ())
123         new-form)
124;;     (format t "op = ~S proclaimed-ftype = ~S~%" op (proclaimed-ftype op))
125    (do ((vars vars (cdr vars))
126         (args args (cdr args)))
127        ((null vars))
128      (push (list (car vars) (car args)) varlist))
129    (setf new-form (list* 'LET (nreverse varlist)
130                          (copy-tree (cddr expansion))))
131    (when proclaimed-ftype
132      (let ((result-type (ftype-result-type proclaimed-ftype)))
133        (when (and result-type
134                   (neq result-type t)
135                   (neq result-type '*))
136          (setf new-form (list 'TRULY-THE result-type new-form)))))
137;;     (format t "expand-inline new form = ~S~%" new-form)
138    new-form))
139
140(define-compiler-macro assoc (&whole form &rest args)
141  (cond ((and (= (length args) 4)
142              (eq (third args) :test)
143              (or (equal (fourth args) '(quote eq))
144                  (equal (fourth args) '(function eq))))
145         `(assq ,(first args) ,(second args)))
146        ((= (length args) 2)
147         `(assql ,(first args) ,(second args)))
148        (t form)))
149
150(define-compiler-macro member (&whole form &rest args)
151  (let ((arg1 (first args))
152        (arg2 (second args)))
153    (case (length args)
154      (2
155       `(memql ,arg1 ,arg2))
156      (4
157       (let ((arg3 (third args))
158             (arg4 (fourth args)))
159         (cond ((and (eq arg3 :test)
160                     (or (equal arg4 '(quote eq))
161                         (equal arg4 '(function eq))))
162                `(memq ,arg1 ,arg2))
163               ((and (eq arg3 :test)
164                     (or (equal arg4 '(quote eql))
165                         (equal arg4 '(function eql))
166                         (equal arg4 '(quote char=))
167                         (equal arg4 '(function char=))))
168                `(memql ,arg1 ,arg2))
169               (t
170                form))))
171      (t
172       form))))
173
174(define-compiler-macro search (&whole form &rest args)
175  (if (= (length args) 2)
176      `(simple-search ,@args)
177      form))
178
179(define-compiler-macro identity (&whole form &rest args)
180  (if (= (length args) 1)
181      `(progn ,(car args))
182      form))
183
184(defun quoted-form-p (form)
185  (and (consp form) (eq (%car form) 'QUOTE) (= (length form) 2)))
186
187(define-compiler-macro eql (&whole form &rest args)
188  (let ((first (car args))
189        (second (cadr args)))
190    (if (or (and (quoted-form-p first) (symbolp (cadr first)))
191            (and (quoted-form-p second) (symbolp (cadr second))))
192        `(eq ,first ,second)
193        form)))
194
195(define-compiler-macro not (&whole form arg)
196  (if (atom arg)
197      form
198      (let ((op (case (car arg)
199                  (>= '<)
200                  (<  '>=)
201                  (<= '>)
202                  (>  '<=)
203                  (t  nil))))
204        (if (and op (= (length arg) 3))
205            (cons op (cdr arg))
206            form))))
207
208(defun predicate-for-type (type)
209  (cdr (assq type '((ARRAY             . arrayp)
210                    (ATOM              . atom)
211                    (BIT-VECTOR        . bit-vector-p)
212                    (CHARACTER         . characterp)
213                    (COMPLEX           . complexp)
214                    (CONS              . consp)
215                    (FIXNUM            . fixnump)
216                    (FLOAT             . floatp)
217                    (FUNCTION          . functionp)
218                    (HASH-TABLE        . hash-table-p)
219                    (INTEGER           . integerp)
220                    (LIST              . listp)
221                    (NULL              . null)
222                    (NUMBER            . numberp)
223                    (NUMBER            . numberp)
224                    (PACKAGE           . packagep)
225                    (RATIONAL          . rationalp)
226                    (REAL              . realp)
227                    (SIMPLE-BIT-VECTOR . simple-bit-vector-p)
228                    (SIMPLE-STRING     . simple-string-p)
229                    (SIMPLE-VECTOR     . simple-vector-p)
230                    (STREAM            . streamp)
231                    (STRING            . stringp)
232                    (SYMBOL            . symbolp)))))
233
234(define-compiler-macro typep (&whole form &rest args)
235  (if (= (length args) 2) ; no environment arg
236      (let* ((object (%car args))
237             (type-specifier (%cadr args))
238             (type (and (consp type-specifier)
239                        (eq (%car type-specifier) 'QUOTE)
240                        (%cadr type-specifier)))
241             (predicate (and type (predicate-for-type type))))
242        (if predicate
243            `(,predicate ,object)
244            `(%typep ,@args)))
245      form))
246
247(define-compiler-macro subtypep (&whole form &rest args)
248  (if (= (length args) 2)
249      `(%subtypep ,@args)
250      form))
251
252(define-compiler-macro funcall (&whole form &rest args)
253  (let ((callee (car args)))
254    (if (and (>= *speed* *debug*)
255             (consp callee)
256             (eq (%car callee) 'function)
257             (symbolp (cadr callee))
258             (not (special-operator-p (cadr callee)))
259             (not (macro-function (cadr callee) *compile-file-environment*))
260             (memq (symbol-package (cadr callee))
261                   (list (find-package "CL") (find-package "SYS"))))
262        `(,(cadr callee) ,@(cdr args))
263        form)))
264
265(define-compiler-macro byte (size position)
266  `(cons ,size ,position))
267
268(define-compiler-macro byte-size (bytespec)
269  `(car ,bytespec))
270
271(define-compiler-macro byte-position (bytespec)
272  `(cdr ,bytespec))
273
274(define-source-transform concatenate (&whole form result-type &rest sequences)
275  (if (equal result-type '(quote STRING))
276      `(sys::concatenate-to-string (list ,@sequences))
277      form))
278
279(define-source-transform ldb (&whole form bytespec integer)
280  (if (and (consp bytespec)
281           (eq (%car bytespec) 'byte)
282           (= (length bytespec) 3))
283      (let ((size (%cadr bytespec))
284            (position (%caddr bytespec)))
285        `(%ldb ,size ,position ,integer))
286      form))
287
288(define-source-transform find (&whole form item sequence &key from-end test test-not start end key)
289  (cond ((and (>= (length form) 3) (null start) (null end))
290         (cond ((and (stringp sequence)
291                     (null from-end)
292                     (member test '(#'eql #'char=) :test #'equal)
293                     (null test-not)
294                     (null key))
295                `(string-find ,item ,sequence))
296               (t
297                (let ((item-var (gensym))
298                      (seq-var (gensym)))
299                  `(let ((,item-var ,item)
300                         (,seq-var ,sequence))
301                     (if (listp ,seq-var)
302                         (list-find* ,item-var ,seq-var ,from-end ,test ,test-not 0 (length ,seq-var) ,key)
303                         (vector-find* ,item-var ,seq-var ,from-end ,test ,test-not 0 (length ,seq-var) ,key)))))))
304        (t
305         form)))
306
307(define-source-transform adjoin (&whole form &rest args)
308  (if (= (length args) 2)
309      `(adjoin-eql ,(first args) ,(second args))
310      form))
311
312(define-compiler-macro catch (&whole form tag &rest args)
313  (declare (ignore tag))
314  (if (and (null (cdr args))
315           (constantp (car args)))
316      (car args)
317      form))
318
319(define-compiler-macro string= (&whole form &rest args)
320  (if (= (length args) 2)
321      `(sys::%%string= ,@args)
322      form))
323
324(define-compiler-macro <= (&whole form &rest args)
325  (cond ((and (= (length args) 3)
326              (numberp (first args))
327              (numberp (third args))
328              (= (first args) (third args)))
329         `(= ,(second args) ,(first args)))
330        (t
331         form)))
332
333(in-package "EXTENSIONS")
334
335(export '(precompile-form precompile))
336
337(unless (find-package "PRECOMPILER")
338  (make-package "PRECOMPILER"
339                :nicknames '("PRE")
340                :use '("COMMON-LISP" "EXTENSIONS" "SYSTEM")))
341
342(in-package "PRECOMPILER")
343
344;; No source-transforms and inlining in precompile-function-call
345;; No macro expansion in precompile-dolist and precompile-dotimes
346;; No macro expansion in precompile-do/do*
347;; No macro expansion in precompile-defun
348;; Special precompilation in precompile-case and precompile-cond
349;; Special precompilation in precompile-when and precompile-unless
350;; No precompilation in precompile-nth-value
351;; Special precompilation in precompile-return
352;; Special precompilation in expand-macro
353;;
354;; if *in-jvm-compile* is false
355
356(defvar *in-jvm-compile* nil)
357
358(declaim (ftype (function (t) t) precompile1))
359(defun precompile1 (form)
360  (cond ((symbolp form)
361         (multiple-value-bind
362               (expansion expanded)
363             (expand-macro form)
364           (if expanded
365               (precompile1 expansion)
366               form)))
367        ((atom form)
368         form)
369        (t
370         (let ((op (%car form))
371               handler)
372           (when (symbolp op)
373             (cond ((setf handler (get op 'precompile-handler))
374                    (return-from precompile1 (funcall handler form)))
375                   ((macro-function op *compile-file-environment*)
376                    (return-from precompile1 (precompile1 (expand-macro form))))
377                   ((special-operator-p op)
378                    (error "PRECOMPILE1: unsupported special operator ~S." op))))
379           (precompile-function-call form)))))
380
381(defun precompile-identity (form)
382  (declare (optimize speed))
383  form)
384
385(declaim (ftype (function (t) cons) precompile-cons))
386(defun precompile-cons (form)
387  (cons (car form) (mapcar #'precompile1 (cdr form))))
388
389(declaim (ftype (function (t t) t) precompile-function-call))
390(defun precompile-function-call (form)
391  (let ((op (car form)))
392    (when (and (consp op) (eq (%car op) 'LAMBDA))
393      (return-from precompile-function-call
394                   (cons (precompile-lambda op)
395                         (mapcar #'precompile1 (cdr form)))))
396    (when (or (not *in-jvm-compile*) (notinline-p op))
397      (return-from precompile-function-call (precompile-cons form)))
398    (when (source-transform op)
399      (let ((new-form (expand-source-transform form)))
400        (when (neq new-form form)
401          (return-from precompile-function-call (precompile1 new-form)))))
402    (when *enable-inline-expansion*
403      (let ((expansion (inline-expansion op)))
404        (when expansion
405          (let ((explain *explain*))
406            (when (and explain (memq :calls explain))
407              (format t ";   inlining call to ~S~%" op)))
408          (return-from precompile-function-call (precompile1 (expand-inline form expansion))))))
409    (cons op (mapcar #'precompile1 (cdr form)))))
410
411(defun precompile-locally (form)
412  (let ((*inline-declarations* *inline-declarations*))
413    (process-optimization-declarations (cdr form))
414  (cons 'LOCALLY (mapcar #'precompile1 (cdr form)))))
415
416(defun precompile-block (form)
417  (let ((args (cdr form)))
418    (if (null (cdr args))
419        nil
420        (list* 'BLOCK (car args) (mapcar #'precompile1 (cdr args))))))
421
422(defun precompile-dolist (form)
423  (if *in-jvm-compile*
424      (precompile1 (macroexpand form *compile-file-environment*))
425      (cons 'DOLIST (cons (mapcar #'precompile1 (cadr form))
426                          (mapcar #'precompile1 (cddr form))))))
427
428(defun precompile-dotimes (form)
429  (if *in-jvm-compile*
430      (precompile1 (macroexpand form *compile-file-environment*))
431      (cons 'DOTIMES (cons (mapcar #'precompile1 (cadr form))
432                           (mapcar #'precompile1 (cddr form))))))
433
434(defun precompile-do/do*-vars (varlist)
435  (let ((result nil))
436    (dolist (varspec varlist)
437      (if (atom varspec)
438          (push varspec result)
439          (case (length varspec)
440            (1
441             (push (%car varspec) result))
442            (2
443             (let* ((var (%car varspec))
444                    (init-form (%cadr varspec)))
445               (unless (symbolp var)
446                 (error 'type-error))
447               (push (list var (precompile1 init-form))
448                     result)))
449            (3
450             (let* ((var (%car varspec))
451                    (init-form (%cadr varspec))
452                    (step-form (%caddr varspec)))
453               (unless (symbolp var)
454                 (error 'type-error))
455               (push (list var (precompile1 init-form) (precompile1 step-form))
456                     result))))))
457    (nreverse result)))
458
459(defun precompile-do/do*-end-form (end-form)
460  (let ((end-test-form (car end-form))
461        (result-forms (cdr end-form)))
462    (list* end-test-form (mapcar #'precompile1 result-forms))))
463
464(defun precompile-do/do* (form)
465  (if *in-jvm-compile*
466      (precompile1 (macroexpand form *compile-file-environment*))
467      (list* (car form)
468             (precompile-do/do*-vars (cadr form))
469             (precompile-do/do*-end-form (caddr form))
470             (mapcar #'precompile1 (cdddr form)))))
471
472(defun precompile-do-symbols (form)
473  (list* (car form) (cadr form) (mapcar #'precompile1 (cddr form))))
474
475(defun precompile-load-time-value (form)
476  form)
477
478(defun precompile-progn (form)
479  (let ((body (cdr form)))
480    (if (eql (length body) 1)
481        (let ((res (precompile1 (%car body))))
482          ;; If the result turns out to be a bare symbol, leave it wrapped
483          ;; with PROGN so it won't be mistaken for a tag in an enclosing
484          ;; TAGBODY.
485          (if (symbolp res)
486              (list 'progn res)
487              res))
488        (cons 'PROGN (mapcar #'precompile1 body)))))
489
490(defun precompile-progv (form)
491  (if (< (length form) 3)
492      (compiler-error "Not enough arguments for ~S." 'progv)
493      (list* 'PROGV (mapcar #'precompile1 (%cdr form)))))
494
495(defun precompile-setf (form)
496  (let ((place (second form)))
497    (cond ((and (consp place)
498                (eq (%car place) 'VALUES))
499     (setf form
500     (list* 'SETF
501      (list* 'VALUES
502             (mapcar #'precompile1 (%cdr place)))
503      (cddr form)))
504     (precompile1 (expand-macro form)))
505    ((symbolp place)
506           (multiple-value-bind
507                 (expansion expanded)
508               (expand-macro place)
509             (if expanded
510                 (precompile1 (list* 'SETF expansion
511                                     (cddr form)))
512                 (precompile1 (expand-macro form)))))
513          (t
514           (precompile1 (expand-macro form))))))
515
516(defun precompile-setq (form)
517  (let* ((args (cdr form))
518         (len (length args)))
519    (when (oddp len)
520      (error 'simple-program-error
521             :format-control "Odd number of arguments to SETQ."))
522    (if (= len 2)
523        (let* ((sym (%car args))
524               (val (%cadr args)))
525          (multiple-value-bind
526                (expansion expanded)
527              (expand-macro sym)
528            (if expanded
529                (precompile1 (list 'SETF expansion val))
530                (list 'SETQ sym (precompile1 val))
531                )))
532        (let ((result ()))
533          (loop
534            (when (null args)
535              (return))
536            (push (precompile-setq (list 'SETQ (car args) (cadr args))) result)
537            (setq args (cddr args)))
538          (setq result (nreverse result))
539          (push 'PROGN result)
540          result))))
541
542(defun precompile-psetf (form)
543  (setf form
544        (list* 'PSETF
545               (mapcar #'precompile1 (cdr form))))
546  (precompile1 (expand-macro form)))
547
548(defun precompile-psetq (form)
549  ;; Make sure all the vars are symbols.
550  (do* ((rest (cdr form) (cddr rest))
551        (var (car rest)))
552       ((null rest))
553    (unless (symbolp var)
554      (error 'simple-error
555             :format-control "~S is not a symbol."
556             :format-arguments (list var))))
557  ;; Delegate to PRECOMPILE-PSETF so symbol macros are handled correctly.
558  (precompile-psetf form))
559
560
561(defun precompile-lambda-list (form)
562  (let (new aux-tail)
563    (dolist (arg form (nreverse new))
564       (if (or (atom arg) (> 2 (length arg)))
565           (progn
566             (when (eq arg '&aux)
567               (setf aux-tail t))
568             (push arg new))
569          ;; must be a cons of more than 1 cell
570          (let ((new-arg (copy-list arg)))
571            (unless (<= 1 (length arg) (if aux-tail 2 3))
572              ;; the aux-vars have a maximum length of 2 conses
573              ;; optional and key vars may have 3
574              (error 'program-error
575                     :format-control
576                     "The ~A binding specification ~S is invalid."
577                     :format-arguments (list (if aux-tail "&AUX"
578                                                 "&OPTIONAL/&KEY") arg)))
579             (setf (second new-arg)
580                   (precompile1 (second arg)))
581             (push new-arg new))))))
582
583(defun precompile-lambda (form)
584  (let ((body (cddr form))
585        (precompiled-lambda-list
586           (precompile-lambda-list (cadr form)))
587        (*inline-declarations* *inline-declarations*))
588    (process-optimization-declarations body)
589    (list* 'LAMBDA precompiled-lambda-list
590           (mapcar #'precompile1 body))))
591
592(defun precompile-named-lambda (form)
593  (let ((lambda-form (list* 'LAMBDA (caddr form) (cdddr form))))
594    (let ((body (cddr lambda-form))
595          (precompiled-lambda-list
596           (precompile-lambda-list (cadr lambda-form)))
597          (*inline-declarations* *inline-declarations*))
598      (process-optimization-declarations body)
599      (list* 'NAMED-LAMBDA (cadr form) precompiled-lambda-list
600             (mapcar #'precompile1 body)))))
601
602(defun precompile-defun (form)
603  (if *in-jvm-compile*
604      (precompile1 (expand-macro form))
605      form))
606
607(defun precompile-macrolet (form)
608  (let ((*compile-file-environment*
609         (make-environment *compile-file-environment*)))
610    (dolist (definition (cadr form))
611      (environment-add-macro-definition
612       *compile-file-environment*
613       (car definition)
614       (make-macro (car definition)
615                   (make-closure
616                    (make-expander-for-macrolet definition)
617                    NIL))))
618    (multiple-value-bind (body decls)
619        (parse-body (cddr form) nil)
620      `(locally ,@decls ,@(mapcar #'precompile1 body)))))
621
622(defun precompile-symbol-macrolet (form)
623  (let ((*compile-file-environment*
624         (make-environment *compile-file-environment*))
625        (defs (cadr form)))
626    (dolist (def defs)
627      (let ((sym (car def))
628            (expansion (cadr def)))
629        (when (special-variable-p sym)
630          (error 'program-error
631                 :format-control "Attempt to bind the special variable ~S with SYMBOL-MACROLET."
632                 :format-arguments (list sym)))
633        (environment-add-symbol-binding *compile-file-environment*
634                                        sym
635                                        (sys::make-symbol-macro expansion))
636        ))
637    (multiple-value-bind (body decls)
638        (parse-body (cddr form) nil)
639      (when decls
640        (let ((specials ()))
641          (dolist (decl decls)
642            (when (eq (car decl) 'DECLARE)
643              (dolist (declspec (cdr decl))
644                (when (eq (car declspec) 'SPECIAL)
645                  (setf specials (append specials (cdr declspec)))))))
646          (when specials
647            (let ((syms (mapcar #'car (cadr form))))
648              (dolist (special specials)
649                (when (memq special syms)
650                  (error 'program-error
651                         :format-control "~S is a symbol-macro and may not be declared special."
652                         :format-arguments (list special))))))))
653      `(locally ,@decls ,@(mapcar #'precompile1 body)))))
654
655(defun precompile-the (form)
656  (list 'THE
657        (second form)
658        (precompile1 (third form))))
659
660(defun precompile-truly-the (form)
661  (list 'TRULY-THE
662        (second form)
663        (precompile1 (third form))))
664
665(defun precompile-let/let*-vars (vars)
666  (let ((result nil))
667    (dolist (var vars)
668      (cond ((consp var)
669             (unless (<= 1 (length var) 2)
670               (error 'program-error
671                       :format-control
672                       "The LET/LET* binding specification ~S is invalid."
673                       :format-arguments (list var)))
674             (let ((v (%car var))
675                   (expr (cadr var)))
676               (unless (symbolp v)
677                 (error 'simple-type-error
678                        :format-control "The variable ~S is not a symbol."
679                        :format-arguments (list v)))
680               (push (list v (precompile1 expr)) result)
681               (environment-add-symbol-binding *compile-file-environment*
682                                               v nil))) ;; any value will do
683            (t
684             (push var result)
685             (environment-add-symbol-binding *compile-file-environment*
686                                             var nil)
687)))
688    (nreverse result)))
689
690(defun precompile-let (form)
691  (let ((*compile-file-environment*
692         (make-environment *compile-file-environment*)))
693    (list* 'LET
694           (precompile-let/let*-vars (cadr form))
695           (mapcar #'precompile1 (cddr form)))))
696
697;; (LET* ((X 1)) (LET* ((Y 2)) (LET* ((Z 3)) (+ X Y Z)))) =>
698;; (LET* ((X 1) (Y 2) (Z 3)) (+ X Y Z))
699(defun maybe-fold-let* (form)
700  (if (and (= (length form) 3)
701           (consp (%caddr form))
702           (eq (%car (%caddr form)) 'LET*))
703      (let ((third (maybe-fold-let* (%caddr form))))
704        (list* 'LET* (append (%cadr form) (cadr third)) (cddr third)))
705      form))
706
707(defun precompile-let* (form)
708  (setf form (maybe-fold-let* form))
709  (let ((*compile-file-environment*
710         (make-environment *compile-file-environment*)))
711    (list* 'LET*
712           (precompile-let/let*-vars (cadr form))
713           (mapcar #'precompile1 (cddr form)))))
714
715(defun precompile-case (form)
716  (if *in-jvm-compile*
717      (precompile1 (macroexpand form *compile-file-environment*))
718      (let* ((keyform (cadr form))
719             (clauses (cddr form))
720             (result (list (precompile1 keyform))))
721        (dolist (clause clauses)
722          (push (precompile-case-clause clause) result))
723        (cons (car form) (nreverse result)))))
724
725(defun precompile-case-clause (clause)
726  (let ((keys (car clause))
727        (forms (cdr clause)))
728    (cons keys (mapcar #'precompile1 forms))))
729
730(defun precompile-cond (form)
731  (if *in-jvm-compile*
732      (precompile1 (macroexpand form *compile-file-environment*))
733      (let ((clauses (cdr form))
734            (result nil))
735        (dolist (clause clauses)
736          (push (precompile-cond-clause clause) result))
737        (cons 'COND (nreverse result)))))
738
739(defun precompile-cond-clause (clause)
740  (let ((test (car clause))
741        (forms (cdr clause)))
742    (cons (precompile1 test) (mapcar #'precompile1 forms))))
743
744(defun precompile-local-function-def (def)
745  (let ((name (car def))
746        (body (cddr def)))
747    ;; Macro names are shadowed by local functions.
748    (environment-add-function-definition *compile-file-environment* name body)
749    (cdr (precompile-named-lambda (list* 'NAMED-LAMBDA def)))))
750
751(defun precompile-local-functions (defs)
752  (let ((result nil))
753    (dolist (def defs (nreverse result))
754      (push (precompile-local-function-def def) result))))
755
756(defun find-use (name expression)
757  (cond ((atom expression)
758         nil)
759        ((eq (%car expression) name)
760         t)
761        ((consp name)
762         t) ;; FIXME Recognize use of SETF functions!
763        (t
764         (or (find-use name (%car expression))
765             (find-use name (%cdr expression))))))
766
767(defun precompile-flet/labels (form)
768  (let ((*compile-file-environment*
769         (make-environment *compile-file-environment*))
770        (operator (car form))
771        (locals (cadr form))
772        (body (cddr form)))
773    (dolist (local locals)
774      (let* ((name (car local))
775             (used-p (find-use name body)))
776        (unless used-p
777          (when (eq operator 'LABELS)
778            (dolist (local locals)
779              (when (neq name (car local))
780                (when (find-use name (cddr local))
781                  (setf used-p t)
782                  (return))
783                ;; Scope of defined function names includes
784                ;; &OPTIONAL, &KEY and &AUX parameters
785                ;; (LABELS.7B, LABELS.7C and LABELS.7D).
786                (let ((vars (or
787                             (cdr (memq '&optional (cadr local)))
788                             (cdr (memq '&key (cadr local)))
789                             (cdr (memq '&aux (cadr local))))))
790                  (when (and vars (find-use name vars)
791                             (setf used-p t)
792                             (return))))))))
793        (unless used-p
794          (format t "; Note: deleting unused local function ~A ~S~%" operator name)
795          (let* ((new-locals (remove local locals :test 'eq))
796                 (new-form
797                  (if new-locals
798                      (list* operator new-locals body)
799                      (list* 'LOCALLY body))))
800            (return-from precompile-flet/labels (precompile1 new-form))))))
801    (list* (car form)
802           (precompile-local-functions locals)
803           (mapcar #'precompile1 body))))
804
805(defun precompile-function (form)
806  (if (and (consp (cadr form)) (eq (caadr form) 'LAMBDA))
807      (list 'FUNCTION (precompile-lambda (%cadr form)))
808      form))
809
810(defun precompile-if (form)
811  (let ((args (cdr form)))
812    (case (length args)
813      (2
814       (let ((test (precompile1 (%car args))))
815         (cond ((null test)
816                nil)
817               (;;(constantp test)
818                (eq test t)
819                (precompile1 (%cadr args)))
820               (t
821                (list 'IF
822                      test
823                      (precompile1 (%cadr args)))))))
824      (3
825       (let ((test (precompile1 (%car args))))
826         (cond ((null test)
827                (precompile1 (%caddr args)))
828               (;;(constantp test)
829                (eq test t)
830                (precompile1 (%cadr args)))
831               (t
832                (list 'IF
833                      test
834                      (precompile1 (%cadr args))
835                      (precompile1 (%caddr args)))))))
836      (t
837       (error "wrong number of arguments for IF")))))
838
839(defun precompile-when (form)
840  (if *in-jvm-compile*
841      (precompile1 (macroexpand form *compile-file-environment*))
842      (precompile-cons form)))
843
844(defun precompile-unless (form)
845  (if *in-jvm-compile*
846      (precompile1 (macroexpand form *compile-file-environment*))
847      (precompile-cons form)))
848
849;; MULTIPLE-VALUE-BIND is handled explicitly by the JVM compiler.
850(defun precompile-multiple-value-bind (form)
851  (let ((vars (cadr form))
852        (values-form (caddr form))
853        (body (cdddr form))
854        (*compile-file-environment*
855         (make-environment *compile-file-environment*))
856)
857    (dolist (var vars)
858      (environment-add-symbol-binding *compile-file-environment* var nil))
859    (list* 'MULTIPLE-VALUE-BIND
860           vars
861           (precompile1 values-form)
862           (mapcar #'precompile1 body))))
863
864;; MULTIPLE-VALUE-LIST is handled explicitly by the JVM compiler.
865(defun precompile-multiple-value-list (form)
866  (list 'MULTIPLE-VALUE-LIST (precompile1 (cadr form))))
867
868(defun precompile-nth-value (form)
869  (if *in-jvm-compile*
870      (precompile1 (macroexpand form *compile-file-environment*))
871      form))
872
873(defun precompile-return (form)
874  (if *in-jvm-compile*
875      (precompile1 (macroexpand form *compile-file-environment*))
876      (list 'RETURN (precompile1 (cadr form)))))
877
878(defun precompile-return-from (form)
879  (list 'RETURN-FROM (cadr form) (precompile1 (caddr form))))
880
881(defun precompile-tagbody (form)
882  (do ((body (cdr form) (cdr body))
883       (result ()))
884      ((null body) (cons 'TAGBODY (nreverse result)))
885    (if (atom (car body))
886        (push (car body) result)
887        (push (let* ((first-form (car body))
888                     (expanded (precompile1 first-form)))
889                (if (and (symbolp expanded)
890                         (neq expanded first-form))
891                    ;; Workaround:
892                    ;;  Since our expansion/compilation order
893                    ;;   is out of sync with the definition of
894                    ;;   TAGBODY (which requires the compiler
895                    ;;   to look for tags before expanding),
896                    ;;   we need to disguise anything which might
897                    ;;   look like a tag. We do this by wrapping
898                    ;;   it in a PROGN form.
899                    (list 'PROGN expanded)
900                    expanded)) result))))
901
902(defun precompile-eval-when (form)
903  (list* 'EVAL-WHEN (cadr form) (mapcar #'precompile1 (cddr form))))
904
905(defun precompile-unwind-protect (form)
906  (list* 'UNWIND-PROTECT
907         (precompile1 (cadr form))
908         (mapcar #'precompile1 (cddr form))))
909
910;; EXPAND-MACRO is like MACROEXPAND, but EXPAND-MACRO quits if *IN-JVM-COMPILE*
911;; is false and a macro is encountered that is also implemented as a special
912;; operator, so interpreted code can use the special operator implementation.
913(defun expand-macro (form)
914  (let (exp)
915    (loop
916       (unless *in-jvm-compile*
917         (when (and (consp form)
918                    (symbolp (%car form))
919                    (special-operator-p (%car form)))
920           (return-from expand-macro form)))
921       (multiple-value-bind (result expanded)
922           (macroexpand-1 form *compile-file-environment*)
923         (unless expanded
924           (return-from expand-macro (values result exp)))
925         (setf form result
926               exp t)))))
927
928(declaim (ftype (function (t t) t) precompile-form))
929(defun precompile-form (form in-jvm-compile)
930  (let ((*in-jvm-compile* in-jvm-compile)
931        (*inline-declarations* *inline-declarations*))
932    (precompile1 form)))
933
934(defun install-handler (symbol &optional handler)
935  (declare (type symbol symbol))
936  (let ((handler (or handler
937                     (find-symbol (sys::%format nil "PRECOMPILE-~A" (symbol-name symbol))
938                                  'precompiler))))
939    (unless (and handler (fboundp handler))
940      (error "No handler for ~S." symbol))
941    (setf (get symbol 'precompile-handler) handler)))
942
943(defun install-handlers ()
944  (mapcar #'install-handler '(BLOCK
945                              CASE
946                              COND
947                              DOLIST
948                              DOTIMES
949                              EVAL-WHEN
950                              FUNCTION
951                              IF
952                              LAMBDA
953                              MACROLET
954                              MULTIPLE-VALUE-BIND
955                              MULTIPLE-VALUE-LIST
956                              NAMED-LAMBDA
957                              NTH-VALUE
958                              PROGN
959                              PROGV
960                              PSETF
961                              PSETQ
962                              RETURN
963                              RETURN-FROM
964                              SETF
965                              SETQ
966                              SYMBOL-MACROLET
967                              TAGBODY
968                              UNWIND-PROTECT
969                              UNLESS
970                              WHEN))
971
972  (dolist (pair '((ECASE                precompile-case)
973
974                  (AND                  precompile-cons)
975                  (OR                   precompile-cons)
976
977                  (CATCH                precompile-cons)
978                  (MULTIPLE-VALUE-CALL  precompile-cons)
979                  (MULTIPLE-VALUE-PROG1 precompile-cons)
980
981                  (DO                   precompile-do/do*)
982                  (DO*                  precompile-do/do*)
983
984                  (LET                  precompile-let)
985                  (LET*                 precompile-let*)
986
987                  (LOCALLY              precompile-locally)
988
989                  (FLET                 precompile-flet/labels)
990                  (LABELS               precompile-flet/labels)
991
992                  (LOAD-TIME-VALUE      precompile-load-time-value)
993
994                  (DECLARE              precompile-identity)
995;;                   (DEFMETHOD            precompile-identity)
996                  (DEFUN                precompile-defun)
997                  (GO                   precompile-identity)
998                  (QUOTE                precompile-identity)
999                  (THE                  precompile-the)
1000                  (THROW                precompile-cons)
1001                  (TRULY-THE            precompile-truly-the)))
1002    (install-handler (first pair) (second pair))))
1003
1004(install-handlers)
1005
1006(in-package #:system)
1007
1008(defun macroexpand-all (form &optional env)
1009  (let ((*compile-file-environment* env))
1010    (precompile-form form nil)))
1011
1012(defmacro compiler-let (bindings &body forms &environment env)
1013  (let ((bindings (mapcar #'(lambda (binding)
1014                              (if (atom binding) (list binding) binding))
1015                          bindings)))
1016    (progv (mapcar #'car bindings)
1017           (mapcar #'(lambda (binding)
1018                       (eval (cadr binding))) bindings)
1019      (macroexpand-all `(progn ,@forms) env))))
1020
1021(defun set-function-definition (name new old)
1022  (let ((*warn-on-redefinition* nil))
1023    (sys::%set-lambda-name new name)
1024    (sys:set-call-count new (sys:call-count old))
1025    (sys::%set-arglist new (sys::arglist old))
1026    (when (macro-function name)
1027      (setf new (make-macro name new)))
1028    (if (typep old 'standard-generic-function)
1029        (mop:set-funcallable-instance-function old new)
1030        (setf (fdefinition name) new))))
1031
1032(defun precompile (name &optional definition)
1033  (unless definition
1034    (setq definition (or (and (symbolp name) (macro-function name))
1035                         (fdefinition name))))
1036  (let (expr result)
1037    (cond ((functionp definition)
1038           (multiple-value-bind (form closure-p)
1039             (function-lambda-expression definition)
1040             (unless form
1041;;                (format t "; No lambda expression available for ~S.~%" name)
1042               (return-from precompile (values nil t t)))
1043             (when closure-p
1044               (format t "; Unable to compile function ~S defined in non-null lexical environment.~%" name)
1045               (finish-output)
1046               (return-from precompile (values nil t t)))
1047             (setq expr form)))
1048          ((and (consp definition) (eq (%car definition) 'lambda))
1049           (setq expr definition))
1050          (t
1051;;            (error 'type-error)))
1052           (format t "Unable to precompile ~S.~%" name)
1053           (return-from precompile (values nil t t))))
1054    (setf result (coerce-to-function (precompile-form expr nil)))
1055    (when (and name (functionp result))
1056      (sys::set-function-definition name result definition))
1057    (values (or name result) nil nil)))
1058
1059(defun precompile-package (pkg &key verbose)
1060  (dolist (sym (package-symbols pkg))
1061    (when (fboundp sym)
1062      (unless (special-operator-p sym)
1063        (let ((f (fdefinition sym)))
1064          (unless (compiled-function-p f)
1065            (when verbose
1066              (format t "Precompiling ~S~%" sym)
1067              (finish-output))
1068            (precompile sym))))))
1069  t)
1070
1071(defun %compile (name definition)
1072  (if (and name (fboundp name) (%typep (symbol-function name) 'generic-function))
1073      (values name nil nil)
1074      (precompile name definition)))
1075
1076;; ;; Redefine EVAL to precompile its argument.
1077;; (defun eval (form)
1078;;   (%eval (precompile-form form nil)))
1079
1080;; ;; Redefine DEFMACRO to precompile the expansion function on the fly.
1081;; (defmacro defmacro (name lambda-list &rest body)
1082;;   (let* ((form (gensym "WHOLE-"))
1083;;          (env (gensym "ENVIRONMENT-")))
1084;;     (multiple-value-bind (body decls)
1085;;         (parse-defmacro lambda-list form body name 'defmacro :environment env)
1086;;       (let ((expander `(lambda (,form ,env) ,@decls (block ,name ,body))))
1087;;         `(progn
1088;;            (let ((macro (make-macro ',name
1089;;                                     (or (precompile nil ,expander) ,expander))))
1090;;              ,@(if (special-operator-p name)
1091;;                    `((put ',name 'macroexpand-macro macro))
1092;;                    `((fset ',name macro)))
1093;;              (%set-arglist macro ',lambda-list)
1094;;              ',name))))))
1095
1096;; Make an exception just this one time...
1097(when (get 'defmacro 'macroexpand-macro)
1098  (fset 'defmacro (get 'defmacro 'macroexpand-macro))
1099  (remprop 'defmacro 'macroexpand-macro))
1100
1101(defvar *defined-functions*)
1102
1103(defvar *undefined-functions*)
1104
1105(defun note-name-defined (name)
1106  (when (boundp '*defined-functions*)
1107    (push name *defined-functions*))
1108  (when (and (boundp '*undefined-functions*) (not (null *undefined-functions*)))
1109    (setf *undefined-functions* (remove name *undefined-functions*))))
1110
1111;; Redefine DEFUN to precompile the definition on the fly.
1112(defmacro defun (name lambda-list &body body &environment env)
1113  (note-name-defined name)
1114  (multiple-value-bind (body decls doc)
1115      (parse-body body)
1116    (let* ((block-name (fdefinition-block-name name))
1117           (lambda-expression
1118            `(named-lambda ,name ,lambda-list
1119                           ,@decls
1120                           ,@(when doc `(,doc))
1121                           (block ,block-name ,@body))))
1122      (cond ((and (boundp 'jvm::*file-compilation*)
1123                  ;; when JVM.lisp isn't loaded yet, this variable isn't bound
1124                  ;; meaning that we're not trying to compile to a file:
1125                  ;; Both COMPILE and COMPILE-FILE bind this variable.
1126                  ;; This function is also triggered by MACROEXPAND, though
1127                  jvm::*file-compilation*)
1128             `(fset ',name ,lambda-expression))
1129            (t
1130             (when (and env (empty-environment-p env))
1131               (setf env nil))
1132             (when (null env)
1133               (setf lambda-expression (precompile-form lambda-expression nil)))
1134             `(progn
1135                (%defun ',name ,lambda-expression)
1136                ,@(when doc
1137                   `((%set-documentation ',name 'function ,doc)))))))))
Note: See TracBrowser for help on using the repository browser.