source: trunk/j/src/org/armedbear/lisp/boot.lisp @ 4180

Last change on this file since 4180 was 4180, checked in by piso, 19 years ago

LAMBDA-LIST-KEYWORDS

File size: 13.1 KB
Line 
1;;; boot.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: boot.lisp,v 1.112 2003-10-03 00:34:39 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20(sys::%in-package "COMMON-LISP")
21
22
23(defmacro in-package (name)
24  (list 'sys::%in-package (string name)))
25
26
27(defmacro when (pred &rest body)
28  (list 'if pred (if (> (length body) 1)
29                     (append '(progn) body)
30                     (car body))))
31
32(defmacro unless (pred &rest body)
33  (list 'if (list 'not pred) (if (> (length body) 1)
34                                 (append '(progn) body)
35                                 (car body))))
36
37(defmacro defun (name lambda-list &rest body)
38  (list 'sys::%defun (list 'QUOTE name) (list 'QUOTE lambda-list) (list 'QUOTE body)))
39
40(defmacro defconstant (name initial-value &optional docstring)
41  (list 'sys::%defconstant (list 'QUOTE name) initial-value docstring))
42
43(defmacro defparameter (name initial-value &optional docstring)
44  (list 'sys::%defparameter (list 'QUOTE name) initial-value docstring))
45
46(sys::%load "autoloads.lisp")
47(sys::%load "early-defuns.lisp")
48(sys::%load "backquote.lisp")
49(sys::%load "setf.lisp")
50(sys::%load "documentation.lisp")
51
52(defmacro defvar (var &optional (val nil valp) (doc nil docp))
53  `(progn
54     (sys::%defvar ',var)
55     ,@(when valp
56   `((unless (boundp ',var)
57       (setq ,var ,val))))
58     ,@(when docp
59         `((setf (documentation ',var 'variable) ',doc)))
60     ',var))
61
62
63(defvar *features*
64  '(:armedbear))
65
66
67(defun make-package (package-name &key nicknames use)
68  (sys::%make-package package-name nicknames use))
69
70
71;;; READ-CONDITIONAL (from OpenMCL)
72
73(defconstant *keyword-package*
74  (find-package "KEYWORD"))
75
76(defun read-conditional (stream subchar int)
77  (cond (*read-suppress* (read stream t nil t) (values))
78        ((eql subchar (read-feature stream)) (read stream t nil t))
79        (t (let* ((*read-suppress* t))
80             (read stream t nil t)
81             (values)))))
82
83(defun read-feature (stream)
84  (let* ((f (let* ((*package* *keyword-package*))
85              (read stream t nil t))))
86    (labels ((eval-feature (form)
87                           (cond ((atom form)
88                                  (member form *features*))
89                                 ((eq (car form) :not)
90                                  (not (eval-feature (cadr form))))
91                                 ((eq (car form) :and)
92                                  (dolist (subform (cdr form) t)
93                                    (unless (eval-feature subform) (return))))
94                                 ((eq (car form) :or)
95                                  (dolist (subform (cdr form) nil)
96                                    (when (eval-feature subform) (return t))))
97                                 (t (error "READ-FEATURE")))))
98            (if (eval-feature f) #\+ #\-))))
99
100(set-dispatch-macro-character #\# #\+ #'read-conditional)
101(set-dispatch-macro-character #\# #\- #'read-conditional)
102
103
104(sys::%load "macros.lisp")
105(sys::%load "fixme.lisp")
106(sys::%load "destructuring-bind.lisp")
107(sys::%load "arrays.lisp")
108(sys::%load "compiler.lisp")
109(sys::%load "list.lisp")
110(sys::%load "sequences.lisp")
111(sys::%load "error.lisp")
112(sys::%load "defpackage.lisp")
113(sys::%load "debug.lisp")
114
115
116(defpackage "JVM" (:use "COMMON-LISP" "EXTENSIONS"))
117
118
119;;; PROVIDE, REQUIRE (from SBCL)
120(defun provide (module-name)
121  (pushnew (string module-name) *modules* :test #'string=)
122  t)
123
124(defun require (module-name &optional pathnames)
125  (finish-output)
126  (unless (member (string module-name) *modules* :test #'string=)
127    (let ((saved-modules (copy-list *modules*)))
128      (cond (pathnames
129             (unless (listp pathnames) (setf pathnames (list pathnames)))
130             (dolist (x pathnames)
131               (load x)))
132            (t
133             (sys::%load (concatenate 'string (string-downcase (string module-name))
134                                      ".lisp"))))
135      (set-difference *modules* saved-modules))))
136
137(defun read-from-string (string &optional eof-error-p eof-value
138        &key (start 0) end preserve-whitespace)
139  (sys::%read-from-string string eof-error-p eof-value start end preserve-whitespace))
140
141(defconstant lambda-list-keywords
142  '(&optional &rest &key &aux &body &whole &allow-other-keys &environment))
143
144(defconstant call-arguments-limit 50)
145
146(defconstant lambda-parameters-limit 50)
147
148(defconstant multiple-values-limit 20)
149
150(defconstant char-code-limit 128)
151
152(defconstant internal-time-units-per-second 1000)
153
154(defconstant boole-clr    0)
155(defconstant boole-set    1)
156(defconstant boole-1      2)
157(defconstant boole-2      3)
158(defconstant boole-c1     4)
159(defconstant boole-c2     5)
160(defconstant boole-and    6)
161(defconstant boole-ior    7)
162(defconstant boole-xor    8)
163(defconstant boole-eqv    9)
164(defconstant boole-nand  10)
165(defconstant boole-nor   11)
166(defconstant boole-andc1 12)
167(defconstant boole-andc2 13)
168(defconstant boole-orc1  14)
169(defconstant boole-orc2  15)
170
171
172;; AND, OR (from CMUCL)
173
174(defmacro and (&rest forms)
175  (cond ((endp forms) t)
176  ((endp (rest forms)) (first forms))
177  (t
178   `(if ,(first forms)
179        (and ,@(rest forms))
180        nil))))
181
182(defmacro or (&rest forms)
183  (cond ((endp forms) nil)
184  ((endp (rest forms)) (first forms))
185  (t
186   (let ((n-result (gensym)))
187     `(let ((,n-result ,(first forms)))
188        (if ,n-result
189      ,n-result
190      (or ,@(rest forms))))))))
191
192
193;; CASE (from CLISP)
194
195(defun case-expand (form-name test keyform clauses)
196  (let ((var (gensym)))
197    `(let ((,var ,keyform))
198       (cond
199        ,@(maplist
200           #'(lambda (remaining-clauses)
201              (let ((clause (first remaining-clauses))
202                    (remaining-clauses (rest remaining-clauses)))
203                (unless (consp clause)
204                  (error 'program-error "~S: missing key list" form-name))
205                (let ((keys (first clause)))
206                  `(,(cond ((or (eq keys 'T) (eq keys 'OTHERWISE))
207                            (if remaining-clauses
208                                (error 'program-error
209                                       "~S: the ~S clause must be the last one"
210                                       form-name keys)
211                                't))
212                           ((listp keys)
213                            `(or ,@(mapcar #'(lambda (key)
214                                              `(,test ,var ',key))
215                                           keys)))
216                           (t `(,test ,var ',keys)))
217                     ,@(rest clause)))))
218           clauses)))))
219
220(defmacro case (keyform &rest clauses)
221  (case-expand 'case 'eql keyform clauses))
222
223
224;; CCASE (from CLISP)
225
226(defun parenthesize-keys (clauses)
227  ;; PARENTHESIZE-KEYS is necessary to avoid confusing
228  ;; the symbols OTHERWISE and T used as keys, with the same
229  ;; symbols used in the syntax of the non exhaustive CASE.
230  (mapcar #'(lambda (c)
231             (cond ((or (eq (car c) 't)
232                        (eq (car c) 'otherwise))
233                    (cons (list (car c)) (cdr c)))
234                   (t c)))
235          clauses))
236
237(defmacro ccase (keyplace &rest clauses)
238  (let ((g (gensym))
239        (h (gensym)))
240    `(block ,g
241            (tagbody
242             ,h
243             (return-from ,g
244                          (case ,keyplace
245                            ,@(parenthesize-keys clauses)
246                            (otherwise
247                             (error 'type-error "CCASE error") ;; FIXME
248                             (go ,h))))))))
249
250
251;;; TYPECASE (from CLISP)
252
253(defmacro typecase (keyform &rest typeclauselist)
254  (let* ((tempvar (gensym))
255         (condclauselist nil))
256    (do ((typeclauselistr typeclauselist (cdr typeclauselistr)))
257        ((atom typeclauselistr))
258      (cond ((atom (car typeclauselistr))
259             (error 'program-error
260                    "invalid clause in ~S: ~S"
261                    'typecase (car typeclauselistr)))
262            ((let ((type (caar typeclauselistr)))
263               (or (eq type T) (eq type 'OTHERWISE)))
264             (push `(T ,@(or (cdar typeclauselistr) '(NIL))) condclauselist)
265             (return))
266            (t (push `((TYPEP ,tempvar (QUOTE ,(caar typeclauselistr)))
267                       ,@(or (cdar typeclauselistr) '(NIL)))
268                     condclauselist))))
269    `(LET ((,tempvar ,keyform)) (COND ,@(nreverse condclauselist)))))
270
271
272(defmacro etypecase (keyform &rest clauses)
273  (let ((var (gensym)))
274    `(let ((,var ,keyform))
275       (typecase ,var
276         ,@clauses
277         (otherwise
278          (error 'type-error "~S fell through ETYPECASE expression" ,var))))))
279
280
281(defmacro ctypecase (keyplace &rest clauses)
282  (let ((g (gensym))
283        (h (gensym)))
284    `(block ,g
285            (tagbody
286             ,h
287             (return-from ,g
288                          (typecase ,keyplace
289                            ,@clauses
290                            (otherwise
291                             (error 'type-error "CTYPECASE error") ;; FIXME
292                             (go ,h))))))))
293
294
295(defmacro cond (&rest clauses)
296  (if (endp clauses)
297      nil
298      (let ((clause (first clauses)))
299  (when (atom clause)
300    (error "COND clause is not a list: ~S" clause))
301  (let ((test (first clause))
302        (forms (rest clause)))
303    (if (endp forms)
304        (let ((n-result (gensym)))
305    `(let ((,n-result ,test))
306       (if ,n-result
307           ,n-result
308           (cond ,@(rest clauses)))))
309        `(if ,test
310       (progn ,@forms)
311       (cond ,@(rest clauses))))))))
312
313
314;;; PROG, PROG* (from GCL)
315
316(defmacro prog (vl &rest body &aux (decl nil))
317  (do ()
318      ((or (endp body)
319           (not (consp (car body)))
320           (not (eq (caar body) 'declare)))
321       `(block nil (let ,vl ,@decl (tagbody ,@body))))
322      (push (car body) decl)
323      (pop body)))
324
325(defmacro prog* (vl &rest body &aux (decl nil))
326  (do ()
327      ((or (endp body)
328           (not (consp (car body)))
329           (not (eq (caar body) 'declare)))
330       `(block nil (let* ,vl ,@decl (tagbody ,@body))))
331      (push (car body) decl)
332      (pop body)))
333
334
335;;; DOTIMES (from CMUCL)
336(defmacro dotimes ((var count &optional (result nil)) &body body)
337  (cond ((numberp count)
338         `(do ((,var 0 (1+ ,var)))
339              ((>= ,var ,count) ,result)
340            ,@body))
341        (t (let ((v1 (gensym)))
342             `(do ((,var 0 (1+ ,var)) (,v1 ,count))
343                  ((>= ,var ,v1) ,result)
344                ,@body)))))
345
346
347;;; DOLIST (from CMUCL)
348
349;;; We repeatedly bind the var instead of setting it so that we never give the
350;;; var a random value such as NIL (which might conflict with a declaration).
351;;; If there is a result form, we introduce a gratitous binding of the variable
352;;; to NIL w/o the declarations, then evaluate the result form in that
353;;; environment.  We spuriously reference the gratuitous variable, since we
354;;; don't want to use IGNORABLE on what might be a special var.
355;;;
356(defmacro dolist ((var list &optional (result nil)) &body body)
357  (multiple-value-bind (forms decls)
358    (sys::parse-body body nil nil)
359    (let ((n-list (gensym)))
360      `(do* ((,n-list ,list (cdr ,n-list)))
361      ((endp ,n-list)
362       ,@(if (constantp result)
363       `(,result)
364       `((let ((,var nil))
365           ,@decls
366           ,var
367           ,result))))
368         (let ((,var (car ,n-list)))
369           ,@decls
370           (tagbody
371            ,@forms))))))
372
373
374;;; From CMUCL.
375
376(defmacro with-output-to-string ((var &optional string &key element-type)
377         &body forms)
378  "If STRING is specified, it must be a string with a fill pointer;
379   the output is incrementally appended to the string (as if by use of
380   VECTOR-PUSH-EXTEND)."
381  (declare (ignore element-type))
382  (if string
383      `(let ((,var (sys::make-fill-pointer-output-stream ,string)))
384   (unwind-protect
385          (progn ,@forms)
386          (close ,var)))
387      `(let ((,var (make-string-output-stream)))
388   (unwind-protect
389          (progn ,@forms)
390          (close ,var))
391   (get-output-stream-string ,var))))
392
393
394(defmacro print-unreadable-object ((object stream &key type identity) &body body)
395  `(let ((s ,stream)
396         (obj ,object))
397     (format s "#<")
398     ,(when type
399        '(format s "~S" (type-of obj)))
400     ,(when (and type (or body identity))
401        '(format s " "))
402     ,@body
403     ,(when (and identity body)
404        '(format s " "))
405     ,(when identity
406        '(format s "@ ~A" (sys::hashcode-to-string obj)))
407     (format s ">")
408     nil))
409
410
411;;; MULTIPLE-VALUE-BIND (from CLISP)
412(defmacro multiple-value-bind (varlist form &body body)
413  (let ((g (gensym))
414        (poplist nil))
415    (dolist (var varlist) (setq poplist (cons `(,var (pop ,g)) poplist)))
416    `(let* ((,g (multiple-value-list ,form)) ,@(nreverse poplist))
417           ,@body)))
418
419
420(sys::%load "top-level.lisp")
Note: See TracBrowser for help on using the repository browser.