source: trunk/j/src/org/armedbear/lisp/boot.lisp @ 5016

Last change on this file since 5016 was 5016, checked in by piso, 18 years ago

(sys::%load "debug.lisp")

File size: 9.7 KB
Line 
1;;; boot.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: boot.lisp,v 1.135 2003-12-08 03:01:06 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20(sys::%in-package "COMMON-LISP")
21
22(setq ext:*autoload-verbose* nil)
23(setq *load-verbose* nil)
24
25(defmacro in-package (name)
26  (list 'sys::%in-package (string name)))
27
28(defmacro lambda (lambda-list &rest body)
29  (list 'function (list* 'lambda lambda-list body)))
30
31(defmacro when (pred &rest body)
32  (list 'if pred (if (> (length body) 1)
33                     (append '(progn) body)
34                     (car body))))
35
36(defmacro unless (pred &rest body)
37  (list 'if (list 'not pred) (if (> (length body) 1)
38                                 (append '(progn) body)
39                                 (car body))))
40
41(defmacro defun (name lambda-list &rest body)
42  (list 'sys::%defun (list 'QUOTE name) (list 'QUOTE lambda-list) (list 'QUOTE body)))
43
44(defmacro defconstant (name initial-value &optional docstring)
45  (list 'sys::%defconstant (list 'QUOTE name) initial-value docstring))
46
47(defmacro defparameter (name initial-value &optional docstring)
48  (list 'sys::%defparameter (list 'QUOTE name) initial-value docstring))
49
50(sys::%load "autoloads.lisp")
51(sys::%load "early-defuns.lisp")
52(sys::%load "backquote.lisp")
53(sys::%load "setf.lisp")
54(sys::%load "documentation.lisp")
55
56(defmacro defvar (var &optional (val nil valp) (doc nil docp))
57  `(progn
58     (sys::%defvar ',var)
59     ,@(when valp
60   `((unless (boundp ',var)
61       (setq ,var ,val))))
62     ,@(when docp
63         `((setf (documentation ',var 'variable) ',doc)))
64     ',var))
65
66
67(defvar *features*
68  '(:armedbear))
69
70
71(defun make-package (package-name &key nicknames use)
72  (sys::%make-package package-name nicknames use))
73
74
75;;; READ-CONDITIONAL (from OpenMCL)
76
77(defconstant *keyword-package*
78  (find-package "KEYWORD"))
79
80(defun read-conditional (stream subchar int)
81  (cond (*read-suppress* (read stream t nil t) (values))
82        ((eql subchar (read-feature stream)) (read stream t nil t))
83        (t (let* ((*read-suppress* t))
84             (read stream t nil t)
85             (values)))))
86
87(defun read-feature (stream)
88  (let* ((f (let* ((*package* *keyword-package*))
89              (read stream t nil t))))
90    (labels ((eval-feature (form)
91                           (cond ((atom form)
92                                  (ext:memql form *features*))
93                                 ((eq (car form) :not)
94                                  (not (eval-feature (cadr form))))
95                                 ((eq (car form) :and)
96                                  (dolist (subform (cdr form) t)
97                                    (unless (eval-feature subform) (return))))
98                                 ((eq (car form) :or)
99                                  (dolist (subform (cdr form) nil)
100                                    (when (eval-feature subform) (return t))))
101                                 (t (error "READ-FEATURE")))))
102            (if (eval-feature f) #\+ #\-))))
103
104(set-dispatch-macro-character #\# #\+ #'read-conditional)
105(set-dispatch-macro-character #\# #\- #'read-conditional)
106
107(make-package "JVM" :use '("COMMON-LISP" "EXTENSIONS"))
108(defvar jvm::*auto-compile* nil)
109(export 'jvm::*auto-compile* "JVM")
110
111(defun compile (name &optional definition)
112  (values (if name name definition) nil nil))
113
114(sys::%load "macros.lisp")
115(sys::%load "fixme.lisp")
116(sys::%load "destructuring-bind.lisp")
117(sys::%load "arrays.lisp")
118(sys::%load "compiler-macro.lisp")
119(sys::%load "precompiler.lisp")
120
121(sys::precompile-package "PRECOMPILER")
122(sys::precompile-package "EXTENSIONS")
123(sys::precompile-package "SYSTEM")
124(sys::precompile-package "COMMON-LISP")
125
126(sys::%load "list.lisp")
127(sys::%load "sequences.lisp")
128(sys::%load "error.lisp")
129(sys::%load "defpackage.lisp")
130(sys::%load "define-modify-macro.lisp")
131
132;;; PROVIDE, REQUIRE (from SBCL)
133(defun provide (module-name)
134  (pushnew (string module-name) *modules* :test #'string=)
135  t)
136
137(defun require (module-name &optional pathnames)
138  (unless (member (string module-name) *modules* :test #'string=)
139    (let ((saved-modules (copy-list *modules*)))
140      (cond (pathnames
141             (unless (listp pathnames) (setf pathnames (list pathnames)))
142             (dolist (x pathnames)
143               (load x)))
144            (t
145             (sys::%load (concatenate 'string (string-downcase (string module-name))
146                                      ".lisp"))))
147      (set-difference *modules* saved-modules))))
148
149(defun read-from-string (string &optional eof-error-p eof-value
150        &key (start 0) end preserve-whitespace)
151  (sys::%read-from-string string eof-error-p eof-value start end preserve-whitespace))
152
153(defconstant lambda-list-keywords
154  '(&optional &rest &key &aux &body &whole &allow-other-keys &environment))
155
156(defconstant call-arguments-limit 50)
157
158(defconstant lambda-parameters-limit 50)
159
160(defconstant multiple-values-limit 20)
161
162(defconstant char-code-limit 128)
163
164(defconstant internal-time-units-per-second 1000)
165
166(defconstant boole-clr    0)
167(defconstant boole-set    1)
168(defconstant boole-1      2)
169(defconstant boole-2      3)
170(defconstant boole-c1     4)
171(defconstant boole-c2     5)
172(defconstant boole-and    6)
173(defconstant boole-ior    7)
174(defconstant boole-xor    8)
175(defconstant boole-eqv    9)
176(defconstant boole-nand  10)
177(defconstant boole-nor   11)
178(defconstant boole-andc1 12)
179(defconstant boole-andc2 13)
180(defconstant boole-orc1  14)
181(defconstant boole-orc2  15)
182
183
184;; AND, OR (from CMUCL)
185
186(defmacro and (&rest forms)
187  (cond ((endp forms) t)
188  ((endp (rest forms)) (first forms))
189  (t
190   `(if ,(first forms)
191        (and ,@(rest forms))
192        nil))))
193
194(defmacro or (&rest forms)
195  (cond ((endp forms) nil)
196  ((endp (rest forms)) (first forms))
197  (t
198   (let ((n-result (gensym)))
199     `(let ((,n-result ,(first forms)))
200        (if ,n-result
201      ,n-result
202      (or ,@(rest forms))))))))
203
204(sys::%load "case.lisp")
205
206(defmacro cond (&rest clauses)
207  (if (endp clauses)
208      nil
209      (let ((clause (first clauses)))
210  (when (atom clause)
211    (error "COND clause is not a list: ~S" clause))
212  (let ((test (first clause))
213        (forms (rest clause)))
214    (if (endp forms)
215        (let ((n-result (gensym)))
216    `(let ((,n-result ,test))
217       (if ,n-result
218           ,n-result
219           (cond ,@(rest clauses)))))
220        `(if ,test
221       (progn ,@forms)
222       (cond ,@(rest clauses))))))))
223
224(defmacro dotimes ((var count &optional (result nil)) &body body)
225  (if (numberp count)
226      (let ((tag (gensym)))
227        `(block nil
228           (let ((,var 0))
229             (tagbody
230              ,tag
231              (if (>= ,var ,count)
232                  (return-from nil (progn ,result)))
233              ,@body
234              (setq ,var (1+ ,var))
235              (go ,tag)))))
236      (let ((limit (gensym))
237            (tag (gensym)))
238        `(block nil
239           (let ((,limit ,count)
240                 (,var 0))
241             (tagbody
242              ,tag
243              (if (>= ,var ,limit)
244                  (return-from nil (progn ,result)))
245              ,@body
246              (setq ,var (1+ ,var))
247              (go ,tag)))))))
248
249;;; DOLIST (from CMUCL)
250
251;;; We repeatedly bind the var instead of setting it so that we never give the
252;;; var a random value such as NIL (which might conflict with a declaration).
253;;; If there is a result form, we introduce a gratitous binding of the variable
254;;; to NIL w/o the declarations, then evaluate the result form in that
255;;; environment.  We spuriously reference the gratuitous variable, since we
256;;; don't want to use IGNORABLE on what might be a special var.
257;;;
258(defmacro dolist ((var list &optional (result nil)) &body body)
259  (multiple-value-bind (forms decls)
260    (sys::parse-body body nil nil)
261    (let ((n-list (gensym)))
262      `(do* ((,n-list ,list (cdr ,n-list)))
263      ((endp ,n-list)
264       ,@(if (constantp result)
265       `(,result)
266       `((let ((,var nil))
267           ,@decls
268           ,var
269           ,result))))
270         (let ((,var (car ,n-list)))
271           ,@decls
272           (tagbody
273            ,@forms))))))
274
275
276;;; From CMUCL.
277
278(defmacro with-output-to-string ((var &optional string &key element-type)
279         &body forms)
280  "If STRING is specified, it must be a string with a fill pointer;
281   the output is incrementally appended to the string (as if by use of
282   VECTOR-PUSH-EXTEND)."
283  (declare (ignore element-type))
284  (if string
285      `(let ((,var (sys::make-fill-pointer-output-stream ,string)))
286   (unwind-protect
287          (progn ,@forms)
288          (close ,var)))
289      `(let ((,var (make-string-output-stream)))
290   (unwind-protect
291          (progn ,@forms)
292          (close ,var))
293   (get-output-stream-string ,var))))
294
295
296;;; MULTIPLE-VALUE-BIND (from CLISP)
297(defmacro multiple-value-bind (varlist form &body body)
298  (let ((g (gensym))
299        (poplist nil))
300    (dolist (var varlist) (setq poplist (cons `(,var (pop ,g)) poplist)))
301    `(let* ((,g (multiple-value-list ,form)) ,@(nreverse poplist))
302           ,@body)))
303
304(sys::%load "late-setf.lisp")
305
306;; MULTIPLE-VALUE-SETQ (from CMUCL)
307(defmacro multiple-value-setq (varlist value-form)
308  (unless (and (listp varlist) (every #'symbolp varlist))
309    (error "~S is not a list of symbols" varlist))
310  `(values (setf (values ,@varlist) ,value-form)))
311
312(sys::%load "debug.lisp")
Note: See TracBrowser for help on using the repository browser.