source: trunk/j/src/org/armedbear/lisp/top-level.lisp @ 5162

Last change on this file since 5162 was 5162, checked in by piso, 18 years ago

TPL::*BREAK-LEVEL* => EXT:*DEBUG-LEVEL*

File size: 8.2 KB
Line 
1;;; top-level.lisp
2;;;
3;;; Copyright (C) 2003 Peter Graves
4;;; $Id: top-level.lisp,v 1.21 2003-12-16 14:38:11 piso Exp $
5;;;
6;;; This program is free software; you can redistribute it and/or
7;;; modify it under the terms of the GNU General Public License
8;;; as published by the Free Software Foundation; either version 2
9;;; of the License, or (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
19
20;;; Adapted from SB-ACLREPL (originally written by Kevin Rosenberg).
21
22(in-package "TOP-LEVEL")
23
24(import 'sys::%format)
25
26(defparameter *command-char* #\:)
27
28(defvar *cmd-number* 1
29  "Number of the next command")
30
31(defun prompt-package-name ()
32  (let ((result (package-name *package*)))
33    (dolist (nickname (package-nicknames *package*))
34      (when (< (length nickname) (length result))
35        (setf result nickname)))
36    result))
37
38(defun repl-prompt-fun (stream)
39  (fresh-line stream)
40  (when (> *debug-level* 0)
41    (%format stream "[~D] " *debug-level*))
42  (%format stream "~A(~D): " (prompt-package-name) *cmd-number*))
43
44(defparameter *repl-prompt-fun* #'repl-prompt-fun)
45
46(defun peek-char-non-whitespace (stream)
47  (loop
48    (let ((c (read-char stream nil)))
49      (unless (eql c #\Space)
50        (unread-char c stream)
51        (return c)))))
52
53(defun read-cmd (stream)
54  (let ((c (peek-char-non-whitespace stream)))
55    (if (eql c *command-char*)
56        (read-line stream)
57        (read stream nil))))
58
59(defun apropos-command (args)
60  (when args (apropos args)))
61
62(defun backtrace-command (args)
63  (let ((count (or (and args (ignore-errors (parse-integer args)))
64                   most-positive-fixnum))
65        (n 0))
66    (dolist (frame *saved-backtrace*)
67      (%format t "  ~D: ~S~%" n frame)
68      (incf n)
69      (when (>= n count)
70        (return))))
71  (values))
72
73(defun continue-command (ignored)
74  (if (> *debug-level* 0)
75      (throw 'continue-catcher nil)))
76
77(defun describe-command (args)
78  (let ((obj (eval (read-from-string args))))
79    (describe obj)))
80
81(defun inspect-command (args)
82  (let ((obj (eval (read-from-string args))))
83    (inspect obj)))
84
85(defun macroexpand-command (args)
86  (format t "~S~%" (macroexpand (read-from-string args)))
87  (values))
88
89(defvar *old-package* nil)
90
91(defun package-command (args)
92  (cond ((null args)
93         (format *standard-output* "The ~A package is current.~%"
94                 (package-name *package*)))
95        ((and *old-package* (string= args "-") (null (find-package "-")))
96         (rotatef *old-package* *package*))
97        (t
98         (when (and (plusp (length args)) (eql (char args 0) #\:))
99           (setf args (subseq args 1)))
100         (setf args (nstring-upcase args))
101         (let ((pkg (find-package args)))
102           (if pkg
103               (setf *old-package* *package*
104                     *package* pkg)
105               (format *standard-output* "Unknown package ~A.~%" args))))))
106
107(defun reset-command (ignored)
108  (throw 'top-level-catcher nil))
109
110(defun exit-command (ignored)
111  (exit))
112
113(defun cd-command (args)
114  (cond ((or (null args) (string= args "~"))
115         (setf args (namestring (user-homedir-pathname))))
116        ((and (> (length args) 1) (string= (subseq args 0 2) "~/")
117              (setf args (concatenate 'string
118                                      (namestring (user-homedir-pathname))
119                                      (subseq args 2))))))
120  (let ((dir (probe-directory args)))
121    (if dir
122        (progn
123          (setf *default-pathname-defaults* dir)
124          (format t "~A" (namestring *default-pathname-defaults*)))
125        (format t "Error: no such directory (~S).~%" args))))
126
127(defvar *last-files-loaded* nil)
128
129(defun tokenize (string)
130  (do* ((res nil)
131        (string (string-left-trim " " string)
132                (string-left-trim " " (subseq string end)))
133        (end (position #\Space string) (position #\Space string)))
134       ((zerop (length string)) (nreverse res))
135    (unless end
136      (setf end (length string)))
137    (push (subseq string 0 end) res)))
138
139(defun ld-command (args)
140  (let ((files (if args (tokenize args) *last-files-loaded*)))
141    (setf *last-files-loaded* files)
142    (dolist (file files)
143      (load file))))
144
145(defun pwd-command (ignored)
146  (format t "~A~%" *default-pathname-defaults*))
147
148(defconstant spaces (make-string 32 :initial-element #\space))
149
150(defun pad (string width)
151  (if (< (length string) width)
152      (concatenate 'string string (subseq spaces 0 (- width (length string))))
153      string))
154
155(defun help-command (ignored)
156  (format t "~%  COMMAND     ABBR DESCRIPTION~%")
157  (dolist (entry *command-table*)
158    (format t "  ~A~A~A~%"
159            (pad (entry-name entry) 12)
160            (pad (entry-abbr entry) 5)
161            (entry-help entry)
162            ))
163  (format t "~%Commands must be prefixed by the command character, which is '~A' by default.~%~%"
164          *command-char*))
165
166(defparameter *command-table*
167  '(("apropos" 2 apropos-command "show apropos")
168    ("bt" 2 backtrace-command "backtrace n stack frames (default all)")
169    ("cd" 2 cd-command "change default directory")
170    ("continue" 4 continue-command "return from break")
171    ("describe" 2 describe-command "describe an object")
172    ("exit" 2 exit-command "exit lisp")
173    ("help" 2 help-command "print this help")
174    ("inspect" 2 inspect-command "inspect an object")
175    ("ld" 2 ld-command "load a file")
176    ("macroexpand" 2 macroexpand-command "macroexpand an expression")
177    ("package" 2 package-command "change current package")
178    ("pwd" 3 pwd-command "print current directory")
179    ("reset" 3 reset-command "return to top level")
180    ))
181
182(defun entry-name (entry)
183  (first entry))
184
185(defun entry-min-len (entry)
186  (second entry))
187
188(defun entry-abbr (entry)
189  (if (< (entry-min-len entry) (length (entry-name entry)))
190      (subseq (entry-name entry) 0 (entry-min-len entry))
191      ""))
192
193(defun entry-command (entry)
194  (third entry))
195
196(defun entry-help (entry)
197  (fourth entry))
198
199(defun find-command (string)
200  (let ((len (length string)))
201    (dolist (entry *command-table*)
202      (let ((min-len (entry-min-len entry)))
203        (when (and (>= len min-len)
204                   (string-equal (entry-name entry) string :end1 len))
205          (return (entry-command entry)))))))
206
207(defun process-cmd (form)
208  (when (and (stringp form) (> (length form) 1) (eql (char form 0) *command-char*))
209    (let* ((pos (position #\Space form))
210           (cmd (subseq form 1 pos))
211           (args (if pos (subseq form (1+ pos)) nil)))
212      (when args
213        (setf args (string-trim " " args))
214        (when (zerop (length args))
215          (setf args nil)))
216      (let ((fun (find-command cmd)))
217        (if fun
218            (funcall fun args)
219            (%format t "Unknown top-level command ~S.~%" cmd)))
220      (return-from process-cmd t)))
221  nil)
222
223(defun repl-read-form-fun (in out)
224  (loop
225    (let ((form (read-cmd in)))
226      (setf (charpos out) 0)
227      (incf *cmd-number*)
228      (cond ((process-cmd form)
229             (funcall *repl-prompt-fun* *standard-output*)
230             (finish-output *standard-output*))
231            (t
232             (return form))))))
233
234(defparameter *repl-read-form-fun* #'repl-read-form-fun)
235
236(defun repl ()
237  (loop
238    (funcall *repl-prompt-fun* *standard-output*)
239    (finish-output *standard-output*)
240    (let* ((form (funcall *repl-read-form-fun*
241                          *standard-input*
242                          *standard-output*))
243           (results (multiple-value-list (sys::interactive-eval form))))
244      (dolist (result results)
245        (fresh-line)
246        (prin1 result)))))
247
248(defun top-level-loop ()
249  (fresh-line)
250  (%format t "Type :HELP for a list of top-level commands.~%")
251  (loop
252    (catch 'top-level-catcher
253      (handler-case
254          (repl)
255        #+j (stream-error (c) (return-from top-level-loop)) ; FIXME
256        (error (c)
257               (invoke-debugger c)
258               (throw 'top-level-catcher nil))))))
Note: See TracBrowser for help on using the repository browser.