source: trunk/j/src/org/armedbear/lisp/clos.lisp @ 5208

Last change on this file since 5208 was 5208, checked in by piso, 17 years ago

Work in progress.

File size: 62.5 KB
Line 
1;;; clos.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: clos.lisp,v 1.47 2003-12-19 19:42:55 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20;;; Adapted from Closette.
21
22;;; Closette Version 1.0 (February 10, 1991)
23;;;
24;;; Copyright (c) 1990, 1991 Xerox Corporation.
25;;; All rights reserved.
26;;;
27;;; Use and copying of this software and preparation of derivative works
28;;; based upon this software are permitted.  Any distribution of this
29;;; software or derivative works must comply with all applicable United
30;;; States export control laws.
31;;;
32;;; This software is made available AS IS, and Xerox Corporation makes no
33;;; warranty about the software, its performance or its conformity to any
34;;; specification.
35;;;
36;;; Closette is an implementation of a subset of CLOS with a metaobject
37;;; protocol as described in "The Art of The Metaobject Protocol",
38;;; MIT Press, 1991.
39
40(in-package "SYSTEM")
41
42(defmacro push-on-end (value location)
43  `(setf ,location (nconc ,location (list ,value))))
44
45;;; (SETF GETF*) is like (SETF GETF) except that it always changes the list,
46;;; which must be non-nil.
47
48(defun (setf getf*) (new-value plist key)
49  (block body
50    (do ((x plist (cddr x)))
51        ((null x))
52      (when (eq (car x) key)
53        (setf (car (cdr x)) new-value)
54        (return-from body new-value)))
55    (push-on-end key plist)
56    (push-on-end new-value plist)
57    new-value))
58
59(defun mapappend (fun &rest args)
60  (if (some #'null args)
61      ()
62      (append (apply fun (mapcar #'car args))
63              (apply #'mapappend fun (mapcar #'cdr args)))))
64
65(defun mapplist (fun x)
66  (if (null x)
67      ()
68      (cons (funcall fun (car x) (cadr x))
69            (mapplist fun (cddr x)))))
70
71(defsetf class-name %set-class-name)
72(defsetf class-layout %set-class-layout)
73(defsetf class-direct-superclasses %set-class-direct-superclasses)
74(defsetf class-direct-subclasses %set-class-direct-subclasses)
75(defsetf class-direct-methods %set-class-direct-methods)
76(defsetf class-direct-slots %set-class-direct-slots)
77(defsetf class-slots %set-class-slots)
78(defsetf class-direct-default-initargs %set-class-direct-default-initargs)
79(defsetf class-default-initargs %set-class-default-initargs)
80(defsetf class-precedence-list %set-class-precedence-list)
81(defsetf std-instance-layout %set-std-instance-layout)
82(defsetf std-instance-slots %set-std-instance-slots)
83(defsetf instance-ref %set-instance-ref)
84
85(defun (setf find-class) (new-value symbol &optional errorp environment)
86  (%set-find-class symbol new-value))
87
88(defun canonicalize-direct-slots (direct-slots)
89  `(list ,@(mapcar #'canonicalize-direct-slot direct-slots)))
90
91(defun canonicalize-direct-slot (spec)
92  (if (symbolp spec)
93      `(list :name ',spec)
94      (let ((name (car spec))
95            (initfunction nil)
96            (initform nil)
97            (initargs ())
98            (type nil)
99            (allocation nil)
100            (documentation nil)
101            (readers ())
102            (writers ())
103            (other-options ()))
104        (do ((olist (cdr spec) (cddr olist)))
105            ((null olist))
106          (case (car olist)
107            (:initform
108             (when initform
109               (error 'program-error
110                      "duplicate slot option :INITFORM for slot named ~S"
111                      name))
112             (setq initfunction
113                   `(function (lambda () ,(cadr olist))))
114             (setq initform `',(cadr olist)))
115            (:initarg
116             (push-on-end (cadr olist) initargs))
117            (:allocation
118             (when allocation
119               (error 'program-error
120                      "duplicate slot option :ALLOCATION for slot named ~S"
121                      name))
122             (setf allocation (cadr olist))
123             (push-on-end (car olist) other-options)
124             (push-on-end (cadr olist) other-options))
125            (:type
126             (when type
127               (error 'program-error
128                      "duplicate slot option :TYPE for slot named ~S"
129                      name))
130             (setf type (cadr olist))) ;; FIXME type is ignored
131            (:documentation
132             (when documentation
133               (error 'program-error
134                      "duplicate slot option :DOCUMENTATION for slot named ~S"
135                      name))
136             (setf documentation (cadr olist))) ;; FIXME documentation is ignored
137            (:reader
138             (push-on-end (cadr olist) readers))
139            (:writer
140             (push-on-end (cadr olist) writers))
141            (:accessor
142             (push-on-end (cadr olist) readers)
143             (push-on-end `(setf ,(cadr olist)) writers))
144            (t
145             (error 'program-error
146                    "invalid initialization argument ~S for slot named ~S"
147                    (car olist) name))))
148        `(list
149          :name ',name
150          ,@(when initfunction
151              `(:initform ,initform
152                          :initfunction ,initfunction))
153          ,@(when initargs `(:initargs ',initargs))
154          ,@(when readers `(:readers ',readers))
155          ,@(when writers `(:writers ',writers))
156          ,@other-options))))
157
158(defun canonicalize-direct-superclasses (direct-superclasses)
159  `(list ,@(mapcar #'canonicalize-direct-superclass direct-superclasses)))
160
161(defun canonicalize-direct-superclass (class-name)
162  `(find-class ',class-name))
163
164(defun canonicalize-defclass-options (options)
165  (mapappend #'canonicalize-defclass-option options))
166
167(defun canonicalize-defclass-option (option)
168  (case (car option)
169    (:metaclass
170     (list ':metaclass
171           `(find-class ',(cadr option))))
172    (:default-initargs
173     (list
174      ':direct-default-initargs
175      `(list ,@(mapappend
176                #'(lambda (x) x)
177                (mapplist
178                 #'(lambda (key value)
179                    `(',key ,(make-initfunction value)))
180                 (cdr option))))))
181    ((:documentation :report)
182     (list (car option) `',(cadr option)))
183    (t
184     (error 'program-error
185            :format-control "invalid DEFCLASS option ~S"
186            :format-arguments (list (car option))))))
187
188(defun make-initfunction (initform)
189  `(function (lambda () ,initform)))
190
191(defconstant +slot-unbound+ (make-symbol "SLOT-UNBOUND"))
192
193;;; Slot definition metaobjects
194
195(defstruct slot-definition
196  name
197  initfunction
198  initform
199  initargs
200  readers
201  writers
202  allocation
203  allocation-class
204  (location nil))
205
206(defun make-direct-slot-definition (class &rest properties
207                                          &key name
208                                          (initargs ())
209                                          (initform nil)
210                                          (initfunction nil)
211                                          (readers ())
212                                          (writers ())
213                                          (allocation :instance)
214                                          &allow-other-keys)
215  (let ((slot (make-slot-definition)))
216    (setf (slot-definition-name slot) name)
217    (setf (slot-definition-initargs slot) initargs)
218    (setf (slot-definition-initform slot) initform)
219    (setf (slot-definition-initfunction slot) initfunction)
220    (setf (slot-definition-readers slot) readers)
221    (setf (slot-definition-writers slot) writers)
222    (setf (slot-definition-allocation slot) allocation)
223    (setf (slot-definition-allocation-class slot) class)
224    slot))
225
226(defun make-effective-slot-definition (&rest properties
227                                             &key name
228                                             (initargs ())
229                                             (initform nil)
230                                             (initfunction nil)
231                                             (allocation :instance)
232                                             (allocation-class nil)
233                                             &allow-other-keys)
234  (let ((slot (make-slot-definition)))
235    (setf (slot-definition-name slot) name)
236    (setf (slot-definition-initargs slot) initargs)
237    (setf (slot-definition-initform slot) initform)
238    (setf (slot-definition-initfunction slot) initfunction)
239    (setf (slot-definition-allocation slot) allocation)
240    (setf (slot-definition-allocation-class slot) allocation-class)
241    slot))
242
243;;; finalize-inheritance
244
245(defun std-finalize-inheritance (class)
246  (setf (class-precedence-list class)
247        (funcall (if (eq (class-of class) the-class-standard-class)
248                     #'std-compute-class-precedence-list
249                     #'compute-class-precedence-list)
250                 class))
251  (setf (class-slots class)
252        (funcall (if (eq (class-of class) the-class-standard-class)
253                     #'std-compute-slots
254                     #'compute-slots)
255                 class))
256  (let ((length 0))
257    (dolist (slot (class-slots class))
258      (case (slot-definition-allocation slot)
259        (:instance
260         (setf (slot-definition-location slot) length)
261         (incf length))
262        (:class
263         (unless (slot-definition-location slot)
264           (let ((allocation-class (slot-definition-allocation-class slot)))
265             (setf (slot-definition-location slot)
266                   (if (eq class allocation-class)
267                       (cons (slot-definition-name slot) +slot-unbound+)
268                       (slot-location allocation-class (slot-definition-name slot)))))))))
269    (setf (class-layout class)
270          (make-layout class length)))
271  (setf (class-default-initargs class)
272        (compute-class-default-initargs class))
273  (values))
274
275(defun compute-class-default-initargs (class)
276  (mapappend #'class-direct-default-initargs
277             (class-precedence-list class)))
278
279;;; Class precedence lists
280
281(defun std-compute-class-precedence-list (class)
282  (let ((classes-to-order (collect-superclasses* class)))
283    (topological-sort classes-to-order
284                      (remove-duplicates
285                       (mapappend #'local-precedence-ordering
286                                  classes-to-order))
287                      #'std-tie-breaker-rule)))
288
289;;; topological-sort implements the standard algorithm for topologically
290;;; sorting an arbitrary set of elements while honoring the precedence
291;;; constraints given by a set of (X,Y) pairs that indicate that element
292;;; X must precede element Y.  The tie-breaker procedure is called when it
293;;; is necessary to choose from multiple minimal elements; both a list of
294;;; candidates and the ordering so far are provided as arguments.
295
296(defun topological-sort (elements constraints tie-breaker)
297  (let ((remaining-constraints constraints)
298        (remaining-elements elements)
299        (result ()))
300    (loop
301      (let ((minimal-elements
302             (remove-if
303              #'(lambda (class)
304                 (member class remaining-constraints
305                         :key #'cadr))
306              remaining-elements)))
307        (when (null minimal-elements)
308          (if (null remaining-elements)
309              (return-from topological-sort result)
310              (error "Inconsistent precedence graph.")))
311        (let ((choice (if (null (cdr minimal-elements))
312                          (car minimal-elements)
313                          (funcall tie-breaker
314                                   minimal-elements
315                                   result))))
316          (setq result (append result (list choice)))
317          (setq remaining-elements
318                (remove choice remaining-elements))
319          (setq remaining-constraints
320                (remove choice
321                        remaining-constraints
322                        :test #'member)))))))
323
324;;; In the event of a tie while topologically sorting class precedence lists,
325;;; the CLOS Specification says to "select the one that has a direct subclass
326;;; rightmost in the class precedence list computed so far."  The same result
327;;; is obtained by inspecting the partially constructed class precedence list
328;;; from right to left, looking for the first minimal element to show up among
329;;; the direct superclasses of the class precedence list constituent.
330;;; (There's a lemma that shows that this rule yields a unique result.)
331
332(defun std-tie-breaker-rule (minimal-elements cpl-so-far)
333  (dolist (cpl-constituent (reverse cpl-so-far))
334    (let* ((supers (class-direct-superclasses cpl-constituent))
335           (common (intersection minimal-elements supers)))
336      (when (not (null common))
337        (return-from std-tie-breaker-rule (car common))))))
338
339;;; This version of collect-superclasses* isn't bothered by cycles in the class
340;;; hierarchy, which sometimes happen by accident.
341
342(defun collect-superclasses* (class)
343  (labels ((all-superclasses-loop (seen superclasses)
344                                  (let ((to-be-processed
345                                         (set-difference superclasses seen)))
346                                    (if (null to-be-processed)
347                                        superclasses
348                                        (let ((class-to-process
349                                               (car to-be-processed)))
350                                          (all-superclasses-loop
351                                           (cons class-to-process seen)
352                                           (union (class-direct-superclasses
353                                                   class-to-process)
354                                                  superclasses)))))))
355          (all-superclasses-loop () (list class))))
356
357;;; The local precedence ordering of a class C with direct superclasses C_1,
358;;; C_2, ..., C_n is the set ((C C_1) (C_1 C_2) ...(C_n-1 C_n)).
359
360(defun local-precedence-ordering (class)
361  (mapcar #'list
362          (cons class
363                (butlast (class-direct-superclasses class)))
364          (class-direct-superclasses class)))
365
366;;; Slot inheritance
367
368(defun std-compute-slots (class)
369  (let* ((all-slots (mapappend #'class-direct-slots
370                               (class-precedence-list class)))
371         (all-names (remove-duplicates
372                     (mapcar #'slot-definition-name all-slots))))
373    (mapcar #'(lambda (name)
374               (funcall
375                (if (eq (class-of class) the-class-standard-class)
376                    #'std-compute-effective-slot-definition
377                    #'compute-effective-slot-definition)
378                class
379                (remove name all-slots
380                        :key #'slot-definition-name
381                        :test-not #'eq)))
382            all-names)))
383
384(defun std-compute-effective-slot-definition (class direct-slots)
385  (declare (ignore class))
386  (let ((initer (find-if-not #'null direct-slots
387                             :key #'slot-definition-initfunction)))
388    (make-effective-slot-definition
389     :name (slot-definition-name (car direct-slots))
390     :initform (if initer
391                   (slot-definition-initform initer)
392                   nil)
393     :initfunction (if initer
394                       (slot-definition-initfunction initer)
395                       nil)
396     :initargs (remove-duplicates
397                (mapappend #'slot-definition-initargs
398                           direct-slots))
399     :allocation (slot-definition-allocation (car direct-slots))
400     :allocation-class (slot-definition-allocation-class (car direct-slots)))))
401
402;;; Standard instance slot access
403
404;;; N.B. The location of the effective-slots slots in the class metaobject for
405;;; standard-class must be determined without making any further slot
406;;; references.
407
408(defvar the-slots-of-standard-class) ;standard-class's class-slots
409(defvar the-class-standard-class (find-class 'standard-class))
410
411(defun find-slot-definition (class slot-name)
412  (dolist (slot (class-slots class) nil)
413    (when (eq slot-name (slot-definition-name slot))
414      (return slot))))
415
416(defun slot-location (class slot-name)
417  (let ((slot (find-slot-definition class slot-name)))
418    (if slot
419        (slot-definition-location slot)
420        nil)))
421
422(defun std-slot-value (instance slot-name)
423  (let* ((location (slot-location (class-of instance) slot-name))
424         (value (cond ((fixnump location)
425                       (instance-ref instance location))
426                      ((consp location)
427                       (cdr location))
428                      (t
429                       (slot-missing (class-of instance) instance slot-name 'slot-value)))))
430    (if (eq +slot-unbound+ value)
431        (error "The slot ~S is unbound in the object ~S." slot-name instance)
432        value)))
433
434(defun slot-value (object slot-name)
435  (if (eq (class-of (class-of object)) the-class-standard-class)
436      (std-slot-value object slot-name)
437      (slot-value-using-class (class-of object) object slot-name)))
438
439(defun (setf std-slot-value) (new-value instance slot-name)
440  (let ((location (slot-location (class-of instance) slot-name)))
441    (cond ((fixnump location)
442           (setf (instance-ref instance location) new-value))
443          ((consp location)
444           (setf (cdr location) new-value))
445          (t
446           (slot-missing (class-of instance) instance slot-name 'setf new-value))))
447  new-value)
448
449(defun (setf slot-value) (new-value object slot-name)
450  (if (eq (class-of (class-of object)) the-class-standard-class)
451      (setf (std-slot-value object slot-name) new-value)
452      (setf-slot-value-using-class
453       new-value (class-of object) object slot-name)))
454
455(defun std-slot-boundp (instance slot-name)
456  (let ((location (slot-location (class-of instance) slot-name)))
457    (cond ((fixnump location)
458           (neq +slot-unbound+ (instance-ref instance location)))
459          ((consp location)
460           (neq +slot-unbound+ (cdr location)))
461          (t
462           (not (null (slot-missing (class-of instance) instance slot-name 'slot-boundp)))))))
463
464(defun slot-boundp (object slot-name)
465  (if (eq (class-of (class-of object)) the-class-standard-class)
466      (std-slot-boundp object slot-name)
467      (slot-boundp-using-class (class-of object) object slot-name)))
468
469(defun std-slot-makunbound (instance slot-name)
470  (let ((location (slot-location (class-of instance) slot-name)))
471    (cond ((fixnump location)
472           (setf (instance-ref instance location) +slot-unbound+))
473          ((consp location)
474           (setf (cdr location) +slot-unbound+))
475          (t
476           (slot-missing (class-of instance) instance slot-name 'slot-makunbound))))
477  instance)
478
479(defun slot-makunbound (object slot-name)
480  (if (eq (class-of (class-of object)) the-class-standard-class)
481      (std-slot-makunbound object slot-name)
482      (slot-makunbound-using-class (class-of object) object slot-name)))
483
484(defun std-slot-exists-p (instance slot-name)
485  (not (null (find slot-name (class-slots (class-of instance))
486                   :key #'slot-definition-name))))
487
488(defun slot-exists-p (object slot-name)
489  (if (eq (class-of (class-of object)) the-class-standard-class)
490      (std-slot-exists-p object slot-name)
491      (slot-exists-p-using-class (class-of object) object slot-name)))
492
493(defun instance-slot-p (slot)
494  (eq (slot-definition-allocation slot) :instance))
495
496(defun std-allocate-instance (class)
497  (let* ((layout (class-layout class))
498         (length (and layout (layout-length layout))))
499    (unless layout
500      (format t "no layout for class ~S~%" class)
501      (backtrace))
502    (unless length
503      (format t "no layout length for class ~S~%" class)
504      (setf length (count-if #'instance-slot-p (class-slots class))))
505    (allocate-std-instance class
506                           (allocate-slot-storage length +slot-unbound+))))
507
508(defun make-instance-standard-class (metaclass
509                                     &key name direct-superclasses direct-slots
510                                     direct-default-initargs
511                                     &allow-other-keys)
512  (declare (ignore metaclass))
513  (let ((class (std-allocate-instance (find-class 'standard-class))))
514    (setf (class-name class) name)
515    (setf (class-direct-subclasses class) ())
516    (setf (class-direct-methods class) ())
517    (std-after-initialization-for-classes class
518                                          :direct-superclasses direct-superclasses
519                                          :direct-slots direct-slots
520                                          :direct-default-initargs direct-default-initargs)
521    class))
522
523(defun std-after-initialization-for-classes (class
524                                             &key direct-superclasses direct-slots
525                                             direct-default-initargs
526                                             &allow-other-keys)
527  (let ((supers (or direct-superclasses
528                    (list (find-class 'standard-object)))))
529    (setf (class-direct-superclasses class) supers)
530    (dolist (superclass supers)
531      (push class (class-direct-subclasses superclass))))
532  (let ((slots (mapcar #'(lambda (slot-properties)
533                          (apply #'make-direct-slot-definition class slot-properties))
534                       direct-slots)))
535    (setf (class-direct-slots class) slots)
536    (dolist (direct-slot slots)
537      (dolist (reader (slot-definition-readers direct-slot))
538        (add-reader-method
539         class reader (slot-definition-name direct-slot)))
540      (dolist (writer (slot-definition-writers direct-slot))
541        (add-writer-method
542         class writer (slot-definition-name direct-slot)))))
543  (setf (class-direct-default-initargs class) direct-default-initargs)
544  (funcall (if (eq (class-of class) (find-class 'standard-class))
545               #'std-finalize-inheritance
546               #'finalize-inheritance)
547           class)
548  (values))
549
550(defun canonical-slot-name (canonical-slot)
551  (getf canonical-slot :name))
552
553(defun ensure-class (name &rest all-keys &allow-other-keys)
554  ;; Check for duplicate slots.
555  (let ((slots (getf all-keys :direct-slots)))
556    (dolist (s1 slots)
557      (let ((name1 (canonical-slot-name s1)))
558        (dolist (s2 (cdr (memq s1 slots)))
559    (when (eq name1 (canonical-slot-name s2))
560            (error 'program-error "duplicate slot ~S" name1))))))
561  ;; Check for duplicate argument names in :DEFAULT-INITARGS.
562  (let ((names ()))
563    (do* ((initargs (getf all-keys :direct-default-initargs) (cddr initargs))
564          (name (car initargs) (car initargs)))
565         ((null initargs))
566      (push name names))
567    (do* ((names names (cdr names))
568          (name (car names) (car names)))
569         ((null names))
570      (when (memq name (cdr names))
571        (error 'program-error
572               "duplicate initialization argument name ~S in :DEFAULT-INITARGS"
573               name))))
574  (let ((class (find-class name nil)))
575    (unless class
576      (setf class (apply #'make-instance-standard-class (find-class 'standard-class)
577                         :name name all-keys))
578      (%set-find-class name class))
579    class))
580
581(defmacro defclass (&whole form name direct-superclasses direct-slots &rest options)
582  (unless (>= (length form) 3)
583    (error 'program-error "wrong number of arguments for DEFCLASS"))
584  `(ensure-class ',name
585                 :direct-superclasses
586                 ,(canonicalize-direct-superclasses direct-superclasses)
587                 :direct-slots
588                 ,(canonicalize-direct-slots direct-slots)
589                 ,@(canonicalize-defclass-options options)))
590
591;;; Generic function metaobjects and standard-generic-function
592
593(defun method-combination-type (method-combination)
594  (if (atom method-combination)
595      method-combination
596      (car method-combination)))
597
598(defun method-combination-options (method-combination)
599  (if (atom method-combination)
600      nil
601      (cdr method-combination)))
602
603(defclass standard-generic-function (generic-function)
604  ((name :initarg :name)      ; :accessor generic-function-name
605   (lambda-list               ; :accessor generic-function-lambda-list
606    :initarg :lambda-list)
607   (methods :initform ())     ; :accessor generic-function-methods
608   (method-class              ; :accessor generic-function-method-class
609    :initarg :method-class)
610   (method-combination
611    :initarg :method-combination)
612   (classes-to-emf-table      ; :accessor classes-to-emf-table
613    :initform (make-hash-table :test #'equal))
614   (required-args :initform ())))
615
616(defvar the-class-standard-gf (find-class 'standard-generic-function))
617
618(defvar *sgf-required-args-index*
619  (slot-location the-class-standard-gf 'required-args))
620
621(defvar *sgf-classes-to-emf-table-index*
622  (slot-location the-class-standard-gf 'classes-to-emf-table))
623
624(defun generic-function-name (gf)
625  (slot-value gf 'name))
626(defun (setf generic-function-name) (new-value gf)
627  (setf (slot-value gf 'name) new-value))
628
629(defun generic-function-lambda-list (gf)
630  (slot-value gf 'lambda-list))
631(defun (setf generic-function-lambda-list) (new-value gf)
632  (setf (slot-value gf 'lambda-list) new-value))
633
634(defun generic-function-methods (gf)
635  (slot-value gf 'methods))
636(defun (setf generic-function-methods) (new-value gf)
637  (setf (slot-value gf 'methods) new-value))
638
639(defsetf generic-function-discriminating-function
640  %set-generic-function-discriminating-function)
641
642(defun generic-function-method-class (gf)
643  (slot-value gf 'method-class))
644(defun (setf generic-function-method-class) (new-value gf)
645  (setf (slot-value gf 'method-class) new-value))
646
647(defun generic-function-method-combination (gf)
648  (slot-value gf 'method-combination))
649(defun (setf generic-function-method-combination) (new-value gf)
650  (setf (slot-value gf 'method-combination) new-value))
651
652;;; Internal accessor for effective method function table
653
654(defun classes-to-emf-table (gf)
655  (instance-ref gf *sgf-classes-to-emf-table-index*))
656
657(defun (setf classes-to-emf-table) (new-value gf)
658  (setf (slot-value gf 'classes-to-emf-table) new-value))
659
660;;; Method metaobjects and standard-method
661
662(defclass standard-method (method)
663  ((lambda-list :initarg :lambda-list)     ; :accessor method-lambda-list
664   (qualifiers :initarg :qualifiers)       ; :accessor method-qualifiers
665   (specializers :initarg :specializers)   ; :accessor method-specializers
666   (body :initarg :body)                   ; :accessor method-body
667   (environment :initarg :environment)     ; :accessor method-environment
668   (generic-function :initform nil)        ; :accessor method-generic-function
669   (function)))                            ; :accessor method-function
670
671(defvar the-class-standard-method (find-class 'standard-method))
672
673(defvar *sm-function-index*
674  (slot-location the-class-standard-method 'function))
675
676(defun method-lambda-list (method) (slot-value method 'lambda-list))
677(defun (setf method-lambda-list) (new-value method)
678  (setf (slot-value method 'lambda-list) new-value))
679
680(defun method-qualifiers (method) (slot-value method 'qualifiers))
681(defun (setf method-qualifiers) (new-value method)
682  (setf (slot-value method 'qualifiers) new-value))
683
684(defun method-specializers (method) (slot-value method 'specializers))
685(defun (setf method-specializers) (new-value method)
686  (setf (slot-value method 'specializers) new-value))
687
688(defun method-body (method) (slot-value method 'body))
689(defun (setf method-body) (new-value method)
690  (setf (slot-value method 'body) new-value))
691
692(defun method-environment (method) (slot-value method 'environment))
693(defun (setf method-environment) (new-value method)
694  (setf (slot-value method 'environment) new-value))
695
696(defun method-generic-function (method)
697  (slot-value method 'generic-function))
698(defun (setf method-generic-function) (new-value method)
699  (setf (slot-value method 'generic-function) new-value))
700
701(defun method-function (method)
702  (instance-ref method *sm-function-index*))
703
704(defun (setf method-function) (new-value method)
705  (setf (slot-value method 'function) new-value))
706
707;;; defgeneric
708
709(defmacro defgeneric (function-name lambda-list
710                                    &rest options-and-method-descriptions)
711  (let ((options ())
712        (methods ()))
713    (dolist (item options-and-method-descriptions)
714      (case (car item)
715        (declare) ; FIXME
716        (:documentation) ; FIXME
717        (:method
718         (push `(defmethod ,function-name ,@(cdr item)) methods))
719        (t
720         (push item options))))
721    (setf options (nreverse options)
722          methods (nreverse methods))
723    `(prog1
724       (ensure-generic-function
725        ',function-name
726        :lambda-list ',lambda-list
727        ,@(canonicalize-defgeneric-options options))
728       ,@methods)))
729
730(defun canonicalize-defgeneric-options (options)
731  (mapappend #'canonicalize-defgeneric-option options))
732
733(defun canonicalize-defgeneric-option (option)
734  (case (car option)
735    (:generic-function-class
736     (list ':generic-function-class `(find-class ',(cadr option))))
737    (:method-class
738     (list ':method-class `(find-class ',(cadr option))))
739    (:method-combination
740     (list `',(car option) `',(cdr option)))
741    (t
742     (list `',(car option) `',(cadr option)))))
743
744(defparameter generic-function-table (make-hash-table :test #'equal))
745
746(defun find-generic-function (symbol &optional (errorp t))
747  (let ((gf (gethash symbol generic-function-table nil)))
748    (if (and (null gf) errorp)
749        (error "no generic function named ~S" symbol)
750        gf)))
751
752(defun (setf find-generic-function) (new-value symbol)
753  (setf (gethash symbol generic-function-table) new-value))
754
755;;; ensure-generic-function
756
757(defun ensure-generic-function (function-name
758                                &rest all-keys
759                                &key
760                                (generic-function-class the-class-standard-gf)
761                                (method-class the-class-standard-method)
762                                (method-combination 'standard)
763                                &allow-other-keys)
764  (when (autoloadp function-name)
765    (resolve function-name))
766  (if (find-generic-function function-name nil)
767      (find-generic-function function-name)
768      (progn
769        (when (fboundp function-name)
770          (error 'program-error
771                 "~A already names an ordinary function, macro, or special operator"
772                 function-name))
773        (let ((gf (apply (if (eq generic-function-class the-class-standard-gf)
774                             #'make-instance-standard-generic-function
775                             #'make-instance)
776                         generic-function-class
777                         :name function-name
778                         :method-class method-class
779                         :method-combination method-combination
780                         all-keys)))
781          (setf (find-generic-function function-name) gf)
782          gf))))
783
784;;; finalize-generic-function
785
786(defun finalize-generic-function (gf)
787  (setf (generic-function-discriminating-function gf)
788        (funcall (if (eq (class-of gf) the-class-standard-gf)
789                     #'std-compute-discriminating-function
790                     #'compute-discriminating-function)
791                 gf))
792  (setf (fdefinition (generic-function-name gf)) gf)
793  (clrhash (classes-to-emf-table gf))
794  (values))
795
796(defun gf-required-args (gf)
797  (instance-ref gf *sgf-required-args-index*))
798
799(defun make-instance-standard-generic-function (generic-function-class
800                                                &key name lambda-list
801                                                method-class
802                                                method-combination)
803  (declare (ignore generic-function-class))
804  (let ((gf (std-allocate-instance the-class-standard-gf)))
805    (setf (generic-function-name gf) name)
806    (setf (generic-function-lambda-list gf) lambda-list)
807    (setf (generic-function-methods gf) ())
808    (setf (generic-function-method-class gf) method-class)
809    (setf (generic-function-method-combination gf) method-combination)
810    (setf (classes-to-emf-table gf) (make-hash-table :test #'equal))
811    (setf (slot-value gf 'required-args)
812          (let ((plist (analyze-lambda-list (generic-function-lambda-list gf))))
813            (getf plist ':required-args)))
814    (finalize-generic-function gf)
815    gf))
816
817;;; Run-time environment hacking (Common Lisp ain't got 'em).
818
819(defun top-level-environment ()
820  nil) ; Bogus top level lexical environment
821
822(defvar compile-methods nil)      ; by default, run everything interpreted
823
824(defun compile-in-lexical-environment (env lambda-expr)
825  (declare (ignore env))
826  (if compile-methods
827      (compile nil lambda-expr)
828      (eval `(function ,lambda-expr))))
829
830;;; defmethod
831
832(defmacro defmethod (&rest args)
833  (multiple-value-bind (function-name qualifiers lambda-list specializers body)
834    (parse-defmethod args)
835    `(progn
836      (ensure-generic-function
837       ',function-name
838       :lambda-list ',lambda-list)
839      (ensure-method (find-generic-function ',function-name)
840                     :lambda-list ',lambda-list
841                     :qualifiers ',qualifiers
842                     :specializers ,(canonicalize-specializers specializers)
843                     :body ',body
844                     :environment (top-level-environment)))))
845
846(defun canonicalize-specializers (specializers)
847  `(list ,@(mapcar #'canonicalize-specializer specializers)))
848
849(defun canonicalize-specializer (specializer)
850  ;; FIXME (EQL specializers)
851  `(if (atom ',specializer) (find-class ',specializer) (find-class 't)))
852
853(defun parse-defmethod (args)
854  (let ((fn-spec (car args))
855        (qualifiers ())
856        (specialized-lambda-list nil)
857        (body ())
858        (parse-state :qualifiers))
859    (dolist (arg (cdr args))
860      (ecase parse-state
861        (:qualifiers
862         (if (and (atom arg) (not (null arg)))
863             (push-on-end arg qualifiers)
864             (progn (setq specialized-lambda-list arg)
865               (setq parse-state :body))))
866        (:body (push-on-end arg body))))
867    (values fn-spec
868            qualifiers
869            (extract-lambda-list specialized-lambda-list)
870            (extract-specializers specialized-lambda-list)
871            (list* 'block
872                   (if (consp fn-spec)
873                       (cadr fn-spec)
874                       fn-spec)
875                   body))))
876
877;;; Several tedious functions for analyzing lambda lists
878
879(defun required-portion (gf args)
880  (let ((number-required (length (gf-required-args gf))))
881    (when (< (length args) number-required)
882      (error 'program-error "not enough arguments for generic function ~S" gf))
883    (subseq args 0 number-required)))
884
885(defun extract-lambda-list (specialized-lambda-list)
886  (let* ((plist (analyze-lambda-list specialized-lambda-list))
887         (requireds (getf plist :required-names))
888         (rv (getf plist :rest-var))
889         (ks (getf plist :key-args))
890         (keysp (getf plist :keysp))
891         (aok (getf plist :allow-other-keys))
892         (opts (getf plist :optional-args))
893         (auxs (getf plist :auxiliary-args)))
894    `(,@requireds
895      ,@(if rv `(&rest ,rv) ())
896      ,@(if (or ks keysp aok) `(&key ,@ks) ())
897      ,@(if aok '(&allow-other-keys) ())
898      ,@(if opts `(&optional ,@opts) ())
899      ,@(if auxs `(&aux ,@auxs) ()))))
900
901(defun extract-specializers (specialized-lambda-list)
902  (let ((plist (analyze-lambda-list specialized-lambda-list)))
903    (getf plist ':specializers)))
904
905(defun analyze-lambda-list (lambda-list)
906  (labels ((make-keyword (symbol)
907                         (intern (symbol-name symbol)
908                                 (find-package 'keyword)))
909           (get-keyword-from-arg (arg)
910                                 (if (listp arg)
911                                     (if (listp (car arg))
912                                         (caar arg)
913                                         (make-keyword (car arg)))
914                                     (make-keyword arg))))
915          (let ((keys ())           ; Just the keywords
916                (key-args ())       ; Keywords argument specs
917                (keysp nil)         ;
918                (required-names ()) ; Just the variable names
919                (required-args ())  ; Variable names & specializers
920                (specializers ())   ; Just the specializers
921                (rest-var nil)
922                (optionals ())
923                (auxs ())
924                (allow-other-keys nil)
925                (state :parsing-required))
926            (dolist (arg lambda-list)
927              (if (member arg lambda-list-keywords)
928                  (ecase arg
929                    (&optional
930                     (setq state :parsing-optional))
931                    (&rest
932                     (setq state :parsing-rest))
933                    (&key
934                     (setq keysp t)
935                     (setq state :parsing-key))
936                    (&allow-other-keys
937                     (setq allow-other-keys 't))
938                    (&aux
939                     (setq state :parsing-aux)))
940                  (case state
941                    (:parsing-required
942                     (push-on-end arg required-args)
943                     (if (listp arg)
944                         (progn (push-on-end (car arg) required-names)
945                           (push-on-end (cadr arg) specializers))
946                         (progn (push-on-end arg required-names)
947                           (push-on-end 't specializers))))
948                    (:parsing-optional (push-on-end arg optionals))
949                    (:parsing-rest (setq rest-var arg))
950                    (:parsing-key
951                     (push-on-end (get-keyword-from-arg arg) keys)
952                     (push-on-end arg key-args))
953                    (:parsing-aux (push-on-end arg auxs)))))
954            (list  :required-names required-names
955                   :required-args required-args
956                   :specializers specializers
957                   :rest-var rest-var
958                   :keywords keys
959                   :key-args key-args
960                   :keysp keysp
961                   :auxiliary-args auxs
962                   :optional-args optionals
963                   :allow-other-keys allow-other-keys))))
964
965;;; ensure method
966
967#+nil
968(defun check-method-arg-info (gf arg-info method)
969  (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
970    (analyze-lambda-list (if (consp method)
971                             (early-method-lambda-list method)
972                             (method-lambda-list method)))
973    (flet ((lose (string &rest args)
974                 (error 'simple-program-error
975                        :format-control "~@<attempt to add the method~2I~_~S~I~_~
976                        to the generic function~2I~_~S;~I~_~
977                        but ~?~:>"
978                        :format-arguments (list method gf string args)))
979     (comparison-description (x y)
980                                   (if (> x y) "more" "fewer")))
981      (let ((gf-nreq (arg-info-number-required arg-info))
982      (gf-nopt (arg-info-number-optional arg-info))
983      (gf-key/rest-p (arg-info-key/rest-p arg-info))
984      (gf-keywords (arg-info-keys arg-info)))
985  (unless (= nreq gf-nreq)
986    (lose
987     "the method has ~A required arguments than the generic function."
988     (comparison-description nreq gf-nreq)))
989  (unless (= nopt gf-nopt)
990    (lose
991     "the method has ~A optional arguments than the generic function."
992     (comparison-description nopt gf-nopt)))
993  (unless (eq (or keysp restp) gf-key/rest-p)
994    (lose
995     "the method and generic function differ in whether they accept~_~
996      &REST or &KEY arguments."))
997  (when (consp gf-keywords)
998    (unless (or (and restp (not keysp))
999          allow-other-keys-p
1000          (every (lambda (k) (memq k keywords)) gf-keywords))
1001      (lose "the method does not accept each of the &KEY arguments~2I~_~
1002            ~S."
1003      gf-keywords)))))))
1004
1005(defun ensure-method (gf &rest all-keys)
1006  (let* ((gf-lambda-list (generic-function-lambda-list gf))
1007         (gf-restp (not (null (memq '&rest gf-lambda-list))))
1008         (gf-plist (analyze-lambda-list gf-lambda-list))
1009         (gf-keysp (getf gf-plist :keysp))
1010         (gf-keywords (getf gf-plist :keywords))
1011         (method-lambda-list (getf all-keys :lambda-list))
1012         (method-plist (analyze-lambda-list method-lambda-list))
1013         (method-restp (not (null (memq '&rest method-lambda-list))))
1014         (method-keysp (getf method-plist :keysp))
1015         (method-keywords (getf method-plist :keywords))
1016         (method-allow-other-keys-p (getf method-plist :allow-other-keys)))
1017    (unless (= (length (getf gf-plist :required-args))
1018               (length (getf method-plist :required-args)))
1019      (error "the method has the wrong number of required arguments for the generic function"))
1020    (unless (= (length (getf gf-plist :optional-args))
1021               (length (getf method-plist :optional-args)))
1022      (error "the method has the wrong number of optional arguments for the generic function"))
1023    (unless (eq (or gf-restp gf-keysp) (or method-restp method-keysp))
1024      (error "the method and the generic function differ in whether they accept &REST or &KEY arguments"))
1025    (when (consp gf-keywords)
1026      (unless (or (and method-restp (not method-keysp))
1027                  method-allow-other-keys-p
1028                  (every (lambda (k) (memq k method-keywords)) gf-keywords))
1029        (error "the method does not accept all of the keyword arguments defined for the generic function"))))
1030  (let ((new-method
1031         (apply
1032          (if (eq (generic-function-method-class gf) the-class-standard-method)
1033              #'make-instance-standard-method
1034              #'make-instance)
1035          (generic-function-method-class gf)
1036          all-keys)))
1037    (add-method gf new-method)
1038    new-method))
1039
1040(defun make-instance-standard-method (method-class
1041                                      &key lambda-list qualifiers
1042                                      specializers body environment)
1043  (declare (ignore method-class))
1044  (let ((method (std-allocate-instance the-class-standard-method)))
1045    (setf (method-lambda-list method) lambda-list)
1046    (setf (method-qualifiers method) qualifiers)
1047    (setf (method-specializers method) specializers)
1048    (setf (method-body method) (precompile-form body nil))
1049    (setf (method-environment method) environment)
1050    (setf (method-generic-function method) nil)
1051    (setf (method-function method)
1052          (std-compute-method-function method))
1053    method))
1054
1055(defun check-congruent (gf method)
1056  (let* ((plist1 (analyze-lambda-list (generic-function-lambda-list gf)))
1057         (args1 (getf plist1 :required-args))
1058         (plist2 (analyze-lambda-list (method-lambda-list method)))
1059         (args2 (getf plist2 :required-args)))
1060    (unless (= (length args1) (length args2))
1061      (error "lambda lists are not congruent"))))
1062
1063(defun add-method (gf method)
1064  (check-congruent gf method)
1065  ;; Remove existing method with same qualifiers and specializers (if any).
1066  (let ((old-method (find-method gf (method-qualifiers method)
1067                                 (method-specializers method) nil)))
1068    (when old-method
1069      (remove-method gf old-method)))
1070  (setf (method-generic-function method) gf)
1071  (push method (generic-function-methods gf))
1072  (dolist (specializer (method-specializers method))
1073    (pushnew method (class-direct-methods specializer)))
1074  (finalize-generic-function gf)
1075  gf)
1076
1077(defun remove-method (gf method)
1078  (setf (generic-function-methods gf)
1079        (remove method (generic-function-methods gf)))
1080  (setf (method-generic-function method) nil)
1081;;   (format t "remove-method method-specializers = ~S~%" (method-specializers method))
1082  (dolist (class (method-specializers method))
1083    (setf (class-direct-methods class)
1084          (remove method (class-direct-methods class))))
1085  (finalize-generic-function gf)
1086  gf)
1087
1088(defun find-method (gf qualifiers specializers &optional (errorp t))
1089  (let ((method
1090         (find-if #'(lambda (method)
1091                     (and (equal qualifiers
1092                                 (method-qualifiers method))
1093                          (equal specializers
1094                                 (method-specializers method))))
1095                  (generic-function-methods gf))))
1096    (if (and (null method) errorp)
1097        (error "no such method for ~S" (generic-function-name gf))
1098        method)))
1099
1100;;; Reader and writer methods
1101
1102(defun add-reader-method (class fn-name slot-name)
1103  (ensure-method
1104   (ensure-generic-function fn-name :lambda-list '(object))
1105   :lambda-list '(object)
1106   :qualifiers ()
1107   :specializers (list class)
1108   :body `(slot-value object ',slot-name)
1109   :environment (top-level-environment))
1110  (values))
1111
1112(defun add-writer-method (class fn-name slot-name)
1113  (ensure-method
1114   (ensure-generic-function
1115    fn-name :lambda-list '(new-value object))
1116   :lambda-list '(new-value object)
1117   :qualifiers ()
1118   :specializers (list (find-class 't) class)
1119   :body `(setf (slot-value object ',slot-name)
1120                new-value)
1121   :environment (top-level-environment))
1122  (values))
1123
1124(defun subclassp (c1 c2)
1125  (not (null (find c2 (class-precedence-list c1)))))
1126
1127;;;
1128;;; Generic function invocation
1129;;;
1130
1131;;; apply-generic-function
1132
1133(defun apply-generic-function (gf args)
1134  (apply (generic-function-discriminating-function gf) args))
1135
1136;;; compute-discriminating-function
1137
1138(defun std-compute-discriminating-function (gf)
1139  #'(lambda (&rest args)
1140     (let* ((classes (mapcar #'class-of
1141                             (required-portion gf args)))
1142            (emfun (gethash classes (classes-to-emf-table gf) nil)))
1143       (if emfun
1144           (funcall emfun args)
1145           (slow-method-lookup gf args classes)))))
1146
1147(defun slow-method-lookup (gf args classes)
1148  (let ((applicable-methods
1149         (compute-applicable-methods-using-classes gf classes)))
1150    (if applicable-methods
1151        (let ((emfun
1152               (funcall
1153                (if (eq (class-of gf) the-class-standard-gf)
1154                    #'std-compute-effective-method-function
1155                  #'compute-effective-method-function)
1156                gf applicable-methods)))
1157          (setf (gethash classes (classes-to-emf-table gf)) emfun)
1158          (funcall emfun args))
1159        (error "no applicable methods for generic function ~S with arguments ~S of classes ~S" gf args classes))))
1160
1161(defun compute-applicable-methods-using-classes (gf required-classes)
1162  (sort
1163   (copy-list
1164    (remove-if-not #'(lambda (method)
1165                      (every #'subclassp
1166                             required-classes
1167                             (method-specializers method)))
1168                   (generic-function-methods gf)))
1169   (if (eq (class-of gf) the-class-standard-gf)
1170       #'(lambda (m1 m2)
1171          (std-method-more-specific-p m1 m2 required-classes))
1172       #'(lambda (m1 m2)
1173          (method-more-specific-p gf m1 m2 required-classes)))))
1174
1175(defun sub-specializer-p (c1 c2 c-arg)
1176  (find c2 (cdr (memq c1 (class-precedence-list c-arg)))))
1177
1178(defun std-method-more-specific-p (method1 method2 required-classes)
1179  (mapc #'(lambda (spec1 spec2 arg-class)
1180           (unless (eq spec1 spec2)
1181             (return-from std-method-more-specific-p
1182                          (sub-specializer-p spec1 spec2 arg-class))))
1183        (method-specializers method1)
1184        (method-specializers method2)
1185        required-classes)
1186  nil)
1187
1188;;; apply-methods and compute-effective-method-function
1189
1190(defun apply-methods (gf args methods)
1191  (funcall (compute-effective-method-function gf methods)
1192           args))
1193
1194(defun primary-method-p (method)
1195  (null (intersection '(:before :after :around) (method-qualifiers method))))
1196
1197(defun before-method-p (method)
1198  (equal '(:before) (method-qualifiers method)))
1199
1200(defun after-method-p (method)
1201  (equal '(:after) (method-qualifiers method)))
1202
1203(defun around-method-p (method)
1204  (equal '(:around) (method-qualifiers method)))
1205
1206(defun std-compute-effective-method-function (gf methods)
1207  (let* ((mc (generic-function-method-combination gf))
1208         (type (method-combination-type mc))
1209         (options (method-combination-options mc))
1210         (order (car options))
1211         (primaries ())
1212         (arounds ())
1213         around)
1214    (dolist (m methods)
1215      (let ((qualifiers (method-qualifiers m)))
1216        (cond ((null qualifiers)
1217               (if (eq type 'standard)
1218                   (push m primaries)
1219                   (error "method combination type mismatch")))
1220              ((cdr qualifiers)
1221               (error "invalid method qualifiers"))
1222              ((eq (car qualifiers) :around)
1223               (push m arounds))
1224              ((eq (car qualifiers) type)
1225               (push m primaries))
1226              ((memq (car qualifiers) '(:before :after)))
1227              (t
1228               (error "invalid method qualifiers")))))
1229    (unless (eq order :most-specific-last)
1230      (setq primaries (nreverse primaries)))
1231    (setq arounds (nreverse arounds))
1232    (setq around (car arounds))
1233    (when (null primaries)
1234      (error "no primary methods for the generic function ~S" gf))
1235    (if around
1236        (let ((next-emfun
1237               (funcall
1238                (if (eq (class-of gf) the-class-standard-gf)
1239                    #'std-compute-effective-method-function
1240                    #'compute-effective-method-function)
1241                gf (remove around methods))))
1242          #'(lambda (args)
1243             (funcall (method-function around) args next-emfun)))
1244        (case type
1245          (STANDARD
1246           (let ((next-emfun (compute-primary-emfun (cdr primaries)))
1247                 (befores (remove-if-not #'before-method-p methods))
1248                 (reverse-afters
1249                  (reverse (remove-if-not #'after-method-p methods))))
1250             #'(lambda (args)
1251                (dolist (before befores)
1252                  (funcall (method-function before) args nil))
1253                (multiple-value-prog1
1254                 (funcall (method-function (car primaries)) args next-emfun)
1255                 (dolist (after reverse-afters)
1256                   (funcall (method-function after) args nil))))))
1257          (LIST
1258           #'(lambda (args)
1259              (let ((result ()))
1260                (dolist (primary primaries)
1261                  (push (funcall (method-function primary) args nil) result))
1262                (nreverse result))))
1263          (APPEND
1264           #'(lambda (args)
1265              (let ((result ()))
1266                (dolist (primary primaries)
1267                  (setf result (append result (funcall (method-function primary) args nil))))
1268                result)))
1269          (NCONC
1270           #'(lambda (args)
1271              (let ((result ()))
1272                (dolist (primary primaries)
1273                  (setf result (nconc result (funcall (method-function primary) args nil))))
1274                result)))
1275          (PROGN
1276           #'(lambda (args)
1277              (let ((result nil))
1278                (dolist (primary primaries)
1279                  (setf result (funcall (method-function primary) args nil)))
1280                result)))
1281          (AND
1282           #'(lambda (args)
1283              (let ((result t))
1284                (dolist (primary primaries)
1285                  (setf result
1286                        (and result
1287                             (funcall (method-function primary) args nil)))
1288                  (unless result (return)))
1289                result)))
1290          (OR
1291           #'(lambda (args)
1292              (let ((result nil))
1293                (dolist (primary primaries)
1294                  (setf result
1295                        (or result
1296                            (funcall (method-function primary) args nil)))
1297                  (when result (return)))
1298                result)))
1299          (+
1300           #'(lambda (args)
1301              (let ((result 0))
1302                (dolist (primary primaries)
1303                  (incf result (funcall (method-function primary) args nil)))
1304                result)))
1305          (MAX
1306           #'(lambda (args)
1307              (let ((result ()))
1308                (dolist (primary primaries)
1309                  (push (funcall (method-function primary) args nil) result))
1310                (apply #'max result))))
1311          (MIN
1312           #'(lambda (args)
1313              (let ((result ()))
1314                (dolist (primary primaries)
1315                  (push (funcall (method-function primary) args nil) result))
1316                (apply #'min result))))
1317          (t
1318           (error "unsupported method combination type ~S" type))))))
1319
1320;;; compute an effective method function from a list of primary methods:
1321
1322(defun compute-primary-emfun (methods)
1323  (if (null methods)
1324      nil
1325      (let ((next-emfun (compute-primary-emfun (cdr methods))))
1326        #'(lambda (args)
1327           (funcall (method-function (car methods)) args next-emfun)))))
1328
1329;;; apply-method and compute-method-function
1330
1331(defun apply-method (method args next-methods)
1332  (funcall (method-function method)
1333           args
1334           (if (null next-methods)
1335               nil
1336               (compute-effective-method-function
1337                (method-generic-function method) next-methods))))
1338
1339(defun std-compute-method-function (method)
1340  (let ((form (method-body method))
1341        (lambda-list (method-lambda-list method)))
1342    (compile-in-lexical-environment
1343     (method-environment method)
1344     `(lambda (args next-emfun)
1345        (flet ((call-next-method (&rest cnm-args)
1346                                 (if (null next-emfun)
1347                                     (error "no next method for generic function ~S"
1348                                            (method-generic-function ',method))
1349                                     (funcall next-emfun (or cnm-args args))))
1350               (next-method-p ()
1351                              (not (null next-emfun))))
1352          (apply #'(lambda ,(kludge-arglist lambda-list)
1353                    ,form)
1354                 args))))))
1355
1356;;; N.B. The function kludge-arglist is used to pave over the differences
1357;;; between argument keyword compatibility for regular functions versus
1358;;; generic functions.
1359
1360(defun kludge-arglist (lambda-list)
1361  (if (and (member '&key lambda-list)
1362           (not (member '&allow-other-keys lambda-list)))
1363      (append lambda-list '(&allow-other-keys))
1364      (if (and (not (member '&rest lambda-list))
1365               (not (member '&key lambda-list)))
1366          (append lambda-list '(&key &allow-other-keys))
1367          lambda-list)))
1368
1369;;; Slot access
1370
1371(defun setf-slot-value-using-class (new-value class instance slot-name)
1372  (setf (std-slot-value instance slot-name) new-value))
1373
1374(defgeneric slot-value-using-class (class instance slot-name))
1375(defmethod slot-value-using-class ((class standard-class) instance slot-name)
1376  (std-slot-value instance slot-name))
1377
1378(defgeneric (setf slot-value-using-class) (new-value class instance slot-name))
1379(defmethod (setf slot-value-using-class)
1380  (new-value (class standard-class) instance slot-name)
1381  (setf (std-slot-value instance slot-name) new-value))
1382
1383(defgeneric slot-exists-p-using-class (class instance slot-name))
1384
1385(defmethod slot-exists-p-using-class (class instance slot-name)
1386  nil)
1387
1388(defmethod slot-exists-p-using-class ((class standard-class) instance slot-name)
1389  (std-slot-exists-p instance slot-name))
1390
1391(defmethod slot-exists-p-using-class ((class structure-class) instance slot-name)
1392  (dolist (dsd (class-slots class))
1393    (when (eq (dsd-name dsd) slot-name)
1394      (return-from slot-exists-p-using-class t)))
1395  nil)
1396
1397(defgeneric slot-boundp-using-class (class instance slot-name))
1398(defmethod slot-boundp-using-class
1399  ((class standard-class) instance slot-name)
1400  (std-slot-boundp instance slot-name))
1401
1402(defgeneric slot-makunbound-using-class (class instance slot-name))
1403(defmethod slot-makunbound-using-class
1404  ((class standard-class) instance slot-name)
1405  (std-slot-makunbound instance slot-name))
1406
1407(defgeneric slot-missing (class instance slot-name operation &optional new-value))
1408(defmethod slot-missing ((class t) instance slot-name operation &optional new-value)
1409  (error "the slot ~S is missing from the class ~S" slot-name class))
1410
1411;;; Instance creation and initialization
1412
1413(defgeneric allocate-instance (class &rest initargs &key &allow-other-keys))
1414
1415(defmethod allocate-instance ((class standard-class) &rest initargs)
1416  (std-allocate-instance class))
1417
1418(defmethod allocate-instance ((class structure-class) &rest initargs)
1419  (%make-structure (class-name class)
1420                   (make-list (length (class-slots class))
1421                              :initial-element +slot-unbound+)))
1422
1423(defgeneric make-instance (class &key))
1424
1425(defmethod make-instance ((class standard-class) &rest initargs)
1426  (let ((class-default-initargs (class-default-initargs class)))
1427    (when class-default-initargs
1428      (let ((default-initargs ())
1429            (not-found (gensym)))
1430        (do* ((list class-default-initargs (cddr list))
1431              (key (car list) (car list))
1432              (fn (cadr list) (cadr list)))
1433             ((null list))
1434          (when (eq (getf initargs key not-found) not-found)
1435            (setf default-initargs (append default-initargs (list key (funcall fn))))))
1436        (setf initargs (append initargs default-initargs)))))
1437  (let ((instance (std-allocate-instance class)))
1438    (apply #'initialize-instance instance initargs)
1439    instance))
1440
1441(defmethod make-instance ((class symbol) &rest initargs)
1442  (apply #'make-instance (find-class class) initargs))
1443
1444(defgeneric initialize-instance (instance &key))
1445
1446(defmethod initialize-instance ((instance standard-object) &rest initargs)
1447  (apply #'shared-initialize instance t initargs))
1448
1449(defgeneric reinitialize-instance (instance &key))
1450
1451(defmethod reinitialize-instance
1452  ((instance standard-object) &rest initargs)
1453  (apply #'shared-initialize instance () initargs))
1454
1455(defgeneric shared-initialize (instance slot-names &key))
1456
1457(defmethod shared-initialize ((instance standard-object)
1458                              slot-names &rest all-keys)
1459  (dolist (slot (class-slots (class-of instance)))
1460    (let ((slot-name (slot-definition-name slot)))
1461      (multiple-value-bind (init-key init-value foundp)
1462        (get-properties all-keys (slot-definition-initargs slot))
1463        (if foundp
1464            (setf (std-slot-value instance slot-name) init-value)
1465            (when (and (not (std-slot-boundp instance slot-name))
1466                       (slot-definition-initfunction slot)
1467                       (or (eq slot-names t)
1468                           (member slot-name slot-names)))
1469              (setf (std-slot-value instance slot-name)
1470                    (funcall (slot-definition-initfunction slot))))))))
1471  instance)
1472
1473;;; change-class
1474
1475(defgeneric change-class (instance new-class &key))
1476
1477(defmethod change-class ((old-instance standard-object) (new-class standard-class)
1478                         &rest initargs)
1479  (let ((new-instance (allocate-instance new-class)))
1480    (dolist (slot-name (mapcar #'slot-definition-name
1481                               (class-slots new-class)))
1482      (when (and (slot-exists-p old-instance slot-name)
1483                 (slot-boundp old-instance slot-name))
1484        (setf (slot-value new-instance slot-name)
1485              (slot-value old-instance slot-name))))
1486    (rotatef (std-instance-slots new-instance)
1487             (std-instance-slots old-instance))
1488    (rotatef (std-instance-layout new-instance)
1489             (std-instance-layout old-instance))
1490    (apply #'update-instance-for-different-class
1491           new-instance old-instance initargs)
1492    old-instance))
1493
1494(defmethod change-class ((instance standard-object) (new-class symbol) &rest initargs)
1495  (apply #'change-class instance (find-class new-class) initargs))
1496
1497(defgeneric update-instance-for-different-class (old new &key))
1498
1499(defmethod update-instance-for-different-class
1500  ((old standard-object) (new standard-object) &rest initargs)
1501  (let ((added-slots
1502         (remove-if #'(lambda (slot-name)
1503                       (slot-exists-p old slot-name))
1504                    (mapcar #'slot-definition-name
1505                            (class-slots (class-of new))))))
1506    (apply #'shared-initialize new added-slots initargs)))
1507
1508;;;  Methods having to do with class metaobjects.
1509
1510(defmethod initialize-instance :after ((class standard-class) &rest args)
1511  (apply #'std-after-initialization-for-classes class args))
1512
1513;;; Finalize inheritance
1514
1515(defgeneric finalize-inheritance (class))
1516(defmethod finalize-inheritance ((class standard-class))
1517  (std-finalize-inheritance class)
1518  (values))
1519
1520;;; Class precedence lists
1521
1522(defgeneric compute-class-precedence-list (class))
1523(defmethod compute-class-precedence-list ((class standard-class))
1524  (std-compute-class-precedence-list class))
1525
1526;;; Slot inheritance
1527
1528(defgeneric compute-slots (class))
1529(defmethod compute-slots ((class standard-class))
1530  (std-compute-slots class))
1531
1532(defgeneric compute-effective-slot-definition (class direct-slots))
1533(defmethod compute-effective-slot-definition
1534  ((class standard-class) direct-slots)
1535  (std-compute-effective-slot-definition class direct-slots))
1536
1537;;; Methods having to do with generic function metaobjects.
1538
1539(defmethod initialize-instance :after ((gf standard-generic-function) &key)
1540  (finalize-generic-function gf))
1541
1542;;; Methods having to do with method metaobjects.
1543
1544(defmethod initialize-instance :after ((method standard-method) &key)
1545  (setf (method-function method) (compute-method-function method)))
1546
1547;;; Methods having to do with generic function invocation.
1548
1549(defgeneric compute-discriminating-function (gf))
1550(defmethod compute-discriminating-function ((gf standard-generic-function))
1551  (std-compute-discriminating-function gf))
1552
1553(defgeneric method-more-specific-p (gf method1 method2 required-classes))
1554
1555(defmethod method-more-specific-p ((gf standard-generic-function)
1556                                   method1 method2 required-classes)
1557  (std-method-more-specific-p method1 method2 required-classes))
1558
1559(defgeneric compute-effective-method-function (gf methods))
1560(defmethod compute-effective-method-function ((gf standard-generic-function) methods)
1561  (std-compute-effective-method-function gf methods))
1562
1563(defgeneric compute-method-function (method))
1564(defmethod compute-method-function ((method standard-method))
1565  (std-compute-method-function method))
1566
1567(defgeneric compute-applicable-methods (gf args))
1568(defmethod compute-applicable-methods ((gf standard-generic-function) args)
1569  (compute-applicable-methods-using-classes gf (mapcar #'class-of args)))
1570
1571;;; Conditions.
1572
1573(defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
1574         &body options)
1575  (let ((parent-types (or parent-types '(condition)))
1576        (report nil))
1577    (dolist (option options)
1578      (when (eq (car option) :report)
1579        (let ((arg (cadr option)))
1580          (setf report
1581                (if (stringp arg)
1582                    `#'(lambda (condition stream)
1583                        (declare (ignore condition))
1584                        (write-string ,arg stream))
1585                    `#'(lambda (condition stream)
1586                        (funcall #',arg condition stream)))))))
1587    `(progn
1588       (defclass ,name ,parent-types ,slot-specs ,@options)
1589       (defmethod print-object ((condition ,name) stream)
1590         (if *print-escape*
1591             (call-next-method)
1592             (funcall ,report condition stream)))
1593       ',name)))
1594
1595(defun make-condition (type &rest initargs)
1596  (or (%make-condition type initargs)
1597      (apply #'make-instance (find-class type) initargs)))
1598
1599(provide 'clos)
Note: See TracBrowser for help on using the repository browser.