source: trunk/j/src/org/armedbear/lisp/print-object.lisp @ 6497

Last change on this file since 6497 was 6497, checked in by piso, 17 years ago

(defmethod print-object ((c simple-condition) stream)

File size: 3.5 KB
Line 
1;;; print-object.lisp
2;;;
3;;; Copyright (C) 2003-2004 Peter Graves
4;;; $Id: print-object.lisp,v 1.6 2004-04-15 15:46:54 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20(in-package "SYSTEM")
21
22(require 'clos)
23
24(when (autoloadp 'print-object)
25  (fmakunbound 'print-object))
26
27(defgeneric print-object (instance stream))
28
29(defmethod print-object ((x t) stream)
30  (print-unreadable-object (x stream :type t :identity t)))
31
32(defmethod print-object ((instance standard-object) stream)
33  (print-unreadable-object (instance stream :identity t)
34                           (format stream "~S"
35                                   (class-name (class-of instance))))
36  instance)
37
38(defmethod print-object ((class standard-class) stream)
39  (print-unreadable-object (class stream :identity t)
40                           (format stream "~S ~S"
41                                   (class-name (class-of class))
42                                   (class-name class)))
43  class)
44
45(defmethod print-object ((gf standard-generic-function) stream)
46  (print-unreadable-object (gf stream :identity t)
47                           (format stream "~S ~S"
48                                   (class-name (class-of gf))
49                                   (generic-function-name gf)))
50  gf)
51
52(defmethod print-object ((method standard-method) stream)
53  (print-unreadable-object (method stream :identity t)
54                           (format stream "~S ~S~{ ~S~} ~S"
55                                   (class-name (class-of method))
56                                   (generic-function-name
57                                    (method-generic-function method))
58                                   (method-qualifiers method)
59                                   (mapcar #'class-name
60                                           (method-specializers method))))
61  method)
62
63(defmethod print-object ((restart restart) stream)
64  (if *print-escape*
65      (print-unreadable-object (restart stream :type t :identity t)
66                               (prin1 (restart-name restart) stream))
67      (restart-report restart stream)))
68
69(defmethod print-object ((c condition) stream)
70  (if *print-escape*
71      (call-next-method)
72      (let ((report (condition-report c)))
73        (cond ((stringp report)
74               (write-string report stream))
75              (t
76               (%format stream "~A" c))))))
77
78(defmethod print-object ((c simple-condition) stream)
79  (if *print-escape*
80      (call-next-method)
81      (let ((format-control (simple-condition-format-control c)))
82        (if format-control
83            (apply #'format stream format-control
84                   (simple-condition-format-arguments c))
85            (call-next-method)))))
86
87(defmethod print-object ((x undefined-function) stream)
88  (if *print-escape*
89      (call-next-method)
90      (format stream "The function ~S is undefined." (cell-error-name x))))
91
92(provide 'print-object)
Note: See TracBrowser for help on using the repository browser.