source: trunk/j/src/org/armedbear/lisp/boot.lisp @ 3639

Last change on this file since 3639 was 3639, checked in by piso, 20 years ago

(sys::%load "with-hash-table-iterator.lisp")

File size: 12.6 KB
Line 
1;;; boot.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: boot.lisp,v 1.104 2003-09-09 23:19:47 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20(sys::%in-package "COMMON-LISP")
21
22
23(defmacro in-package (name)
24  (list 'sys::%in-package (string name)))
25
26
27(defmacro when (pred &rest body)
28  (list 'if pred (if (> (length body) 1)
29                     (append '(progn) body)
30                     (car body))))
31
32(defmacro unless (pred &rest body)
33  (list 'if (list 'not pred) (if (> (length body) 1)
34                                 (append '(progn) body)
35                                 (car body))))
36
37(defmacro defun (name lambda-list &rest body)
38  (list 'sys::%defun (list 'QUOTE name) (list 'QUOTE lambda-list) (list 'QUOTE body)))
39
40(defmacro defconstant (name initial-value &optional docstring)
41  (list 'sys::%defconstant (list 'QUOTE name) initial-value docstring))
42
43(defmacro defparameter (name initial-value &optional docstring)
44  (list 'sys::%defparameter (list 'QUOTE name) initial-value docstring))
45
46(sys::%load "autoloads.lisp")
47(sys::%load "early-defuns.lisp")
48(sys::%load "backquote.lisp")
49(sys::%load "setf.lisp")
50(sys::%load "documentation.lisp")
51
52(defmacro defvar (var &optional (val nil valp) (doc nil docp))
53  `(progn
54     (sys::%defvar ',var)
55     ,@(when valp
56   `((unless (boundp ',var)
57       (setq ,var ,val))))
58     ,@(when docp
59         `((setf (documentation ',var 'variable) ',doc)))
60     ',var))
61
62
63(defvar *features*
64  '(:armedbear))
65
66
67(defun make-package (package-name &key nicknames use)
68  (sys::%make-package package-name nicknames use))
69
70
71;;; READ-CONDITIONAL (from OpenMCL)
72
73(defconstant *keyword-package*
74  (find-package "KEYWORD"))
75
76(defun read-conditional (stream subchar int)
77  (cond (*read-suppress* (read stream t nil t) (values))
78        ((eql subchar (read-feature stream)) (read stream t nil t))
79        (t (let* ((*read-suppress* t))
80             (read stream t nil t)
81             (values)))))
82
83(defun read-feature (stream)
84  (let* ((f (let* ((*package* *keyword-package*))
85              (read stream t nil t))))
86    (labels ((eval-feature (form)
87                           (cond ((atom form)
88                                  (member form *features*))
89                                 ((eq (car form) :not)
90                                  (not (eval-feature (cadr form))))
91                                 ((eq (car form) :and)
92                                  (dolist (subform (cdr form) t)
93                                    (unless (eval-feature subform) (return))))
94                                 ((eq (car form) :or)
95                                  (dolist (subform (cdr form) nil)
96                                    (when (eval-feature subform) (return t))))
97                                 (t (error "READ-FEATURE")))))
98            (if (eval-feature f) #\+ #\-))))
99
100(set-dispatch-macro-character #\# #\+ #'read-conditional)
101(set-dispatch-macro-character #\# #\- #'read-conditional)
102
103
104(sys::%load "macros.lisp")
105(sys::%load "fixme.lisp")
106(sys::%load "destructuring-bind.lisp")
107(sys::%load "arrays.lisp")
108(sys::%load "compiler.lisp")
109(sys::%load "list.lisp")
110(sys::%load "sequences.lisp")
111(sys::%load "error.lisp")
112(sys::%load "defpackage.lisp")
113(sys::%load "with-hash-table-iterator.lisp")
114(sys::%load "with-package-iterator.lisp")
115(sys::%load "debug.lisp")
116
117
118(defpackage "JVM" (:use "COMMON-LISP" "EXTENSIONS"))
119
120
121;;; PROVIDE, REQUIRE (from SBCL)
122(defun provide (module-name)
123  (pushnew (string module-name) *modules* :test #'string=)
124  t)
125
126(defun require (module-name &optional pathnames)
127  (finish-output)
128  (unless (member (string module-name) *modules* :test #'string=)
129    (let ((saved-modules (copy-list *modules*)))
130      (cond (pathnames
131             (unless (listp pathnames) (setf pathnames (list pathnames)))
132             (dolist (x pathnames)
133               (load x)))
134            (t
135             (sys::%load (concatenate 'string (string-downcase (string module-name))
136                                      ".lisp"))))
137      (set-difference *modules* saved-modules))))
138
139
140;;; Miscellany.
141
142(defun integerp (n)
143  (typep n 'integer))
144
145(defun read-from-string (string &optional eof-error-p eof-value
146        &key (start 0) end preserve-whitespace)
147  (sys::%read-from-string string eof-error-p eof-value start end preserve-whitespace))
148
149(defconstant call-arguments-limit 50)
150
151(defconstant lambda-parameters-limit 50)
152
153(defconstant multiple-values-limit 20)
154
155(defconstant char-code-limit 128)
156
157(defconstant internal-time-units-per-second 1000)
158
159
160;; AND, OR (from CMUCL)
161
162(defmacro and (&rest forms)
163  (cond ((endp forms) t)
164  ((endp (rest forms)) (first forms))
165  (t
166   `(if ,(first forms)
167        (and ,@(rest forms))
168        nil))))
169
170(defmacro or (&rest forms)
171  (cond ((endp forms) nil)
172  ((endp (rest forms)) (first forms))
173  (t
174   (let ((n-result (gensym)))
175     `(let ((,n-result ,(first forms)))
176        (if ,n-result
177      ,n-result
178      (or ,@(rest forms))))))))
179
180
181;; CASE (from CLISP)
182
183(defun case-expand (form-name test keyform clauses)
184  (let ((var (gensym)))
185    `(let ((,var ,keyform))
186       (cond
187        ,@(maplist
188           #'(lambda (remaining-clauses)
189              (let ((clause (first remaining-clauses))
190                    (remaining-clauses (rest remaining-clauses)))
191                (unless (consp clause)
192                  (error 'program-error "~S: missing key list" form-name))
193                (let ((keys (first clause)))
194                  `(,(cond ((or (eq keys 'T) (eq keys 'OTHERWISE))
195                            (if remaining-clauses
196                                (error 'program-error
197                                       "~S: the ~S clause must be the last one"
198                                       form-name keys)
199                                't))
200                           ((listp keys)
201                            `(or ,@(mapcar #'(lambda (key)
202                                              `(,test ,var ',key))
203                                           keys)))
204                           (t `(,test ,var ',keys)))
205                     ,@(rest clause)))))
206           clauses)))))
207
208(defmacro case (keyform &rest clauses)
209  (case-expand 'case 'eql keyform clauses))
210
211
212;; CCASE (from CLISP)
213
214(defun parenthesize-keys (clauses)
215  ;; PARENTHESIZE-KEYS is necessary to avoid confusing
216  ;; the symbols OTHERWISE and T used as keys, with the same
217  ;; symbols used in the syntax of the non exhaustive CASE.
218  (mapcar #'(lambda (c)
219             (cond ((or (eq (car c) 't)
220                        (eq (car c) 'otherwise))
221                    (cons (list (car c)) (cdr c)))
222                   (t c)))
223          clauses))
224
225(defmacro ccase (keyplace &rest clauses)
226  (let ((g (gensym))
227        (h (gensym)))
228    `(block ,g
229            (tagbody
230             ,h
231             (return-from ,g
232                          (case ,keyplace
233                            ,@(parenthesize-keys clauses)
234                            (otherwise
235                             (error 'type-error "CCASE error") ;; FIXME
236                             (go ,h))))))))
237
238
239;;; TYPECASE (from CLISP)
240
241(defmacro typecase (keyform &rest typeclauselist)
242  (let* ((tempvar (gensym))
243         (condclauselist nil))
244    (do ((typeclauselistr typeclauselist (cdr typeclauselistr)))
245        ((atom typeclauselistr))
246      (cond ((atom (car typeclauselistr))
247             (error 'program-error
248                    "invalid clause in ~S: ~S"
249                    'typecase (car typeclauselistr)))
250            ((let ((type (caar typeclauselistr)))
251               (or (eq type T) (eq type 'OTHERWISE)))
252             (push `(T ,@(or (cdar typeclauselistr) '(NIL))) condclauselist)
253             (return))
254            (t (push `((TYPEP ,tempvar (QUOTE ,(caar typeclauselistr)))
255                       ,@(or (cdar typeclauselistr) '(NIL)))
256                     condclauselist))))
257    `(LET ((,tempvar ,keyform)) (COND ,@(nreverse condclauselist)))))
258
259
260(defmacro etypecase (keyform &rest clauses)
261  (let ((var (gensym)))
262    `(let ((,var ,keyform))
263       (typecase ,var
264         ,@clauses
265         (otherwise
266          (error 'type-error "~S fell through ETYPECASE expression" ,var))))))
267
268
269(defmacro ctypecase (keyplace &rest clauses)
270  (let ((g (gensym))
271        (h (gensym)))
272    `(block ,g
273            (tagbody
274             ,h
275             (return-from ,g
276                          (typecase ,keyplace
277                            ,@clauses
278                            (otherwise
279                             (error 'type-error "CTYPECASE error") ;; FIXME
280                             (go ,h))))))))
281
282
283(defmacro cond (&rest clauses)
284  (if (endp clauses)
285      nil
286      (let ((clause (first clauses)))
287  (when (atom clause)
288    (error "COND clause is not a list: ~S" clause))
289  (let ((test (first clause))
290        (forms (rest clause)))
291    (if (endp forms)
292        (let ((n-result (gensym)))
293    `(let ((,n-result ,test))
294       (if ,n-result
295           ,n-result
296           (cond ,@(rest clauses)))))
297        `(if ,test
298       (progn ,@forms)
299       (cond ,@(rest clauses))))))))
300
301
302;;; PROG, PROG* (from GCL)
303
304(defmacro prog (vl &rest body &aux (decl nil))
305  (do ()
306      ((or (endp body)
307           (not (consp (car body)))
308           (not (eq (caar body) 'declare)))
309       `(block nil (let ,vl ,@decl (tagbody ,@body))))
310      (push (car body) decl)
311      (pop body)))
312
313(defmacro prog* (vl &rest body &aux (decl nil))
314  (do ()
315      ((or (endp body)
316           (not (consp (car body)))
317           (not (eq (caar body) 'declare)))
318       `(block nil (let* ,vl ,@decl (tagbody ,@body))))
319      (push (car body) decl)
320      (pop body)))
321
322
323;;; DOTIMES (from CMUCL)
324(defmacro dotimes ((var count &optional (result nil)) &body body)
325  (cond ((numberp count)
326         `(do ((,var 0 (1+ ,var)))
327              ((>= ,var ,count) ,result)
328            ,@body))
329        (t (let ((v1 (gensym)))
330             `(do ((,var 0 (1+ ,var)) (,v1 ,count))
331                  ((>= ,var ,v1) ,result)
332                ,@body)))))
333
334
335;;; DOLIST (from CMUCL)
336
337;;; We repeatedly bind the var instead of setting it so that we never give the
338;;; var a random value such as NIL (which might conflict with a declaration).
339;;; If there is a result form, we introduce a gratitous binding of the variable
340;;; to NIL w/o the declarations, then evaluate the result form in that
341;;; environment.  We spuriously reference the gratuitous variable, since we
342;;; don't want to use IGNORABLE on what might be a special var.
343;;;
344(defmacro dolist ((var list &optional (result nil)) &body body)
345  (multiple-value-bind (forms decls)
346    (parse-body body nil nil)
347    (let ((n-list (gensym)))
348      `(do* ((,n-list ,list (cdr ,n-list)))
349      ((endp ,n-list)
350       ,@(if (constantp result)
351       `(,result)
352       `((let ((,var nil))
353           ,@decls
354           ,var
355           ,result))))
356         (let ((,var (car ,n-list)))
357           ,@decls
358           (tagbody
359            ,@forms))))))
360
361
362;;; From CMUCL.
363
364(defmacro with-output-to-string ((var &optional string &key element-type)
365         &body forms)
366  "If STRING is specified, it must be a string with a fill pointer;
367   the output is incrementally appended to the string (as if by use of
368   VECTOR-PUSH-EXTEND)."
369  (declare (ignore element-type))
370  (if string
371      `(let ((,var (sys::make-fill-pointer-output-stream ,string)))
372   (unwind-protect
373          (progn ,@forms)
374          (close ,var)))
375      `(let ((,var (make-string-output-stream)))
376   (unwind-protect
377          (progn ,@forms)
378          (close ,var))
379   (get-output-stream-string ,var))))
380
381
382(defmacro print-unreadable-object ((object stream &key type identity) &body body)
383  `(let ((s ,stream)
384         (obj ,object))
385     (format s "#<")
386     ,(when type
387        '(format s "~S" (type-of obj)))
388     ,(when (and type (or body identity))
389        '(format s " "))
390     ,@body
391     ,(when (and identity body)
392        '(format s " "))
393     ,(when identity
394        '(format s "@ ~A" (sys::hashcode-to-string obj)))
395     (format s ">")
396     nil))
397
398
399;;; MULTIPLE-VALUE-BIND (from CLISP)
400
401(defmacro multiple-value-bind (varlist form &body body)
402  (let ((g (gensym))
403        (poplist nil))
404    (dolist (var varlist) (setq poplist (cons `(,var (pop ,g)) poplist)))
405    `(let* ((,g (multiple-value-list ,form)) ,@(nreverse poplist))
406           ,@body)))
Note: See TracBrowser for help on using the repository browser.