source: trunk/j/src/org/armedbear/lisp/java.lisp @ 11297

Last change on this file since 11297 was 11297, checked in by ehuelsmann, 13 years ago

Set Id keyword for expansion.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 9.8 KB
Line 
1;;; java.lisp
2;;;
3;;; Copyright (C) 2003-2007 Peter Graves, Andras Simon
4;;; $Id: java.lisp 11297 2008-08-31 13:26:45Z ehuelsmann $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
19
20(in-package "JAVA")
21
22(require "CLOS")
23
24(defun jregister-handler (object event handler &key data count)
25  (%jregister-handler object event handler data count))
26
27(defun jinterface-implementation (interface &rest method-names-and-defs)
28  "Creates and returns an implementation of a Java interface with
29   methods calling Lisp closures as given in METHOD-NAMES-AND-DEFS.
30
31   INTERFACE is either a Java interface or a string naming one.
32
33   METHOD-NAMES-AND-DEFS is an alternating list of method names
34   (strings) and method definitions (closures).
35
36   For missing methods, a dummy implementation is provided that
37   returns nothing or null depending on whether the return type is
38   void or not. This is for convenience only, and a warning is issued
39   for each undefined method."
40  (let ((interface (jclass interface))
41        (implemented-methods
42         (loop for m in method-names-and-defs
43           for i from 0
44           if (evenp i)
45           do (assert (stringp m) (m) "Method names must be strings: ~s" m) and collect m
46           else
47           do (assert (or (symbolp m) (functionp m)) (m) "Methods must be function designators: ~s" m)))
48        (null (make-immediate-object nil :ref)))
49    (loop for method across
50      (jclass-methods interface :declared nil :public t)
51      for method-name = (jmethod-name method)
52      when (not (member method-name implemented-methods :test #'string=))
53      do
54      (let* ((void-p (string= (jclass-name (jmethod-return-type method)) "void"))
55             (arglist (when (plusp (length (jmethod-params method))) '(&rest ignore)))
56             (def `(lambda
57                     ,arglist
58                     ,(when arglist '(declare (ignore ignore)))
59                     ,(if void-p '(values) null))))
60        (warn "Implementing dummy method ~a for interface ~a"
61              method-name (jclass-name interface))
62        (push (coerce def 'function) method-names-and-defs)
63        (push method-name method-names-and-defs)))
64    (apply #'%jnew-proxy interface method-names-and-defs)))
65
66(defun jobject-class (obj)
67  "Returns the Java class that OBJ belongs to"
68  (jcall (jmethod "java.lang.Object" "getClass") obj))
69
70(defun jclass-superclass (class)
71  "Returns the superclass of CLASS, or NIL if it hasn't got one"
72  (jcall (jmethod "java.lang.Class" "getSuperclass") (jclass class)))
73
74(defun jclass-interfaces (class)
75  "Returns the vector of interfaces of CLASS"
76  (jcall (jmethod "java.lang.Class" "getInterfaces") (jclass class)))
77
78(defun jclass-interface-p (class)
79  "Returns T if CLASS is an interface"
80  (jcall (jmethod "java.lang.Class" "isInterface") (jclass class)))
81
82(defun jclass-superclass-p (class-1 class-2)
83  "Returns T if CLASS-1 is a superclass or interface of CLASS-2"
84  (jcall (jmethod "java.lang.Class" "isAssignableFrom" "java.lang.Class")
85         (jclass class-1)
86         (jclass class-2)))
87
88(defun jclass-array-p (class)
89  "Returns T if CLASS is an array class"
90  (jcall (jmethod "java.lang.Class" "isArray") (jclass class)))
91
92(defun jarray-component-type (atype)
93  "Returns the component type of the array type ATYPE"
94  (assert (jclass-array-p atype))
95  (jcall (jmethod "java.lang.Class" "getComponentType") atype))
96
97(defun jarray-length (java-array)
98  (jstatic "getLength" "java.lang.reflect.Array" java-array)  )
99
100(defun (setf jarray-ref) (new-value java-array &rest indices)
101  (apply #'jarray-set java-array new-value indices))
102
103(defun jnew-array-from-array (element-type array)
104  "Returns a new Java array with base type ELEMENT-TYPE (a string or a class-ref)
105   initialized from ARRAY"
106  (flet
107    ((row-major-to-index (dimensions n)
108                         (loop for dims on dimensions
109                           with indices
110                           do
111                           (multiple-value-bind (m r) (floor n (apply #'* (cdr dims)))
112                             (push m indices)
113                             (setq n r))
114                           finally (return (nreverse indices)))))
115    (let* ((fill-pointer (when (array-has-fill-pointer-p array) (fill-pointer array)))
116           (dimensions (if fill-pointer (list fill-pointer) (array-dimensions array)))
117           (jarray (apply #'jnew-array element-type dimensions)))
118      (dotimes (i (if fill-pointer fill-pointer (array-total-size array)) jarray)
119        #+maybe_one_day
120        (setf (apply #'jarray-ref jarray (row-major-to-index dimensions i)) (row-major-aref array i))
121        (apply #'(setf jarray-ref) (row-major-aref array i) jarray (row-major-to-index dimensions i))))))
122
123(defun jclass-constructors (class)
124  "Returns a vector of constructors for CLASS"
125  (jcall (jmethod "java.lang.Class" "getConstructors") (jclass class)))
126
127(defun jconstructor-params (constructor)
128  "Returns a vector of parameter types (Java classes) for CONSTRUCTOR"
129  (jcall (jmethod "java.lang.reflect.Constructor" "getParameterTypes") constructor))
130
131(defun jclass-fields (class &key declared public)
132  "Returns a vector of all (or just the declared/public, if DECLARED/PUBLIC is true) fields of CLASS"
133  (let* ((getter (if declared "getDeclaredFields" "getFields"))
134         (fields (jcall (jmethod "java.lang.Class" getter) (jclass class))))
135    (if public (delete-if-not #'jmember-public-p fields) fields)))
136
137(defun jclass-field (class field-name)
138  "Returns the field named FIELD-NAME of CLASS"
139  (jcall (jmethod "java.lang.Class" "getField" "java.lang.String")
140         (jclass class) field-name))
141
142(defun jfield-type (field)
143  "Returns the type (Java class) of FIELD"
144  (jcall (jmethod "java.lang.reflect.Field" "getType") field))
145
146(defun jfield-name (field)
147  "Returns the name of FIELD as a Lisp string"
148  (jcall (jmethod "java.lang.reflect.Field" "getName") field))
149
150(defun jclass-methods (class &key declared public)
151  "Return a vector of all (or just the declared/public, if DECLARED/PUBLIC is true) methods of CLASS"
152  (let* ((getter (if declared "getDeclaredMethods" "getMethods"))
153         (methods (jcall (jmethod "java.lang.Class" getter) (jclass class))))
154    (if public (delete-if-not #'jmember-public-p methods) methods)))
155
156(defun jmethod-params (method)
157  "Returns a vector of parameter types (Java classes) for METHOD"
158  (jcall (jmethod "java.lang.reflect.Method" "getParameterTypes") method))
159
160;; (defun jmethod-return-type (method)
161;;   "Returns the result type (Java class) of the METHOD"
162;;   (jcall (jmethod "java.lang.reflect.Method" "getReturnType") method))
163
164(defun jmethod-name (method)
165  "Returns the name of METHOD as a Lisp string"
166  (jcall (jmethod "java.lang.reflect.Method" "getName") method))
167
168(defun jinstance-of-p (obj class)
169  "OBJ is an instance of CLASS (or one of its subclasses)"
170  (and (java-object-p obj)
171       (jcall (jmethod "java.lang.Class" "isInstance" "java.lang.Object") (jclass class) obj)))
172
173(defun jmember-static-p (member)
174  "MEMBER is a static member of its declaring class"
175  (jstatic (jmethod "java.lang.reflect.Modifier" "isStatic" "int")
176           "java.lang.reflect.Modifier"
177           (jcall (jmethod "java.lang.reflect.Member" "getModifiers") member)))
178
179(defun jmember-public-p (member)
180  "MEMBER is a public member of its declaring class"
181  (jstatic (jmethod "java.lang.reflect.Modifier" "isPublic" "int")
182           "java.lang.reflect.Modifier"
183           (jcall (jmethod "java.lang.reflect.Member" "getModifiers") member)))
184
185(defun jmember-protected-p (member)
186  "MEMBER is a protected member of its declaring class"
187  (jstatic (jmethod "java.lang.reflect.Modifier" "isProtected" "int")
188           "java.lang.reflect.Modifier"
189           (jcall (jmethod "java.lang.reflect.Member" "getModifiers") member)))
190
191(defmethod make-load-form ((object java-object) &optional environment)
192  (declare (ignore environment))
193  (let ((class-name (jclass-name (jclass-of object))))
194    (cond
195     ((string= class-name "java.lang.reflect.Constructor")
196      `(java:jconstructor ,(jclass-name
197                            (jcall (jmethod "java.lang.reflect.Constructor"
198                                            "getDeclaringClass") object))
199                          ,@(loop for arg-type across
200                              (jcall
201                               (jmethod "java.lang.reflect.Constructor"
202                                        "getParameterTypes")
203                               object)
204                              collecting
205                              (jclass-name arg-type))))
206     ((string= class-name "java.lang.reflect.Method")
207      `(java:jmethod ,(jclass-name
208                       (jcall (jmethod "java.lang.reflect.Method"
209                                       "getDeclaringClass") object))
210                     ,(jmethod-name object)
211                     ,@(loop for arg-type across
212                         (jcall
213                          (jmethod "java.lang.reflect.Method"
214                                   "getParameterTypes")
215                          object)
216                         collecting
217                         (jclass-name arg-type))))
218     ((jinstance-of-p object "java.lang.Class")
219      `(java:jclass ,(jcall (jmethod "java.lang.Class" "getName") object)))
220     (t
221      (error "Unknown load-from for ~A" class-name)))))
222
223(provide "JAVA-EXTENSIONS")
Note: See TracBrowser for help on using the repository browser.