source: trunk/j/src/org/armedbear/lisp/clos.lisp @ 5054

Last change on this file since 5054 was 5054, checked in by piso, 18 years ago

ALLOCATE-INSTANCE is a generic function.

File size: 61.2 KB
Line 
1;;; clos.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: clos.lisp,v 1.30 2003-12-10 17:31:01 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20;;; Adapted from Closette.
21
22;;; Closette Version 1.0 (February 10, 1991)
23;;;
24;;; Copyright (c) 1990, 1991 Xerox Corporation.
25;;; All rights reserved.
26;;;
27;;; Use and copying of this software and preparation of derivative works
28;;; based upon this software are permitted.  Any distribution of this
29;;; software or derivative works must comply with all applicable United
30;;; States export control laws.
31;;;
32;;; This software is made available AS IS, and Xerox Corporation makes no
33;;; warranty about the software, its performance or its conformity to any
34;;; specification.
35;;;
36;;; Closette is an implementation of a subset of CLOS with a metaobject
37;;; protocol as described in "The Art of The Metaobject Protocol",
38;;; MIT Press, 1991.
39
40(in-package "SYSTEM")
41
42(defmacro push-on-end (value location)
43  `(setf ,location (nconc ,location (list ,value))))
44
45;;; (SETF GETF*) is like (SETF GETF) except that it always changes the list,
46;;; which must be non-nil.
47
48(defun (setf getf*) (new-value plist key)
49  (block body
50    (do ((x plist (cddr x)))
51        ((null x))
52      (when (eq (car x) key)
53        (setf (car (cdr x)) new-value)
54        (return-from body new-value)))
55    (push-on-end key plist)
56    (push-on-end new-value plist)
57    new-value))
58
59(defun mapappend (fun &rest args)
60  (if (some #'null args)
61      ()
62      (append (apply fun (mapcar #'car args))
63              (apply #'mapappend fun (mapcar #'cdr args)))))
64
65(defun mapplist (fun x)
66  (if (null x)
67      ()
68      (cons (funcall fun (car x) (cadr x))
69            (mapplist fun (cddr x)))))
70
71(defsetf class-name %set-class-name)
72(defsetf class-direct-superclasses %set-class-direct-superclasses)
73(defsetf class-direct-subclasses %set-class-direct-subclasses)
74(defsetf class-direct-methods %set-class-direct-methods)
75(defsetf class-direct-slots %set-class-direct-slots)
76(defsetf class-slots %set-class-slots)
77(defsetf class-direct-default-initargs %set-class-direct-default-initargs)
78(defsetf class-default-initargs %set-class-default-initargs)
79(defsetf class-precedence-list %set-class-precedence-list)
80(defsetf std-instance-class %set-std-instance-class)
81(defsetf std-instance-slots %set-std-instance-slots)
82
83(defun (setf find-class) (new-value symbol &optional errorp environment)
84  (%set-find-class symbol new-value))
85
86(defun canonicalize-direct-slots (direct-slots)
87  `(list ,@(mapcar #'canonicalize-direct-slot direct-slots)))
88
89(defun canonicalize-direct-slot (spec)
90  (if (symbolp spec)
91      `(list :name ',spec)
92      (let ((name (car spec))
93            (initfunction nil)
94            (initform nil)
95            (initargs ())
96            (type nil)
97            (allocation nil)
98            (documentation nil)
99            (readers ())
100            (writers ())
101            (other-options ()))
102        (do ((olist (cdr spec) (cddr olist)))
103            ((null olist))
104          (case (car olist)
105            (:initform
106             (when initform
107               (error 'program-error
108                      "duplicate slot option :INITFORM for slot named ~S"
109                      name))
110             (setq initfunction
111                   `(function (lambda () ,(cadr olist))))
112             (setq initform `',(cadr olist)))
113            (:initarg
114             (push-on-end (cadr olist) initargs))
115            (:allocation
116             (when allocation
117               (error 'program-error
118                      "duplicate slot option :ALLOCATION for slot named ~S"
119                      name))
120             (setf allocation (cadr olist))
121             (push-on-end (car olist) other-options)
122             (push-on-end (cadr olist) other-options))
123            (:type
124             (when type
125               (error 'program-error
126                      "duplicate slot option :TYPE for slot named ~S"
127                      name))
128             (setf type (cadr olist))) ;; FIXME type is ignored
129            (:documentation
130             (when documentation
131               (error 'program-error
132                      "duplicate slot option :DOCUMENTATION for slot named ~S"
133                      name))
134             (setf documentation (cadr olist))) ;; FIXME documentation is ignored
135            (:reader
136             (push-on-end (cadr olist) readers))
137            (:writer
138             (push-on-end (cadr olist) writers))
139            (:accessor
140             (push-on-end (cadr olist) readers)
141             (push-on-end `(setf ,(cadr olist)) writers))
142            (t
143             (error 'program-error
144                    "invalid initialization argument ~S for slot named ~S"
145                    (car olist) name))))
146        `(list
147          :name ',name
148          ,@(when initfunction
149              `(:initform ,initform
150                          :initfunction ,initfunction))
151          ,@(when initargs `(:initargs ',initargs))
152          ,@(when readers `(:readers ',readers))
153          ,@(when writers `(:writers ',writers))
154          ,@other-options))))
155
156(defun canonicalize-direct-superclasses (direct-superclasses)
157  `(list ,@(mapcar #'canonicalize-direct-superclass direct-superclasses)))
158
159(defun canonicalize-direct-superclass (class-name)
160  `(find-class ',class-name))
161
162(defun canonicalize-defclass-options (options)
163  (mapappend #'canonicalize-defclass-option options))
164
165(defun canonicalize-defclass-option (option)
166  (case (car option)
167    (:metaclass
168     (list ':metaclass
169           `(find-class ',(cadr option))))
170    (:default-initargs
171     (list
172      ':direct-default-initargs
173      `(list ,@(mapappend
174                #'(lambda (x) x)
175                (mapplist
176                 #'(lambda (key value)
177                    `(',key ,(make-initfunction value)))
178                 (cdr option))))))
179    (:documentation
180     (list (car option) `',(cadr option)))
181    (t
182     (error 'program-error
183            "invalid DEFCLASS option ~S"
184            (car option)))))
185
186(defun make-initfunction (initform)
187  `(function (lambda () ,initform)))
188
189(defconstant +slot-unbound+ (make-symbol "SLOT-UNBOUND"))
190
191;;; Slot definition metaobjects
192
193(defstruct slot-definition
194  name
195  initfunction
196  initform
197  initargs
198  readers
199  writers
200  allocation
201  allocation-class
202  (location nil))
203
204(defun make-direct-slot-definition (class &rest properties
205                                          &key name
206                                          (initargs ())
207                                          (initform nil)
208                                          (initfunction nil)
209                                          (readers ())
210                                          (writers ())
211                                          (allocation :instance)
212                                          &allow-other-keys)
213  (let ((slot (make-slot-definition)))
214    (setf (slot-definition-name slot) name)
215    (setf (slot-definition-initargs slot) initargs)
216    (setf (slot-definition-initform slot) initform)
217    (setf (slot-definition-initfunction slot) initfunction)
218    (setf (slot-definition-readers slot) readers)
219    (setf (slot-definition-writers slot) writers)
220    (setf (slot-definition-allocation slot) allocation)
221    (setf (slot-definition-allocation-class slot) class)
222    slot))
223
224(defun make-effective-slot-definition (&rest properties
225                                             &key name
226                                             (initargs ())
227                                             (initform nil)
228                                             (initfunction nil)
229                                             (allocation :instance)
230                                             (allocation-class nil)
231                                             &allow-other-keys)
232  (let ((slot (make-slot-definition)))
233    (setf (slot-definition-name slot) name)
234    (setf (slot-definition-initargs slot) initargs)
235    (setf (slot-definition-initform slot) initform)
236    (setf (slot-definition-initfunction slot) initfunction)
237    (setf (slot-definition-allocation slot) allocation)
238    (setf (slot-definition-allocation-class slot) allocation-class)
239    slot))
240
241;;; finalize-inheritance
242
243(defun std-finalize-inheritance (class)
244  (setf (class-precedence-list class)
245        (funcall (if (eq (class-of class) the-class-standard-class)
246                     #'std-compute-class-precedence-list
247                     #'compute-class-precedence-list)
248                 class))
249  (setf (class-slots class)
250        (funcall (if (eq (class-of class) the-class-standard-class)
251                     #'std-compute-slots
252                     #'compute-slots)
253                 class))
254  (let ((location 0))
255    (dolist (slot (class-slots class))
256      (case (slot-definition-allocation slot)
257        (:instance
258         (setf (slot-definition-location slot) location)
259         (incf location))
260        (:class
261         (unless (slot-definition-location slot)
262           (let ((allocation-class (slot-definition-allocation-class slot)))
263             (setf (slot-definition-location slot)
264                   (if (eq class allocation-class)
265                       (cons (slot-definition-name slot) +slot-unbound+)
266                       (slot-location allocation-class (slot-definition-name slot))))))))))
267  (setf (class-default-initargs class)
268        (compute-class-default-initargs class))
269  (values))
270
271(defun compute-class-default-initargs (class)
272  (mapappend #'class-direct-default-initargs
273             (class-precedence-list class)))
274
275;;; Class precedence lists
276
277(defun std-compute-class-precedence-list (class)
278  (let ((classes-to-order (collect-superclasses* class)))
279    (topological-sort classes-to-order
280                      (remove-duplicates
281                       (mapappend #'local-precedence-ordering
282                                  classes-to-order))
283                      #'std-tie-breaker-rule)))
284
285;;; topological-sort implements the standard algorithm for topologically
286;;; sorting an arbitrary set of elements while honoring the precedence
287;;; constraints given by a set of (X,Y) pairs that indicate that element
288;;; X must precede element Y.  The tie-breaker procedure is called when it
289;;; is necessary to choose from multiple minimal elements; both a list of
290;;; candidates and the ordering so far are provided as arguments.
291
292(defun topological-sort (elements constraints tie-breaker)
293  (let ((remaining-constraints constraints)
294        (remaining-elements elements)
295        (result ()))
296    (loop
297      (let ((minimal-elements
298             (remove-if
299              #'(lambda (class)
300                 (member class remaining-constraints
301                         :key #'cadr))
302              remaining-elements)))
303        (when (null minimal-elements)
304          (if (null remaining-elements)
305              (return-from topological-sort result)
306              (error "Inconsistent precedence graph.")))
307        (let ((choice (if (null (cdr minimal-elements))
308                          (car minimal-elements)
309                          (funcall tie-breaker
310                                   minimal-elements
311                                   result))))
312          (setq result (append result (list choice)))
313          (setq remaining-elements
314                (remove choice remaining-elements))
315          (setq remaining-constraints
316                (remove choice
317                        remaining-constraints
318                        :test #'member)))))))
319
320;;; In the event of a tie while topologically sorting class precedence lists,
321;;; the CLOS Specification says to "select the one that has a direct subclass
322;;; rightmost in the class precedence list computed so far."  The same result
323;;; is obtained by inspecting the partially constructed class precedence list
324;;; from right to left, looking for the first minimal element to show up among
325;;; the direct superclasses of the class precedence list constituent.
326;;; (There's a lemma that shows that this rule yields a unique result.)
327
328(defun std-tie-breaker-rule (minimal-elements cpl-so-far)
329  (dolist (cpl-constituent (reverse cpl-so-far))
330    (let* ((supers (class-direct-superclasses cpl-constituent))
331           (common (intersection minimal-elements supers)))
332      (when (not (null common))
333        (return-from std-tie-breaker-rule (car common))))))
334
335;;; This version of collect-superclasses* isn't bothered by cycles in the class
336;;; hierarchy, which sometimes happen by accident.
337
338(defun collect-superclasses* (class)
339  (labels ((all-superclasses-loop (seen superclasses)
340                                  (let ((to-be-processed
341                                         (set-difference superclasses seen)))
342                                    (if (null to-be-processed)
343                                        superclasses
344                                        (let ((class-to-process
345                                               (car to-be-processed)))
346                                          (all-superclasses-loop
347                                           (cons class-to-process seen)
348                                           (union (class-direct-superclasses
349                                                   class-to-process)
350                                                  superclasses)))))))
351          (all-superclasses-loop () (list class))))
352
353;;; The local precedence ordering of a class C with direct superclasses C_1,
354;;; C_2, ..., C_n is the set ((C C_1) (C_1 C_2) ...(C_n-1 C_n)).
355
356(defun local-precedence-ordering (class)
357  (mapcar #'list
358          (cons class
359                (butlast (class-direct-superclasses class)))
360          (class-direct-superclasses class)))
361
362;;; Slot inheritance
363
364(defun std-compute-slots (class)
365  (let* ((all-slots (mapappend #'class-direct-slots
366                               (class-precedence-list class)))
367         (all-names (remove-duplicates
368                     (mapcar #'slot-definition-name all-slots))))
369    (mapcar #'(lambda (name)
370               (funcall
371                (if (eq (class-of class) the-class-standard-class)
372                    #'std-compute-effective-slot-definition
373                    #'compute-effective-slot-definition)
374                class
375                (remove name all-slots
376                        :key #'slot-definition-name
377                        :test-not #'eq)))
378            all-names)))
379
380(defun std-compute-effective-slot-definition (class direct-slots)
381  (declare (ignore class))
382  (let ((initer (find-if-not #'null direct-slots
383                             :key #'slot-definition-initfunction)))
384    (make-effective-slot-definition
385     :name (slot-definition-name (car direct-slots))
386     :initform (if initer
387                   (slot-definition-initform initer)
388                   nil)
389     :initfunction (if initer
390                       (slot-definition-initfunction initer)
391                       nil)
392     :initargs (remove-duplicates
393                (mapappend #'slot-definition-initargs
394                           direct-slots))
395     :allocation (slot-definition-allocation (car direct-slots))
396     :allocation-class (slot-definition-allocation-class (car direct-slots)))))
397
398;;; Simple vectors are used for slot storage.
399
400(defun allocate-slot-storage (size initial-value)
401  (make-array size :initial-element initial-value))
402
403;;; Standard instance slot access
404
405;;; N.B. The location of the effective-slots slots in the class metaobject for
406;;; standard-class must be determined without making any further slot
407;;; references.
408
409(defvar the-slots-of-standard-class) ;standard-class's class-slots
410(defvar the-class-standard-class (find-class 'standard-class))
411
412(defun find-slot-definition (class slot-name)
413  (dolist (slot (class-slots class) nil)
414    (when (eq slot-name (slot-definition-name slot))
415      (return slot))))
416
417(defun slot-location (class slot-name)
418  (let ((slot (find-slot-definition class slot-name)))
419    (if slot
420        (slot-definition-location slot)
421        nil)))
422
423(defmacro slot-contents (slots location)
424  `(aref ,slots ,location))
425
426(defun (setf slot-contents) (new-value slots location)
427  (setf (svref slots location) new-value))
428
429(defun std-slot-value (instance slot-name)
430  (let* ((location (slot-location (class-of instance) slot-name))
431         (value (cond ((fixnump location)
432                       (slot-contents (std-instance-slots instance) location))
433                      ((consp location)
434                       (cdr location))
435                      (t
436                       (slot-missing (class-of instance) instance slot-name 'slot-value)))))
437    (if (eq +slot-unbound+ value)
438        (error "the slot ~S is unbound in the object ~S" slot-name instance)
439        value)))
440
441(defun slot-value (object slot-name)
442  (if (eq (class-of (class-of object)) the-class-standard-class)
443      (std-slot-value object slot-name)
444      (slot-value-using-class (class-of object) object slot-name)))
445
446(defun (setf std-slot-value) (new-value instance slot-name)
447  (let ((location (slot-location (class-of instance) slot-name)))
448    (cond ((fixnump location)
449           (setf (slot-contents (std-instance-slots instance) location) new-value))
450          ((consp location)
451           (setf (cdr location) new-value))
452          (t
453           (slot-missing (class-of instance) instance slot-name 'setf new-value))))
454  new-value)
455
456(defun (setf slot-value) (new-value object slot-name)
457  (if (eq (class-of (class-of object)) the-class-standard-class)
458      (setf (std-slot-value object slot-name) new-value)
459      (setf-slot-value-using-class
460       new-value (class-of object) object slot-name)))
461
462(defun std-slot-boundp (instance slot-name)
463  (let ((location (slot-location (class-of instance) slot-name)))
464    (cond ((fixnump location)
465           (neq +slot-unbound+ (slot-contents (std-instance-slots instance) location)))
466          ((consp location)
467           (neq +slot-unbound+ (cdr location)))
468          (t
469           (not (null (slot-missing (class-of instance) instance slot-name 'slot-boundp)))))))
470
471(defun slot-boundp (object slot-name)
472  (if (eq (class-of (class-of object)) the-class-standard-class)
473      (std-slot-boundp object slot-name)
474      (slot-boundp-using-class (class-of object) object slot-name)))
475
476(defun std-slot-makunbound (instance slot-name)
477  (let ((location (slot-location (class-of instance) slot-name)))
478    (cond ((fixnump location)
479           (setf (slot-contents (std-instance-slots instance) location) +slot-unbound+))
480          ((consp location)
481           (setf (cdr location) +slot-unbound+))
482          (t
483           (slot-missing (class-of instance) instance slot-name 'slot-makunbound))))
484  instance)
485
486(defun slot-makunbound (object slot-name)
487  (if (eq (class-of (class-of object)) the-class-standard-class)
488      (std-slot-makunbound object slot-name)
489      (slot-makunbound-using-class (class-of object) object slot-name)))
490
491(defun std-slot-exists-p (instance slot-name)
492  (not (null (find slot-name (class-slots (class-of instance))
493                   :key #'slot-definition-name))))
494(defun slot-exists-p (object slot-name)
495  (if (eq (class-of (class-of object)) the-class-standard-class)
496      (std-slot-exists-p object slot-name)
497      (slot-exists-p-using-class (class-of object) object slot-name)))
498
499;;; Standard instance allocation
500
501(defun instance-slot-p (slot)
502  (eq (slot-definition-allocation slot) :instance))
503
504(defun std-allocate-instance (class)
505  (allocate-std-instance
506   class
507   (allocate-slot-storage (count-if #'instance-slot-p (class-slots class))
508                          +slot-unbound+)))
509
510(defun make-instance-standard-class (metaclass
511                                     &key name direct-superclasses direct-slots
512                                     direct-default-initargs
513                                     &allow-other-keys)
514  (declare (ignore metaclass))
515  (let ((class (std-allocate-instance (find-class 'standard-class))))
516    (setf (class-name class) name)
517    (setf (class-direct-subclasses class) ())
518    (setf (class-direct-methods class) ())
519    (std-after-initialization-for-classes class
520                                          :direct-superclasses direct-superclasses
521                                          :direct-slots direct-slots
522                                          :direct-default-initargs direct-default-initargs)
523    class))
524
525(defun std-after-initialization-for-classes (class
526                                             &key direct-superclasses direct-slots
527                                             direct-default-initargs
528                                             &allow-other-keys)
529  (let ((supers (or direct-superclasses
530                    (list (find-class 'standard-object)))))
531    (setf (class-direct-superclasses class) supers)
532    (dolist (superclass supers)
533      (push class (class-direct-subclasses superclass))))
534  (let ((slots (mapcar #'(lambda (slot-properties)
535                          (apply #'make-direct-slot-definition class slot-properties))
536                       direct-slots)))
537    (setf (class-direct-slots class) slots)
538    (dolist (direct-slot slots)
539      (dolist (reader (slot-definition-readers direct-slot))
540        (add-reader-method
541         class reader (slot-definition-name direct-slot)))
542      (dolist (writer (slot-definition-writers direct-slot))
543        (add-writer-method
544         class writer (slot-definition-name direct-slot)))))
545  (setf (class-direct-default-initargs class) direct-default-initargs)
546  (funcall (if (eq (class-of class) (find-class 'standard-class))
547               #'std-finalize-inheritance
548               #'finalize-inheritance)
549           class)
550  (values))
551
552(defun canonical-slot-name (canonical-slot)
553  (getf canonical-slot :name))
554
555(defun ensure-class (name &rest all-keys &allow-other-keys)
556  ;; Check for duplicate slots.
557  (let ((slots (getf all-keys :direct-slots)))
558    (dolist (s1 slots)
559      (let ((name1 (canonical-slot-name s1)))
560        (dolist (s2 (cdr (memq s1 slots)))
561    (when (eq name1 (canonical-slot-name s2))
562            (error 'program-error "duplicate slot ~S" name1))))))
563  ;; Check for duplicate argument names in :DEFAULT-INITARGS.
564  (let ((names ()))
565    (do* ((initargs (getf all-keys :direct-default-initargs) (cddr initargs))
566          (name (car initargs) (car initargs)))
567         ((null initargs))
568      (push name names))
569    (do* ((names names (cdr names))
570          (name (car names) (car names)))
571         ((null names))
572      (when (memq name (cdr names))
573        (error 'program-error
574               "duplicate initialization argument name ~S in :DEFAULT-INITARGS"
575               name))))
576  (let ((class (find-class name nil)))
577    (unless class
578      (setf class (apply #'make-instance-standard-class (find-class 'standard-class)
579                         :name name all-keys))
580      (%set-find-class name class))
581    class))
582
583(defmacro defclass (&whole form name direct-superclasses direct-slots &rest options)
584  (unless (>= (length form) 3)
585    (error 'program-error "wrong number of arguments for DEFCLASS"))
586  `(ensure-class ',name
587                 :direct-superclasses
588                 ,(canonicalize-direct-superclasses direct-superclasses)
589                 :direct-slots
590                 ,(canonicalize-direct-slots direct-slots)
591                 ,@(canonicalize-defclass-options options)))
592
593;;; Generic function metaobjects and standard-generic-function
594
595(defun method-combination-type (method-combination)
596  (if (atom method-combination)
597      method-combination
598      (car method-combination)))
599
600(defun method-combination-options (method-combination)
601  (if (atom method-combination)
602      nil
603      (cdr method-combination)))
604
605(defclass standard-generic-function (generic-function)
606  ((name :initarg :name)      ; :accessor generic-function-name
607   (lambda-list               ; :accessor generic-function-lambda-list
608    :initarg :lambda-list)
609   (methods :initform ())     ; :accessor generic-function-methods
610   (method-class              ; :accessor generic-function-method-class
611    :initarg :method-class)
612   (method-combination
613    :initarg :method-combination)
614   (classes-to-emf-table      ; :accessor classes-to-emf-table
615    :initform (make-hash-table :test #'equal))
616   (required-args :initform ())))
617
618(defvar the-class-standard-gf (find-class 'standard-generic-function))
619
620(defvar *sgf-required-args-index*
621  (slot-location the-class-standard-gf 'required-args))
622
623(defvar *sgf-classes-to-emf-table-index*
624  (slot-location the-class-standard-gf 'classes-to-emf-table))
625
626(defun generic-function-name (gf)
627  (slot-value gf 'name))
628(defun (setf generic-function-name) (new-value gf)
629  (setf (slot-value gf 'name) new-value))
630
631(defun generic-function-lambda-list (gf)
632  (slot-value gf 'lambda-list))
633(defun (setf generic-function-lambda-list) (new-value gf)
634  (setf (slot-value gf 'lambda-list) new-value))
635
636(defun generic-function-methods (gf)
637  (slot-value gf 'methods))
638(defun (setf generic-function-methods) (new-value gf)
639  (setf (slot-value gf 'methods) new-value))
640
641(defsetf generic-function-discriminating-function
642  %set-generic-function-discriminating-function)
643
644(defun generic-function-method-class (gf)
645  (slot-value gf 'method-class))
646(defun (setf generic-function-method-class) (new-value gf)
647  (setf (slot-value gf 'method-class) new-value))
648
649(defun generic-function-method-combination (gf)
650  (slot-value gf 'method-combination))
651(defun (setf generic-function-method-combination) (new-value gf)
652  (setf (slot-value gf 'method-combination) new-value))
653
654;;; Internal accessor for effective method function table
655
656(defun classes-to-emf-table (gf)
657;;   (slot-value gf 'classes-to-emf-table))
658  (slot-contents (std-instance-slots gf) *sgf-classes-to-emf-table-index*))
659(defun (setf classes-to-emf-table) (new-value gf)
660  (setf (slot-value gf 'classes-to-emf-table) new-value))
661
662;;; Method metaobjects and standard-method
663
664(defclass standard-method (method)
665  ((lambda-list :initarg :lambda-list)     ; :accessor method-lambda-list
666   (qualifiers :initarg :qualifiers)       ; :accessor method-qualifiers
667   (specializers :initarg :specializers)   ; :accessor method-specializers
668   (body :initarg :body)                   ; :accessor method-body
669   (environment :initarg :environment)     ; :accessor method-environment
670   (generic-function :initform nil)        ; :accessor method-generic-function
671   (function)))                            ; :accessor method-function
672
673(defvar the-class-standard-method (find-class 'standard-method))
674
675(defvar *sm-function-index*
676  (slot-location the-class-standard-method 'function))
677
678(defun method-lambda-list (method) (slot-value method 'lambda-list))
679(defun (setf method-lambda-list) (new-value method)
680  (setf (slot-value method 'lambda-list) new-value))
681
682(defun method-qualifiers (method) (slot-value method 'qualifiers))
683(defun (setf method-qualifiers) (new-value method)
684  (setf (slot-value method 'qualifiers) new-value))
685
686(defun method-specializers (method) (slot-value method 'specializers))
687(defun (setf method-specializers) (new-value method)
688  (setf (slot-value method 'specializers) new-value))
689
690(defun method-body (method) (slot-value method 'body))
691(defun (setf method-body) (new-value method)
692  (setf (slot-value method 'body) new-value))
693
694(defun method-environment (method) (slot-value method 'environment))
695(defun (setf method-environment) (new-value method)
696  (setf (slot-value method 'environment) new-value))
697
698(defun method-generic-function (method)
699  (slot-value method 'generic-function))
700(defun (setf method-generic-function) (new-value method)
701  (setf (slot-value method 'generic-function) new-value))
702
703(defun method-function (method)
704;;   (slot-value method 'function))
705  (slot-contents (std-instance-slots method) *sm-function-index*))
706(defun (setf method-function) (new-value method)
707  (setf (slot-value method 'function) new-value))
708
709;;; defgeneric
710
711(defmacro defgeneric (function-name lambda-list
712                                    &rest options-and-method-descriptions)
713  (let ((options ())
714        (methods ()))
715    (dolist (item options-and-method-descriptions)
716      (case (car item)
717        (declare) ; FIXME
718        (:documentation) ; FIXME
719        (:method
720         (push `(defmethod ,function-name ,@(cdr item)) methods))
721        (t
722         (push item options))))
723    (setf options (nreverse options)
724          methods (nreverse methods))
725    `(prog1
726       (ensure-generic-function
727        ',function-name
728        :lambda-list ',lambda-list
729        ,@(canonicalize-defgeneric-options options))
730       ,@methods)))
731
732(defun canonicalize-defgeneric-options (options)
733  (mapappend #'canonicalize-defgeneric-option options))
734
735(defun canonicalize-defgeneric-option (option)
736  (case (car option)
737    (:generic-function-class
738     (list ':generic-function-class `(find-class ',(cadr option))))
739    (:method-class
740     (list ':method-class `(find-class ',(cadr option))))
741    (:method-combination
742     (list `',(car option) `',(cdr option)))
743    (t
744     (list `',(car option) `',(cadr option)))))
745
746(defparameter generic-function-table (make-hash-table :test #'equal))
747
748(defun find-generic-function (symbol &optional (errorp t))
749  (let ((gf (gethash symbol generic-function-table nil)))
750    (if (and (null gf) errorp)
751        (error "no generic function named ~S" symbol)
752        gf)))
753
754(defun (setf find-generic-function) (new-value symbol)
755  (setf (gethash symbol generic-function-table) new-value))
756
757;;; ensure-generic-function
758
759(defun ensure-generic-function (function-name
760                                &rest all-keys
761                                &key
762                                (generic-function-class the-class-standard-gf)
763                                (method-class the-class-standard-method)
764                                (method-combination 'standard)
765                                &allow-other-keys)
766  (when (autoloadp function-name)
767    (resolve function-name))
768  (if (find-generic-function function-name nil)
769      (find-generic-function function-name)
770      (progn
771        (when (fboundp function-name)
772          (error 'program-error
773                 "~A already names an ordinary function, macro, or special operator"
774                 function-name))
775        (let ((gf (apply (if (eq generic-function-class the-class-standard-gf)
776                             #'make-instance-standard-generic-function
777                             #'make-instance)
778                         generic-function-class
779                         :name function-name
780                         :method-class method-class
781                         :method-combination method-combination
782                         all-keys)))
783          (setf (find-generic-function function-name) gf)
784          gf))))
785
786;;; finalize-generic-function
787
788(defun finalize-generic-function (gf)
789  (setf (generic-function-discriminating-function gf)
790        (funcall (if (eq (class-of gf) the-class-standard-gf)
791                     #'std-compute-discriminating-function
792                     #'compute-discriminating-function)
793                 gf))
794  (setf (fdefinition (generic-function-name gf)) gf)
795  (clrhash (classes-to-emf-table gf))
796  (values))
797
798(defun gf-required-args (gf)
799  (slot-contents (std-instance-slots gf) *sgf-required-args-index*))
800
801(defun make-instance-standard-generic-function (generic-function-class
802                                                &key name lambda-list
803                                                method-class
804                                                method-combination)
805  (declare (ignore generic-function-class))
806  (let ((gf (std-allocate-instance the-class-standard-gf)))
807    (setf (generic-function-name gf) name)
808    (setf (generic-function-lambda-list gf) lambda-list)
809    (setf (generic-function-methods gf) ())
810    (setf (generic-function-method-class gf) method-class)
811    (setf (generic-function-method-combination gf) method-combination)
812    (setf (classes-to-emf-table gf) (make-hash-table :test #'equal))
813    (setf (slot-value gf 'required-args)
814          (let ((plist (analyze-lambda-list (generic-function-lambda-list gf))))
815            (getf plist ':required-args)))
816    (finalize-generic-function gf)
817    gf))
818
819;;; Run-time environment hacking (Common Lisp ain't got 'em).
820
821(defun top-level-environment ()
822  nil) ; Bogus top level lexical environment
823
824(defvar compile-methods nil)      ; by default, run everything interpreted
825
826(defun compile-in-lexical-environment (env lambda-expr)
827  (declare (ignore env))
828  (if compile-methods
829      (compile nil lambda-expr)
830      (eval `(function ,lambda-expr))))
831
832;;; defmethod
833
834(defmacro defmethod (&rest args)
835  (multiple-value-bind (function-name qualifiers lambda-list specializers body)
836    (parse-defmethod args)
837    `(progn
838      (ensure-generic-function
839       ',function-name
840       :lambda-list ',lambda-list)
841      (ensure-method (find-generic-function ',function-name)
842                     :lambda-list ',lambda-list
843                     :qualifiers ',qualifiers
844                     :specializers ,(canonicalize-specializers specializers)
845                     :body ',body
846                     :environment (top-level-environment)))))
847
848(defun canonicalize-specializers (specializers)
849  `(list ,@(mapcar #'canonicalize-specializer specializers)))
850
851(defun canonicalize-specializer (specializer)
852  ;; FIXME (EQL specializers)
853  `(if (atom ',specializer) (find-class ',specializer) (find-class 't)))
854
855(defun parse-defmethod (args)
856  (let ((fn-spec (car args))
857        (qualifiers ())
858        (specialized-lambda-list nil)
859        (body ())
860        (parse-state :qualifiers))
861    (dolist (arg (cdr args))
862      (ecase parse-state
863        (:qualifiers
864         (if (and (atom arg) (not (null arg)))
865             (push-on-end arg qualifiers)
866             (progn (setq specialized-lambda-list arg)
867               (setq parse-state :body))))
868        (:body (push-on-end arg body))))
869    (values fn-spec
870            qualifiers
871            (extract-lambda-list specialized-lambda-list)
872            (extract-specializers specialized-lambda-list)
873            (list* 'block
874                   (if (consp fn-spec)
875                       (cadr fn-spec)
876                       fn-spec)
877                   body))))
878
879;;; Several tedious functions for analyzing lambda lists
880
881(defun required-portion (gf args)
882  (let ((number-required (length (gf-required-args gf))))
883    (when (< (length args) number-required)
884      (error 'program-error "not enough arguments for generic function ~S" gf))
885    (subseq args 0 number-required)))
886
887(defun extract-lambda-list (specialized-lambda-list)
888  (let* ((plist (analyze-lambda-list specialized-lambda-list))
889         (requireds (getf plist :required-names))
890         (rv (getf plist :rest-var))
891         (ks (getf plist :key-args))
892         (keysp (getf plist :keysp))
893         (aok (getf plist :allow-other-keys))
894         (opts (getf plist :optional-args))
895         (auxs (getf plist :auxiliary-args)))
896    `(,@requireds
897      ,@(if rv `(&rest ,rv) ())
898      ,@(if (or ks keysp aok) `(&key ,@ks) ())
899      ,@(if aok '(&allow-other-keys) ())
900      ,@(if opts `(&optional ,@opts) ())
901      ,@(if auxs `(&aux ,@auxs) ()))))
902
903(defun extract-specializers (specialized-lambda-list)
904  (let ((plist (analyze-lambda-list specialized-lambda-list)))
905    (getf plist ':specializers)))
906
907(defun analyze-lambda-list (lambda-list)
908  (labels ((make-keyword (symbol)
909                         (intern (symbol-name symbol)
910                                 (find-package 'keyword)))
911           (get-keyword-from-arg (arg)
912                                 (if (listp arg)
913                                     (if (listp (car arg))
914                                         (caar arg)
915                                         (make-keyword (car arg)))
916                                     (make-keyword arg))))
917          (let ((keys ())           ; Just the keywords
918                (key-args ())       ; Keywords argument specs
919                (keysp nil)         ;
920                (required-names ()) ; Just the variable names
921                (required-args ())  ; Variable names & specializers
922                (specializers ())   ; Just the specializers
923                (rest-var nil)
924                (optionals ())
925                (auxs ())
926                (allow-other-keys nil)
927                (state :parsing-required))
928            (dolist (arg lambda-list)
929              (if (member arg lambda-list-keywords)
930                  (ecase arg
931                    (&optional
932                     (setq state :parsing-optional))
933                    (&rest
934                     (setq state :parsing-rest))
935                    (&key
936                     (setq keysp t)
937                     (setq state :parsing-key))
938                    (&allow-other-keys
939                     (setq allow-other-keys 't))
940                    (&aux
941                     (setq state :parsing-aux)))
942                  (case state
943                    (:parsing-required
944                     (push-on-end arg required-args)
945                     (if (listp arg)
946                         (progn (push-on-end (car arg) required-names)
947                           (push-on-end (cadr arg) specializers))
948                         (progn (push-on-end arg required-names)
949                           (push-on-end 't specializers))))
950                    (:parsing-optional (push-on-end arg optionals))
951                    (:parsing-rest (setq rest-var arg))
952                    (:parsing-key
953                     (push-on-end (get-keyword-from-arg arg) keys)
954                     (push-on-end arg key-args))
955                    (:parsing-aux (push-on-end arg auxs)))))
956            (list  :required-names required-names
957                   :required-args required-args
958                   :specializers specializers
959                   :rest-var rest-var
960                   :keywords keys
961                   :key-args key-args
962                   :keysp keysp
963                   :auxiliary-args auxs
964                   :optional-args optionals
965                   :allow-other-keys allow-other-keys))))
966
967;;; ensure method
968
969#+nil
970(defun check-method-arg-info (gf arg-info method)
971  (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
972    (analyze-lambda-list (if (consp method)
973                             (early-method-lambda-list method)
974                             (method-lambda-list method)))
975    (flet ((lose (string &rest args)
976                 (error 'simple-program-error
977                        :format-control "~@<attempt to add the method~2I~_~S~I~_~
978                        to the generic function~2I~_~S;~I~_~
979                        but ~?~:>"
980                        :format-arguments (list method gf string args)))
981     (comparison-description (x y)
982                                   (if (> x y) "more" "fewer")))
983      (let ((gf-nreq (arg-info-number-required arg-info))
984      (gf-nopt (arg-info-number-optional arg-info))
985      (gf-key/rest-p (arg-info-key/rest-p arg-info))
986      (gf-keywords (arg-info-keys arg-info)))
987  (unless (= nreq gf-nreq)
988    (lose
989     "the method has ~A required arguments than the generic function."
990     (comparison-description nreq gf-nreq)))
991  (unless (= nopt gf-nopt)
992    (lose
993     "the method has ~A optional arguments than the generic function."
994     (comparison-description nopt gf-nopt)))
995  (unless (eq (or keysp restp) gf-key/rest-p)
996    (lose
997     "the method and generic function differ in whether they accept~_~
998      &REST or &KEY arguments."))
999  (when (consp gf-keywords)
1000    (unless (or (and restp (not keysp))
1001          allow-other-keys-p
1002          (every (lambda (k) (memq k keywords)) gf-keywords))
1003      (lose "the method does not accept each of the &KEY arguments~2I~_~
1004            ~S."
1005      gf-keywords)))))))
1006
1007(defun ensure-method (gf &rest all-keys)
1008  (let* ((gf-lambda-list (generic-function-lambda-list gf))
1009         (gf-restp (not (null (memq '&rest gf-lambda-list))))
1010         (gf-plist (analyze-lambda-list gf-lambda-list))
1011         (gf-keysp (getf gf-plist :keysp))
1012         (gf-keywords (getf gf-plist :keywords))
1013         (method-lambda-list (getf all-keys :lambda-list))
1014         (method-plist (analyze-lambda-list method-lambda-list))
1015         (method-restp (not (null (memq '&rest method-lambda-list))))
1016         (method-keysp (getf method-plist :keysp))
1017         (method-keywords (getf method-plist :keywords))
1018         (method-allow-other-keys-p (getf method-plist :allow-other-keys)))
1019    (unless (= (length (getf gf-plist :required-args))
1020               (length (getf method-plist :required-args)))
1021      (error "the method has the wrong number of required arguments for the generic function"))
1022    (unless (= (length (getf gf-plist :optional-args))
1023               (length (getf method-plist :optional-args)))
1024      (error "the method has the wrong number of optional arguments for the generic function"))
1025    (unless (eq (or gf-restp gf-keysp) (or method-restp method-keysp))
1026      (error "the method and the generic function differ in whether they accept &REST or &KEY arguments"))
1027    (when (consp gf-keywords)
1028      (unless (or (and method-restp (not method-keysp))
1029                  method-allow-other-keys-p
1030                  (every (lambda (k) (memq k method-keywords)) gf-keywords))
1031        (error "the method does not accept all of the keyword arguments defined for the generic function"))))
1032  (let ((new-method
1033         (apply
1034          (if (eq (generic-function-method-class gf) the-class-standard-method)
1035              #'make-instance-standard-method
1036              #'make-instance)
1037          (generic-function-method-class gf)
1038          all-keys)))
1039    (add-method gf new-method)
1040    new-method))
1041
1042(defun make-instance-standard-method (method-class
1043                                      &key lambda-list qualifiers
1044                                      specializers body environment)
1045  (declare (ignore method-class))
1046  (let ((method (std-allocate-instance the-class-standard-method)))
1047    (setf (method-lambda-list method) lambda-list)
1048    (setf (method-qualifiers method) qualifiers)
1049    (setf (method-specializers method) specializers)
1050    (setf (method-body method) (precompile-form body nil))
1051    (setf (method-environment method) environment)
1052    (setf (method-generic-function method) nil)
1053    (setf (method-function method)
1054          (std-compute-method-function method))
1055    method))
1056
1057(defun check-congruent (gf method)
1058  (let* ((plist1 (analyze-lambda-list (generic-function-lambda-list gf)))
1059         (args1 (getf plist1 :required-args))
1060         (plist2 (analyze-lambda-list (method-lambda-list method)))
1061         (args2 (getf plist2 :required-args)))
1062    (unless (= (length args1) (length args2))
1063      (error "lambda lists are not congruent"))))
1064
1065(defun add-method (gf method)
1066  (check-congruent gf method)
1067  ;; Remove existing method with same qualifiers and specializers (if any).
1068  (let ((old-method (find-method gf (method-qualifiers method)
1069                                 (method-specializers method) nil)))
1070    (when old-method
1071      (remove-method gf old-method)))
1072  (setf (method-generic-function method) gf)
1073  (push method (generic-function-methods gf))
1074  (dolist (specializer (method-specializers method))
1075    (pushnew method (class-direct-methods specializer)))
1076  (finalize-generic-function gf)
1077  gf)
1078
1079(defun remove-method (gf method)
1080  (setf (generic-function-methods gf)
1081        (remove method (generic-function-methods gf)))
1082  (setf (method-generic-function method) nil)
1083;;   (format t "remove-method method-specializers = ~S~%" (method-specializers method))
1084  (dolist (class (method-specializers method))
1085    (setf (class-direct-methods class)
1086          (remove method (class-direct-methods class))))
1087  (finalize-generic-function gf)
1088  gf)
1089
1090(defun find-method (gf qualifiers specializers &optional (errorp t))
1091  (let ((method
1092         (find-if #'(lambda (method)
1093                     (and (equal qualifiers
1094                                 (method-qualifiers method))
1095                          (equal specializers
1096                                 (method-specializers method))))
1097                  (generic-function-methods gf))))
1098    (if (and (null method) errorp)
1099        (error "no such method for ~S" (generic-function-name gf))
1100        method)))
1101
1102;;; Reader and writer methods
1103
1104(defun add-reader-method (class fn-name slot-name)
1105  (ensure-method
1106   (ensure-generic-function fn-name :lambda-list '(object))
1107   :lambda-list '(object)
1108   :qualifiers ()
1109   :specializers (list class)
1110   :body `(slot-value object ',slot-name)
1111   :environment (top-level-environment))
1112  (values))
1113
1114(defun add-writer-method (class fn-name slot-name)
1115  (ensure-method
1116   (ensure-generic-function
1117    fn-name :lambda-list '(new-value object))
1118   :lambda-list '(new-value object)
1119   :qualifiers ()
1120   :specializers (list (find-class 't) class)
1121   :body `(setf (slot-value object ',slot-name)
1122                new-value)
1123   :environment (top-level-environment))
1124  (values))
1125
1126;;; subclassp and sub-specializer-p
1127
1128(defun subclassp (c1 c2)
1129  (not (null (find c2 (class-precedence-list c1)))))
1130
1131(defun sub-specializer-p (c1 c2 c-arg)
1132  (let ((cpl (class-precedence-list c-arg)))
1133    (not (null (find c2 (cdr (member c1 cpl)))))))
1134
1135;;;
1136;;; Generic function invocation
1137;;;
1138
1139;;; apply-generic-function
1140
1141(defun apply-generic-function (gf args)
1142  (apply (generic-function-discriminating-function gf) args))
1143
1144;;; compute-discriminating-function
1145
1146(defun std-compute-discriminating-function (gf)
1147  #'(lambda (&rest args)
1148     (let* ((classes (mapcar #'class-of
1149                             (required-portion gf args)))
1150            (emfun (gethash classes (classes-to-emf-table gf) nil)))
1151       (if emfun
1152           (funcall emfun args)
1153           (slow-method-lookup gf args classes)))))
1154
1155(defun slow-method-lookup (gf args classes)
1156  (let ((applicable-methods
1157         (compute-applicable-methods-using-classes gf classes)))
1158    (if applicable-methods
1159        (let ((emfun
1160               (funcall
1161                (if (eq (class-of gf) the-class-standard-gf)
1162                    #'std-compute-effective-method-function
1163                  #'compute-effective-method-function)
1164                gf applicable-methods)))
1165          (setf (gethash classes (classes-to-emf-table gf)) emfun)
1166          (funcall emfun args))
1167        (error "no applicable methods for generic function ~S with arguments ~S of classes ~S" gf args classes))))
1168
1169;;; compute-applicable-methods-using-classes
1170
1171(defun compute-applicable-methods-using-classes (gf required-classes)
1172  (sort
1173   (copy-list
1174    (remove-if-not #'(lambda (method)
1175                      (every #'subclassp
1176                             required-classes
1177                             (method-specializers method)))
1178                   (generic-function-methods gf)))
1179   #'(lambda (m1 m2)
1180      (funcall
1181       (if (eq (class-of gf) the-class-standard-gf)
1182           #'std-method-more-specific-p
1183           #'method-more-specific-p)
1184       gf m1 m2 required-classes))))
1185
1186;;; method-more-specific-p
1187
1188(defun std-method-more-specific-p (gf method1 method2 required-classes)
1189  (declare (ignore gf))
1190  (mapc #'(lambda (spec1 spec2 arg-class)
1191           (unless (eq spec1 spec2)
1192             (return-from std-method-more-specific-p
1193                          (sub-specializer-p spec1 spec2 arg-class))))
1194        (method-specializers method1)
1195        (method-specializers method2)
1196        required-classes)
1197  nil)
1198
1199;;; apply-methods and compute-effective-method-function
1200
1201(defun apply-methods (gf args methods)
1202  (funcall (compute-effective-method-function gf methods)
1203           args))
1204
1205(defun primary-method-p (method)
1206  (null (intersection '(:before :after :around) (method-qualifiers method))))
1207
1208(defun before-method-p (method)
1209  (equal '(:before) (method-qualifiers method)))
1210
1211(defun after-method-p (method)
1212  (equal '(:after) (method-qualifiers method)))
1213
1214(defun around-method-p (method)
1215  (equal '(:around) (method-qualifiers method)))
1216
1217(defun std-compute-effective-method-function (gf methods)
1218  (let* ((mc (generic-function-method-combination gf))
1219         (type (method-combination-type mc))
1220         (options (method-combination-options mc))
1221         (order (car options))
1222         (primaries ())
1223         (arounds ())
1224         around)
1225    (dolist (m methods)
1226      (let ((qualifiers (method-qualifiers m)))
1227        (cond ((null qualifiers)
1228               (if (eq type 'standard)
1229                   (push m primaries)
1230                   (error "method combination type mismatch")))
1231              ((cdr qualifiers)
1232               (error "invalid method qualifiers"))
1233              ((eq (car qualifiers) :around)
1234               (push m arounds))
1235              ((eq (car qualifiers) type)
1236               (push m primaries))
1237              ((memq (car qualifiers) '(:before :after)))
1238              (t
1239               (invalid generic-function combin m)))))
1240    (unless (eq order :most-specific-last)
1241      (setq primaries (nreverse primaries)))
1242    (setq arounds (nreverse arounds))
1243    (setq around (car arounds))
1244    (when (null primaries)
1245      (error "no primary methods for the generic function ~S" gf))
1246    (if around
1247        (let ((next-emfun
1248               (funcall
1249                (if (eq (class-of gf) the-class-standard-gf)
1250                    #'std-compute-effective-method-function
1251                    #'compute-effective-method-function)
1252                gf (remove around methods))))
1253          #'(lambda (args)
1254             (funcall (method-function around) args next-emfun)))
1255        (case type
1256          (STANDARD
1257           (let ((next-emfun (compute-primary-emfun (cdr primaries)))
1258                 (befores (remove-if-not #'before-method-p methods))
1259                 (reverse-afters
1260                  (reverse (remove-if-not #'after-method-p methods))))
1261             #'(lambda (args)
1262                (dolist (before befores)
1263                  (funcall (method-function before) args nil))
1264                (multiple-value-prog1
1265                 (funcall (method-function (car primaries)) args next-emfun)
1266                 (dolist (after reverse-afters)
1267                   (funcall (method-function after) args nil))))))
1268          (LIST
1269           #'(lambda (args)
1270              (let ((result ()))
1271                (dolist (primary primaries)
1272                  (push (funcall (method-function primary) args nil) result))
1273                (nreverse result))))
1274          (APPEND
1275           #'(lambda (args)
1276              (let ((result ()))
1277                (dolist (primary primaries)
1278                  (setf result (append result (funcall (method-function primary) args nil))))
1279                result)))
1280          (NCONC
1281           #'(lambda (args)
1282              (let ((result ()))
1283                (dolist (primary primaries)
1284                  (setf result (nconc result (funcall (method-function primary) args nil))))
1285                result)))
1286          (PROGN
1287           #'(lambda (args)
1288              (let ((result nil))
1289                (dolist (primary primaries)
1290                  (setf result (funcall (method-function primary) args nil)))
1291                result)))
1292          (AND
1293           #'(lambda (args)
1294              (let ((result t))
1295                (dolist (primary primaries)
1296                  (setf result
1297                        (and result
1298                             (funcall (method-function primary) args nil)))
1299                  (unless result (return)))
1300                result)))
1301          (OR
1302           #'(lambda (args)
1303              (let ((result nil))
1304                (dolist (primary primaries)
1305                  (setf result
1306                        (or result
1307                            (funcall (method-function primary) args nil)))
1308                  (when result (return)))
1309                result)))
1310          (+
1311           #'(lambda (args)
1312              (let ((result 0))
1313                (dolist (primary primaries)
1314                  (incf result (funcall (method-function primary) args nil)))
1315                result)))
1316          (MAX
1317           #'(lambda (args)
1318              (let ((result ()))
1319                (dolist (primary primaries)
1320                  (push (funcall (method-function primary) args nil) result))
1321                (apply #'max result))))
1322          (MIN
1323           #'(lambda (args)
1324              (let ((result ()))
1325                (dolist (primary primaries)
1326                  (push (funcall (method-function primary) args nil) result))
1327                (apply #'min result))))
1328          (t
1329           (error "unsupported method combination type ~S" type))))))
1330
1331;;; compute an effective method function from a list of primary methods:
1332
1333(defun compute-primary-emfun (methods)
1334  (if (null methods)
1335      nil
1336      (let ((next-emfun (compute-primary-emfun (cdr methods))))
1337        #'(lambda (args)
1338           (funcall (method-function (car methods)) args next-emfun)))))
1339
1340;;; apply-method and compute-method-function
1341
1342(defun apply-method (method args next-methods)
1343  (funcall (method-function method)
1344           args
1345           (if (null next-methods)
1346               nil
1347               (compute-effective-method-function
1348                (method-generic-function method) next-methods))))
1349
1350(defun std-compute-method-function (method)
1351  (let ((form (method-body method))
1352        (lambda-list (method-lambda-list method)))
1353    (compile-in-lexical-environment
1354     (method-environment method)
1355     `(lambda (args next-emfun)
1356        (flet ((call-next-method (&rest cnm-args)
1357                                 (if (null next-emfun)
1358                                     (error "no next method for generic function ~S"
1359                                            (method-generic-function ',method))
1360                                     (funcall next-emfun (or cnm-args args))))
1361               (next-method-p ()
1362                              (not (null next-emfun))))
1363          (apply #'(lambda ,(kludge-arglist lambda-list)
1364                    ,form)
1365                 args))))))
1366
1367;;; N.B. The function kludge-arglist is used to pave over the differences
1368;;; between argument keyword compatibility for regular functions versus
1369;;; generic functions.
1370
1371(defun kludge-arglist (lambda-list)
1372  (if (and (member '&key lambda-list)
1373           (not (member '&allow-other-keys lambda-list)))
1374      (append lambda-list '(&allow-other-keys))
1375      (if (and (not (member '&rest lambda-list))
1376               (not (member '&key lambda-list)))
1377          (append lambda-list '(&key &allow-other-keys))
1378          lambda-list)))
1379
1380;;; Slot access
1381
1382(defun setf-slot-value-using-class (new-value class instance slot-name)
1383  (setf (std-slot-value instance slot-name) new-value))
1384
1385(defgeneric slot-value-using-class (class instance slot-name))
1386(defmethod slot-value-using-class ((class standard-class) instance slot-name)
1387  (std-slot-value instance slot-name))
1388
1389(defgeneric (setf slot-value-using-class) (new-value class instance slot-name))
1390(defmethod (setf slot-value-using-class)
1391  (new-value (class standard-class) instance slot-name)
1392  (setf (std-slot-value instance slot-name) new-value))
1393
1394(defgeneric slot-exists-p-using-class (class instance slot-name))
1395(defmethod slot-exists-p-using-class
1396  ((class standard-class) instance slot-name)
1397  (std-slot-exists-p instance slot-name))
1398
1399(defgeneric slot-boundp-using-class (class instance slot-name))
1400(defmethod slot-boundp-using-class
1401  ((class standard-class) instance slot-name)
1402  (std-slot-boundp instance slot-name))
1403
1404(defgeneric slot-makunbound-using-class (class instance slot-name))
1405(defmethod slot-makunbound-using-class
1406  ((class standard-class) instance slot-name)
1407  (std-slot-makunbound instance slot-name))
1408
1409(defgeneric slot-missing (class instance slot-name operation &optional new-value))
1410(defmethod slot-missing ((class t) instance slot-name operation &optional new-value)
1411  (error "the slot ~S is missing from the class ~S" slot-name class))
1412
1413;;; Instance creation and initialization
1414
1415(defgeneric allocate-instance (class &rest initargs &key &allow-other-keys))
1416
1417(defmethod allocate-instance ((class standard-class) &rest initargs)
1418  (std-allocate-instance class))
1419
1420(defgeneric make-instance (class &key))
1421
1422(defmethod make-instance ((class standard-class) &rest initargs)
1423  (let ((class-default-initargs (class-default-initargs class)))
1424    (when class-default-initargs
1425      (let ((default-initargs ())
1426            (not-found (gensym)))
1427        (do* ((list class-default-initargs (cddr list))
1428              (key (car list) (car list))
1429              (fn (cadr list) (cadr list)))
1430             ((null list))
1431          (when (eq (getf initargs key not-found) not-found)
1432            (setf default-initargs (append default-initargs (list key (funcall fn))))))
1433        (setf initargs (append initargs default-initargs)))))
1434  (let ((instance (std-allocate-instance class)))
1435    (apply #'initialize-instance instance initargs)
1436    instance))
1437
1438(defmethod make-instance ((class symbol) &rest initargs)
1439  (apply #'make-instance (find-class class) initargs))
1440
1441(defgeneric initialize-instance (instance &key))
1442
1443(defmethod initialize-instance ((instance standard-object) &rest initargs)
1444  (apply #'shared-initialize instance t initargs))
1445
1446(defgeneric reinitialize-instance (instance &key))
1447
1448(defmethod reinitialize-instance
1449  ((instance standard-object) &rest initargs)
1450  (apply #'shared-initialize instance () initargs))
1451
1452(defgeneric shared-initialize (instance slot-names &key))
1453
1454(defmethod shared-initialize ((instance standard-object)
1455                              slot-names &rest all-keys)
1456  (dolist (slot (class-slots (class-of instance)))
1457    (let ((slot-name (slot-definition-name slot)))
1458      (multiple-value-bind (init-key init-value foundp)
1459        (get-properties all-keys (slot-definition-initargs slot))
1460        (declare (ignore init-key))
1461        (if foundp
1462            (setf (slot-value instance slot-name) init-value)
1463            (when (and (not (slot-boundp instance slot-name))
1464                       (not (null (slot-definition-initfunction slot)))
1465                       (or (eq slot-names t)
1466                           (member slot-name slot-names)))
1467              (setf (slot-value instance slot-name)
1468                    (funcall (slot-definition-initfunction slot))))))))
1469  instance)
1470
1471;;; change-class
1472
1473(defgeneric change-class (instance new-class &key))
1474
1475(defmethod change-class
1476  ((old-instance standard-object)
1477   (new-class standard-class)
1478   &rest initargs)
1479  (let ((new-instance (allocate-instance new-class)))
1480    (dolist (slot-name (mapcar #'slot-definition-name
1481                               (class-slots new-class)))
1482      (when (and (slot-exists-p old-instance slot-name)
1483                 (slot-boundp old-instance slot-name))
1484        (setf (slot-value new-instance slot-name)
1485              (slot-value old-instance slot-name))))
1486    (rotatef (std-instance-slots new-instance)
1487             (std-instance-slots old-instance))
1488    (rotatef (std-instance-class new-instance)
1489             (std-instance-class old-instance))
1490    (apply #'update-instance-for-different-class
1491           new-instance old-instance initargs)
1492    old-instance))
1493
1494(defmethod change-class
1495  ((instance standard-object) (new-class symbol) &rest initargs)
1496  (apply #'change-class instance (find-class new-class) initargs))
1497
1498(defgeneric update-instance-for-different-class (old new &key))
1499
1500(defmethod update-instance-for-different-class
1501  ((old standard-object) (new standard-object) &rest initargs)
1502  (let ((added-slots
1503         (remove-if #'(lambda (slot-name)
1504                       (slot-exists-p old slot-name))
1505                    (mapcar #'slot-definition-name
1506                            (class-slots (class-of new))))))
1507    (apply #'shared-initialize new added-slots initargs)))
1508
1509;;;  Methods having to do with class metaobjects.
1510
1511(defmethod initialize-instance :after ((class standard-class) &rest args)
1512  (apply #'std-after-initialization-for-classes class args))
1513
1514;;; Finalize inheritance
1515
1516(defgeneric finalize-inheritance (class))
1517(defmethod finalize-inheritance ((class standard-class))
1518  (std-finalize-inheritance class)
1519  (values))
1520
1521;;; Class precedence lists
1522
1523(defgeneric compute-class-precedence-list (class))
1524(defmethod compute-class-precedence-list ((class standard-class))
1525  (std-compute-class-precedence-list class))
1526
1527;;; Slot inheritance
1528
1529(defgeneric compute-slots (class))
1530(defmethod compute-slots ((class standard-class))
1531  (std-compute-slots class))
1532
1533(defgeneric compute-effective-slot-definition (class direct-slots))
1534(defmethod compute-effective-slot-definition
1535  ((class standard-class) direct-slots)
1536  (std-compute-effective-slot-definition class direct-slots))
1537
1538;;; Methods having to do with generic function metaobjects.
1539
1540(defmethod initialize-instance :after ((gf standard-generic-function) &key)
1541  (finalize-generic-function gf))
1542
1543;;; Methods having to do with method metaobjects.
1544
1545(defmethod initialize-instance :after ((method standard-method) &key)
1546  (setf (method-function method) (compute-method-function method)))
1547
1548;;; Methods having to do with generic function invocation.
1549
1550(defgeneric compute-discriminating-function (gf))
1551(defmethod compute-discriminating-function ((gf standard-generic-function))
1552  (std-compute-discriminating-function gf))
1553
1554(defgeneric method-more-specific-p (gf method1 method2 required-classes))
1555(defmethod method-more-specific-p
1556  ((gf standard-generic-function) method1 method2 required-classes)
1557  (std-method-more-specific-p gf method1 method2 required-classes))
1558
1559(defgeneric compute-effective-method-function (gf methods))
1560(defmethod compute-effective-method-function
1561  ((gf standard-generic-function) methods)
1562  (std-compute-effective-method-function gf methods))
1563
1564(defgeneric compute-method-function (method))
1565(defmethod compute-method-function ((method standard-method))
1566  (std-compute-method-function method))
1567
1568(defgeneric compute-applicable-methods (gf args))
1569(defmethod compute-applicable-methods ((gf standard-generic-function) args)
1570  (compute-applicable-methods-using-classes gf (mapcar #'class-of args)))
1571
1572(provide 'clos)
Note: See TracBrowser for help on using the repository browser.