source: trunk/j/src/org/armedbear/lisp/precompiler.lisp @ 4797

Last change on this file since 4797 was 4797, checked in by piso, 18 years ago

PRECOMPILE-IF

File size: 17.6 KB
Line 
1;;; precompiler.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: precompiler.lisp,v 1.8 2003-11-17 01:44:50 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20(in-package "SYSTEM")
21
22(define-compiler-macro assoc (&whole form &rest args)
23  (cond ((and (= (length args) 4)
24              (eq (third args) :test)
25              (or (equal (fourth args) '(quote eq))
26                  (equal (fourth args) '(function eq))))
27         `(assq ,(first args) ,(second args)))
28        (t form)))
29
30(define-compiler-macro member (&whole form &rest args)
31  (cond ((and (= (length args) 4)
32              (eq (third args) :test)
33              (or (equal (fourth args) '(quote eq))
34                  (equal (fourth args) '(function eq))))
35         `(memq ,(first args) ,(second args)))
36        ((and (= (length args) 4)
37              (eq (third args) :test)
38              (or (equal (fourth args) '(quote eql))
39                  (equal (fourth args) '(function eql))))
40         `(memql ,(first args) ,(second args)))
41        ((= (length args) 2)
42         `(memql ,(first args) ,(second args)))
43        (t form)))
44
45(define-compiler-macro identity (&whole form &rest args)
46  (if (= (length args) 1)
47      `(progn ,(car args))
48      form))
49
50(in-package "EXTENSIONS")
51
52(export '(precompile-form precompile))
53
54(unless (find-package "PRECOMPILER")
55  (make-package "PRECOMPILER"
56                :nicknames '("PRE")
57                :use '("COMMON-LISP" "EXTENSIONS")))
58
59(in-package "PRECOMPILER")
60
61(defvar *in-jvm-compile* nil)
62
63(defun precompile-identity (form)
64  form)
65
66(defun precompile-cons (form)
67  (cons (car form) (mapcar #'precompile1 (cdr form))))
68
69(defun precompile-block (form)
70  (let ((args (cdr form)))
71    (if (null (cdr args))
72        nil
73        (list* 'BLOCK (car args) (mapcar #'precompile1 (cdr args))))))
74
75(defun precompile-dolist (form)
76  (cons 'DOLIST (cons (cadr form) (mapcar #'precompile1 (cddr form)))))
77
78(defun precompile-dotimes (form)
79  (cons 'DOTIMES (cons (cadr form) (mapcar #'precompile1 (cddr form)))))
80
81(defun precompile-do/do* (form)
82  (list* (car form) (cadr form) (caddr form)
83         (mapcar #'precompile1 (cdddr form))))
84
85(defun precompile-do-symbols (form)
86   (list* (car form) (cadr form) (mapcar #'precompile1 (cddr form))))
87
88(defun precompile-progn (form)
89   (let ((body (cdr form)))
90     (if (= (length body) 1)
91         (let ((res (precompile1 (car body))))
92           ;; If the result turns out to be a bare symbol, leave it wrapped
93           ;; with PROGN so it won't be mistaken for a tag in an enclosing
94           ;; TAGBODY.
95           (if (symbolp res)
96               (list 'progn res)
97               res))
98         (cons 'PROGN (mapcar #'precompile1 body)))))
99
100(defun precompile-progv (form)
101   (list* 'PROGV (cadr form) (caddr form) (mapcar #'precompile1 (cdddr form))))
102
103(defun precompile-setq (form)
104  (let* ((args (cdr form))
105        (len (length args)))
106    (when (oddp len)
107      (error "odd number of arguments to SETQ"))
108    (if (= len 2)
109        (list 'SETQ (car args) (precompile1 (cadr args)))
110        (let ((result ()))
111          (loop
112            (when (null args)
113              (return))
114            (push (list 'SETQ (car args) (precompile1 (cadr args))) result)
115            (setq args (cddr args)))
116          (setq result (nreverse result))
117          (push 'PROGN result)
118          result))))
119
120(defun precompile-lambda (form)
121  (let* ((args (cdr form))
122         (lambda-list (car args))
123         (auxvars (memq '&AUX lambda-list)))
124    (if auxvars
125        (append (list 'LAMBDA (subseq lambda-list 0 (position '&AUX lambda-list))
126                      (append (list 'LET*
127                                    (cdr auxvars))
128                              (mapcar #'precompile1 (cdr args)))))
129        (list* 'LAMBDA lambda-list (mapcar #'precompile1 (cdr args))))))
130
131(defun define-local-macro (name lambda-list body)
132  (let* ((form (gensym))
133         (env (gensym))
134         (body (sys::parse-defmacro lambda-list form body name 'macrolet
135                                    :environment env))
136         (expander `(lambda (,form ,env) (block ,name ,body)))
137         (compiled-expander (compile nil expander)))
138    (sys::coerce-to-function (or compiled-expander expander))))
139
140(defvar *local-macros* ())
141
142(defun local-macro-function (name)
143  (getf *local-macros* name))
144
145(defun expand-local-macro (form)
146  (let ((expansion (funcall (local-macro-function (car form)) form nil)))
147    ;; If the expansion turns out to be a bare symbol, wrap it with PROGN so it
148    ;; won't be mistaken for a tag in an enclosing TAGBODY.
149    (if (symbolp expansion)
150        (list 'progn expansion)
151        expansion)))
152
153(defun precompile-macrolet (form)
154  (let ((*local-macros* *local-macros*)
155        (macros (cadr form))
156        (body (cddr form))
157        (res ())
158        compiled-body)
159    (dolist (macro macros)
160      (let ((name (car macro))
161            (lambda-list (cadr macro))
162            (forms (cddr macro)))
163        (push (define-local-macro name lambda-list forms) *local-macros*)
164        (push name *local-macros*)
165        (push (list* name lambda-list (mapcar #'precompile1 forms)) res)))
166    (setf compiled-body (mapcar #'precompile1 body))
167    (setf res (list* 'PROGN compiled-body))
168    res))
169
170(defun precompile-let/let*-vars (vars)
171  (let ((result nil))
172    (dolist (var vars)
173      (if (consp var)
174          (let* ((v (car var))
175                 (expr (cadr var)))
176            (unless (symbolp v)
177              (error 'type-error))
178            (push (list v (precompile1 expr)) result))
179          (push var result)))
180    (nreverse result)))
181
182(defun precompile-let/let* (form)
183  (list* (car form)
184         (precompile-let/let*-vars (cadr form))
185         (mapcar #'precompile1 (cddr form))))
186
187(defun precompile-case (form)
188  (let* ((keyform (cadr form))
189         (clauses (cddr form))
190         (result (list (precompile1 keyform))))
191    (dolist (clause clauses)
192      (push (precompile-case-clause clause) result))
193    (cons (car form) (nreverse result))))
194
195(defun precompile-case-clause (clause)
196  (let ((keys (car clause))
197        (forms (cdr clause)))
198    (cons keys (mapcar #'precompile1 forms))))
199
200(defun precompile-cond (form)
201  (let ((clauses (cdr form))
202        (result nil))
203    (dolist (clause clauses)
204      (push (precompile-cond-clause clause) result))
205    (cons 'COND (nreverse result))))
206
207(defun precompile-cond-clause (clause)
208  (let ((test (car clause))
209        (forms (cdr clause)))
210    (cons (precompile1 test) (mapcar #'precompile1 forms))))
211
212(defun precompile-local-function-def (def)
213  (let ((name (car def))
214        (arglist (cadr def))
215        (body (cddr def)))
216    (list* name arglist (mapcar #'precompile1 body))))
217
218(defun precompile-local-functions (defs)
219  (let ((result nil))
220    (dolist (def defs)
221      (setq result (append result (list (precompile-local-function-def def)))))
222    result))
223
224(defun precompile-flet/labels (form)
225  (let ((locals (cadr form))
226        (body (cddr form)))
227    (list* (car form)
228           (precompile-local-functions locals)
229           (mapcar #'precompile1 body))))
230
231(defun precompile-function (form)
232  (if (and (consp (cadr form)) (eq (caadr form) 'LAMBDA))
233      (list 'FUNCTION (precompile-lambda (cadr form)))
234      form))
235
236(defun precompile-if (form)
237  (let ((args (cdr form)))
238    (case (length args)
239      (2
240       (let ((test (precompile1 (car args))))
241         (cond ((null test)
242                nil)
243               ((constantp test)
244                (precompile1 (cadr args)))
245               (t
246                (list 'IF
247                      test
248                      (precompile1 (cadr args)))))))
249      (3
250       (let ((test (precompile1 (car args))))
251         (cond ((null test)
252                (precompile1 (caddr args)))
253               ((constantp test)
254                (precompile1 (cadr args)))
255               (t
256                (list 'IF
257                      test
258                      (precompile1 (cadr args))
259                      (precompile1 (caddr args)))))))
260      (t
261       (error "wrong number of arguments for IF")))))
262
263(defun precompile-multiple-value-bind (form)
264  (let ((vars (cadr form))
265        (values-form (caddr form))
266        (body (cdddr form)))
267    (list* 'MULTIPLE-VALUE-BIND
268           vars
269           (precompile1 values-form)
270           (mapcar #'precompile1 body))))
271
272(defun precompile-multiple-value-list (form)
273   (list 'MULTIPLE-VALUE-LIST (precompile1 (cadr form))))
274
275(defun precompile-return (form)
276   (list 'RETURN (precompile1 (cadr form))))
277
278(defun precompile-return-from (form)
279  (list 'RETURN-FROM (cadr form) (precompile1 (caddr form))))
280
281(defun precompile-tagbody (form)
282  (do ((body (cdr form) (cdr body))
283       (result ()))
284      ((null body) (cons 'TAGBODY (nreverse result)))
285    (if (atom (car body))
286        (push (car body) result)
287        (push (precompile1 (car body)) result))))
288
289(defun precompile-the (form)
290  (precompile1 (caddr form)))
291
292(defun precompile-unwind-protect (form)
293   (list* 'UNWIND-PROTECT
294          (precompile1 (cadr form))
295          (mapcar #'precompile1 (cddr form))))
296
297;; EXPAND-MACRO is like MACROEXPAND, but EXPAND-MACRO quits if *in-jvm-compile*
298;; is false and a macro is encountered that's also implemented as a special
299;; operator, so interpreted code can use the special operator implementation.
300(defun expand-macro (form)
301  (loop
302    (unless *in-jvm-compile*
303      (when (and (consp form)
304                 (symbolp (car form))
305                 (special-operator-p (car form)))
306        (return-from expand-macro form)))
307    (multiple-value-bind (result expanded) (macroexpand-1 form)
308      (unless expanded
309        (return-from expand-macro result))
310      (setf form result))))
311
312;;; From OpenMCL.
313(defun compiler-macroexpand-1 (form &optional env)
314  (let ((expander nil)
315        (newdef nil))
316    (if (and (consp form)
317             (symbolp (car form))
318             (setq expander (compiler-macro-function (car form) env)))
319        (values (setq newdef (funcall expander form env))
320                (not (eq newdef form)))
321        (values form
322                nil))))
323
324(defun compiler-macroexpand (form &optional env)
325  (let ((expanded-p nil))
326    (loop
327      (multiple-value-bind (expansion exp-p) (compiler-macroexpand-1 form env)
328        (if exp-p
329            (setf form expansion expanded-p t)
330            (return))))
331    (values form expanded-p)))
332
333(defun precompile1 (form)
334  (if (atom form)
335      form
336      (let ((op (car form)))
337        (when (symbolp op)
338          (cond ((local-macro-function op)
339                 (let ((result (expand-local-macro form)))
340                   (if (equal result form)
341                       (return-from precompile1 result)
342                       (return-from precompile1 (precompile1 result)))))
343                ((compiler-macro-function op)
344                 (let ((result (compiler-macroexpand form)))
345                   (if (equal result form)
346                       (return-from precompile1 result)
347                       (return-from precompile1 (precompile1 result)))))
348                ((and (not (eq op 'LAMBDA))
349                      (macro-function op))
350                 ;; It's a macro...
351                 (unless (and (special-operator-p op) (not *in-jvm-compile*))
352                   (let ((result (expand-macro form)))
353                     (return-from precompile1 (precompile1 result))))))
354          (let ((handler (get op 'precompile-handler)))
355            (when handler
356              (return-from precompile1 (funcall handler form)))))
357        (when (and (symbolp op) (special-operator-p op))
358          (format t "PRECOMPILE1: unsupported special operator ~S~%" op))
359        (precompile-cons form))))
360
361(defun precompile-form (form in-jvm-compile)
362  (let ((*in-jvm-compile* in-jvm-compile))
363    (precompile1 form)))
364
365(defun install-handler (fun &optional handler)
366  (let ((handler (or handler
367                     (find-symbol (concatenate 'string "PRECOMPILE-"
368                                               (symbol-name fun))
369                                  'precompiler))))
370    (unless (and handler (fboundp handler))
371      (error "no handler for ~S" fun))
372    (setf (get fun 'precompile-handler) handler)))
373
374(mapcar #'install-handler '(block
375                            case
376                            cond
377                            dolist
378                            dotimes
379                            function
380                            if
381                            lambda
382                            macrolet
383                            multiple-value-bind
384                            multiple-value-list
385                            progn
386                            progv
387                            return
388                            return-from
389                            setq
390                            tagbody
391                            the
392                            unwind-protect))
393
394(install-handler 'ecase                'precompile-case)
395
396(install-handler 'and                  'precompile-cons)
397(install-handler 'locally              'precompile-cons)
398(install-handler 'multiple-value-call  'precompile-cons)
399(install-handler 'multiple-value-prog1 'precompile-cons)
400(install-handler 'or                   'precompile-cons)
401(install-handler 'unless               'precompile-cons)
402(install-handler 'when                 'precompile-cons)
403
404(install-handler 'do                   'precompile-do/do*)
405(install-handler 'do*                  'precompile-do/do*)
406
407(install-handler 'flet                 'precompile-flet/labels)
408(install-handler 'labels               'precompile-flet/labels)
409
410(install-handler 'do-symbols           'precompile-do-symbols)
411(install-handler 'do-external-symbols  'precompile-do-symbols)
412
413(install-handler 'let                  'precompile-let/let*)
414(install-handler 'let*                 'precompile-let/let*)
415
416(install-handler 'catch                'precompile-identity)
417(install-handler 'declare              'precompile-identity)
418(install-handler 'go                   'precompile-identity)
419(install-handler 'handler-bind         'precompile-identity)
420(install-handler 'handler-case         'precompile-identity)
421(install-handler 'nth-value            'precompile-identity)
422(install-handler 'quote                'precompile-identity)
423(install-handler 'throw                'precompile-identity)
424
425(in-package "SYSTEM")
426
427(defun precompile (name &optional definition)
428  (unless definition
429    (setq definition (or (and (symbolp name) (macro-function name))
430                         (fdefinition name))))
431  (let (expr result)
432    (cond ((functionp definition)
433           (multiple-value-bind (form closure-p)
434             (function-lambda-expression definition)
435             (unless form
436               (format t "; No lambda expression available for ~S.~%" name)
437               (return-from precompile (values nil t t)))
438             (when closure-p
439               (format t "; Unable to compile function ~S defined in non-null lexical environment.~%" name)
440               (finish-output)
441               (return-from precompile (values nil t t)))
442             (setq expr form)))
443          ((and (consp definition) (eq (car definition) 'lambda))
444           (setq expr definition))
445          (t
446           (error 'type-error)))
447    (setf result (coerce-to-function (precompile-form expr nil)))
448    (when (and name (functionp result))
449      (%set-lambda-name result name)
450      (%set-call-count result (%call-count definition))
451      (%set-arglist result (arglist definition))
452      (if (and (symbolp name) (macro-function name))
453          (setf (fdefinition name) (make-macro result))
454          (setf (fdefinition name) result)))
455    (values (or name result) nil nil)))
456
457(defun precompile-package (pkg &key verbose)
458  (dolist (sym (package-symbols pkg))
459    (when (fboundp sym)
460      (unless (special-operator-p sym)
461        (let ((f (fdefinition sym)))
462          (unless (compiled-function-p f)
463            (when verbose
464              (format t "compiling ~S~%" sym)
465              (finish-output))
466            (precompile sym))))))
467  t)
468
469(precompile-package "PRECOMPILER")
470(precompile-package "EXTENSIONS")
471(precompile-package "SYSTEM")
472(precompile-package "COMMON-LISP")
473
474(defun compile (name &optional definition)
475  (if (and name (fboundp name) (typep (symbol-function name) 'generic-function))
476      (values name nil nil)
477      (precompile name definition)))
478
479;; Redefine DEFMACRO to compile the expansion function on the fly.
480(defmacro defmacro (name lambda-list &rest body)
481  (let* ((form (gensym))
482         (env (gensym))
483         (body (parse-defmacro lambda-list form body name 'defmacro
484                               :environment env))
485         (expander `(lambda (,form ,env) (block ,name ,body))))
486    `(progn
487       (if (special-operator-p ',name)
488           (%put ',name
489                 'macroexpand-macro
490                 (make-macro (or (precompile nil ,expander) ,expander)))
491           (fset ',name
492                 (make-macro (or (precompile nil ,expander) ,expander))))
493       ',name)))
494
495;; Make an exception just this one time...
496(fset 'defmacro (get 'defmacro 'macroexpand-macro))
497
498;; Redefine DEFUN to compile the definition on the fly.
499(defmacro defun (name lambda-list &rest body &environment env)
500  `(progn
501     (%defun ',name ',lambda-list ',body ,env)
502     (precompile ',name)
503     ',name))
Note: See TracBrowser for help on using the repository browser.