source: trunk/j/src/org/armedbear/lisp/precompiler.lisp @ 4765

Last change on this file since 4765 was 4765, checked in by piso, 18 years ago

Work in progress.

File size: 17.2 KB
Line 
1;;; precompiler.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: precompiler.lisp,v 1.7 2003-11-15 15:26:12 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20(in-package "SYSTEM")
21
22(define-compiler-macro assoc (&whole form &rest args)
23  (cond ((and (= (length args) 4)
24              (eq (third args) :test)
25              (or (equal (fourth args) '(quote eq))
26                  (equal (fourth args) '(function eq))))
27         `(assq ,(first args) ,(second args)))
28        (t form)))
29
30(define-compiler-macro member (&whole form &rest args)
31  (cond ((and (= (length args) 4)
32              (eq (third args) :test)
33              (or (equal (fourth args) '(quote eq))
34                  (equal (fourth args) '(function eq))))
35         `(memq ,(first args) ,(second args)))
36        ((and (= (length args) 4)
37              (eq (third args) :test)
38              (or (equal (fourth args) '(quote eql))
39                  (equal (fourth args) '(function eql))))
40         `(memql ,(first args) ,(second args)))
41        ((= (length args) 2)
42         `(memql ,(first args) ,(second args)))
43        (t form)))
44
45(define-compiler-macro identity (&whole form &rest args)
46  (if (= (length args) 1)
47      `(progn ,(car args))
48      form))
49
50(in-package "EXTENSIONS")
51
52(export '(precompile-form precompile))
53
54(unless (find-package "PRECOMPILER")
55  (make-package "PRECOMPILER"
56                :nicknames '("PRE")
57                :use '("COMMON-LISP" "EXTENSIONS")))
58
59(in-package "PRECOMPILER")
60
61(defvar *in-jvm-compile* nil)
62
63(defun precompile-identity (form)
64  form)
65
66(defun precompile-cons (form)
67  (cons (car form) (mapcar #'precompile1 (cdr form))))
68
69(defun precompile-block (form)
70  (let ((args (cdr form)))
71    (if (null (cdr args))
72        nil
73        (list* 'BLOCK (car args) (mapcar #'precompile1 (cdr args))))))
74
75(defun precompile-dolist (form)
76  (cons 'DOLIST (cons (cadr form) (mapcar #'precompile1 (cddr form)))))
77
78(defun precompile-dotimes (form)
79  (cons 'DOTIMES (cons (cadr form) (mapcar #'precompile1 (cddr form)))))
80
81(defun precompile-do/do* (form)
82  (list* (car form) (cadr form) (caddr form)
83         (mapcar #'precompile1 (cdddr form))))
84
85(defun precompile-do-symbols (form)
86   (list* (car form) (cadr form) (mapcar #'precompile1 (cddr form))))
87
88(defun precompile-progn (form)
89   (let ((body (cdr form)))
90     (if (= (length body) 1)
91         (let ((res (precompile1 (car body))))
92           ;; If the result turns out to be a bare symbol, leave it wrapped
93           ;; with PROGN so it won't be mistaken for a tag in an enclosing
94           ;; TAGBODY.
95           (if (symbolp res)
96               (list 'progn res)
97               res))
98         (cons 'PROGN (mapcar #'precompile1 body)))))
99
100(defun precompile-progv (form)
101   (list* 'PROGV (cadr form) (caddr form) (mapcar #'precompile1 (cdddr form))))
102
103(defun precompile-setq (form)
104  (let* ((args (cdr form))
105        (len (length args)))
106    (when (oddp len)
107      (error "odd number of arguments to SETQ"))
108    (if (= len 2)
109        (list 'SETQ (car args) (precompile1 (cadr args)))
110        (let ((result ()))
111          (loop
112            (when (null args)
113              (return))
114            (push (list 'SETQ (car args) (precompile1 (cadr args))) result)
115            (setq args (cddr args)))
116          (setq result (nreverse result))
117          (push 'PROGN result)
118          result))))
119
120(defun precompile-lambda (form)
121  (let* ((args (cdr form))
122         (lambda-list (car args))
123         (auxvars (memq '&AUX lambda-list)))
124    (if auxvars
125        (append (list 'LAMBDA (subseq lambda-list 0 (position '&AUX lambda-list))
126                      (append (list 'LET*
127                                    (cdr auxvars))
128                              (mapcar #'precompile1 (cdr args)))))
129        (list* 'LAMBDA lambda-list (mapcar #'precompile1 (cdr args))))))
130
131(defun define-local-macro (name lambda-list body)
132  (let* ((form (gensym))
133         (env (gensym))
134         (body (sys::parse-defmacro lambda-list form body name 'macrolet
135                                    :environment env))
136         (expander `(lambda (,form ,env) (block ,name ,body)))
137         (compiled-expander (compile nil expander)))
138    (sys::coerce-to-function (or compiled-expander expander))))
139
140(defvar *local-macros* ())
141
142(defun local-macro-function (name)
143  (getf *local-macros* name))
144
145(defun expand-local-macro (form)
146  (let ((expansion (funcall (local-macro-function (car form)) form nil)))
147    ;; If the expansion turns out to be a bare symbol, wrap it with PROGN so it
148    ;; won't be mistaken for a tag in an enclosing TAGBODY.
149    (if (symbolp expansion)
150        (list 'progn expansion)
151        expansion)))
152
153(defun precompile-macrolet (form)
154  (let ((*local-macros* *local-macros*)
155        (macros (cadr form))
156        (body (cddr form))
157        (res ())
158        compiled-body)
159    (dolist (macro macros)
160      (let ((name (car macro))
161            (lambda-list (cadr macro))
162            (forms (cddr macro)))
163        (push (define-local-macro name lambda-list forms) *local-macros*)
164        (push name *local-macros*)
165        (push (list* name lambda-list (mapcar #'precompile1 forms)) res)))
166    (setf compiled-body (mapcar #'precompile1 body))
167    (setf res (list* 'PROGN compiled-body))
168    res))
169
170(defun precompile-let/let*-vars (vars)
171  (let ((result nil))
172    (dolist (var vars)
173      (if (consp var)
174          (let* ((v (car var))
175                 (expr (cadr var)))
176            (unless (symbolp v)
177              (error 'type-error))
178            (push (list v (precompile1 expr)) result))
179          (push var result)))
180    (nreverse result)))
181
182(defun precompile-let/let* (form)
183  (list* (car form)
184         (precompile-let/let*-vars (cadr form))
185         (mapcar #'precompile1 (cddr form))))
186
187(defun precompile-case (form)
188  (let* ((keyform (cadr form))
189         (clauses (cddr form))
190         (result (list (precompile1 keyform))))
191    (dolist (clause clauses)
192      (push (precompile-case-clause clause) result))
193    (cons (car form) (nreverse result))))
194
195(defun precompile-case-clause (clause)
196  (let ((keys (car clause))
197        (forms (cdr clause)))
198    (cons keys (mapcar #'precompile1 forms))))
199
200(defun precompile-cond (form)
201  (let ((clauses (cdr form))
202        (result nil))
203    (dolist (clause clauses)
204      (push (precompile-cond-clause clause) result))
205    (cons 'COND (nreverse result))))
206
207(defun precompile-cond-clause (clause)
208  (let ((test (car clause))
209        (forms (cdr clause)))
210    (cons (precompile1 test) (mapcar #'precompile1 forms))))
211
212(defun precompile-local-function-def (def)
213  (let ((name (car def))
214        (arglist (cadr def))
215        (body (cddr def)))
216    (list* name arglist (mapcar #'precompile1 body))))
217
218(defun precompile-local-functions (defs)
219  (let ((result nil))
220    (dolist (def defs)
221      (setq result (append result (list (precompile-local-function-def def)))))
222    result))
223
224(defun precompile-flet/labels (form)
225  (let ((locals (cadr form))
226        (body (cddr form)))
227    (list* (car form)
228           (precompile-local-functions locals)
229           (mapcar #'precompile1 body))))
230
231(defun precompile-function (form)
232  (if (and (consp (cadr form)) (eq (caadr form) 'LAMBDA))
233      (list 'FUNCTION (precompile-lambda (cadr form)))
234      form))
235
236(defun precompile-if (form)
237  (let ((args (cdr form)))
238    (case (length args)
239      (2
240       (list 'IF
241             (precompile1 (car args))
242             (precompile1 (cadr args))))
243      (3
244       (list 'IF
245             (precompile1 (car args))
246             (precompile1 (cadr args))
247             (precompile1 (caddr args))))
248      (t
249       (error "wrong number of arguments for IF")))))
250
251(defun precompile-multiple-value-bind (form)
252  (let ((vars (cadr form))
253        (values-form (caddr form))
254        (body (cdddr form)))
255    (list* 'MULTIPLE-VALUE-BIND
256           vars
257           (precompile1 values-form)
258           (mapcar #'precompile1 body))))
259
260(defun precompile-multiple-value-list (form)
261   (list 'MULTIPLE-VALUE-LIST (precompile1 (cadr form))))
262
263(defun precompile-return (form)
264   (list 'RETURN (precompile1 (cadr form))))
265
266(defun precompile-return-from (form)
267  (list 'RETURN-FROM (cadr form) (precompile1 (caddr form))))
268
269(defun precompile-tagbody (form)
270  (do ((body (cdr form) (cdr body))
271       (result ()))
272      ((null body) (cons 'TAGBODY (nreverse result)))
273    (if (atom (car body))
274        (push (car body) result)
275        (push (precompile1 (car body)) result))))
276
277(defun precompile-the (form)
278  (precompile1 (caddr form)))
279
280(defun precompile-unwind-protect (form)
281   (list* 'UNWIND-PROTECT
282          (precompile1 (cadr form))
283          (mapcar #'precompile1 (cddr form))))
284
285;; EXPAND-MACRO is like MACROEXPAND, but EXPAND-MACRO quits if *in-jvm-compile*
286;; is false and a macro is encountered that's also implemented as a special
287;; operator, so interpreted code can use the special operator implementation.
288(defun expand-macro (form)
289  (loop
290    (unless *in-jvm-compile*
291      (when (and (consp form)
292                 (symbolp (car form))
293                 (special-operator-p (car form)))
294        (return-from expand-macro form)))
295    (multiple-value-bind (result expanded) (macroexpand-1 form)
296      (unless expanded
297        (return-from expand-macro result))
298      (setf form result))))
299
300;;; From OpenMCL.
301(defun compiler-macroexpand-1 (form &optional env)
302  (let ((expander nil)
303        (newdef nil))
304    (if (and (consp form)
305             (symbolp (car form))
306             (setq expander (compiler-macro-function (car form) env)))
307        (values (setq newdef (funcall expander form env))
308                (not (eq newdef form)))
309        (values form
310                nil))))
311
312(defun compiler-macroexpand (form &optional env)
313  (let ((expanded-p nil))
314    (loop
315      (multiple-value-bind (expansion exp-p) (compiler-macroexpand-1 form env)
316        (if exp-p
317            (setf form expansion expanded-p t)
318            (return))))
319    (values form expanded-p)))
320
321(defun precompile1 (form)
322  (if (atom form)
323      form
324      (let ((op (car form)))
325        (when (symbolp op)
326          (cond ((local-macro-function op)
327                 (let ((result (expand-local-macro form)))
328                   (if (equal result form)
329                       (return-from precompile1 result)
330                       (return-from precompile1 (precompile1 result)))))
331                ((compiler-macro-function op)
332                 (let ((result (compiler-macroexpand form)))
333                   (if (equal result form)
334                       (return-from precompile1 result)
335                       (return-from precompile1 (precompile1 result)))))
336                ((and (not (eq op 'LAMBDA))
337                      (macro-function op))
338                 ;; It's a macro...
339                 (unless (and (special-operator-p op) (not *in-jvm-compile*))
340                   (let ((result (expand-macro form)))
341                     (return-from precompile1 (precompile1 result))))))
342          (let ((handler (get op 'precompile-handler)))
343            (when handler
344              (return-from precompile1 (funcall handler form)))))
345        (when (and (symbolp op) (special-operator-p op))
346          (format t "PRECOMPILE1: unsupported special operator ~S~%" op))
347        (precompile-cons form))))
348
349(defun precompile-form (form in-jvm-compile)
350  (let ((*in-jvm-compile* in-jvm-compile))
351    (precompile1 form)))
352
353(defun install-handler (fun &optional handler)
354  (let ((handler (or handler
355                     (find-symbol (concatenate 'string "PRECOMPILE-"
356                                               (symbol-name fun))
357                                  'precompiler))))
358    (unless (and handler (fboundp handler))
359      (error "no handler for ~S" fun))
360    (setf (get fun 'precompile-handler) handler)))
361
362(mapcar #'install-handler '(block
363                            case
364                            cond
365                            dolist
366                            dotimes
367                            function
368                            if
369                            lambda
370                            macrolet
371                            multiple-value-bind
372                            multiple-value-list
373                            progn
374                            progv
375                            return
376                            return-from
377                            setq
378                            tagbody
379                            the
380                            unwind-protect))
381
382(install-handler 'ecase                'precompile-case)
383
384(install-handler 'and                  'precompile-cons)
385(install-handler 'locally              'precompile-cons)
386(install-handler 'multiple-value-call  'precompile-cons)
387(install-handler 'multiple-value-prog1 'precompile-cons)
388(install-handler 'or                   'precompile-cons)
389(install-handler 'unless               'precompile-cons)
390(install-handler 'when                 'precompile-cons)
391
392(install-handler 'do                   'precompile-do/do*)
393(install-handler 'do*                  'precompile-do/do*)
394
395(install-handler 'flet                 'precompile-flet/labels)
396(install-handler 'labels               'precompile-flet/labels)
397
398(install-handler 'do-symbols           'precompile-do-symbols)
399(install-handler 'do-external-symbols  'precompile-do-symbols)
400
401(install-handler 'let                  'precompile-let/let*)
402(install-handler 'let*                 'precompile-let/let*)
403
404(install-handler 'catch                'precompile-identity)
405(install-handler 'declare              'precompile-identity)
406(install-handler 'go                   'precompile-identity)
407(install-handler 'handler-bind         'precompile-identity)
408(install-handler 'handler-case         'precompile-identity)
409(install-handler 'nth-value            'precompile-identity)
410(install-handler 'quote                'precompile-identity)
411(install-handler 'throw                'precompile-identity)
412
413(in-package "SYSTEM")
414
415(defun precompile (name &optional definition)
416  (unless definition
417    (setq definition (or (and (symbolp name) (macro-function name))
418                         (fdefinition name))))
419  (let (expr result)
420    (cond ((functionp definition)
421           (multiple-value-bind (form closure-p)
422             (function-lambda-expression definition)
423             (unless form
424               (format t "; No lambda expression available for ~S.~%" name)
425               (return-from precompile (values nil t t)))
426             (when closure-p
427               (format t "; Unable to compile function ~S defined in non-null lexical environment.~%" name)
428               (finish-output)
429               (return-from precompile (values nil t t)))
430             (setq expr form)))
431          ((and (consp definition) (eq (car definition) 'lambda))
432           (setq expr definition))
433          (t
434           (error 'type-error)))
435    (setf result (coerce-to-function (precompile-form expr nil)))
436    (when (and name (functionp result))
437      (%set-lambda-name result name)
438      (%set-call-count result (%call-count definition))
439      (%set-arglist result (arglist definition))
440      (if (and (symbolp name) (macro-function name))
441          (setf (fdefinition name) (make-macro result))
442          (setf (fdefinition name) result)))
443    (values (or name result) nil nil)))
444
445(defun precompile-package (pkg &key verbose)
446  (dolist (sym (package-symbols pkg))
447    (when (fboundp sym)
448      (unless (special-operator-p sym)
449        (let ((f (fdefinition sym)))
450          (unless (compiled-function-p f)
451            (when verbose
452              (format t "compiling ~S~%" sym)
453              (finish-output))
454            (precompile sym))))))
455  t)
456
457(precompile-package "PRECOMPILER")
458(precompile-package "EXTENSIONS")
459(precompile-package "SYSTEM")
460(precompile-package "COMMON-LISP")
461
462(defun compile (name &optional definition)
463  (if (and name (fboundp name) (typep (symbol-function name) 'generic-function))
464      (values name nil nil)
465      (precompile name definition)))
466
467;; Redefine DEFMACRO to compile the expansion function on the fly.
468(defmacro defmacro (name lambda-list &rest body)
469  (let* ((form (gensym))
470         (env (gensym))
471         (body (parse-defmacro lambda-list form body name 'defmacro
472                               :environment env))
473         (expander `(lambda (,form ,env) (block ,name ,body))))
474    `(progn
475       (if (special-operator-p ',name)
476           (%put ',name
477                 'macroexpand-macro
478                 (make-macro (or (precompile nil ,expander) ,expander)))
479           (fset ',name
480                 (make-macro (or (precompile nil ,expander) ,expander))))
481       ',name)))
482
483;; Make an exception just this one time...
484(fset 'defmacro (get 'defmacro 'macroexpand-macro))
485
486;; Redefine DEFUN to compile the definition on the fly.
487(defmacro defun (name lambda-list &rest body &environment env)
488  `(progn
489     (%defun ',name ',lambda-list ',body ,env)
490     (precompile ',name)
491     ',name))
Note: See TracBrowser for help on using the repository browser.