source: trunk/abcl/src/org/armedbear/lisp/precompiler.lisp @ 12248

Last change on this file since 12248 was 12248, checked in by ehuelsmann, 11 years ago

Fix macroexpansion bug in the precompiler.

Reported by: szergling at gmail

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 40.8 KB
Line 
1;;; precompiler.lisp
2;;;
3;;; Copyright (C) 2003-2008 Peter Graves <peter@armedbear.org>
4;;; $Id: precompiler.lisp 12248 2009-11-05 20:01:38Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19;;;
20;;; As a special exception, the copyright holders of this library give you
21;;; permission to link this library with independent modules to produce an
22;;; executable, regardless of the license terms of these independent
23;;; modules, and to copy and distribute the resulting executable under
24;;; terms of your choice, provided that you also meet, for each linked
25;;; independent module, the terms and conditions of the license of that
26;;; module.  An independent module is a module which is not derived from
27;;; or based on this library.  If you modify this library, you may extend
28;;; this exception to your version of the library, but you are not
29;;; obligated to do so.  If you do not wish to do so, delete this
30;;; exception statement from your version.
31
32(in-package "SYSTEM")
33
34
35(export '(*inline-declarations*
36          process-optimization-declarations
37          inline-p notinline-p inline-expansion expand-inline
38          *defined-functions* *undefined-functions* note-name-defined))
39
40(defvar *inline-declarations* nil)
41
42(declaim (ftype (function (t) t) process-optimization-declarations))
43(defun process-optimization-declarations (forms)
44  (dolist (form forms)
45    (unless (and (consp form) (eq (%car form) 'DECLARE))
46      (return))
47    (dolist (decl (%cdr form))
48      (case (car decl)
49        (OPTIMIZE
50         (dolist (spec (%cdr decl))
51           (let ((val 3)
52                 (quality spec))
53             (when (consp spec)
54               (setf quality (%car spec)
55                     val (cadr spec)))
56             (when (and (fixnump val)
57                        (<= 0 val 3))
58               (case quality
59                 (speed
60                  (setf *speed* val))
61                 (safety
62                  (setf *safety* val))
63                 (debug
64                  (setf *debug* val))
65                 (space
66                  (setf *space* val))
67                 (compilation-speed) ;; Ignored.
68                 (t
69                  (compiler-warn "Ignoring unknown optimization quality ~S in ~S." quality decl)))))))
70        ((INLINE NOTINLINE)
71         (dolist (symbol (%cdr decl))
72           (push (cons symbol (%car decl)) *inline-declarations*)))
73        (:explain
74         (dolist (spec (%cdr decl))
75           (let ((val t)
76                 (quality spec))
77             (when (consp spec)
78               (setf quality (%car spec))
79               (when (= (length spec) 2)
80                 (setf val (%cadr spec))))
81             (if val
82                 (pushnew quality *explain*)
83                 (setf *explain* (remove quality *explain*)))))))))
84  t)
85
86(declaim (ftype (function (t) t) inline-p))
87(defun inline-p (name)
88  (declare (optimize speed))
89  (let ((entry (assoc name *inline-declarations*)))
90    (if entry
91        (eq (cdr entry) 'INLINE)
92        (and (symbolp name) (eq (get name '%inline) 'INLINE)))))
93
94(declaim (ftype (function (t) t) notinline-p))
95(defun notinline-p (name)
96  (declare (optimize speed))
97  (let ((entry (assoc name *inline-declarations*)))
98    (if entry
99        (eq (cdr entry) 'NOTINLINE)
100        (and (symbolp name) (eq (get name '%inline) 'NOTINLINE)))))
101
102(defun expand-inline (form expansion)
103;;   (format t "expand-inline form = ~S~%" form)
104;;   (format t "expand-inline expansion = ~S~%" expansion)
105  (let* ((op (car form))
106         (proclaimed-ftype (proclaimed-ftype op))
107         (args (cdr form))
108         (vars (cadr expansion))
109         (varlist ())
110         new-form)
111;;     (format t "op = ~S proclaimed-ftype = ~S~%" op (proclaimed-ftype op))
112    (do ((vars vars (cdr vars))
113         (args args (cdr args)))
114        ((null vars))
115      (push (list (car vars) (car args)) varlist))
116    (setf new-form (list* 'LET (nreverse varlist)
117                          (copy-tree (cddr expansion))))
118    (when proclaimed-ftype
119      (let ((result-type (ftype-result-type proclaimed-ftype)))
120        (when (and result-type
121                   (neq result-type t)
122                   (neq result-type '*))
123          (setf new-form (list 'TRULY-THE result-type new-form)))))
124;;     (format t "expand-inline new form = ~S~%" new-form)
125    new-form))
126
127(define-compiler-macro assoc (&whole form &rest args)
128  (cond ((and (= (length args) 4)
129              (eq (third args) :test)
130              (or (equal (fourth args) '(quote eq))
131                  (equal (fourth args) '(function eq))))
132         `(assq ,(first args) ,(second args)))
133        ((= (length args) 2)
134         `(assql ,(first args) ,(second args)))
135        (t form)))
136
137(define-compiler-macro member (&whole form &rest args)
138  (let ((arg1 (first args))
139        (arg2 (second args)))
140    (case (length args)
141      (2
142       `(memql ,arg1 ,arg2))
143      (4
144       (let ((arg3 (third args))
145             (arg4 (fourth args)))
146         (cond ((and (eq arg3 :test)
147                     (or (equal arg4 '(quote eq))
148                         (equal arg4 '(function eq))))
149                `(memq ,arg1 ,arg2))
150               ((and (eq arg3 :test)
151                     (or (equal arg4 '(quote eql))
152                         (equal arg4 '(function eql))
153                         (equal arg4 '(quote char=))
154                         (equal arg4 '(function char=))))
155                `(memql ,arg1 ,arg2))
156               (t
157                form))))
158      (t
159       form))))
160
161(define-compiler-macro search (&whole form &rest args)
162  (if (= (length args) 2)
163      `(simple-search ,@args)
164      form))
165
166(define-compiler-macro identity (&whole form &rest args)
167  (if (= (length args) 1)
168      `(progn ,(car args))
169      form))
170
171(defun quoted-form-p (form)
172  (and (consp form) (eq (%car form) 'QUOTE) (= (length form) 2)))
173
174(define-compiler-macro eql (&whole form &rest args)
175  (let ((first (car args))
176        (second (cadr args)))
177    (if (or (and (quoted-form-p first) (symbolp (cadr first)))
178            (and (quoted-form-p second) (symbolp (cadr second))))
179        `(eq ,first ,second)
180        form)))
181
182(define-compiler-macro not (&whole form arg)
183  (if (atom arg)
184      form
185      (let ((op (case (car arg)
186                  (>= '<)
187                  (<  '>=)
188                  (<= '>)
189                  (>  '<=)
190                  (t  nil))))
191        (if (and op (= (length arg) 3))
192            (cons op (cdr arg))
193            form))))
194
195(defun predicate-for-type (type)
196  (cdr (assq type '((ARRAY             . arrayp)
197                    (ATOM              . atom)
198                    (BIT-VECTOR        . bit-vector-p)
199                    (CHARACTER         . characterp)
200                    (COMPLEX           . complexp)
201                    (CONS              . consp)
202                    (FIXNUM            . fixnump)
203                    (FLOAT             . floatp)
204                    (FUNCTION          . functionp)
205                    (HASH-TABLE        . hash-table-p)
206                    (INTEGER           . integerp)
207                    (LIST              . listp)
208                    (NULL              . null)
209                    (NUMBER            . numberp)
210                    (NUMBER            . numberp)
211                    (PACKAGE           . packagep)
212                    (RATIONAL          . rationalp)
213                    (REAL              . realp)
214                    (SIMPLE-BIT-VECTOR . simple-bit-vector-p)
215                    (SIMPLE-STRING     . simple-string-p)
216                    (SIMPLE-VECTOR     . simple-vector-p)
217                    (STREAM            . streamp)
218                    (STRING            . stringp)
219                    (SYMBOL            . symbolp)))))
220
221(define-compiler-macro typep (&whole form &rest args)
222  (if (= (length args) 2) ; no environment arg
223      (let* ((object (%car args))
224             (type-specifier (%cadr args))
225             (type (and (consp type-specifier)
226                        (eq (%car type-specifier) 'QUOTE)
227                        (%cadr type-specifier)))
228             (predicate (and type (predicate-for-type type))))
229        (if predicate
230            `(,predicate ,object)
231            `(%typep ,@args)))
232      form))
233
234(define-compiler-macro subtypep (&whole form &rest args)
235  (if (= (length args) 2)
236      `(%subtypep ,@args)
237      form))
238
239(define-compiler-macro funcall (&whole form
240                                &environment env &rest args)
241  (let ((callee (car args)))
242    (if (and (>= *speed* *debug*)
243             (consp callee)
244             (eq (%car callee) 'function)
245             (symbolp (cadr callee))
246             (not (special-operator-p (cadr callee)))
247             (not (macro-function (cadr callee) env))
248             (memq (symbol-package (cadr callee))
249                   (list (find-package "CL") (find-package "SYS"))))
250        `(,(cadr callee) ,@(cdr args))
251        form)))
252
253(define-compiler-macro byte (size position)
254  `(cons ,size ,position))
255
256(define-compiler-macro byte-size (bytespec)
257  `(car ,bytespec))
258
259(define-compiler-macro byte-position (bytespec)
260  `(cdr ,bytespec))
261
262(define-source-transform concatenate (&whole form result-type &rest sequences)
263  (if (equal result-type '(quote STRING))
264      `(sys::concatenate-to-string (list ,@sequences))
265      form))
266
267(define-source-transform ldb (&whole form bytespec integer)
268  (if (and (consp bytespec)
269           (eq (%car bytespec) 'byte)
270           (= (length bytespec) 3))
271      (let ((size (%cadr bytespec))
272            (position (%caddr bytespec)))
273        `(%ldb ,size ,position ,integer))
274      form))
275
276(define-source-transform find (&whole form item sequence &key from-end test test-not start end key)
277  (cond ((and (>= (length form) 3) (null start) (null end))
278         (cond ((and (stringp sequence)
279                     (null from-end)
280                     (member test '(#'eql #'char=) :test #'equal)
281                     (null test-not)
282                     (null key))
283                `(string-find ,item ,sequence))
284               (t
285                (let ((item-var (gensym))
286                      (seq-var (gensym)))
287                  `(let ((,item-var ,item)
288                         (,seq-var ,sequence))
289                     (if (listp ,seq-var)
290                         (list-find* ,item-var ,seq-var ,from-end ,test ,test-not 0 (length ,seq-var) ,key)
291                         (vector-find* ,item-var ,seq-var ,from-end ,test ,test-not 0 (length ,seq-var) ,key)))))))
292        (t
293         form)))
294
295(define-source-transform adjoin (&whole form &rest args)
296  (if (= (length args) 2)
297      `(adjoin-eql ,(first args) ,(second args))
298      form))
299
300(define-compiler-macro catch (&whole form tag &rest args)
301  (declare (ignore tag))
302  (if (and (null (cdr args))
303           (constantp (car args)))
304      (car args)
305      form))
306
307(define-compiler-macro string= (&whole form &rest args)
308  (if (= (length args) 2)
309      `(sys::%%string= ,@args)
310      form))
311
312(define-compiler-macro <= (&whole form &rest args)
313  (cond ((and (= (length args) 3)
314              (numberp (first args))
315              (numberp (third args))
316              (= (first args) (third args)))
317         `(= ,(second args) ,(first args)))
318        (t
319         form)))
320
321
322(in-package "PRECOMPILER")
323
324;; No source-transforms and inlining in precompile-function-call
325;; No macro expansion in precompile-dolist and precompile-dotimes
326;; No macro expansion in precompile-do/do*
327;; No macro expansion in precompile-defun
328;; Special precompilation in precompile-case and precompile-cond
329;; Special precompilation in precompile-when and precompile-unless
330;; No precompilation in precompile-nth-value
331;; Special precompilation in precompile-return
332;; Special precompilation in expand-macro
333;;
334;; if *in-jvm-compile* is false
335
336(defvar *in-jvm-compile* nil)
337(defvar *precompile-env* nil)
338
339
340(declaim (ftype (function (t) t) precompile1))
341(defun precompile1 (form)
342  (cond ((symbolp form)
343         (multiple-value-bind
344               (expansion expanded)
345             (expand-macro form)
346           (if expanded
347               (precompile1 expansion)
348               form)))
349        ((atom form)
350         form)
351        (t
352         (let ((op (%car form))
353               handler)
354           (when (symbolp op)
355             (cond ((setf handler (get op 'precompile-handler))
356                    (return-from precompile1 (funcall handler form)))
357                   ((macro-function op *precompile-env*)
358                    (return-from precompile1 (precompile1 (expand-macro form))))
359                   ((special-operator-p op)
360                    (error "PRECOMPILE1: unsupported special operator ~S." op))))
361           (precompile-function-call form)))))
362
363(defun precompile-identity (form)
364  (declare (optimize speed))
365  form)
366
367(declaim (ftype (function (t) cons) precompile-cons))
368(defun precompile-cons (form)
369  (cons (car form) (mapcar #'precompile1 (cdr form))))
370
371(declaim (ftype (function (t t) t) precompile-function-call))
372(defun precompile-function-call (form)
373  (let ((op (car form)))
374    (when (and (consp op) (eq (%car op) 'LAMBDA))
375      (return-from precompile-function-call
376                   (cons (precompile-lambda op)
377                         (mapcar #'precompile1 (cdr form)))))
378    (when (or (not *in-jvm-compile*) (notinline-p op))
379      (return-from precompile-function-call (precompile-cons form)))
380    (when (source-transform op)
381      (let ((new-form (expand-source-transform form)))
382        (when (neq new-form form)
383          (return-from precompile-function-call (precompile1 new-form)))))
384    (when *enable-inline-expansion*
385      (let ((expansion (inline-expansion op)))
386        (when expansion
387          (let ((explain *explain*))
388            (when (and explain (memq :calls explain))
389              (format t ";   inlining call to ~S~%" op)))
390          (return-from precompile-function-call (precompile1 (expand-inline form expansion))))))
391    (cons op (mapcar #'precompile1 (cdr form)))))
392
393(defun precompile-locally (form)
394  (let ((*inline-declarations* *inline-declarations*))
395    (process-optimization-declarations (cdr form))
396  (cons 'LOCALLY (mapcar #'precompile1 (cdr form)))))
397
398(defun precompile-block (form)
399  (let ((args (cdr form)))
400    (if (null (cdr args))
401        nil
402        (list* 'BLOCK (car args) (mapcar #'precompile1 (cdr args))))))
403
404(defun precompile-dolist (form)
405  (if *in-jvm-compile*
406      (precompile1 (macroexpand form *precompile-env*))
407      (cons 'DOLIST (cons (mapcar #'precompile1 (cadr form))
408                          (mapcar #'precompile1 (cddr form))))))
409
410(defun precompile-dotimes (form)
411  (if *in-jvm-compile*
412      (precompile1 (macroexpand form *precompile-env*))
413      (cons 'DOTIMES (cons (mapcar #'precompile1 (cadr form))
414                           (mapcar #'precompile1 (cddr form))))))
415
416(defun precompile-do/do*-vars (varlist)
417  (let ((result nil))
418    (dolist (varspec varlist)
419      (if (atom varspec)
420          (push varspec result)
421          (case (length varspec)
422            (1
423             (push (%car varspec) result))
424            (2
425             (let* ((var (%car varspec))
426                    (init-form (%cadr varspec)))
427               (unless (symbolp var)
428                 (error 'type-error))
429               (push (list var (precompile1 init-form))
430                     result)))
431            (3
432             (let* ((var (%car varspec))
433                    (init-form (%cadr varspec))
434                    (step-form (%caddr varspec)))
435               (unless (symbolp var)
436                 (error 'type-error))
437               (push (list var (precompile1 init-form) (precompile1 step-form))
438                     result))))))
439    (nreverse result)))
440
441(defun precompile-do/do*-end-form (end-form)
442  (let ((end-test-form (car end-form))
443        (result-forms (cdr end-form)))
444    (list* end-test-form (mapcar #'precompile1 result-forms))))
445
446(defun precompile-do/do* (form)
447  (if *in-jvm-compile*
448      (precompile1 (macroexpand form *precompile-env*))
449      (list* (car form)
450             (precompile-do/do*-vars (cadr form))
451             (precompile-do/do*-end-form (caddr form))
452             (mapcar #'precompile1 (cdddr form)))))
453
454(defun precompile-do-symbols (form)
455  (list* (car form) (cadr form) (mapcar #'precompile1 (cddr form))))
456
457(defun precompile-load-time-value (form)
458  form)
459
460(defun precompile-progn (form)
461  (let ((body (cdr form)))
462    (if (eql (length body) 1)
463        (let ((res (precompile1 (%car body))))
464          ;; If the result turns out to be a bare symbol, leave it wrapped
465          ;; with PROGN so it won't be mistaken for a tag in an enclosing
466          ;; TAGBODY.
467          (if (symbolp res)
468              (list 'progn res)
469              res))
470        (cons 'PROGN (mapcar #'precompile1 body)))))
471
472(defun precompile-threads-synchronized-on (form)
473  (cons 'threads:synchronized-on (mapcar #'precompile1 (cdr form))))
474
475(defun precompile-progv (form)
476  (if (< (length form) 3)
477      (error "Not enough arguments for ~S." 'progv)
478      (list* 'PROGV (mapcar #'precompile1 (%cdr form)))))
479
480(defun precompile-setf (form)
481  (let ((place (second form)))
482    (cond ((and (consp place)
483                (eq (%car place) 'VALUES))
484     (setf form
485     (list* 'SETF
486      (list* 'VALUES
487             (mapcar #'precompile1 (%cdr place)))
488      (cddr form)))
489     (precompile1 (expand-macro form)))
490    ((symbolp place)
491           (multiple-value-bind
492                 (expansion expanded)
493               (expand-macro place)
494             (if expanded
495                 (precompile1 (list* 'SETF expansion
496                                     (cddr form)))
497                 (precompile1 (expand-macro form)))))
498          (t
499           (precompile1 (expand-macro form))))))
500
501(defun precompile-setq (form)
502  (let* ((args (cdr form))
503         (len (length args)))
504    (when (oddp len)
505      (error 'simple-program-error
506             :format-control "Odd number of arguments to SETQ."))
507    (if (= len 2)
508        (let* ((sym (%car args))
509               (val (%cadr args)))
510          (multiple-value-bind
511                (expansion expanded)
512              (expand-macro sym)
513            (if expanded
514                (precompile1 (list 'SETF expansion val))
515                (list 'SETQ sym (precompile1 val)))))
516        (let ((result ()))
517          (loop
518            (when (null args)
519              (return))
520            (push (precompile-setq (list 'SETQ (car args) (cadr args))) result)
521            (setq args (cddr args)))
522          (setq result (nreverse result))
523          (push 'PROGN result)
524          result))))
525
526(defun precompile-psetf (form)
527  (setf form
528        (list* 'PSETF
529               (mapcar #'precompile1 (cdr form))))
530  (precompile1 (expand-macro form)))
531
532(defun precompile-psetq (form)
533  ;; Make sure all the vars are symbols.
534  (do* ((rest (cdr form) (cddr rest))
535        (var (car rest)))
536       ((null rest))
537    (unless (symbolp var)
538      (error 'simple-error
539             :format-control "~S is not a symbol."
540             :format-arguments (list var))))
541  ;; Delegate to PRECOMPILE-PSETF so symbol macros are handled correctly.
542  (precompile-psetf form))
543
544
545(defun precompile-lambda-list (form)
546  (let (new aux-tail)
547    (dolist (arg form (nreverse new))
548       (if (or (atom arg) (> 2 (length arg)))
549           (progn
550             (when (eq arg '&aux)
551               (setf aux-tail t))
552             (push arg new))
553          ;; must be a cons of more than 1 cell
554          (let ((new-arg (copy-list arg)))
555            (unless (<= 1 (length arg) (if aux-tail 2 3))
556              ;; the aux-vars have a maximum length of 2 conses
557              ;; optional and key vars may have 3
558              (error 'program-error
559                     :format-control
560                     "The ~A binding specification ~S is invalid."
561                     :format-arguments (list (if aux-tail "&AUX"
562                                                 "&OPTIONAL/&KEY") arg)))
563             (setf (second new-arg)
564                   (precompile1 (second arg)))
565             (push new-arg new))))))
566
567(defun precompile-lambda (form)
568  (let ((body (cddr form))
569        (precompiled-lambda-list
570           (precompile-lambda-list (cadr form)))
571        (*inline-declarations* *inline-declarations*))
572    (process-optimization-declarations body)
573    (list* 'LAMBDA precompiled-lambda-list
574           (mapcar #'precompile1 body))))
575
576(defun precompile-named-lambda (form)
577  (let ((lambda-form (list* 'LAMBDA (caddr form) (cdddr form))))
578    (let ((body (cddr lambda-form))
579          (precompiled-lambda-list
580           (precompile-lambda-list (cadr lambda-form)))
581          (*inline-declarations* *inline-declarations*))
582      (process-optimization-declarations body)
583      (list* 'NAMED-LAMBDA (cadr form) precompiled-lambda-list
584             (mapcar #'precompile1 body)))))
585
586(defun precompile-defun (form)
587  (if *in-jvm-compile*
588      (precompile1 (expand-macro form))
589      form))
590
591(defun precompile-macrolet (form)
592  (let ((*precompile-env* (make-environment *precompile-env*)))
593    (dolist (definition (cadr form))
594      (environment-add-macro-definition
595       *precompile-env*
596       (car definition)
597       (make-macro (car definition)
598                   (make-closure
599                    (make-expander-for-macrolet definition)
600                    NIL))))
601    (multiple-value-bind (body decls)
602        (parse-body (cddr form) nil)
603      `(locally ,@decls ,@(mapcar #'precompile1 body)))))
604
605(defun precompile-symbol-macrolet (form)
606  (let ((*precompile-env* (make-environment *precompile-env*))
607        (defs (cadr form)))
608    (dolist (def defs)
609      (let ((sym (car def))
610            (expansion (cadr def)))
611        (when (special-variable-p sym)
612          (error 'program-error
613                 :format-control
614                 "Attempt to bind the special variable ~S with SYMBOL-MACROLET."
615                 :format-arguments (list sym)))
616        (environment-add-symbol-binding *precompile-env*
617                                        sym
618                                        (sys::make-symbol-macro expansion))))
619    (multiple-value-bind (body decls)
620        (parse-body (cddr form) nil)
621      (when decls
622        (let ((specials ()))
623          (dolist (decl decls)
624            (when (eq (car decl) 'DECLARE)
625              (dolist (declspec (cdr decl))
626                (when (eq (car declspec) 'SPECIAL)
627                  (setf specials (append specials (cdr declspec)))))))
628          (when specials
629            (let ((syms (mapcar #'car (cadr form))))
630              (dolist (special specials)
631                (when (memq special syms)
632                  (error 'program-error
633                         :format-control
634                         "~S is a symbol-macro and may not be declared special."
635                         :format-arguments (list special))))))))
636      `(locally ,@decls ,@(mapcar #'precompile1 body)))))
637
638(defun precompile-the (form)
639  (list 'THE
640        (second form)
641        (precompile1 (third form))))
642
643(defun precompile-truly-the (form)
644  (list 'TRULY-THE
645        (second form)
646        (precompile1 (third form))))
647
648(defun precompile-let/let*-vars (vars)
649  (let ((result nil))
650    (dolist (var vars)
651      (cond ((consp var)
652             (unless (<= 1 (length var) 2)
653               (error 'program-error
654                       :format-control
655                       "The LET/LET* binding specification ~S is invalid."
656                       :format-arguments (list var)))
657             (let ((v (%car var))
658                   (expr (cadr var)))
659               (unless (symbolp v)
660                 (error 'simple-type-error
661                        :format-control "The variable ~S is not a symbol."
662                        :format-arguments (list v)))
663               (push (list v (precompile1 expr)) result)
664               (environment-add-symbol-binding *precompile-env* v nil)))
665               ;; any value will do: we just need to shadow any symbol macros
666            (t
667             (push var result)
668             (environment-add-symbol-binding *precompile-env* var nil))))
669    (nreverse result)))
670
671(defun precompile-let (form)
672  (let ((*precompile-env* (make-environment *precompile-env*)))
673    (list* 'LET
674           (precompile-let/let*-vars (cadr form))
675           (mapcar #'precompile1 (cddr form)))))
676
677;; (LET* ((X 1)) (LET* ((Y 2)) (LET* ((Z 3)) (+ X Y Z)))) =>
678;; (LET* ((X 1) (Y 2) (Z 3)) (+ X Y Z))
679(defun maybe-fold-let* (form)
680  (if (and (= (length form) 3)
681           (consp (%caddr form))
682           (eq (%car (%caddr form)) 'LET*))
683      (let ((third (maybe-fold-let* (%caddr form))))
684        (list* 'LET* (append (%cadr form) (cadr third)) (cddr third)))
685      form))
686
687(defun precompile-let* (form)
688  (setf form (maybe-fold-let* form))
689  (let ((*precompile-env* (make-environment *precompile-env*)))
690    (list* 'LET*
691           (precompile-let/let*-vars (cadr form))
692           (mapcar #'precompile1 (cddr form)))))
693
694(defun precompile-case (form)
695  (if *in-jvm-compile*
696      (precompile1 (macroexpand form *precompile-env*))
697      (let* ((keyform (cadr form))
698             (clauses (cddr form))
699             (result (list (precompile1 keyform))))
700        (dolist (clause clauses)
701          (push (precompile-case-clause clause) result))
702        (cons (car form) (nreverse result)))))
703
704(defun precompile-case-clause (clause)
705  (let ((keys (car clause))
706        (forms (cdr clause)))
707    (cons keys (mapcar #'precompile1 forms))))
708
709(defun precompile-cond (form)
710  (if *in-jvm-compile*
711      (precompile1 (macroexpand form *precompile-env*))
712      (let ((clauses (cdr form))
713            (result nil))
714        (dolist (clause clauses)
715          (push (precompile-cond-clause clause) result))
716        (cons 'COND (nreverse result)))))
717
718(defun precompile-cond-clause (clause)
719  (let ((test (car clause))
720        (forms (cdr clause)))
721    (cons (precompile1 test) (mapcar #'precompile1 forms))))
722
723(defun precompile-local-function-def (def)
724  (let ((name (car def))
725        (body (cddr def)))
726    ;; Macro names are shadowed by local functions.
727    (environment-add-function-definition *precompile-env* name body)
728    (cdr (precompile-named-lambda (list* 'NAMED-LAMBDA def)))))
729
730(defun precompile-local-functions (defs)
731  (let ((result nil))
732    (dolist (def defs (nreverse result))
733      (push (precompile-local-function-def def) result))))
734
735(defun find-use (name expression)
736  (cond ((atom expression)
737         nil)
738        ((eq (%car expression) name)
739         t)
740        ((consp name)
741         t) ;; FIXME Recognize use of SETF functions!
742        (t
743         (or (find-use name (%car expression))
744             (find-use name (%cdr expression))))))
745
746(defun precompile-flet/labels (form)
747  (let ((*precompile-env* (make-environment *precompile-env*))
748        (operator (car form))
749        (locals (cadr form))
750        (body (cddr form)))
751    (dolist (local locals)
752      (let* ((name (car local))
753             (used-p (find-use name body)))
754        (unless used-p
755          (when (eq operator 'LABELS)
756            (dolist (local locals)
757              (when (neq name (car local))
758                (when (find-use name (cddr local))
759                  (setf used-p t)
760                  (return))
761                ;; Scope of defined function names includes
762                ;; &OPTIONAL, &KEY and &AUX parameters
763                ;; (LABELS.7B, LABELS.7C and LABELS.7D).
764                (let ((vars (or
765                             (cdr (memq '&optional (cadr local)))
766                             (cdr (memq '&key (cadr local)))
767                             (cdr (memq '&aux (cadr local))))))
768                  (when (and vars (find-use name vars)
769                             (setf used-p t)
770                             (return))))))))
771        (unless used-p
772          (format t "; Note: deleting unused local function ~A ~S~%"
773                  operator name)
774          (let* ((new-locals (remove local locals :test 'eq))
775                 (new-form
776                  (if new-locals
777                      (list* operator new-locals body)
778                      (list* 'LOCALLY body))))
779            (return-from precompile-flet/labels (precompile1 new-form))))))
780    (list* (car form)
781           (precompile-local-functions locals)
782           (mapcar #'precompile1 body))))
783
784(defun precompile-function (form)
785  (if (and (consp (cadr form)) (eq (caadr form) 'LAMBDA))
786      (list 'FUNCTION (precompile-lambda (%cadr form)))
787      form))
788
789(defun precompile-if (form)
790  (let ((args (cdr form)))
791    (case (length args)
792      (2
793       (let ((test (precompile1 (%car args))))
794         (cond ((null test)
795                nil)
796               (;;(constantp test)
797                (eq test t)
798                (precompile1 (%cadr args)))
799               (t
800                (list 'IF
801                      test
802                      (precompile1 (%cadr args)))))))
803      (3
804       (let ((test (precompile1 (%car args))))
805         (cond ((null test)
806                (precompile1 (%caddr args)))
807               (;;(constantp test)
808                (eq test t)
809                (precompile1 (%cadr args)))
810               (t
811                (list 'IF
812                      test
813                      (precompile1 (%cadr args))
814                      (precompile1 (%caddr args)))))))
815      (t
816       (error "wrong number of arguments for IF")))))
817
818(defun precompile-when (form)
819  (if *in-jvm-compile*
820      (precompile1 (macroexpand form *precompile-env*))
821      (precompile-cons form)))
822
823(defun precompile-unless (form)
824  (if *in-jvm-compile*
825      (precompile1 (macroexpand form *precompile-env*))
826      (precompile-cons form)))
827
828;; MULTIPLE-VALUE-BIND is handled explicitly by the JVM compiler.
829(defun precompile-multiple-value-bind (form)
830  (let ((vars (cadr form))
831        (values-form (caddr form))
832        (body (cdddr form))
833        (*precompile-env* (make-environment *precompile-env*)))
834    (dolist (var vars)
835      (environment-add-symbol-binding *precompile-env* var nil))
836    (list* 'MULTIPLE-VALUE-BIND
837           vars
838           (precompile1 values-form)
839           (mapcar #'precompile1 body))))
840
841;; MULTIPLE-VALUE-LIST is handled explicitly by the JVM compiler.
842(defun precompile-multiple-value-list (form)
843  (list 'MULTIPLE-VALUE-LIST (precompile1 (cadr form))))
844
845(defun precompile-nth-value (form)
846  (if *in-jvm-compile*
847      (precompile1 (macroexpand form *precompile-env*))
848      form))
849
850(defun precompile-return (form)
851  (if *in-jvm-compile*
852      (precompile1 (macroexpand form *precompile-env*))
853      (list 'RETURN (precompile1 (cadr form)))))
854
855(defun precompile-return-from (form)
856  (list 'RETURN-FROM (cadr form) (precompile1 (caddr form))))
857
858(defun precompile-tagbody (form)
859  (do ((body (cdr form) (cdr body))
860       (result ()))
861      ((null body) (cons 'TAGBODY (nreverse result)))
862    (if (atom (car body))
863        (push (car body) result)
864        (push (let* ((first-form (car body))
865                     (expanded (precompile1 first-form)))
866                (if (and (symbolp expanded)
867                         (neq expanded first-form))
868                    ;; Workaround:
869                    ;;  Since our expansion/compilation order
870                    ;;   is out of sync with the definition of
871                    ;;   TAGBODY (which requires the compiler
872                    ;;   to look for tags before expanding),
873                    ;;   we need to disguise anything which might
874                    ;;   look like a tag. We do this by wrapping
875                    ;;   it in a PROGN form.
876                    (list 'PROGN expanded)
877                    expanded)) result))))
878
879(defun precompile-eval-when (form)
880  (list* 'EVAL-WHEN (cadr form) (mapcar #'precompile1 (cddr form))))
881
882(defun precompile-unwind-protect (form)
883  (list* 'UNWIND-PROTECT
884         (precompile1 (cadr form))
885         (mapcar #'precompile1 (cddr form))))
886
887;; EXPAND-MACRO is like MACROEXPAND, but EXPAND-MACRO quits if *IN-JVM-COMPILE*
888;; is false and a macro is encountered that is also implemented as a special
889;; operator, so interpreted code can use the special operator implementation.
890(defun expand-macro (form)
891  (let (exp)
892    (loop
893       (unless *in-jvm-compile*
894         (when (and (consp form)
895                    (symbolp (%car form))
896                    (special-operator-p (%car form)))
897           (return-from expand-macro (values form exp))))
898       (multiple-value-bind (result expanded)
899           (macroexpand-1 form *precompile-env*)
900         (unless expanded
901           (return-from expand-macro (values result exp)))
902         (setf form result
903               exp t)))))
904
905(declaim (ftype (function (t t) t) precompile-form))
906(defun precompile-form (form in-jvm-compile
907                        &optional precompile-env)
908  (let ((*in-jvm-compile* in-jvm-compile)
909        (*inline-declarations* *inline-declarations*)
910        (pre::*precompile-env* precompile-env))
911    (precompile1 form)))
912
913(defun install-handler (symbol &optional handler)
914  (declare (type symbol symbol))
915  (let ((handler (or handler
916                     (find-symbol (sys::%format nil "PRECOMPILE-~A"
917                                                (symbol-name symbol))
918                                  'precompiler))))
919    (unless (and handler (fboundp handler))
920      (error "No handler for ~S." symbol))
921    (setf (get symbol 'precompile-handler) handler)))
922
923(defun install-handlers ()
924  (mapcar #'install-handler '(BLOCK
925                              CASE
926                              COND
927                              DOLIST
928                              DOTIMES
929                              EVAL-WHEN
930                              FUNCTION
931                              IF
932                              LAMBDA
933                              MACROLET
934                              MULTIPLE-VALUE-BIND
935                              MULTIPLE-VALUE-LIST
936                              NAMED-LAMBDA
937                              NTH-VALUE
938                              PROGN
939                              PROGV
940                              PSETF
941                              PSETQ
942                              RETURN
943                              RETURN-FROM
944                              SETF
945                              SETQ
946                              SYMBOL-MACROLET
947                              TAGBODY
948                              UNWIND-PROTECT
949                              UNLESS
950                              WHEN))
951
952  (dolist (pair '((ECASE                precompile-case)
953
954                  (AND                  precompile-cons)
955                  (OR                   precompile-cons)
956
957                  (CATCH                precompile-cons)
958                  (MULTIPLE-VALUE-CALL  precompile-cons)
959                  (MULTIPLE-VALUE-PROG1 precompile-cons)
960
961                  (DO                   precompile-do/do*)
962                  (DO*                  precompile-do/do*)
963
964                  (LET                  precompile-let)
965                  (LET*                 precompile-let*)
966
967                  (LOCALLY              precompile-locally)
968
969                  (FLET                 precompile-flet/labels)
970                  (LABELS               precompile-flet/labels)
971
972                  (LOAD-TIME-VALUE      precompile-load-time-value)
973
974                  (DECLARE              precompile-identity)
975                  (DEFUN                precompile-defun)
976                  (GO                   precompile-identity)
977                  (QUOTE                precompile-identity)
978                  (THE                  precompile-the)
979                  (THROW                precompile-cons)
980                  (TRULY-THE            precompile-truly-the)
981
982                  (THREADS:SYNCHRONIZED-ON
983                                        precompile-threads-synchronized-on)))
984    (install-handler (first pair) (second pair))))
985
986(install-handlers)
987
988(export '(precompile-form))
989
990(in-package #:ext)
991(defun macroexpand-all (form &optional env)
992  (precompiler:precompile-form form t env))
993
994(in-package #:lisp)
995
996(defmacro compiler-let (bindings &body forms &environment env)
997  (let ((bindings (mapcar #'(lambda (binding)
998                              (if (atom binding) (list binding) binding))
999                          bindings)))
1000    (progv (mapcar #'car bindings)
1001           (mapcar #'(lambda (binding)
1002                       (eval (cadr binding))) bindings)
1003      (macroexpand-all `(progn ,@forms) env))))
1004
1005(in-package #:system)
1006
1007(defun set-function-definition (name new old)
1008  (let ((*warn-on-redefinition* nil))
1009    (sys::%set-lambda-name new name)
1010    (sys:set-call-count new (sys:call-count old))
1011    (sys::%set-arglist new (sys::arglist old))
1012    (when (macro-function name)
1013      (setf new (make-macro name new)))
1014    (if (typep old 'standard-generic-function)
1015        (mop:set-funcallable-instance-function old new)
1016        (setf (fdefinition name) new))))
1017
1018(defun precompile (name &optional definition)
1019  (unless definition
1020    (setq definition (or (and (symbolp name) (macro-function name))
1021                         (fdefinition name))))
1022  (let ((expr definition)
1023        env result
1024        (pre::*precompile-env* nil))
1025    (when (functionp definition)
1026      (multiple-value-bind (form closure-p)
1027          (function-lambda-expression definition)
1028        (unless form
1029          (return-from precompile (values nil t t)))
1030        (setq env closure-p)
1031        (setq expr form)))
1032    (unless (and (consp expr) (eq (car expr) 'lambda))
1033      (format t "Unable to precompile ~S.~%" name)
1034      (return-from precompile (values nil t t)))
1035    (setf result
1036          (sys:make-closure (precompiler:precompile-form expr nil env) env))
1037    (when (and name (functionp result))
1038      (sys::set-function-definition name result definition))
1039    (values (or name result) nil nil)))
1040
1041(defun precompile-package (pkg &key verbose)
1042  (dolist (sym (package-symbols pkg))
1043    (when (fboundp sym)
1044      (unless (special-operator-p sym)
1045        (let ((f (fdefinition sym)))
1046          (unless (compiled-function-p f)
1047            (when verbose
1048              (format t "Precompiling ~S~%" sym)
1049              (finish-output))
1050            (precompile sym))))))
1051  t)
1052
1053(defun %compile (name definition)
1054  (if (and name (fboundp name) (%typep (symbol-function name) 'generic-function))
1055      (values name nil nil)
1056      (precompile name definition)))
1057
1058;; ;; Redefine EVAL to precompile its argument.
1059;; (defun eval (form)
1060;;   (%eval (precompile-form form nil)))
1061
1062;; ;; Redefine DEFMACRO to precompile the expansion function on the fly.
1063;; (defmacro defmacro (name lambda-list &rest body)
1064;;   (let* ((form (gensym "WHOLE-"))
1065;;          (env (gensym "ENVIRONMENT-")))
1066;;     (multiple-value-bind (body decls)
1067;;         (parse-defmacro lambda-list form body name 'defmacro :environment env)
1068;;       (let ((expander `(lambda (,form ,env) ,@decls (block ,name ,body))))
1069;;         `(progn
1070;;            (let ((macro (make-macro ',name
1071;;                                     (or (precompile nil ,expander) ,expander))))
1072;;              ,@(if (special-operator-p name)
1073;;                    `((put ',name 'macroexpand-macro macro))
1074;;                    `((fset ',name macro)))
1075;;              (%set-arglist macro ',lambda-list)
1076;;              ',name))))))
1077
1078;; Make an exception just this one time...
1079(when (get 'defmacro 'macroexpand-macro)
1080  (fset 'defmacro (get 'defmacro 'macroexpand-macro))
1081  (remprop 'defmacro 'macroexpand-macro))
1082
1083(defvar *defined-functions*)
1084
1085(defvar *undefined-functions*)
1086
1087(defun note-name-defined (name)
1088  (when (boundp '*defined-functions*)
1089    (push name *defined-functions*))
1090  (when (and (boundp '*undefined-functions*) (not (null *undefined-functions*)))
1091    (setf *undefined-functions* (remove name *undefined-functions*))))
1092
1093;; Redefine DEFUN to precompile the definition on the fly.
1094(defmacro defun (name lambda-list &body body &environment env)
1095  (note-name-defined name)
1096  (multiple-value-bind (body decls doc)
1097      (parse-body body)
1098    (let* ((block-name (fdefinition-block-name name))
1099           (lambda-expression
1100            `(named-lambda ,name ,lambda-list
1101                           ,@decls
1102                           ,@(when doc `(,doc))
1103                           (block ,block-name ,@body))))
1104      (cond ((and (boundp 'jvm::*file-compilation*)
1105                  ;; when JVM.lisp isn't loaded yet, this variable isn't bound
1106                  ;; meaning that we're not trying to compile to a file:
1107                  ;; Both COMPILE and COMPILE-FILE bind this variable.
1108                  ;; This function is also triggered by MACROEXPAND, though
1109                  jvm::*file-compilation*)
1110             `(fset ',name ,lambda-expression))
1111            (t
1112             (when (and env (empty-environment-p env))
1113               (setf env nil))
1114             (when (null env)
1115               (setf lambda-expression (precompiler:precompile-form lambda-expression nil)))
1116             `(progn
1117                (%defun ',name ,lambda-expression)
1118                ,@(when doc
1119                   `((%set-documentation ',name 'function ,doc)))))))))
1120
1121(export '(precompile))
1122
1123;;(provide "PRECOMPILER")
Note: See TracBrowser for help on using the repository browser.