source: trunk/j/src/org/armedbear/lisp/boot.lisp @ 5130

Last change on this file since 5130 was 5130, checked in by piso, 18 years ago

(sys::%load "signal.lisp")

File size: 10.1 KB
Line 
1;;; boot.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: boot.lisp,v 1.137 2003-12-14 17:15:31 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20(sys::%in-package "COMMON-LISP")
21
22(setq ext:*autoload-verbose* nil)
23(setq *load-verbose* nil)
24
25(defmacro in-package (name)
26  (list 'sys::%in-package (string name)))
27
28(defmacro lambda (lambda-list &rest body)
29  (list 'function (list* 'lambda lambda-list body)))
30
31(defmacro when (pred &rest body)
32  (list 'if pred (if (> (length body) 1)
33                     (append '(progn) body)
34                     (car body))))
35
36(defmacro unless (pred &rest body)
37  (list 'if (list 'not pred) (if (> (length body) 1)
38                                 (append '(progn) body)
39                                 (car body))))
40
41(defmacro defun (name lambda-list &rest body)
42  (list 'sys::%defun (list 'QUOTE name) (list 'QUOTE lambda-list) (list 'QUOTE body)))
43
44(defmacro defconstant (name initial-value &optional docstring)
45  (list 'sys::%defconstant (list 'QUOTE name) initial-value docstring))
46
47(defmacro defparameter (name initial-value &optional docstring)
48  (list 'sys::%defparameter (list 'QUOTE name) initial-value docstring))
49
50(sys::%load "autoloads.lisp")
51(sys::%load "early-defuns.lisp")
52(sys::%load "backquote.lisp")
53(sys::%load "setf.lisp")
54(sys::%load "documentation.lisp")
55
56(defmacro defvar (var &optional (val nil valp) (doc nil docp))
57  `(progn
58     (sys::%defvar ',var)
59     ,@(when valp
60   `((unless (boundp ',var)
61       (setq ,var ,val))))
62     ,@(when docp
63         `((setf (documentation ',var 'variable) ',doc)))
64     ',var))
65
66
67(defvar *features*
68  '(:armedbear))
69
70
71(defun make-package (package-name &key nicknames use)
72  (sys::%make-package package-name nicknames use))
73
74
75;;; READ-CONDITIONAL (from OpenMCL)
76
77(defconstant *keyword-package*
78  (find-package "KEYWORD"))
79
80(defun read-conditional (stream subchar int)
81  (cond (*read-suppress* (read stream t nil t) (values))
82        ((eql subchar (read-feature stream)) (read stream t nil t))
83        (t (let* ((*read-suppress* t))
84             (read stream t nil t)
85             (values)))))
86
87(defun read-feature (stream)
88  (let* ((f (let* ((*package* *keyword-package*))
89              (read stream t nil t))))
90    (labels ((eval-feature (form)
91                           (cond ((atom form)
92                                  (ext:memql form *features*))
93                                 ((eq (car form) :not)
94                                  (not (eval-feature (cadr form))))
95                                 ((eq (car form) :and)
96                                  (dolist (subform (cdr form) t)
97                                    (unless (eval-feature subform) (return))))
98                                 ((eq (car form) :or)
99                                  (dolist (subform (cdr form) nil)
100                                    (when (eval-feature subform) (return t))))
101                                 (t (error "READ-FEATURE")))))
102            (if (eval-feature f) #\+ #\-))))
103
104(set-dispatch-macro-character #\# #\+ #'read-conditional)
105(set-dispatch-macro-character #\# #\- #'read-conditional)
106
107(make-package "JVM" :use '("COMMON-LISP" "EXTENSIONS"))
108(defvar jvm::*auto-compile* nil)
109(export 'jvm::*auto-compile* "JVM")
110
111(defun compile (name &optional definition)
112  (values (if name name definition) nil nil))
113
114(sys::%load "macros.lisp")
115(sys::%load "fixme.lisp")
116(sys::%load "destructuring-bind.lisp")
117(sys::%load "arrays.lisp")
118(sys::%load "compiler-macro.lisp")
119(sys::%load "precompiler.lisp")
120
121(sys::precompile-package "PRECOMPILER")
122(sys::precompile-package "EXTENSIONS")
123(sys::precompile-package "SYSTEM")
124(sys::precompile-package "COMMON-LISP")
125
126(sys::%load "signal.lisp")
127(sys::%load "list.lisp")
128(sys::%load "sequences.lisp")
129(sys::%load "error.lisp")
130(sys::%load "defpackage.lisp")
131(sys::%load "define-modify-macro.lisp")
132
133;;; PROVIDE, REQUIRE (from SBCL)
134(defun provide (module-name)
135  (pushnew (string module-name) *modules* :test #'string=)
136  t)
137
138(defun require (module-name &optional pathnames)
139  (unless (member (string module-name) *modules* :test #'string=)
140    (let ((saved-modules (copy-list *modules*)))
141      (cond (pathnames
142             (unless (listp pathnames) (setf pathnames (list pathnames)))
143             (dolist (x pathnames)
144               (load x)))
145            (t
146             (sys::%load (concatenate 'string (string-downcase (string module-name))
147                                      ".lisp"))))
148      (set-difference *modules* saved-modules))))
149
150(defun read-from-string (string &optional eof-error-p eof-value
151        &key (start 0) end preserve-whitespace)
152  (sys::%read-from-string string eof-error-p eof-value start end preserve-whitespace))
153
154(defconstant lambda-list-keywords
155  '(&optional &rest &key &aux &body &whole &allow-other-keys &environment))
156
157(defconstant call-arguments-limit 50)
158
159(defconstant lambda-parameters-limit 50)
160
161(defconstant multiple-values-limit 20)
162
163(defconstant char-code-limit 128)
164
165(defconstant internal-time-units-per-second 1000)
166
167(defconstant boole-clr    0)
168(defconstant boole-set    1)
169(defconstant boole-1      2)
170(defconstant boole-2      3)
171(defconstant boole-c1     4)
172(defconstant boole-c2     5)
173(defconstant boole-and    6)
174(defconstant boole-ior    7)
175(defconstant boole-xor    8)
176(defconstant boole-eqv    9)
177(defconstant boole-nand  10)
178(defconstant boole-nor   11)
179(defconstant boole-andc1 12)
180(defconstant boole-andc2 13)
181(defconstant boole-orc1  14)
182(defconstant boole-orc2  15)
183
184
185;; AND, OR (from CMUCL)
186
187(defmacro and (&rest forms)
188  (cond ((endp forms) t)
189  ((endp (rest forms)) (first forms))
190  (t
191   `(if ,(first forms)
192        (and ,@(rest forms))
193        nil))))
194
195(defmacro or (&rest forms)
196  (cond ((endp forms) nil)
197  ((endp (rest forms)) (first forms))
198  (t
199   (let ((n-result (gensym)))
200     `(let ((,n-result ,(first forms)))
201        (if ,n-result
202      ,n-result
203      (or ,@(rest forms))))))))
204
205(sys::%load "case.lisp")
206
207(defmacro cond (&rest clauses)
208  (if (endp clauses)
209      nil
210      (let ((clause (first clauses)))
211  (when (atom clause)
212    (error "COND clause is not a list: ~S" clause))
213  (let ((test (first clause))
214        (forms (rest clause)))
215    (if (endp forms)
216        (let ((n-result (gensym)))
217    `(let ((,n-result ,test))
218       (if ,n-result
219           ,n-result
220           (cond ,@(rest clauses)))))
221        `(if ,test
222       (progn ,@forms)
223       (cond ,@(rest clauses))))))))
224
225(defmacro dotimes ((var count &optional (result nil)) &body body)
226  (if (numberp count)
227      (let ((tag (gensym)))
228        `(block nil
229           (let ((,var 0))
230             (tagbody
231              ,tag
232              (if (>= ,var ,count)
233                  (return-from nil (progn ,result)))
234              ,@body
235              (setq ,var (1+ ,var))
236              (go ,tag)))))
237      (let ((limit (gensym))
238            (tag (gensym)))
239        `(block nil
240           (let ((,limit ,count)
241                 (,var 0))
242             (tagbody
243              ,tag
244              (if (>= ,var ,limit)
245                  (return-from nil (progn ,result)))
246              ,@body
247              (setq ,var (1+ ,var))
248              (go ,tag)))))))
249
250;;; DOLIST (from CMUCL)
251
252;;; We repeatedly bind the var instead of setting it so that we never give the
253;;; var a random value such as NIL (which might conflict with a declaration).
254;;; If there is a result form, we introduce a gratitous binding of the variable
255;;; to NIL w/o the declarations, then evaluate the result form in that
256;;; environment.  We spuriously reference the gratuitous variable, since we
257;;; don't want to use IGNORABLE on what might be a special var.
258;;;
259(defmacro dolist ((var list &optional (result nil)) &body body)
260  (multiple-value-bind (forms decls)
261    (sys::parse-body body nil nil)
262    (let ((n-list (gensym)))
263      `(do* ((,n-list ,list (cdr ,n-list)))
264      ((endp ,n-list)
265       ,@(if (constantp result)
266       `(,result)
267       `((let ((,var nil))
268           ,@decls
269           ,var
270           ,result))))
271         (let ((,var (car ,n-list)))
272           ,@decls
273           (tagbody
274            ,@forms))))))
275
276(defmacro do-symbols ((var &optional (package '*package*) (result nil)) &body body)
277  `(dolist (,var
278            (append (sys::package-symbols ,package)
279                    (sys::package-inherited-symbols ,package))
280            ,result)
281     ,@body))
282
283(defmacro do-external-symbols ((var &optional (package '*package*) (result nil)) &body body)
284  `(dolist (,var (sys::package-external-symbols ,package) ,result) ,@body))
285
286;;; From CMUCL.
287(defmacro with-output-to-string ((var &optional string &key element-type)
288         &body forms)
289  "If STRING is specified, it must be a string with a fill pointer;
290   the output is incrementally appended to the string (as if by use of
291   VECTOR-PUSH-EXTEND)."
292  (declare (ignore element-type))
293  (if string
294      `(let ((,var (sys::make-fill-pointer-output-stream ,string)))
295   (unwind-protect
296          (progn ,@forms)
297          (close ,var)))
298      `(let ((,var (make-string-output-stream)))
299   (unwind-protect
300          (progn ,@forms)
301          (close ,var))
302   (get-output-stream-string ,var))))
303
304
305;;; MULTIPLE-VALUE-BIND (from CLISP)
306(defmacro multiple-value-bind (varlist form &body body)
307  (let ((g (gensym))
308        (poplist nil))
309    (dolist (var varlist) (setq poplist (cons `(,var (pop ,g)) poplist)))
310    `(let* ((,g (multiple-value-list ,form)) ,@(nreverse poplist))
311           ,@body)))
312
313(sys::%load "late-setf.lisp")
314
315;; MULTIPLE-VALUE-SETQ (from CMUCL)
316(defmacro multiple-value-setq (varlist value-form)
317  (unless (and (listp varlist) (every #'symbolp varlist))
318    (error "~S is not a list of symbols" varlist))
319  `(values (setf (values ,@varlist) ,value-form)))
320
321(sys::%load "debug.lisp")
Note: See TracBrowser for help on using the repository browser.