source: trunk/j/src/org/armedbear/lisp/defstruct.lisp @ 4820

Last change on this file since 4820 was 4820, checked in by piso, 18 years ago

Work in progress.

File size: 6.6 KB
Line 
1;;; defstruct.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: defstruct.lisp,v 1.30 2003-11-18 01:23:16 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20(in-package "SYSTEM")
21
22(defvar *ds-name*)
23(defvar *ds-conc-name*)
24(defvar *ds-constructors*)
25(defvar *ds-copier*)
26(defvar *ds-type*)
27(defvar *ds-named*)
28(defvar *ds-predicate*)
29(defvar *ds-print-function*)
30
31(defun define-constructor (constructor slots)
32  (let* ((constructor-name (intern (car constructor)))
33         (slot-names (mapcar #'(lambda (x) (if (atom x) x (car x))) slots))
34         (inits (mapcar #'(lambda (x) (if (atom x) nil (cadr x))) slots))
35         (slot-descriptions (mapcar #'(lambda (x y) (list x y)) slot-names inits))
36         (keys (cons '&key slot-descriptions)))
37    (case *ds-type*
38      (LIST
39       (if *ds-named*
40           `((defun ,constructor-name ,keys
41               (list ',*ds-name* ,@slot-names)))
42           `((defun ,constructor-name ,keys
43               (list ,@slot-names)))))
44      (t
45       `((defun ,constructor-name ,keys
46           (%make-structure ',*ds-name* (list ,@slot-names))))))))
47
48(defun default-constructor-name ()
49  (concatenate 'string "MAKE-" (symbol-name *ds-name*)))
50
51(defun define-constructors (slots)
52  (if *ds-constructors*
53      (let ((results ()))
54        (dolist (constructor *ds-constructors*)
55          (when (car constructor)
56            (setf results (nconc results (define-constructor constructor slots)))))
57        results)
58      (define-constructor (cons (default-constructor-name) nil) slots)))
59
60(defun define-predicate ()
61  (when (and *ds-predicate*
62             (or *ds-named* (null *ds-type*)))
63    (let ((pred (intern *ds-predicate*)))
64      `((defun ,pred (object)
65          (typep object ',*ds-name*))))))
66
67(defun get-slot-accessor (slot)
68  (case *ds-type*
69    (LIST
70     (when *ds-named*
71       (incf slot))
72     `(lambda (instance) (elt instance ,slot)))
73    (t
74     (case slot
75       (0 #'%structure-ref-0)
76       (1 #'%structure-ref-1)
77       (2 #'%structure-ref-2)
78       (t
79        `(lambda (instance) (%structure-ref instance ,slot)))))))
80
81(defun get-slot-mutator (slot)
82  (case *ds-type*
83    (LIST
84     (when *ds-named*
85       (incf slot))
86     `(lambda (instance value) (%set-elt instance ,slot value)))
87    (t
88     (case slot
89       (0 #'%structure-set-0)
90       (1 #'%structure-set-1)
91       (2 #'%structure-set-2)
92       (t
93        `(lambda (instance value) (%structure-set instance ,slot value)))))))
94
95(defun define-access-function (slot-name index)
96  (let ((accessor
97         (if *ds-conc-name*
98             (intern (concatenate 'string (symbol-name *ds-conc-name*) (symbol-name slot-name)))
99             slot-name)))
100    `((setf (symbol-function ',accessor) ,(get-slot-accessor index))
101      (%put ',accessor 'setf-inverse ,(get-slot-mutator index )))))
102
103(defun define-access-functions (slots)
104  (let ((index 0)
105        (result ()))
106    (dolist (slot slots)
107      (let ((slot-name (if (atom slot) slot (car slot))))
108        (setf result (nconc result (define-access-function slot-name index))))
109      (incf index))
110    result))
111
112(defun define-copier ()
113  (when *ds-copier*
114    (case *ds-type*
115      (LIST
116       `((setf (fdefinition ',*ds-copier*) #'copy-list)))
117      (t
118       `((setf (fdefinition ',*ds-copier*) #'copy-structure))))))
119
120(defun parse-1-option (option)
121  (case (car option)
122    (:conc-name
123     (setf *ds-conc-name* (if (symbolp (cadr option))
124                              (cadr option)
125                              (make-symbol (string (cadr option))))))
126    (:constructor
127     (let* ((args (cdr option))
128            (numargs (length args))
129            name arglist)
130       (case numargs
131         (0 ; Use default name.
132          (setf name (default-constructor-name))
133          (setf arglist nil)
134          (push (list name arglist) *ds-constructors*))
135         (1
136          (if (null (car args))
137              (setf name nil) ; No constructor.
138              (setf name (symbol-name (car args))))
139          (setf arglist nil)
140          (push (list name arglist) *ds-constructors*))
141         (2))))
142    (:copier
143     (let* ((args (cdr option))
144            (numargs (length args)))
145       (when (= numargs 1)
146          (setf *ds-copier* (car args)))))
147    (:predicate
148     (when (= (length option) 2)
149       (if (null (cadr option))
150           (setf *ds-predicate* nil)
151           (setf *ds-predicate* (symbol-name (cadr option))))))
152    (:type
153     (setf *ds-type* (cadr option)))
154    (t
155     (format t "unrecognized DEFSTRUCT option: ~S~%" (car option)))))
156
157(defun parse-name-and-options (name-and-options)
158  (setf *ds-name* (car name-and-options))
159  (setf *ds-conc-name* (make-symbol (concatenate 'string (symbol-name *ds-name*) "-")))
160  (setf *ds-copier* (intern (concatenate 'string "COPY-" (symbol-name *ds-name*))))
161  (setf *ds-predicate* (concatenate 'string (symbol-name *ds-name*) "-P"))
162  (let ((options (cdr name-and-options)))
163    (dolist (option options)
164      (cond ((consp option)
165             (parse-1-option option))
166            ((eq option :named)
167             (setf *ds-named* t))
168            ((member option '(:constructor :copier :predicate :named
169                              :conc-name))
170             (parse-1-option (list option)))
171            (t
172             (error "unrecognized DEFSTRUCT option: ~S" option))))))
173
174(defmacro defstruct (name-and-options &rest slots)
175  (let ((*ds-name* nil)
176        (*ds-conc-name* nil)
177        (*ds-constructors* nil)
178        (*ds-copier* nil)
179        (*ds-type* nil)
180        (*ds-named* nil)
181        (*ds-predicate* nil)
182        (*ds-print-function* nil))
183    (parse-name-and-options (if (atom name-and-options)
184                                (list name-and-options)
185                                name-and-options))
186    (when (stringp (car slots))
187      (setf (documentation *ds-name* 'structure) (pop slots)))
188    `(progn
189       (make-structure-class ',*ds-name*)
190       ,@(define-constructors slots)
191       ,@(define-predicate)
192       ,@(define-access-functions slots)
193       ,@(define-copier)
194       ',*ds-name*)))
Note: See TracBrowser for help on using the repository browser.