source: trunk/j/src/org/armedbear/lisp/top-level.lisp @ 4578

Last change on this file since 4578 was 4578, checked in by piso, 18 years ago

INSPECT-COMMAND

File size: 8.1 KB
Line 
1;;; top-level.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: top-level.lisp,v 1.11 2003-10-30 18:40:53 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20;;; Adapted from SB-ACLREPL (originally written by Kevin Rosenberg).
21
22;;; A few things we're gonna be needing...
23(mapc #'sys::resolve '(sort position break write make-sequence))
24
25(in-package "EXTENSIONS")
26
27(export '(*saved-backtrace*))
28
29(defvar *saved-backtrace* nil)
30
31(in-package "TOP-LEVEL")
32
33(defvar *break-level* 0)
34
35(defparameter *command-char* #\:)
36
37(defvar *cmd-number* 1
38  "Number of the next command")
39
40(defun prompt-package-name ()
41  (car (sort (append
42              (package-nicknames cl:*package*)
43              (list (package-name cl:*package*)))
44             (lambda (a b) (< (length a) (length b))))))
45
46(defun repl-prompt-fun (stream)
47  (fresh-line stream)
48  (when (> *break-level* 0)
49    (format stream "[~D] " *break-level*))
50  (format stream "~A(~D): " (prompt-package-name) *cmd-number*))
51
52(defparameter *repl-prompt-fun* #'repl-prompt-fun)
53
54(defun peek-char-non-whitespace (stream)
55  (loop
56    (let ((c (read-char stream nil)))
57      (unless (eql c #\Space)
58        (unread-char c stream)
59        (return c)))))
60
61(defun read-cmd (stream)
62  (let ((c (peek-char-non-whitespace stream)))
63    (if (eql c *command-char*)
64        (read-line stream)
65        (read stream nil))))
66
67(defun apropos-command (args)
68  (when args (apropos args)))
69
70(defun backtrace-command (args)
71  (let ((count (or (and args (ignore-errors (parse-integer args)))
72                   most-positive-fixnum))
73        (n 0))
74    (dolist (frame *saved-backtrace*)
75      (format t "  ~D: ~S~%" n frame)
76      (incf n)
77      (when (>= n count)
78        (return))))
79  (values))
80
81(defun continue-command (ignored)
82  (if (> *break-level* 0)
83      (throw 'continue-catcher nil)))
84
85(defun describe-command (args)
86  (let ((obj (eval (read-from-string args))))
87    (describe obj)))
88
89(defun inspect-command (args)
90  (let ((obj (eval (read-from-string args))))
91    (inspect obj)))
92
93(defun macroexpand-command (args)
94  (format t "~S~%" (macroexpand (read-from-string args)))
95  (values))
96
97(defun package-command (args)
98  (cond ((null args)
99         (format *standard-output* "The ~A package is current.~%"
100                 (package-name *package*)))
101        (t
102         (when (and (plusp (length args)) (eql (char args 0) #\:))
103           (setf args (subseq args 1)))
104         (setf args (nstring-upcase args))
105         (let ((pkg (find-package args)))
106           (if pkg
107               (setf *package* pkg)
108               (format *standard-output* "Unknown package ~A.~%" args))))))
109
110(defun reset-command (ignored)
111  (throw 'top-level-catcher nil))
112
113(defun exit-command (ignored)
114  (exit))
115
116(defun cd-command (args)
117  (cond ((or (null args) (string= args "~"))
118         (setf args (namestring (user-homedir-pathname))))
119        ((and (> (length args) 1) (string= (subseq args 0 2) "~/")
120              (setf args (concatenate 'string
121                                      (namestring (user-homedir-pathname))
122                                      (subseq args 2))))))
123  (let ((dir (probe-directory args)))
124    (if dir
125        (progn
126          (setf *default-pathname-defaults* dir)
127          (format t "~A" (namestring *default-pathname-defaults*)))
128        (format t "Error: no such directory (~S).~%" args))))
129
130(defvar *last-files-loaded* nil)
131
132(defun tokenize (string)
133  (do* ((res nil)
134        (string (string-left-trim " " string)
135                (string-left-trim " " (subseq string end)))
136        (end (position #\Space string) (position #\Space string)))
137       ((zerop (length string)) (nreverse res))
138    (unless end
139      (setf end (length string)))
140    (push (subseq string 0 end) res)))
141
142(defun ld-command (args)
143  (let ((files (if args (tokenize args) *last-files-loaded*)))
144    (setf *last-files-loaded* files)
145    (dolist (file files)
146      (load file))))
147
148(defun pwd-command (ignored)
149  (format t "~A~%" *default-pathname-defaults*))
150
151(defconstant spaces (make-string 32 :initial-element #\space))
152
153(defun pad (string width)
154  (if (< (length string) width)
155      (concatenate 'string string (subseq spaces 0 (- width (length string))))
156      string))
157
158(defun help-command (ignored)
159  (format t "~%  COMMAND     ABBR DESCRIPTION~%")
160  (dolist (entry *command-table*)
161    (format t "  ~A~A~A~%"
162            (pad (entry-name entry) 12)
163            (pad (entry-abbr entry) 5)
164            (entry-help entry)
165            ))
166  (format t "~%Commands must be prefixed by the command character, which is '~A' by default.~%~%"
167          *command-char*))
168
169(defparameter *command-table*
170  '(("apropos" 2 apropos-command "show apropos")
171    ("bt" 2 backtrace-command "backtrace n stack frames (default all)")
172    ("cd" 2 cd-command "change default directory")
173    ("continue" 4 continue-command "return from break")
174    ("describe" 2 describe-command "describe an object")
175    ("exit" 2 exit-command "exit lisp")
176    ("help" 2 help-command "print this help")
177    ("inspect" 2 inspect-command "inspect an object")
178    ("ld" 2 ld-command "load a file")
179    ("macroexpand" 2 macroexpand-command "macroexpand an expression")
180    ("package" 2 package-command "change current package")
181    ("pwd" 3 pwd-command "print current directory")
182    ("reset" 3 reset-command "return to top level")
183    ))
184
185(defun entry-name (entry)
186  (first entry))
187
188(defun entry-min-len (entry)
189  (second entry))
190
191(defun entry-abbr (entry)
192  (if (< (entry-min-len entry) (length (entry-name entry)))
193      (subseq (entry-name entry) 0 (entry-min-len entry))
194      ""))
195
196(defun entry-command (entry)
197  (third entry))
198
199(defun entry-help (entry)
200  (fourth entry))
201
202(defun find-command (string)
203  (let ((len (length string)))
204    (dolist (entry *command-table*)
205      (let ((min-len (entry-min-len entry)))
206        (when (and (>= len min-len)
207                   (string-equal (entry-name entry) string :end1 len))
208          (return (entry-command entry)))))))
209
210(defun process-cmd (form)
211  (when (and (stringp form) (> (length form) 1) (eql (char form 0) *command-char*))
212    (let* ((pos (position #\Space form))
213           (cmd (subseq form 1 pos))
214           (args (if pos (subseq form (1+ pos)) nil)))
215      (when args
216        (setf args (string-trim " " args))
217        (when (zerop (length args))
218          (setf args nil)))
219      (let ((fun (find-command cmd)))
220        (if fun
221            (funcall fun args)
222            (format t "Unknown top-level command ~S.~%" cmd)))
223      (return-from process-cmd t)))
224  nil)
225
226(defun repl-read-form-fun (in out)
227  (loop
228    (let ((form (read-cmd in)))
229      (setf (charpos out) 0)
230      (incf *cmd-number*)
231      (cond ((process-cmd form)
232             (funcall *repl-prompt-fun* *standard-output*)
233             (finish-output *standard-output*))
234            (t
235             (return form))))))
236
237(defparameter *repl-read-form-fun* #'repl-read-form-fun)
238
239(defun repl ()
240  (loop
241    (funcall *repl-prompt-fun* *standard-output*)
242    (finish-output *standard-output*)
243    (let* ((form (funcall *repl-read-form-fun*
244                          *standard-input*
245                          *standard-output*))
246           (results (multiple-value-list (sys::interactive-eval form))))
247      (dolist (result results)
248        (fresh-line)
249        (prin1 result)))))
250
251(defun top-level-loop ()
252  (fresh-line)
253  (format t "Type :HELP for a list of top-level commands.~%")
254  (loop
255    (catch 'top-level-catcher
256      (handler-case
257          (repl)
258        #+j (stream-error (c) (return-from top-level-loop)) ; FIXME
259        (error (c) (format t "Error: ~S.~%" c) (break) (throw 'top-level-catcher nil))))))
Note: See TracBrowser for help on using the repository browser.