source: trunk/j/src/org/armedbear/lisp/defstruct.lisp @ 4854

Last change on this file since 4854 was 4854, checked in by piso, 18 years ago

Work in progress.

File size: 9.0 KB
Line 
1;;; defstruct.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: defstruct.lisp,v 1.36 2003-11-20 19:04:24 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20(in-package "SYSTEM")
21
22(defvar *ds-name*)
23(defvar *ds-conc-name*)
24(defvar *ds-constructors*)
25(defvar *ds-copier*)
26(defvar *ds-type*)
27(defvar *ds-named*)
28(defvar *ds-initial-offset*)
29(defvar *ds-predicate*)
30(defvar *ds-print-function*)
31(defvar *ds-direct-slots*)
32
33(defun define-constructor (constructor)
34  (let* ((constructor-name (intern (car constructor)))
35         (keys ())
36         (elements ()))
37    (dolist (slot *ds-direct-slots*)
38      (let ((name (getf slot :name))
39            (initform (getf slot :initform)))
40        (push (list name initform) keys)
41        (push name elements)))
42    (setf keys (cons '&key (nreverse keys)))
43    (setf elements (nreverse elements))
44    (when *ds-named*
45      (push (list 'quote *ds-name*) elements))
46    (when *ds-initial-offset*
47      (dotimes (i *ds-initial-offset*)
48        (push nil elements)))
49    (cond ((eq *ds-type* 'list)
50           `((defun ,constructor-name ,keys
51               (list ,@elements))))
52          ((or (eq *ds-type* 'vector)
53               (and (consp *ds-type*) (eq (car *ds-type*) 'vector)))
54           (let ((element-type (if (consp *ds-type*) (cadr *ds-type*) t)))
55             `((defun ,constructor-name ,keys
56                 (make-array ,(length elements)
57                             :element-type ',element-type
58                             :initial-contents (list ,@elements))))))
59          (t
60           `((defun ,constructor-name ,keys
61               (%make-structure ',*ds-name* (list ,@elements))))))))
62
63(defun default-constructor-name ()
64  (concatenate 'string "MAKE-" (symbol-name *ds-name*)))
65
66(defun define-constructors ()
67  (if *ds-constructors*
68      (let ((results ()))
69        (dolist (constructor *ds-constructors*)
70          (when (car constructor)
71            (setf results (nconc results (define-constructor constructor)))))
72        results)
73      (define-constructor (cons (default-constructor-name) nil))))
74
75(defun define-predicate ()
76  (when (and *ds-predicate*
77             (or *ds-named* (null *ds-type*)))
78    (let ((pred (intern *ds-predicate*)))
79      (cond ((eq *ds-type* 'list)
80             (if *ds-initial-offset*
81                 `((defun ,pred (object)
82                     (and (consp object)
83                          (> (length object) ,*ds-initial-offset*)
84                          (eq (elt object ,*ds-initial-offset*) ',*ds-name*))))
85                 `((defun ,pred (object)
86                     (and (consp object) (eq (car object) ',*ds-name*))))))
87            ((or (eq *ds-type* 'vector)
88                 (and (consp *ds-type*) (eq (car *ds-type*) 'vector)))
89             (let ((index (or *ds-initial-offset* 0)))
90               `((defun ,pred (object)
91                   (and (vectorp object)
92                        (> (length object) ,index)
93                        (eq (aref object ,index) ',*ds-name*))))))
94            (t
95             `((defun ,pred (object)
96                 (typep object ',*ds-name*))))))))
97
98(defun get-slot-accessor (slot)
99  (when *ds-initial-offset*
100    (incf slot *ds-initial-offset*))
101  (when *ds-named*
102    (incf slot))
103  (cond ((eq *ds-type* 'list)
104         `(lambda (instance) (elt instance ,slot)))
105        ((or (eq *ds-type* 'vector)
106             (and (consp *ds-type*) (eq (car *ds-type*) 'vector)))
107         `(lambda (instance) (aref instance ,slot)))
108        (t
109         (case slot
110           (0 #'%structure-ref-0)
111           (1 #'%structure-ref-1)
112           (2 #'%structure-ref-2)
113           (t
114            `(lambda (instance) (%structure-ref instance ,slot)))))))
115
116(defun get-slot-mutator (slot)
117  (when *ds-initial-offset*
118    (incf slot *ds-initial-offset*))
119  (when *ds-named*
120    (incf slot))
121  (cond ((eq *ds-type* 'list)
122         `(lambda (instance value) (%set-elt instance ,slot value)))
123        ((or (eq *ds-type* 'vector)
124             (and (consp *ds-type*) (eq (car *ds-type*) 'vector)))
125         `(lambda (instance value) (%aset instance ,slot value)))
126        (t
127         (case slot
128           (0 #'%structure-set-0)
129           (1 #'%structure-set-1)
130           (2 #'%structure-set-2)
131           (t
132            `(lambda (instance value) (%structure-set instance ,slot value)))))))
133
134(defun define-access-function (slot-name index)
135  (let ((accessor
136         (if *ds-conc-name*
137             (intern (concatenate 'string (symbol-name *ds-conc-name*) (symbol-name slot-name)))
138             slot-name)))
139    `((setf (symbol-function ',accessor) ,(get-slot-accessor index))
140      (%put ',accessor 'setf-inverse ,(get-slot-mutator index )))))
141
142(defun define-access-functions (slots)
143  (let ((index 0)
144        (result ()))
145    (dolist (slot slots)
146      (let ((slot-name (if (atom slot) slot (car slot))))
147        (setf result (nconc result (define-access-function slot-name index))))
148      (incf index))
149    result))
150
151(defun define-copier ()
152  (when *ds-copier*
153    (cond ((eq *ds-type* 'list)
154           `((setf (fdefinition ',*ds-copier*) #'copy-list)))
155          ((or (eq *ds-type* 'vector)
156               (and (consp *ds-type*) (eq (car *ds-type*) 'vector)))
157           `((setf (fdefinition ',*ds-copier*) #'copy-seq)))
158          (t
159           `((setf (fdefinition ',*ds-copier*) #'copy-structure))))))
160
161(defun parse-1-option (option)
162  (case (car option)
163    (:conc-name
164     (setf *ds-conc-name* (if (symbolp (cadr option))
165                              (cadr option)
166                              (make-symbol (string (cadr option))))))
167    (:constructor
168     (let* ((args (cdr option))
169            (numargs (length args))
170            name arglist)
171       (case numargs
172         (0 ; Use default name.
173          (setf name (default-constructor-name))
174          (setf arglist nil)
175          (push (list name arglist) *ds-constructors*))
176         (1
177          (if (null (car args))
178              (setf name nil) ; No constructor.
179              (setf name (symbol-name (car args))))
180          (setf arglist nil)
181          (push (list name arglist) *ds-constructors*))
182         (2))))
183    (:copier
184     (let* ((args (cdr option))
185            (numargs (length args)))
186       (when (= numargs 1)
187          (setf *ds-copier* (car args)))))
188    (:initial-offset
189     (setf *ds-initial-offset* (cadr option)))
190    (:predicate
191     (when (= (length option) 2)
192       (if (null (cadr option))
193           (setf *ds-predicate* nil)
194           (setf *ds-predicate* (symbol-name (cadr option))))))
195    (:type
196     (setf *ds-type* (cadr option)))
197    (t
198     (format t "unrecognized DEFSTRUCT option: ~S~%" (car option)))))
199
200(defun parse-name-and-options (name-and-options)
201  (setf *ds-name* (car name-and-options))
202  (setf *ds-conc-name* (make-symbol (concatenate 'string (symbol-name *ds-name*) "-")))
203  (setf *ds-copier* (intern (concatenate 'string "COPY-" (symbol-name *ds-name*))))
204  (setf *ds-predicate* (concatenate 'string (symbol-name *ds-name*) "-P"))
205  (let ((options (cdr name-and-options)))
206    (dolist (option options)
207      (cond ((consp option)
208             (parse-1-option option))
209            ((eq option :named)
210             (setf *ds-named* t))
211            ((member option '(:constructor :copier :predicate :named
212                              :conc-name))
213             (parse-1-option (list option)))
214            (t
215             (error "unrecognized DEFSTRUCT option: ~S" option))))))
216
217(defmacro defstruct (name-and-options &rest slots)
218  (let ((*ds-name* nil)
219        (*ds-conc-name* nil)
220        (*ds-constructors* nil)
221        (*ds-copier* nil)
222        (*ds-type* nil)
223        (*ds-named* nil)
224        (*ds-initial-offset* nil)
225        (*ds-predicate* nil)
226        (*ds-print-function* nil)
227        (*ds-direct-slots* ()))
228    (parse-name-and-options (if (atom name-and-options)
229                                (list name-and-options)
230                                name-and-options))
231    (when (stringp (car slots))
232      (setf (documentation *ds-name* 'structure) (pop slots)))
233    (dolist (slot slots)
234      (let ((slot-description (if (atom slot)
235                                  (list :name slot :initform nil)
236                                  (list :name (car slot) :initform (cadr slot)))))
237        (push slot-description *ds-direct-slots*)))
238    (setf *ds-direct-slots* (nreverse *ds-direct-slots*))
239    `(progn
240       (make-structure-class ',*ds-name* ',*ds-direct-slots*)
241       ,@(define-constructors)
242       ,@(define-predicate)
243       ,@(define-access-functions slots)
244       ,@(define-copier)
245       ',*ds-name*)))
Note: See TracBrowser for help on using the repository browser.