source: trunk/j/src/org/armedbear/lisp/clos.lisp @ 5215

Last change on this file since 5215 was 5215, checked in by piso, 18 years ago

INSTANCE-SLOT-LOCATION

File size: 63.2 KB
Line 
1;;; clos.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: clos.lisp,v 1.50 2003-12-20 03:08:23 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20;;; Adapted from Closette.
21
22;;; Closette Version 1.0 (February 10, 1991)
23;;;
24;;; Copyright (c) 1990, 1991 Xerox Corporation.
25;;; All rights reserved.
26;;;
27;;; Use and copying of this software and preparation of derivative works
28;;; based upon this software are permitted.  Any distribution of this
29;;; software or derivative works must comply with all applicable United
30;;; States export control laws.
31;;;
32;;; This software is made available AS IS, and Xerox Corporation makes no
33;;; warranty about the software, its performance or its conformity to any
34;;; specification.
35;;;
36;;; Closette is an implementation of a subset of CLOS with a metaobject
37;;; protocol as described in "The Art of The Metaobject Protocol",
38;;; MIT Press, 1991.
39
40(in-package "SYSTEM")
41
42(defmacro push-on-end (value location)
43  `(setf ,location (nconc ,location (list ,value))))
44
45;;; (SETF GETF*) is like (SETF GETF) except that it always changes the list,
46;;; which must be non-nil.
47
48(defun (setf getf*) (new-value plist key)
49  (block body
50    (do ((x plist (cddr x)))
51        ((null x))
52      (when (eq (car x) key)
53        (setf (car (cdr x)) new-value)
54        (return-from body new-value)))
55    (push-on-end key plist)
56    (push-on-end new-value plist)
57    new-value))
58
59(defun mapappend (fun &rest args)
60  (if (some #'null args)
61      ()
62      (append (apply fun (mapcar #'car args))
63              (apply #'mapappend fun (mapcar #'cdr args)))))
64
65(defun mapplist (fun x)
66  (if (null x)
67      ()
68      (cons (funcall fun (car x) (cadr x))
69            (mapplist fun (cddr x)))))
70
71(defsetf class-name %set-class-name)
72(defsetf class-layout %set-class-layout)
73(defsetf class-direct-superclasses %set-class-direct-superclasses)
74(defsetf class-direct-subclasses %set-class-direct-subclasses)
75(defsetf class-direct-methods %set-class-direct-methods)
76(defsetf class-direct-slots %set-class-direct-slots)
77(defsetf class-slots %set-class-slots)
78(defsetf class-direct-default-initargs %set-class-direct-default-initargs)
79(defsetf class-default-initargs %set-class-default-initargs)
80(defsetf class-precedence-list %set-class-precedence-list)
81(defsetf std-instance-layout %set-std-instance-layout)
82(defsetf std-instance-slots %set-std-instance-slots)
83(defsetf instance-ref %set-instance-ref)
84
85(defun (setf find-class) (new-value symbol &optional errorp environment)
86  (%set-find-class symbol new-value))
87
88(defun canonicalize-direct-slots (direct-slots)
89  `(list ,@(mapcar #'canonicalize-direct-slot direct-slots)))
90
91(defun canonicalize-direct-slot (spec)
92  (if (symbolp spec)
93      `(list :name ',spec)
94      (let ((name (car spec))
95            (initfunction nil)
96            (initform nil)
97            (initargs ())
98            (type nil)
99            (allocation nil)
100            (documentation nil)
101            (readers ())
102            (writers ())
103            (other-options ()))
104        (do ((olist (cdr spec) (cddr olist)))
105            ((null olist))
106          (case (car olist)
107            (:initform
108             (when initform
109               (error 'program-error
110                      "duplicate slot option :INITFORM for slot named ~S"
111                      name))
112             (setq initfunction
113                   `(function (lambda () ,(cadr olist))))
114             (setq initform `',(cadr olist)))
115            (:initarg
116             (push-on-end (cadr olist) initargs))
117            (:allocation
118             (when allocation
119               (error 'program-error
120                      "duplicate slot option :ALLOCATION for slot named ~S"
121                      name))
122             (setf allocation (cadr olist))
123             (push-on-end (car olist) other-options)
124             (push-on-end (cadr olist) other-options))
125            (:type
126             (when type
127               (error 'program-error
128                      "duplicate slot option :TYPE for slot named ~S"
129                      name))
130             (setf type (cadr olist))) ;; FIXME type is ignored
131            (:documentation
132             (when documentation
133               (error 'program-error
134                      "duplicate slot option :DOCUMENTATION for slot named ~S"
135                      name))
136             (setf documentation (cadr olist))) ;; FIXME documentation is ignored
137            (:reader
138             (push-on-end (cadr olist) readers))
139            (:writer
140             (push-on-end (cadr olist) writers))
141            (:accessor
142             (push-on-end (cadr olist) readers)
143             (push-on-end `(setf ,(cadr olist)) writers))
144            (t
145             (error 'program-error
146                    "invalid initialization argument ~S for slot named ~S"
147                    (car olist) name))))
148        `(list
149          :name ',name
150          ,@(when initfunction
151              `(:initform ,initform
152                          :initfunction ,initfunction))
153          ,@(when initargs `(:initargs ',initargs))
154          ,@(when readers `(:readers ',readers))
155          ,@(when writers `(:writers ',writers))
156          ,@other-options))))
157
158(defun canonicalize-direct-superclasses (direct-superclasses)
159  `(list ,@(mapcar #'canonicalize-direct-superclass direct-superclasses)))
160
161(defun canonicalize-direct-superclass (class-name)
162  `(find-class ',class-name))
163
164(defun canonicalize-defclass-options (options)
165  (mapappend #'canonicalize-defclass-option options))
166
167(defun canonicalize-defclass-option (option)
168  (case (car option)
169    (:metaclass
170     (list ':metaclass
171           `(find-class ',(cadr option))))
172    (:default-initargs
173     (list
174      ':direct-default-initargs
175      `(list ,@(mapappend
176                #'(lambda (x) x)
177                (mapplist
178                 #'(lambda (key value)
179                    `(',key ,(make-initfunction value)))
180                 (cdr option))))))
181    ((:documentation :report)
182     (list (car option) `',(cadr option)))
183    (t
184     (error 'program-error
185            :format-control "invalid DEFCLASS option ~S"
186            :format-arguments (list (car option))))))
187
188(defun make-initfunction (initform)
189  `(function (lambda () ,initform)))
190
191(defconstant +slot-unbound+ (make-symbol "SLOT-UNBOUND"))
192
193;;; Slot definition metaobjects
194
195(defstruct slot-definition
196  name
197  initfunction
198  initform
199  initargs
200  readers
201  writers
202  allocation
203  allocation-class
204  (location nil))
205
206(defun make-direct-slot-definition (class &rest properties
207                                          &key name
208                                          (initargs ())
209                                          (initform nil)
210                                          (initfunction nil)
211                                          (readers ())
212                                          (writers ())
213                                          (allocation :instance)
214                                          &allow-other-keys)
215  (let ((slot (make-slot-definition)))
216    (setf (slot-definition-name slot) name)
217    (setf (slot-definition-initargs slot) initargs)
218    (setf (slot-definition-initform slot) initform)
219    (setf (slot-definition-initfunction slot) initfunction)
220    (setf (slot-definition-readers slot) readers)
221    (setf (slot-definition-writers slot) writers)
222    (setf (slot-definition-allocation slot) allocation)
223    (setf (slot-definition-allocation-class slot) class)
224    slot))
225
226(defun make-effective-slot-definition (&rest properties
227                                             &key name
228                                             (initargs ())
229                                             (initform nil)
230                                             (initfunction nil)
231                                             (allocation :instance)
232                                             (allocation-class nil)
233                                             &allow-other-keys)
234  (let ((slot (make-slot-definition)))
235    (setf (slot-definition-name slot) name)
236    (setf (slot-definition-initargs slot) initargs)
237    (setf (slot-definition-initform slot) initform)
238    (setf (slot-definition-initfunction slot) initfunction)
239    (setf (slot-definition-allocation slot) allocation)
240    (setf (slot-definition-allocation-class slot) allocation-class)
241    slot))
242
243;;; finalize-inheritance
244
245(defun std-finalize-inheritance (class)
246  (setf (class-precedence-list class)
247        (funcall (if (eq (class-of class) the-class-standard-class)
248                     #'std-compute-class-precedence-list
249                     #'compute-class-precedence-list)
250                 class))
251  (setf (class-slots class)
252        (funcall (if (eq (class-of class) the-class-standard-class)
253                     #'std-compute-slots
254                     #'compute-slots)
255                 class))
256  (let ((length 0)
257        (instance-slots ()))
258    (dolist (slot (class-slots class))
259      (case (slot-definition-allocation slot)
260        (:instance
261         (setf (slot-definition-location slot) length)
262         (incf length)
263         (push (slot-definition-name slot) instance-slots))
264        (:class
265         (unless (slot-definition-location slot)
266           (let ((allocation-class (slot-definition-allocation-class slot)))
267             (setf (slot-definition-location slot)
268                   (if (eq class allocation-class)
269                       (cons (slot-definition-name slot) +slot-unbound+)
270                       (slot-location allocation-class (slot-definition-name slot)))))))))
271    (setf (class-layout class)
272          (make-layout class length (nreverse instance-slots))))
273  (setf (class-default-initargs class)
274        (compute-class-default-initargs class)))
275
276(defun compute-class-default-initargs (class)
277  (mapappend #'class-direct-default-initargs
278             (class-precedence-list class)))
279
280;;; Class precedence lists
281
282(defun std-compute-class-precedence-list (class)
283  (let ((classes-to-order (collect-superclasses* class)))
284    (topological-sort classes-to-order
285                      (remove-duplicates
286                       (mapappend #'local-precedence-ordering
287                                  classes-to-order))
288                      #'std-tie-breaker-rule)))
289
290;;; topological-sort implements the standard algorithm for topologically
291;;; sorting an arbitrary set of elements while honoring the precedence
292;;; constraints given by a set of (X,Y) pairs that indicate that element
293;;; X must precede element Y.  The tie-breaker procedure is called when it
294;;; is necessary to choose from multiple minimal elements; both a list of
295;;; candidates and the ordering so far are provided as arguments.
296
297(defun topological-sort (elements constraints tie-breaker)
298  (let ((remaining-constraints constraints)
299        (remaining-elements elements)
300        (result ()))
301    (loop
302      (let ((minimal-elements
303             (remove-if
304              #'(lambda (class)
305                 (member class remaining-constraints
306                         :key #'cadr))
307              remaining-elements)))
308        (when (null minimal-elements)
309          (if (null remaining-elements)
310              (return-from topological-sort result)
311              (error "Inconsistent precedence graph.")))
312        (let ((choice (if (null (cdr minimal-elements))
313                          (car minimal-elements)
314                          (funcall tie-breaker
315                                   minimal-elements
316                                   result))))
317          (setq result (append result (list choice)))
318          (setq remaining-elements
319                (remove choice remaining-elements))
320          (setq remaining-constraints
321                (remove choice
322                        remaining-constraints
323                        :test #'member)))))))
324
325;;; In the event of a tie while topologically sorting class precedence lists,
326;;; the CLOS Specification says to "select the one that has a direct subclass
327;;; rightmost in the class precedence list computed so far."  The same result
328;;; is obtained by inspecting the partially constructed class precedence list
329;;; from right to left, looking for the first minimal element to show up among
330;;; the direct superclasses of the class precedence list constituent.
331;;; (There's a lemma that shows that this rule yields a unique result.)
332
333(defun std-tie-breaker-rule (minimal-elements cpl-so-far)
334  (dolist (cpl-constituent (reverse cpl-so-far))
335    (let* ((supers (class-direct-superclasses cpl-constituent))
336           (common (intersection minimal-elements supers)))
337      (when (not (null common))
338        (return-from std-tie-breaker-rule (car common))))))
339
340;;; This version of collect-superclasses* isn't bothered by cycles in the class
341;;; hierarchy, which sometimes happen by accident.
342
343(defun collect-superclasses* (class)
344  (labels ((all-superclasses-loop (seen superclasses)
345                                  (let ((to-be-processed
346                                         (set-difference superclasses seen)))
347                                    (if (null to-be-processed)
348                                        superclasses
349                                        (let ((class-to-process
350                                               (car to-be-processed)))
351                                          (all-superclasses-loop
352                                           (cons class-to-process seen)
353                                           (union (class-direct-superclasses
354                                                   class-to-process)
355                                                  superclasses)))))))
356          (all-superclasses-loop () (list class))))
357
358;;; The local precedence ordering of a class C with direct superclasses C_1,
359;;; C_2, ..., C_n is the set ((C C_1) (C_1 C_2) ...(C_n-1 C_n)).
360
361(defun local-precedence-ordering (class)
362  (mapcar #'list
363          (cons class
364                (butlast (class-direct-superclasses class)))
365          (class-direct-superclasses class)))
366
367;;; Slot inheritance
368
369(defun std-compute-slots (class)
370  (let* ((all-slots (mapappend #'class-direct-slots
371                               (class-precedence-list class)))
372         (all-names (remove-duplicates
373                     (mapcar #'slot-definition-name all-slots))))
374    (mapcar #'(lambda (name)
375               (funcall
376                (if (eq (class-of class) the-class-standard-class)
377                    #'std-compute-effective-slot-definition
378                    #'compute-effective-slot-definition)
379                class
380                (remove name all-slots
381                        :key #'slot-definition-name
382                        :test-not #'eq)))
383            all-names)))
384
385(defun std-compute-effective-slot-definition (class direct-slots)
386  (declare (ignore class))
387  (let ((initer (find-if-not #'null direct-slots
388                             :key #'slot-definition-initfunction)))
389    (make-effective-slot-definition
390     :name (slot-definition-name (car direct-slots))
391     :initform (if initer
392                   (slot-definition-initform initer)
393                   nil)
394     :initfunction (if initer
395                       (slot-definition-initfunction initer)
396                       nil)
397     :initargs (remove-duplicates
398                (mapappend #'slot-definition-initargs
399                           direct-slots))
400     :allocation (slot-definition-allocation (car direct-slots))
401     :allocation-class (slot-definition-allocation-class (car direct-slots)))))
402
403;;; Standard instance slot access
404
405;;; N.B. The location of the effective-slots slots in the class metaobject for
406;;; standard-class must be determined without making any further slot
407;;; references.
408
409(defvar the-slots-of-standard-class) ;standard-class's class-slots
410(defvar the-class-standard-class (find-class 'standard-class))
411
412(defun find-slot-definition (class slot-name)
413  (dolist (slot (class-slots class) nil)
414    (when (eq slot-name (slot-definition-name slot))
415      (return slot))))
416
417(defun slot-location (class slot-name)
418  (let ((slot (find-slot-definition class slot-name)))
419    (if slot
420        (slot-definition-location slot)
421        nil)))
422
423(defun instance-slot-location (instance slot-name)
424  (let* ((layout (std-instance-layout instance))
425         (location (and layout (instance-slot-index layout slot-name))))
426    (if location
427        location
428        (slot-location (class-of instance) slot-name))))
429
430(defun std-slot-value (instance slot-name)
431  (let* ((location (instance-slot-location instance slot-name))
432         (value (cond ((fixnump location)
433                       (instance-ref instance location))
434                      ((consp location)
435                       (cdr location))
436                      (t
437                       (slot-missing (class-of instance) instance slot-name 'slot-value)))))
438    (if (eq +slot-unbound+ value)
439        (error "The slot ~S is unbound in the object ~S." slot-name instance)
440        value)))
441
442(defun slot-value (object slot-name)
443  (if (eq (class-of (class-of object)) the-class-standard-class)
444      (std-slot-value object slot-name)
445      (slot-value-using-class (class-of object) object slot-name)))
446
447(defun %set-std-slot-value (instance slot-name new-value)
448  (let ((location (instance-slot-location instance slot-name)))
449    (cond ((fixnump location)
450           (setf (instance-ref instance location) new-value))
451          ((consp location)
452           (setf (cdr location) new-value))
453          (t
454           (slot-missing (class-of instance) instance slot-name 'setf new-value))))
455  new-value)
456
457(defsetf std-slot-value %set-std-slot-value)
458
459(defun (setf slot-value) (new-value object slot-name)
460  (if (eq (class-of (class-of object)) the-class-standard-class)
461      (setf (std-slot-value object slot-name) new-value)
462      (setf-slot-value-using-class
463       new-value (class-of object) object slot-name)))
464
465(defun std-slot-boundp (instance slot-name)
466  (let ((location (instance-slot-location instance slot-name)))
467    (cond ((fixnump location)
468           (neq +slot-unbound+ (instance-ref instance location)))
469          ((consp location)
470           (neq +slot-unbound+ (cdr location)))
471          (t
472           (not (null (slot-missing (class-of instance) instance slot-name 'slot-boundp)))))))
473
474(defun slot-boundp (object slot-name)
475  (if (eq (class-of (class-of object)) the-class-standard-class)
476      (std-slot-boundp object slot-name)
477      (slot-boundp-using-class (class-of object) object slot-name)))
478
479(defun std-slot-makunbound (instance slot-name)
480  (let ((location (instance-slot-location instance slot-name)))
481    (cond ((fixnump location)
482           (setf (instance-ref instance location) +slot-unbound+))
483          ((consp location)
484           (setf (cdr location) +slot-unbound+))
485          (t
486           (slot-missing (class-of instance) instance slot-name 'slot-makunbound))))
487  instance)
488
489(defun slot-makunbound (object slot-name)
490  (if (eq (class-of (class-of object)) the-class-standard-class)
491      (std-slot-makunbound object slot-name)
492      (slot-makunbound-using-class (class-of object) object slot-name)))
493
494(defun std-slot-exists-p (instance slot-name)
495  (not (null (find slot-name (class-slots (class-of instance))
496                   :key #'slot-definition-name))))
497
498(defun slot-exists-p (object slot-name)
499  (if (eq (class-of (class-of object)) the-class-standard-class)
500      (std-slot-exists-p object slot-name)
501      (slot-exists-p-using-class (class-of object) object slot-name)))
502
503(defun instance-slot-p (slot)
504  (eq (slot-definition-allocation slot) :instance))
505
506(defun std-allocate-instance (class)
507  (let* ((layout (class-layout class))
508         (length (and layout (layout-length layout))))
509    (unless layout
510      (format t "no layout for class ~S~%" class)
511      (backtrace))
512    (unless length
513      (format t "no layout length for class ~S~%" class)
514      (setf length (count-if #'instance-slot-p (class-slots class))))
515    (allocate-std-instance class
516                           (allocate-slot-storage length +slot-unbound+))))
517
518(defun make-instance-standard-class (metaclass
519                                     &key name direct-superclasses direct-slots
520                                     direct-default-initargs
521                                     &allow-other-keys)
522  (declare (ignore metaclass))
523  (let ((class (std-allocate-instance (find-class 'standard-class))))
524    (setf (class-name class) name)
525    (setf (class-direct-subclasses class) ())
526    (setf (class-direct-methods class) ())
527    (std-after-initialization-for-classes class
528                                          :direct-superclasses direct-superclasses
529                                          :direct-slots direct-slots
530                                          :direct-default-initargs direct-default-initargs)
531    class))
532
533(defun std-after-initialization-for-classes (class
534                                             &key direct-superclasses direct-slots
535                                             direct-default-initargs
536                                             &allow-other-keys)
537  (let ((supers (or direct-superclasses
538                    (list (find-class 'standard-object)))))
539    (setf (class-direct-superclasses class) supers)
540    (dolist (superclass supers)
541      (push class (class-direct-subclasses superclass))))
542  (let ((slots (mapcar #'(lambda (slot-properties)
543                          (apply #'make-direct-slot-definition class slot-properties))
544                       direct-slots)))
545    (setf (class-direct-slots class) slots)
546    (dolist (direct-slot slots)
547      (dolist (reader (slot-definition-readers direct-slot))
548        (add-reader-method
549         class reader (slot-definition-name direct-slot)))
550      (dolist (writer (slot-definition-writers direct-slot))
551        (add-writer-method
552         class writer (slot-definition-name direct-slot)))))
553  (setf (class-direct-default-initargs class) direct-default-initargs)
554  (funcall (if (eq (class-of class) (find-class 'standard-class))
555               #'std-finalize-inheritance
556               #'finalize-inheritance)
557           class)
558  (values))
559
560(defun canonical-slot-name (canonical-slot)
561  (getf canonical-slot :name))
562
563(defun ensure-class (name &rest all-keys &allow-other-keys)
564  ;; Check for duplicate slots.
565  (let ((slots (getf all-keys :direct-slots)))
566    (dolist (s1 slots)
567      (let ((name1 (canonical-slot-name s1)))
568        (dolist (s2 (cdr (memq s1 slots)))
569    (when (eq name1 (canonical-slot-name s2))
570            (error 'program-error "duplicate slot ~S" name1))))))
571  ;; Check for duplicate argument names in :DEFAULT-INITARGS.
572  (let ((names ()))
573    (do* ((initargs (getf all-keys :direct-default-initargs) (cddr initargs))
574          (name (car initargs) (car initargs)))
575         ((null initargs))
576      (push name names))
577    (do* ((names names (cdr names))
578          (name (car names) (car names)))
579         ((null names))
580      (when (memq name (cdr names))
581        (error 'program-error
582               "duplicate initialization argument name ~S in :DEFAULT-INITARGS"
583               name))))
584  (let ((class (find-class name nil)))
585    (unless class
586      (setf class (apply #'make-instance-standard-class (find-class 'standard-class)
587                         :name name all-keys))
588      (%set-find-class name class))
589    class))
590
591(defmacro defclass (&whole form name direct-superclasses direct-slots &rest options)
592  (unless (>= (length form) 3)
593    (error 'program-error "wrong number of arguments for DEFCLASS"))
594  `(ensure-class ',name
595                 :direct-superclasses
596                 ,(canonicalize-direct-superclasses direct-superclasses)
597                 :direct-slots
598                 ,(canonicalize-direct-slots direct-slots)
599                 ,@(canonicalize-defclass-options options)))
600
601;;; Generic function metaobjects and standard-generic-function
602
603(defun method-combination-type (method-combination)
604  (if (atom method-combination)
605      method-combination
606      (car method-combination)))
607
608(defun method-combination-options (method-combination)
609  (if (atom method-combination)
610      nil
611      (cdr method-combination)))
612
613(defclass standard-generic-function (generic-function)
614  ((name :initarg :name)      ; :accessor generic-function-name
615   (lambda-list               ; :accessor generic-function-lambda-list
616    :initarg :lambda-list)
617   (methods :initform ())     ; :accessor generic-function-methods
618   (method-class              ; :accessor generic-function-method-class
619    :initarg :method-class)
620   (method-combination
621    :initarg :method-combination)
622   (classes-to-emf-table      ; :accessor classes-to-emf-table
623    :initform (make-hash-table :test #'equal))
624   (required-args :initform ())))
625
626(defvar the-class-standard-gf (find-class 'standard-generic-function))
627
628(defvar *sgf-required-args-index*
629  (slot-location the-class-standard-gf 'required-args))
630
631(defvar *sgf-classes-to-emf-table-index*
632  (slot-location the-class-standard-gf 'classes-to-emf-table))
633
634(defun generic-function-name (gf)
635  (slot-value gf 'name))
636(defun (setf generic-function-name) (new-value gf)
637  (setf (slot-value gf 'name) new-value))
638
639(defun generic-function-lambda-list (gf)
640  (slot-value gf 'lambda-list))
641(defun (setf generic-function-lambda-list) (new-value gf)
642  (setf (slot-value gf 'lambda-list) new-value))
643
644(defun generic-function-methods (gf)
645  (slot-value gf 'methods))
646(defun (setf generic-function-methods) (new-value gf)
647  (setf (slot-value gf 'methods) new-value))
648
649(defsetf generic-function-discriminating-function
650  %set-generic-function-discriminating-function)
651
652(defun generic-function-method-class (gf)
653  (slot-value gf 'method-class))
654(defun (setf generic-function-method-class) (new-value gf)
655  (setf (slot-value gf 'method-class) new-value))
656
657(defun generic-function-method-combination (gf)
658  (slot-value gf 'method-combination))
659(defun (setf generic-function-method-combination) (new-value gf)
660  (setf (slot-value gf 'method-combination) new-value))
661
662;;; Internal accessor for effective method function table
663
664(defun classes-to-emf-table (gf)
665  (instance-ref gf *sgf-classes-to-emf-table-index*))
666
667(defun (setf classes-to-emf-table) (new-value gf)
668  (setf (slot-value gf 'classes-to-emf-table) new-value))
669
670;;; Method metaobjects and standard-method
671
672(defclass standard-method (method)
673  ((lambda-list :initarg :lambda-list)     ; :accessor method-lambda-list
674   (qualifiers :initarg :qualifiers)       ; :accessor method-qualifiers
675   (specializers :initarg :specializers)   ; :accessor method-specializers
676   (body :initarg :body)                   ; :accessor method-body
677   (environment :initarg :environment)     ; :accessor method-environment
678   (generic-function :initform nil)        ; :accessor method-generic-function
679   (function)))                            ; :accessor method-function
680
681(defvar the-class-standard-method (find-class 'standard-method))
682
683(defvar *sm-function-index*
684  (slot-location the-class-standard-method 'function))
685
686(defun method-lambda-list (method) (slot-value method 'lambda-list))
687(defun (setf method-lambda-list) (new-value method)
688  (setf (slot-value method 'lambda-list) new-value))
689
690(defun method-qualifiers (method) (slot-value method 'qualifiers))
691(defun (setf method-qualifiers) (new-value method)
692  (setf (slot-value method 'qualifiers) new-value))
693
694(defun method-specializers (method) (slot-value method 'specializers))
695(defun (setf method-specializers) (new-value method)
696  (setf (slot-value method 'specializers) new-value))
697
698(defun method-body (method) (slot-value method 'body))
699(defun (setf method-body) (new-value method)
700  (setf (slot-value method 'body) new-value))
701
702(defun method-environment (method) (slot-value method 'environment))
703(defun (setf method-environment) (new-value method)
704  (setf (slot-value method 'environment) new-value))
705
706(defun method-generic-function (method)
707  (slot-value method 'generic-function))
708(defun (setf method-generic-function) (new-value method)
709  (setf (slot-value method 'generic-function) new-value))
710
711(defun method-function (method)
712  (instance-ref method *sm-function-index*))
713
714(defun (setf method-function) (new-value method)
715  (setf (slot-value method 'function) new-value))
716
717;;; defgeneric
718
719(defmacro defgeneric (function-name lambda-list
720                                    &rest options-and-method-descriptions)
721  (let ((options ())
722        (methods ()))
723    (dolist (item options-and-method-descriptions)
724      (case (car item)
725        (declare) ; FIXME
726        (:documentation) ; FIXME
727        (:method
728         (push `(defmethod ,function-name ,@(cdr item)) methods))
729        (t
730         (push item options))))
731    (setf options (nreverse options)
732          methods (nreverse methods))
733    `(prog1
734       (ensure-generic-function
735        ',function-name
736        :lambda-list ',lambda-list
737        ,@(canonicalize-defgeneric-options options))
738       ,@methods)))
739
740(defun canonicalize-defgeneric-options (options)
741  (mapappend #'canonicalize-defgeneric-option options))
742
743(defun canonicalize-defgeneric-option (option)
744  (case (car option)
745    (:generic-function-class
746     (list ':generic-function-class `(find-class ',(cadr option))))
747    (:method-class
748     (list ':method-class `(find-class ',(cadr option))))
749    (:method-combination
750     (list `',(car option) `',(cdr option)))
751    (t
752     (list `',(car option) `',(cadr option)))))
753
754(defparameter generic-function-table (make-hash-table :test #'equal))
755
756(defun find-generic-function (symbol &optional (errorp t))
757  (let ((gf (gethash symbol generic-function-table nil)))
758    (if (and (null gf) errorp)
759        (error "no generic function named ~S" symbol)
760        gf)))
761
762(defun (setf find-generic-function) (new-value symbol)
763  (setf (gethash symbol generic-function-table) new-value))
764
765;;; ensure-generic-function
766
767(defun ensure-generic-function (function-name
768                                &rest all-keys
769                                &key
770                                (generic-function-class the-class-standard-gf)
771                                (method-class the-class-standard-method)
772                                (method-combination 'standard)
773                                &allow-other-keys)
774  (when (autoloadp function-name)
775    (resolve function-name))
776  (if (find-generic-function function-name nil)
777      (find-generic-function function-name)
778      (progn
779        (when (fboundp function-name)
780          (error 'program-error
781                 :format-control "~A already names an ordinary function, macro, or special operator."
782                 :format-args (list function-name)))
783        (let ((gf (apply (if (eq generic-function-class the-class-standard-gf)
784                             #'make-instance-standard-generic-function
785                             #'make-instance)
786                         generic-function-class
787                         :name function-name
788                         :method-class method-class
789                         :method-combination method-combination
790                         all-keys)))
791          (setf (find-generic-function function-name) gf)
792          gf))))
793
794;;; finalize-generic-function
795
796(defun finalize-generic-function (gf)
797  (setf (generic-function-discriminating-function gf)
798        (funcall (if (eq (class-of gf) the-class-standard-gf)
799                     #'std-compute-discriminating-function
800                     #'compute-discriminating-function)
801                 gf))
802  (setf (fdefinition (generic-function-name gf)) gf)
803  (clrhash (classes-to-emf-table gf))
804  (values))
805
806(defun gf-required-args (gf)
807  (instance-ref gf *sgf-required-args-index*))
808
809(defun make-instance-standard-generic-function (generic-function-class
810                                                &key name lambda-list
811                                                method-class
812                                                method-combination)
813  (declare (ignore generic-function-class))
814  (let ((gf (std-allocate-instance the-class-standard-gf)))
815    (setf (generic-function-name gf) name)
816    (setf (generic-function-lambda-list gf) lambda-list)
817    (setf (generic-function-methods gf) ())
818    (setf (generic-function-method-class gf) method-class)
819    (setf (generic-function-method-combination gf) method-combination)
820    (setf (classes-to-emf-table gf) (make-hash-table :test #'equal))
821    (setf (slot-value gf 'required-args)
822          (let ((plist (analyze-lambda-list (generic-function-lambda-list gf))))
823            (getf plist ':required-args)))
824    (finalize-generic-function gf)
825    gf))
826
827;;; Run-time environment hacking (Common Lisp ain't got 'em).
828
829(defun top-level-environment ()
830  nil) ; Bogus top level lexical environment
831
832(defvar compile-methods nil)      ; by default, run everything interpreted
833
834(defun compile-in-lexical-environment (env lambda-expr)
835  (declare (ignore env))
836  (if compile-methods
837      (compile nil lambda-expr)
838      (eval `(function ,lambda-expr))))
839
840;;; defmethod
841
842(defmacro defmethod (&rest args)
843  (multiple-value-bind (function-name qualifiers lambda-list specializers body)
844    (parse-defmethod args)
845    `(progn
846      (ensure-generic-function
847       ',function-name
848       :lambda-list ',lambda-list)
849      (ensure-method (find-generic-function ',function-name)
850                     :lambda-list ',lambda-list
851                     :qualifiers ',qualifiers
852                     :specializers ,(canonicalize-specializers specializers)
853                     :body ',body
854                     :environment (top-level-environment)))))
855
856(defun canonicalize-specializers (specializers)
857  `(list ,@(mapcar #'canonicalize-specializer specializers)))
858
859(defun canonicalize-specializer (specializer)
860  ;; FIXME (EQL specializers)
861  `(if (atom ',specializer) (find-class ',specializer) (find-class 't)))
862
863(defun parse-defmethod (args)
864  (let ((fn-spec (car args))
865        (qualifiers ())
866        (specialized-lambda-list nil)
867        (body ())
868        (parse-state :qualifiers))
869    (dolist (arg (cdr args))
870      (ecase parse-state
871        (:qualifiers
872         (if (and (atom arg) (not (null arg)))
873             (push-on-end arg qualifiers)
874             (progn (setq specialized-lambda-list arg)
875               (setq parse-state :body))))
876        (:body (push-on-end arg body))))
877    (values fn-spec
878            qualifiers
879            (extract-lambda-list specialized-lambda-list)
880            (extract-specializers specialized-lambda-list)
881            (list* 'block
882                   (if (consp fn-spec)
883                       (cadr fn-spec)
884                       fn-spec)
885                   body))))
886
887;;; Several tedious functions for analyzing lambda lists
888
889(defun required-portion (gf args)
890  (let ((number-required (length (gf-required-args gf))))
891    (when (< (length args) number-required)
892      (error 'program-error "not enough arguments for generic function ~S" gf))
893    (subseq args 0 number-required)))
894
895(defun extract-lambda-list (specialized-lambda-list)
896  (let* ((plist (analyze-lambda-list specialized-lambda-list))
897         (requireds (getf plist :required-names))
898         (rv (getf plist :rest-var))
899         (ks (getf plist :key-args))
900         (keysp (getf plist :keysp))
901         (aok (getf plist :allow-other-keys))
902         (opts (getf plist :optional-args))
903         (auxs (getf plist :auxiliary-args)))
904    `(,@requireds
905      ,@(if rv `(&rest ,rv) ())
906      ,@(if (or ks keysp aok) `(&key ,@ks) ())
907      ,@(if aok '(&allow-other-keys) ())
908      ,@(if opts `(&optional ,@opts) ())
909      ,@(if auxs `(&aux ,@auxs) ()))))
910
911(defun extract-specializers (specialized-lambda-list)
912  (let ((plist (analyze-lambda-list specialized-lambda-list)))
913    (getf plist ':specializers)))
914
915(defun analyze-lambda-list (lambda-list)
916  (labels ((make-keyword (symbol)
917                         (intern (symbol-name symbol)
918                                 (find-package 'keyword)))
919           (get-keyword-from-arg (arg)
920                                 (if (listp arg)
921                                     (if (listp (car arg))
922                                         (caar arg)
923                                         (make-keyword (car arg)))
924                                     (make-keyword arg))))
925          (let ((keys ())           ; Just the keywords
926                (key-args ())       ; Keywords argument specs
927                (keysp nil)         ;
928                (required-names ()) ; Just the variable names
929                (required-args ())  ; Variable names & specializers
930                (specializers ())   ; Just the specializers
931                (rest-var nil)
932                (optionals ())
933                (auxs ())
934                (allow-other-keys nil)
935                (state :parsing-required))
936            (dolist (arg lambda-list)
937              (if (member arg lambda-list-keywords)
938                  (ecase arg
939                    (&optional
940                     (setq state :parsing-optional))
941                    (&rest
942                     (setq state :parsing-rest))
943                    (&key
944                     (setq keysp t)
945                     (setq state :parsing-key))
946                    (&allow-other-keys
947                     (setq allow-other-keys 't))
948                    (&aux
949                     (setq state :parsing-aux)))
950                  (case state
951                    (:parsing-required
952                     (push-on-end arg required-args)
953                     (if (listp arg)
954                         (progn (push-on-end (car arg) required-names)
955                           (push-on-end (cadr arg) specializers))
956                         (progn (push-on-end arg required-names)
957                           (push-on-end 't specializers))))
958                    (:parsing-optional (push-on-end arg optionals))
959                    (:parsing-rest (setq rest-var arg))
960                    (:parsing-key
961                     (push-on-end (get-keyword-from-arg arg) keys)
962                     (push-on-end arg key-args))
963                    (:parsing-aux (push-on-end arg auxs)))))
964            (list  :required-names required-names
965                   :required-args required-args
966                   :specializers specializers
967                   :rest-var rest-var
968                   :keywords keys
969                   :key-args key-args
970                   :keysp keysp
971                   :auxiliary-args auxs
972                   :optional-args optionals
973                   :allow-other-keys allow-other-keys))))
974
975;;; ensure method
976
977#+nil
978(defun check-method-arg-info (gf arg-info method)
979  (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p keywords)
980    (analyze-lambda-list (if (consp method)
981                             (early-method-lambda-list method)
982                             (method-lambda-list method)))
983    (flet ((lose (string &rest args)
984                 (error 'simple-program-error
985                        :format-control "~@<attempt to add the method~2I~_~S~I~_~
986                        to the generic function~2I~_~S;~I~_~
987                        but ~?~:>"
988                        :format-arguments (list method gf string args)))
989     (comparison-description (x y)
990                                   (if (> x y) "more" "fewer")))
991      (let ((gf-nreq (arg-info-number-required arg-info))
992      (gf-nopt (arg-info-number-optional arg-info))
993      (gf-key/rest-p (arg-info-key/rest-p arg-info))
994      (gf-keywords (arg-info-keys arg-info)))
995  (unless (= nreq gf-nreq)
996    (lose
997     "the method has ~A required arguments than the generic function."
998     (comparison-description nreq gf-nreq)))
999  (unless (= nopt gf-nopt)
1000    (lose
1001     "the method has ~A optional arguments than the generic function."
1002     (comparison-description nopt gf-nopt)))
1003  (unless (eq (or keysp restp) gf-key/rest-p)
1004    (lose
1005     "the method and generic function differ in whether they accept~_~
1006      &REST or &KEY arguments."))
1007  (when (consp gf-keywords)
1008    (unless (or (and restp (not keysp))
1009          allow-other-keys-p
1010          (every (lambda (k) (memq k keywords)) gf-keywords))
1011      (lose "the method does not accept each of the &KEY arguments~2I~_~
1012            ~S."
1013      gf-keywords)))))))
1014
1015(defun ensure-method (gf &rest all-keys)
1016  (let* ((gf-lambda-list (generic-function-lambda-list gf))
1017         (gf-restp (not (null (memq '&rest gf-lambda-list))))
1018         (gf-plist (analyze-lambda-list gf-lambda-list))
1019         (gf-keysp (getf gf-plist :keysp))
1020         (gf-keywords (getf gf-plist :keywords))
1021         (method-lambda-list (getf all-keys :lambda-list))
1022         (method-plist (analyze-lambda-list method-lambda-list))
1023         (method-restp (not (null (memq '&rest method-lambda-list))))
1024         (method-keysp (getf method-plist :keysp))
1025         (method-keywords (getf method-plist :keywords))
1026         (method-allow-other-keys-p (getf method-plist :allow-other-keys)))
1027    (unless (= (length (getf gf-plist :required-args))
1028               (length (getf method-plist :required-args)))
1029      (error "The method has the wrong number of required arguments for the generic function."))
1030    (unless (= (length (getf gf-plist :optional-args))
1031               (length (getf method-plist :optional-args)))
1032      (error "The method has the wrong number of optional arguments for the generic function."))
1033    (unless (eq (or gf-restp gf-keysp) (or method-restp method-keysp))
1034      (format t "gf-restp = ~S~% gf-keysp = ~S~% method-restp = ~S~% method-keysp = ~S~%"
1035              gf-restp gf-keysp method-restp method-keysp)
1036      (error "The method and the generic function differ in whether they accept &REST or &KEY arguments."))
1037    (when (consp gf-keywords)
1038      (unless (or (and method-restp (not method-keysp))
1039                  method-allow-other-keys-p
1040                  (every (lambda (k) (memq k method-keywords)) gf-keywords))
1041        (error "The method does not accept all of the keyword arguments defined for the generic function."))))
1042  (let ((new-method
1043         (apply
1044          (if (eq (generic-function-method-class gf) the-class-standard-method)
1045              #'make-instance-standard-method
1046              #'make-instance)
1047          (generic-function-method-class gf)
1048          all-keys)))
1049    (add-method gf new-method)
1050    new-method))
1051
1052(defun make-instance-standard-method (method-class
1053                                      &key lambda-list qualifiers
1054                                      specializers body environment)
1055  (declare (ignore method-class))
1056  (let ((method (std-allocate-instance the-class-standard-method)))
1057    (setf (method-lambda-list method) lambda-list)
1058    (setf (method-qualifiers method) qualifiers)
1059    (setf (method-specializers method) specializers)
1060    (setf (method-body method) (precompile-form body nil))
1061    (setf (method-environment method) environment)
1062    (setf (method-generic-function method) nil)
1063    (setf (method-function method)
1064          (std-compute-method-function method))
1065    method))
1066
1067(defun check-congruent (gf method)
1068  (let* ((plist1 (analyze-lambda-list (generic-function-lambda-list gf)))
1069         (args1 (getf plist1 :required-args))
1070         (plist2 (analyze-lambda-list (method-lambda-list method)))
1071         (args2 (getf plist2 :required-args)))
1072    (unless (= (length args1) (length args2))
1073      (error "lambda lists are not congruent"))))
1074
1075(defun add-method (gf method)
1076  (check-congruent gf method)
1077  ;; Remove existing method with same qualifiers and specializers (if any).
1078  (let ((old-method (find-method gf (method-qualifiers method)
1079                                 (method-specializers method) nil)))
1080    (when old-method
1081      (remove-method gf old-method)))
1082  (setf (method-generic-function method) gf)
1083  (push method (generic-function-methods gf))
1084  (dolist (specializer (method-specializers method))
1085    (pushnew method (class-direct-methods specializer)))
1086  (finalize-generic-function gf)
1087  gf)
1088
1089(defun remove-method (gf method)
1090  (setf (generic-function-methods gf)
1091        (remove method (generic-function-methods gf)))
1092  (setf (method-generic-function method) nil)
1093;;   (format t "remove-method method-specializers = ~S~%" (method-specializers method))
1094  (dolist (class (method-specializers method))
1095    (setf (class-direct-methods class)
1096          (remove method (class-direct-methods class))))
1097  (finalize-generic-function gf)
1098  gf)
1099
1100(defun find-method (gf qualifiers specializers &optional (errorp t))
1101  (let ((method
1102         (find-if #'(lambda (method)
1103                     (and (equal qualifiers
1104                                 (method-qualifiers method))
1105                          (equal specializers
1106                                 (method-specializers method))))
1107                  (generic-function-methods gf))))
1108    (if (and (null method) errorp)
1109        (error "no such method for ~S" (generic-function-name gf))
1110        method)))
1111
1112;;; Reader and writer methods
1113
1114(defun add-reader-method (class fn-name slot-name)
1115  (ensure-method
1116   (ensure-generic-function fn-name :lambda-list '(object))
1117   :lambda-list '(object)
1118   :qualifiers ()
1119   :specializers (list class)
1120   :body `(slot-value object ',slot-name)
1121   :environment (top-level-environment))
1122  (values))
1123
1124(defun add-writer-method (class fn-name slot-name)
1125  (ensure-method
1126   (ensure-generic-function
1127    fn-name :lambda-list '(new-value object))
1128   :lambda-list '(new-value object)
1129   :qualifiers ()
1130   :specializers (list (find-class 't) class)
1131   :body `(setf (slot-value object ',slot-name)
1132                new-value)
1133   :environment (top-level-environment))
1134  (values))
1135
1136(defun subclassp (c1 c2)
1137  (not (null (find c2 (class-precedence-list c1)))))
1138
1139;;;
1140;;; Generic function invocation
1141;;;
1142
1143;;; apply-generic-function
1144
1145(defun apply-generic-function (gf args)
1146  (apply (generic-function-discriminating-function gf) args))
1147
1148;;; compute-discriminating-function
1149
1150(defun std-compute-discriminating-function (gf)
1151  #'(lambda (&rest args)
1152     (let* ((classes (mapcar #'class-of
1153                             (required-portion gf args)))
1154            (emfun (gethash classes (classes-to-emf-table gf) nil)))
1155       (if emfun
1156           (funcall emfun args)
1157           (slow-method-lookup gf args classes)))))
1158
1159(defun slow-method-lookup (gf args classes)
1160  (let ((applicable-methods
1161         (compute-applicable-methods-using-classes gf classes)))
1162    (if applicable-methods
1163        (let ((emfun
1164               (funcall
1165                (if (eq (class-of gf) the-class-standard-gf)
1166                    #'std-compute-effective-method-function
1167                  #'compute-effective-method-function)
1168                gf applicable-methods)))
1169          (setf (gethash classes (classes-to-emf-table gf)) emfun)
1170          (funcall emfun args))
1171        (error "no applicable methods for generic function ~S with arguments ~S of classes ~S" gf args classes))))
1172
1173(defun compute-applicable-methods-using-classes (gf required-classes)
1174  (sort
1175   (copy-list
1176    (remove-if-not #'(lambda (method)
1177                      (every #'subclassp
1178                             required-classes
1179                             (method-specializers method)))
1180                   (generic-function-methods gf)))
1181   (if (eq (class-of gf) the-class-standard-gf)
1182       #'(lambda (m1 m2)
1183          (std-method-more-specific-p m1 m2 required-classes))
1184       #'(lambda (m1 m2)
1185          (method-more-specific-p gf m1 m2 required-classes)))))
1186
1187(defun sub-specializer-p (c1 c2 c-arg)
1188  (find c2 (cdr (memq c1 (class-precedence-list c-arg)))))
1189
1190(defun std-method-more-specific-p (method1 method2 required-classes)
1191  (mapc #'(lambda (spec1 spec2 arg-class)
1192           (unless (eq spec1 spec2)
1193             (return-from std-method-more-specific-p
1194                          (sub-specializer-p spec1 spec2 arg-class))))
1195        (method-specializers method1)
1196        (method-specializers method2)
1197        required-classes)
1198  nil)
1199
1200;;; apply-methods and compute-effective-method-function
1201
1202(defun apply-methods (gf args methods)
1203  (funcall (compute-effective-method-function gf methods)
1204           args))
1205
1206(defun primary-method-p (method)
1207  (null (intersection '(:before :after :around) (method-qualifiers method))))
1208
1209(defun before-method-p (method)
1210  (equal '(:before) (method-qualifiers method)))
1211
1212(defun after-method-p (method)
1213  (equal '(:after) (method-qualifiers method)))
1214
1215(defun around-method-p (method)
1216  (equal '(:around) (method-qualifiers method)))
1217
1218(defun std-compute-effective-method-function (gf methods)
1219  (let* ((mc (generic-function-method-combination gf))
1220         (type (method-combination-type mc))
1221         (options (method-combination-options mc))
1222         (order (car options))
1223         (primaries ())
1224         (arounds ())
1225         around)
1226    (dolist (m methods)
1227      (let ((qualifiers (method-qualifiers m)))
1228        (cond ((null qualifiers)
1229               (if (eq type 'standard)
1230                   (push m primaries)
1231                   (error "method combination type mismatch")))
1232              ((cdr qualifiers)
1233               (error "invalid method qualifiers"))
1234              ((eq (car qualifiers) :around)
1235               (push m arounds))
1236              ((eq (car qualifiers) type)
1237               (push m primaries))
1238              ((memq (car qualifiers) '(:before :after)))
1239              (t
1240               (error "invalid method qualifiers")))))
1241    (unless (eq order :most-specific-last)
1242      (setq primaries (nreverse primaries)))
1243    (setq arounds (nreverse arounds))
1244    (setq around (car arounds))
1245    (when (null primaries)
1246      (error "No primary methods for the generic function ~S." gf))
1247    (if around
1248        (let ((next-emfun
1249               (funcall
1250                (if (eq (class-of gf) the-class-standard-gf)
1251                    #'std-compute-effective-method-function
1252                    #'compute-effective-method-function)
1253                gf (remove around methods))))
1254          #'(lambda (args)
1255             (funcall (method-function around) args next-emfun)))
1256        (case type
1257          (STANDARD
1258           (let ((next-emfun (compute-primary-emfun (cdr primaries)))
1259                 (befores (remove-if-not #'before-method-p methods))
1260                 (reverse-afters
1261                  (reverse (remove-if-not #'after-method-p methods))))
1262             #'(lambda (args)
1263                (dolist (before befores)
1264                  (funcall (method-function before) args nil))
1265                (multiple-value-prog1
1266                 (funcall (method-function (car primaries)) args next-emfun)
1267                 (dolist (after reverse-afters)
1268                   (funcall (method-function after) args nil))))))
1269          (LIST
1270           #'(lambda (args)
1271              (let ((result ()))
1272                (dolist (primary primaries)
1273                  (push (funcall (method-function primary) args nil) result))
1274                (nreverse result))))
1275          (APPEND
1276           #'(lambda (args)
1277              (let ((result ()))
1278                (dolist (primary primaries)
1279                  (setf result (append result (funcall (method-function primary) args nil))))
1280                result)))
1281          (NCONC
1282           #'(lambda (args)
1283              (let ((result ()))
1284                (dolist (primary primaries)
1285                  (setf result (nconc result (funcall (method-function primary) args nil))))
1286                result)))
1287          (PROGN
1288           #'(lambda (args)
1289              (let ((result nil))
1290                (dolist (primary primaries)
1291                  (setf result (funcall (method-function primary) args nil)))
1292                result)))
1293          (AND
1294           #'(lambda (args)
1295              (let ((result t))
1296                (dolist (primary primaries)
1297                  (setf result
1298                        (and result
1299                             (funcall (method-function primary) args nil)))
1300                  (unless result (return)))
1301                result)))
1302          (OR
1303           #'(lambda (args)
1304              (let ((result nil))
1305                (dolist (primary primaries)
1306                  (setf result
1307                        (or result
1308                            (funcall (method-function primary) args nil)))
1309                  (when result (return)))
1310                result)))
1311          (+
1312           #'(lambda (args)
1313              (let ((result 0))
1314                (dolist (primary primaries)
1315                  (incf result (funcall (method-function primary) args nil)))
1316                result)))
1317          (MAX
1318           #'(lambda (args)
1319              (let ((result ()))
1320                (dolist (primary primaries)
1321                  (push (funcall (method-function primary) args nil) result))
1322                (apply #'max result))))
1323          (MIN
1324           #'(lambda (args)
1325              (let ((result ()))
1326                (dolist (primary primaries)
1327                  (push (funcall (method-function primary) args nil) result))
1328                (apply #'min result))))
1329          (t
1330           (error "unsupported method combination type ~S" type))))))
1331
1332;;; compute an effective method function from a list of primary methods:
1333
1334(defun compute-primary-emfun (methods)
1335  (if (null methods)
1336      nil
1337      (let ((next-emfun (compute-primary-emfun (cdr methods))))
1338        #'(lambda (args)
1339           (funcall (method-function (car methods)) args next-emfun)))))
1340
1341;;; apply-method and compute-method-function
1342
1343(defun apply-method (method args next-methods)
1344  (funcall (method-function method)
1345           args
1346           (if (null next-methods)
1347               nil
1348               (compute-effective-method-function
1349                (method-generic-function method) next-methods))))
1350
1351(defun std-compute-method-function (method)
1352  (let ((form (method-body method))
1353        (lambda-list (method-lambda-list method)))
1354    (compile-in-lexical-environment
1355     (method-environment method)
1356     `(lambda (args next-emfun)
1357        (flet ((call-next-method (&rest cnm-args)
1358                                 (if (null next-emfun)
1359                                     (error "no next method for generic function ~S"
1360                                            (method-generic-function ',method))
1361                                     (funcall next-emfun (or cnm-args args))))
1362               (next-method-p ()
1363                              (not (null next-emfun))))
1364          (apply #'(lambda ,(kludge-arglist lambda-list)
1365                    ,form)
1366                 args))))))
1367
1368;;; N.B. The function kludge-arglist is used to pave over the differences
1369;;; between argument keyword compatibility for regular functions versus
1370;;; generic functions.
1371
1372(defun kludge-arglist (lambda-list)
1373  (if (and (member '&key lambda-list)
1374           (not (member '&allow-other-keys lambda-list)))
1375      (append lambda-list '(&allow-other-keys))
1376      (if (and (not (member '&rest lambda-list))
1377               (not (member '&key lambda-list)))
1378          (append lambda-list '(&key &allow-other-keys))
1379          lambda-list)))
1380
1381;;; Slot access
1382
1383(defun setf-slot-value-using-class (new-value class instance slot-name)
1384  (setf (std-slot-value instance slot-name) new-value))
1385
1386(defgeneric slot-value-using-class (class instance slot-name))
1387
1388(defmethod slot-value-using-class ((class standard-class) instance slot-name)
1389  (std-slot-value instance slot-name))
1390
1391(defgeneric (setf slot-value-using-class) (new-value class instance slot-name))
1392(defmethod (setf slot-value-using-class)
1393  (new-value (class standard-class) instance slot-name)
1394  (setf (std-slot-value instance slot-name) new-value))
1395
1396(defgeneric slot-exists-p-using-class (class instance slot-name))
1397
1398(defmethod slot-exists-p-using-class (class instance slot-name)
1399  nil)
1400
1401(defmethod slot-exists-p-using-class ((class standard-class) instance slot-name)
1402  (std-slot-exists-p instance slot-name))
1403
1404(defmethod slot-exists-p-using-class ((class structure-class) instance slot-name)
1405  (dolist (dsd (class-slots class))
1406    (when (eq (dsd-name dsd) slot-name)
1407      (return-from slot-exists-p-using-class t)))
1408  nil)
1409
1410(defgeneric slot-boundp-using-class (class instance slot-name))
1411(defmethod slot-boundp-using-class
1412  ((class standard-class) instance slot-name)
1413  (std-slot-boundp instance slot-name))
1414
1415(defgeneric slot-makunbound-using-class (class instance slot-name))
1416(defmethod slot-makunbound-using-class
1417  ((class standard-class) instance slot-name)
1418  (std-slot-makunbound instance slot-name))
1419
1420(defgeneric slot-missing (class instance slot-name operation &optional new-value))
1421(defmethod slot-missing ((class t) instance slot-name operation &optional new-value)
1422  (error "the slot ~S is missing from the class ~S" slot-name class))
1423
1424;;; Instance creation and initialization
1425
1426(defgeneric allocate-instance (class &rest initargs &key &allow-other-keys))
1427
1428(defmethod allocate-instance ((class standard-class) &rest initargs)
1429  (std-allocate-instance class))
1430
1431(defmethod allocate-instance ((class structure-class) &rest initargs)
1432  (%make-structure (class-name class)
1433                   (make-list (length (class-slots class))
1434                              :initial-element +slot-unbound+)))
1435
1436(defgeneric make-instance (class &key))
1437
1438(defmethod make-instance ((class standard-class) &rest initargs)
1439  (let ((class-default-initargs (class-default-initargs class)))
1440    (when class-default-initargs
1441      (let ((default-initargs ())
1442            (not-found (gensym)))
1443        (do* ((list class-default-initargs (cddr list))
1444              (key (car list) (car list))
1445              (fn (cadr list) (cadr list)))
1446             ((null list))
1447          (when (eq (getf initargs key not-found) not-found)
1448            (setf default-initargs (append default-initargs (list key (funcall fn))))))
1449        (setf initargs (append initargs default-initargs)))))
1450  (let ((instance (std-allocate-instance class)))
1451    (apply #'initialize-instance instance initargs)
1452    instance))
1453
1454(defmethod make-instance ((class symbol) &rest initargs)
1455  (apply #'make-instance (find-class class) initargs))
1456
1457(defgeneric initialize-instance (instance &key))
1458
1459(defmethod initialize-instance ((instance standard-object) &rest initargs)
1460  (apply #'shared-initialize instance t initargs))
1461
1462(defgeneric reinitialize-instance (instance &key))
1463
1464(defmethod reinitialize-instance
1465  ((instance standard-object) &rest initargs)
1466  (apply #'shared-initialize instance () initargs))
1467
1468(defun std-shared-initialize (instance slot-names all-keys)
1469  (dolist (slot (class-slots (class-of instance)))
1470    (let ((slot-name (slot-definition-name slot)))
1471      (multiple-value-bind (init-key init-value foundp)
1472        (get-properties all-keys (slot-definition-initargs slot))
1473        (if foundp
1474            (setf (std-slot-value instance slot-name) init-value)
1475            (when (and (not (std-slot-boundp instance slot-name))
1476                       (slot-definition-initfunction slot)
1477                       (or (eq slot-names t)
1478                           (member slot-name slot-names)))
1479              (setf (std-slot-value instance slot-name)
1480                    (funcall (slot-definition-initfunction slot))))))))
1481  instance)
1482
1483(defgeneric shared-initialize (instance slot-names &key))
1484
1485(defmethod shared-initialize ((instance standard-object)
1486                              slot-names &rest all-keys)
1487  (std-shared-initialize instance slot-names all-keys))
1488
1489;;; change-class
1490
1491(defgeneric change-class (instance new-class &key))
1492
1493(defmethod change-class ((old-instance standard-object) (new-class standard-class)
1494                         &rest initargs)
1495  (let ((new-instance (allocate-instance new-class)))
1496    (dolist (slot-name (mapcar #'slot-definition-name
1497                               (class-slots new-class)))
1498      (when (and (slot-exists-p old-instance slot-name)
1499                 (slot-boundp old-instance slot-name))
1500        (setf (slot-value new-instance slot-name)
1501              (slot-value old-instance slot-name))))
1502    (rotatef (std-instance-slots new-instance)
1503             (std-instance-slots old-instance))
1504    (rotatef (std-instance-layout new-instance)
1505             (std-instance-layout old-instance))
1506    (apply #'update-instance-for-different-class
1507           new-instance old-instance initargs)
1508    old-instance))
1509
1510(defmethod change-class ((instance standard-object) (new-class symbol) &rest initargs)
1511  (apply #'change-class instance (find-class new-class) initargs))
1512
1513(defgeneric update-instance-for-different-class (old new &key))
1514
1515(defmethod update-instance-for-different-class
1516  ((old standard-object) (new standard-object) &rest initargs)
1517  (let ((added-slots
1518         (remove-if #'(lambda (slot-name)
1519                       (slot-exists-p old slot-name))
1520                    (mapcar #'slot-definition-name
1521                            (class-slots (class-of new))))))
1522    (apply #'shared-initialize new added-slots initargs)))
1523
1524;;;  Methods having to do with class metaobjects.
1525
1526(defmethod initialize-instance :after ((class standard-class) &rest args)
1527  (apply #'std-after-initialization-for-classes class args))
1528
1529;;; Finalize inheritance
1530
1531(defgeneric finalize-inheritance (class))
1532
1533(defmethod finalize-inheritance ((class standard-class))
1534  (std-finalize-inheritance class))
1535
1536;;; Class precedence lists
1537
1538(defgeneric compute-class-precedence-list (class))
1539(defmethod compute-class-precedence-list ((class standard-class))
1540  (std-compute-class-precedence-list class))
1541
1542;;; Slot inheritance
1543
1544(defgeneric compute-slots (class))
1545(defmethod compute-slots ((class standard-class))
1546  (std-compute-slots class))
1547
1548(defgeneric compute-effective-slot-definition (class direct-slots))
1549(defmethod compute-effective-slot-definition
1550  ((class standard-class) direct-slots)
1551  (std-compute-effective-slot-definition class direct-slots))
1552
1553;;; Methods having to do with generic function metaobjects.
1554
1555(defmethod initialize-instance :after ((gf standard-generic-function) &key)
1556  (finalize-generic-function gf))
1557
1558;;; Methods having to do with method metaobjects.
1559
1560(defmethod initialize-instance :after ((method standard-method) &key)
1561  (setf (method-function method) (compute-method-function method)))
1562
1563;;; Methods having to do with generic function invocation.
1564
1565(defgeneric compute-discriminating-function (gf))
1566(defmethod compute-discriminating-function ((gf standard-generic-function))
1567  (std-compute-discriminating-function gf))
1568
1569(defgeneric method-more-specific-p (gf method1 method2 required-classes))
1570
1571(defmethod method-more-specific-p ((gf standard-generic-function)
1572                                   method1 method2 required-classes)
1573  (std-method-more-specific-p method1 method2 required-classes))
1574
1575(defgeneric compute-effective-method-function (gf methods))
1576(defmethod compute-effective-method-function ((gf standard-generic-function) methods)
1577  (std-compute-effective-method-function gf methods))
1578
1579(defgeneric compute-method-function (method))
1580(defmethod compute-method-function ((method standard-method))
1581  (std-compute-method-function method))
1582
1583(defgeneric compute-applicable-methods (gf args))
1584(defmethod compute-applicable-methods ((gf standard-generic-function) args)
1585  (compute-applicable-methods-using-classes gf (mapcar #'class-of args)))
1586
1587;;; Conditions.
1588
1589(defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
1590         &body options)
1591  (let ((parent-types (or parent-types '(condition)))
1592        (report nil))
1593    (dolist (option options)
1594      (when (eq (car option) :report)
1595        (let ((arg (cadr option)))
1596          (setf report
1597                (if (stringp arg)
1598                    `#'(lambda (condition stream)
1599                        (declare (ignore condition))
1600                        (write-string ,arg stream))
1601                    `#'(lambda (condition stream)
1602                        (funcall #',arg condition stream)))))))
1603    `(progn
1604       (defclass ,name ,parent-types ,slot-specs ,@options)
1605       (defmethod print-object ((condition ,name) stream)
1606         (if *print-escape*
1607             (call-next-method)
1608             (funcall ,report condition stream)))
1609       ',name)))
1610
1611(defun make-condition (type &rest initargs)
1612  (or (%make-condition type initargs)
1613      (apply #'make-instance (find-class type) initargs)))
1614
1615(provide 'clos)
Note: See TracBrowser for help on using the repository browser.